IkiWiki/Plugin/aggregate.pm

   1 #!/usr/bin/perl
   2 # Feed aggregation plugin.
   3 package IkiWiki::Plugin::aggregate;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8 use HTML::Parser;
   9 use HTML::Tagset;
  10 use HTML::Entities;
  11 use URI;
  12 use open qw{:utf8 :std};
  13
  14 my %feeds;
  15 my %guids;
  16
  17 sub import {
  18         hook(type => "getopt", id => "aggregate", call => \&getopt);
  19         hook(type => "getsetup", id => "aggregate", call => \&getsetup);
  20         hook(type => "checkconfig", id => "aggregate", call => \&checkconfig);
  21         hook(type => "needsbuild", id => "aggregate", call => \&needsbuild);
  22         hook(type => "preprocess", id => "aggregate", call => \&preprocess);
  23         hook(type => "delete", id => "aggregate", call => \&delete);
  24         hook(type => "savestate", id => "aggregate", call => \&savestate);
  25         hook(type => "htmlize", id => "_aggregated", call => \&htmlize);
  26         if (exists $config{aggregate_webtrigger} && $config{aggregate_webtrigger}) {
  27                 hook(type => "cgi", id => "aggregate", call => \&cgi);
  28         }
  29 }
  30
  31 sub getopt () {
  32         eval q{use Getopt::Long};
  33         error($@) if $@;
  34         Getopt::Long::Configure('pass_through');
  35         GetOptions(
  36                 "aggregate" => \$config{aggregate},
  37                 "aggregateinternal!" => \$config{aggregateinternal},
  38         );
  39 }
  40
  41 sub getsetup () {
  42         return
  43                 plugin => {
  44                         safe => 1,
  45                         rebuild => undef,
  46                 },
  47                 aggregateinternal => {
  48                         type => "boolean",
  49                         example => 1,
  50                         description => "enable aggregation to internal pages?",
  51                         safe => 0, # enabling needs manual transition
  52                         rebuild => 0,
  53                 },
  54                 aggregate_webtrigger => {
  55                         type => "boolean",
  56                         example => 0,
  57                         description => "allow aggregation to be triggered via the web?",
  58                         safe => 1,
  59                         rebuild => 0,
  60                 },
  61 }
  62
  63 sub checkconfig () {
  64         if (! defined $config{aggregateinternal}) {
  65                 $config{aggregateinternal}=1;
  66         }
  67
  68         if ($config{aggregate} && ! ($config{post_commit} &&
  69                                      IkiWiki::commit_hook_enabled())) {
  70                 launchaggregation();
  71         }
  72 }
  73
  74 sub cgi ($) {
  75         my $cgi=shift;
  76
  77         if (defined $cgi->param('do') &&
  78             $cgi->param("do") eq "aggregate_webtrigger") {
  79                 $|=1;
  80                 print "Content-Type: text/plain\n\n";
  81                 $config{cgi}=0;
  82                 $config{verbose}=1;
  83                 $config{syslog}=0;
  84                 print gettext("Aggregation triggered via web.")."\n\n";
  85                 if (launchaggregation()) {
  86                         IkiWiki::lockwiki();
  87                         IkiWiki::loadindex();
  88                         require IkiWiki::Render;
  89                         IkiWiki::refresh();
  90                         IkiWiki::saveindex();
  91                 }
  92                 else {
  93                         print gettext("Nothing to do right now, all feeds are up-to-date!")."\n";
  94                 }
  95                 exit 0;
  96         }
  97 }
  98
  99 sub launchaggregation () {
 100         # See if any feeds need aggregation.
 101         loadstate();
 102         my @feeds=needsaggregate();
 103         return unless @feeds;
 104         if (! lockaggregate()) {
 105                 debug("an aggregation process is already running");
 106                 return;
 107         }
 108         # force a later rebuild of source pages
 109         $IkiWiki::forcerebuild{$_->{sourcepage}}=1
 110                 foreach @feeds;
 111
 112         # Fork a child process to handle the aggregation.
 113         # The parent process will then handle building the
 114         # result. This avoids messy code to clear state
 115         # accumulated while aggregating.
 116         defined(my $pid = fork) or error("Can't fork: $!");
 117         if (! $pid) {
 118                 IkiWiki::loadindex();
 119                 # Aggregation happens without the main wiki lock
 120                 # being held. This allows editing pages etc while
 121                 # aggregation is running.
 122                 aggregate(@feeds);
 123
 124                 IkiWiki::lockwiki;
 125                 # Merge changes, since aggregation state may have
 126                 # changed on disk while the aggregation was happening.
 127                 mergestate();
 128                 expire();
 129                 savestate();
 130                 IkiWiki::unlockwiki;
 131                 exit 0;
 132         }
 133         waitpid($pid,0);
 134         if ($?) {
 135                 error "aggregation failed with code $?";
 136         }
 137
 138         clearstate();
 139         unlockaggregate();
 140
 141         return 1;
 142 }
 143
 144 #  Pages with extension _aggregated have plain html markup, pass through.
 145 sub htmlize (@) {
 146         my %params=@_;
 147         return $params{content};
 148 }
 149
 150 # Used by ikiwiki-transition aggregateinternal.
 151 sub migrate_to_internal {
 152         if (! lockaggregate()) {
 153                 error("an aggregation process is currently running");
 154         }
 155
 156         IkiWiki::lockwiki();
 157         loadstate();
 158         $config{verbose}=1;
 159
 160         foreach my $data (values %guids) {
 161                 next unless $data->{page};
 162                 next if $data->{expired};
 163
 164                 $config{aggregateinternal} = 0;
 165                 my $oldname = "$config{srcdir}/".htmlfn($data->{page});
 166                 my $oldoutput = $config{destdir}."/".IkiWiki::htmlpage($data->{page});
 167
 168                 $config{aggregateinternal} = 1;
 169                 my $newname = "$config{srcdir}/".htmlfn($data->{page});
 170
 171                 debug "moving $oldname -> $newname";
 172                 if (-e $newname) {
 173                         if (-e $oldname) {
 174                                 error("$newname already exists");
 175                         }
 176                         else {
 177                                 debug("already renamed to $newname?");
 178                         }
 179                 }
 180                 elsif (-e $oldname) {
 181                         rename($oldname, $newname) || error("$!");
 182                 }
 183                 else {
 184                         debug("$oldname not found");
 185                 }
 186                 if (-e $oldoutput) {
 187                         require IkiWiki::Render;
 188                         debug("removing output file $oldoutput");
 189                         IkiWiki::prune($oldoutput);
 190                 }
 191         }
 192
 193         savestate();
 194         IkiWiki::unlockwiki;
 195
 196         unlockaggregate();
 197 }
 198
 199 sub needsbuild (@) {
 200         my $needsbuild=shift;
 201
 202         loadstate();
 203
 204         foreach my $feed (values %feeds) {
 205                 if (exists $pagesources{$feed->{sourcepage}} &&
 206                     grep { $_ eq $pagesources{$feed->{sourcepage}} } @$needsbuild) {
 207                         # Mark all feeds originating on this page as
 208                         # not yet seen; preprocess will unmark those that
 209                         # still exist.
 210                         markunseen($feed->{sourcepage});
 211                 }
 212         }
 213 }
 214
 215 sub preprocess (@) {
 216         my %params=@_;
 217
 218         foreach my $required (qw{name url}) {
 219                 if (! exists $params{$required}) {
 220                         error sprintf(gettext("missing %s parameter"), $required)
 221                 }
 222         }
 223
 224         my $feed={};
 225         my $name=$params{name};
 226         if (exists $feeds{$name}) {
 227                 $feed=$feeds{$name};
 228         }
 229         else {
 230                 $feeds{$name}=$feed;
 231         }
 232         $feed->{name}=$name;
 233         $feed->{sourcepage}=$params{page};
 234         $feed->{url}=$params{url};
 235         my $dir=exists $params{dir} ? $params{dir} : $params{page}."/".titlepage($params{name});
 236         $dir=~s/^\/+//;
 237         ($dir)=$dir=~/$config{wiki_file_regexp}/;
 238         $feed->{dir}=$dir;
 239         $feed->{feedurl}=defined $params{feedurl} ? $params{feedurl} : "";
 240         $feed->{updateinterval}=defined $params{updateinterval} ? $params{updateinterval} * 60 : 15 * 60;
 241         $feed->{expireage}=defined $params{expireage} ? $params{expireage} : 0;
 242         $feed->{expirecount}=defined $params{expirecount} ? $params{expirecount} : 0;
 243         if (exists $params{template}) {
 244                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 245         }
 246         else {
 247                 $params{template} = "aggregatepost"
 248         }
 249         $feed->{template}=$params{template} . ".tmpl";
 250         delete $feed->{unseen};
 251         $feed->{lastupdate}=0 unless defined $feed->{lastupdate};
 252         $feed->{lasttry}=$feed->{lastupdate} unless defined $feed->{lasttry};
 253         $feed->{numposts}=0 unless defined $feed->{numposts};
 254         $feed->{newposts}=0 unless defined $feed->{newposts};
 255         $feed->{message}=gettext("new feed") unless defined $feed->{message};
 256         $feed->{error}=0 unless defined $feed->{error};
 257         $feed->{tags}=[];
 258         while (@_) {
 259                 my $key=shift;
 260                 my $value=shift;
 261                 if ($key eq 'tag') {
 262                         push @{$feed->{tags}}, $value;
 263                 }
 264         }
 265
 266         return "<a href=\"".$feed->{url}."\">".$feed->{name}."</a>: ".
 267                ($feed->{error} ? "<em>" : "").$feed->{message}.
 268                ($feed->{error} ? "</em>" : "").
 269                " (".$feed->{numposts}." ".gettext("posts").
 270                ($feed->{newposts} ? "; ".$feed->{newposts}.
 271                                     " ".gettext("new") : "").
 272                ")";
 273 }
 274
 275 sub delete (@) {
 276         my @files=@_;
 277
 278         # Remove feed data for removed pages.
 279         foreach my $file (@files) {
 280                 my $page=pagename($file);
 281                 markunseen($page);
 282         }
 283 }
 284
 285 sub markunseen ($) {
 286         my $page=shift;
 287
 288         foreach my $id (keys %feeds) {
 289                 if ($feeds{$id}->{sourcepage} eq $page) {
 290                         $feeds{$id}->{unseen}=1;
 291                 }
 292         }
 293 }
 294
 295 my $state_loaded=0;
 296
 297 sub loadstate () {
 298         return if $state_loaded;
 299         $state_loaded=1;
 300         if (-e "$config{wikistatedir}/aggregate") {
 301                 open(IN, "$config{wikistatedir}/aggregate") ||
 302                         die "$config{wikistatedir}/aggregate: $!";
 303                 while (<IN>) {
 304                         $_=IkiWiki::possibly_foolish_untaint($_);
 305                         chomp;
 306                         my $data={};
 307                         foreach my $i (split(/ /, $_)) {
 308                                 my ($field, $val)=split(/=/, $i, 2);
 309                                 if ($field eq "name" || $field eq "feed" ||
 310                                     $field eq "guid" || $field eq "message") {
 311                                         $data->{$field}=decode_entities($val, " \t\n");
 312                                 }
 313                                 elsif ($field eq "tag") {
 314                                         push @{$data->{tags}}, $val;
 315                                 }
 316                                 else {
 317                                         $data->{$field}=$val;
 318                                 }
 319                         }
 320
 321                         if (exists $data->{name}) {
 322                                 $feeds{$data->{name}}=$data;
 323                         }
 324                         elsif (exists $data->{guid}) {
 325                                 $guids{$data->{guid}}=$data;
 326                         }
 327                 }
 328
 329                 close IN;
 330         }
 331 }
 332
 333 sub savestate () {
 334         return unless $state_loaded;
 335         garbage_collect();
 336         my $newfile="$config{wikistatedir}/aggregate.new";
 337         my $cleanup = sub { unlink($newfile) };
 338         open (OUT, ">$newfile") || error("open $newfile: $!", $cleanup);
 339         foreach my $data (values %feeds, values %guids) {
 340                 my @line;
 341                 foreach my $field (keys %$data) {
 342                         if ($field eq "name" || $field eq "feed" ||
 343                             $field eq "guid" || $field eq "message") {
 344                                 push @line, "$field=".encode_entities($data->{$field}, " \t\n");
 345                         }
 346                         elsif ($field eq "tags") {
 347                                 push @line, "tag=$_" foreach @{$data->{tags}};
 348                         }
 349                         else {
 350                                 push @line, "$field=".$data->{$field}
 351                                         if defined $data->{$field};
 352                         }
 353                 }
 354                 print OUT join(" ", @line)."\n" || error("write $newfile: $!", $cleanup);
 355         }
 356         close OUT || error("save $newfile: $!", $cleanup);
 357         rename($newfile, "$config{wikistatedir}/aggregate") ||
 358                 error("rename $newfile: $!", $cleanup);
 359 }
 360
 361 sub garbage_collect () {
 362         foreach my $name (keys %feeds) {
 363                 # remove any feeds that were not seen while building the pages
 364                 # that used to contain them
 365                 if ($feeds{$name}->{unseen}) {
 366                         delete $feeds{$name};
 367                 }
 368         }
 369
 370         foreach my $guid (values %guids) {
 371                 # any guid whose feed is gone should be removed
 372                 if (! exists $feeds{$guid->{feed}}) {
 373                         unlink "$config{srcdir}/".htmlfn($guid->{page})
 374                                 if exists $guid->{page};
 375                         delete $guids{$guid->{guid}};
 376                 }
 377                 # handle expired guids
 378                 elsif ($guid->{expired} && exists $guid->{page}) {
 379                         unlink "$config{srcdir}/".htmlfn($guid->{page});
 380                         delete $guid->{page};
 381                         delete $guid->{md5};
 382                 }
 383         }
 384 }
 385
 386 sub mergestate () {
 387         # Load the current state in from disk, and merge into it
 388         # values from the state in memory that might have changed
 389         # during aggregation.
 390         my %myfeeds=%feeds;
 391         my %myguids=%guids;
 392         clearstate();
 393         loadstate();
 394
 395         # All that can change in feed state during aggregation is a few
 396         # fields.
 397         foreach my $name (keys %myfeeds) {
 398                 if (exists $feeds{$name}) {
 399                         foreach my $field (qw{message lastupdate lasttry
 400                                               numposts newposts error}) {
 401                                 $feeds{$name}->{$field}=$myfeeds{$name}->{$field};
 402                         }
 403                 }
 404         }
 405
 406         # New guids can be created during aggregation.
 407         # It's also possible that guids were removed from the on-disk state
 408         # while the aggregation was in process. That would only happen if
 409         # their feed was also removed, so any removed guids added back here
 410         # will be garbage collected later.
 411         foreach my $guid (keys %myguids) {
 412                 if (! exists $guids{$guid}) {
 413                         $guids{$guid}=$myguids{$guid};
 414                 }
 415         }
 416 }
 417
 418 sub clearstate () {
 419         %feeds=();
 420         %guids=();
 421         $state_loaded=0;
 422 }
 423
 424 sub expire () {
 425         foreach my $feed (values %feeds) {
 426                 next unless $feed->{expireage} || $feed->{expirecount};
 427                 my $count=0;
 428                 my %seen;
 429                 foreach my $item (sort { ($IkiWiki::pagectime{$b->{page}} || 0) <=> ($IkiWiki::pagectime{$a->{page}} || 0) }
 430                                   grep { exists $_->{page} && $_->{feed} eq $feed->{name} }
 431                                   values %guids) {
 432                         if ($feed->{expireage}) {
 433                                 my $days_old = (time - ($IkiWiki::pagectime{$item->{page}} || 0)) / 60 / 60 / 24;
 434                                 if ($days_old > $feed->{expireage}) {
 435                                         debug(sprintf(gettext("expiring %s (%s days old)"),
 436                                                 $item->{page}, int($days_old)));
 437                                         $item->{expired}=1;
 438                                 }
 439                         }
 440                         elsif ($feed->{expirecount} &&
 441                                $count >= $feed->{expirecount}) {
 442                                 debug(sprintf(gettext("expiring %s"), $item->{page}));
 443                                 $item->{expired}=1;
 444                         }
 445                         else {
 446                                 if (! $seen{$item->{page}}) {
 447                                         $seen{$item->{page}}=1;
 448                                         $count++;
 449                                 }
 450                         }
 451                 }
 452         }
 453 }
 454
 455 sub needsaggregate () {
 456         return values %feeds if $config{rebuild};
 457         return grep { time - $_->{lastupdate} >= $_->{updateinterval} } values %feeds;
 458 }
 459
 460 sub aggregate (@) {
 461         eval q{use XML::Feed};
 462         error($@) if $@;
 463         eval q{use URI::Fetch};
 464         error($@) if $@;
 465
 466         foreach my $feed (@_) {
 467                 $feed->{lasttry}=time;
 468                 $feed->{newposts}=0;
 469                 $feed->{message}=sprintf(gettext("last checked %s"),
 470                         displaytime($feed->{lasttry}));
 471                 $feed->{error}=0;
 472
 473                 debug(sprintf(gettext("checking feed %s ..."), $feed->{name}));
 474
 475                 if (! length $feed->{feedurl}) {
 476                         my @urls=XML::Feed->find_feeds($feed->{url});
 477                         if (! @urls) {
 478                                 $feed->{message}=sprintf(gettext("could not find feed at %s"), $feed->{url});
 479                                 $feed->{error}=1;
 480                                 debug($feed->{message});
 481                                 next;
 482                         }
 483                         $feed->{feedurl}=pop @urls;
 484                 }
 485                 my $res=URI::Fetch->fetch($feed->{feedurl});
 486                 if (! $res) {
 487                         $feed->{message}=URI::Fetch->errstr;
 488                         $feed->{error}=1;
 489                         debug($feed->{message});
 490                         next;
 491                 }
 492
 493                 # lastupdate is only set if we were able to contact the server
 494                 $feed->{lastupdate}=$feed->{lasttry};
 495
 496                 if ($res->status == URI::Fetch::URI_GONE()) {
 497                         $feed->{message}=gettext("feed not found");
 498                         $feed->{error}=1;
 499                         debug($feed->{message});
 500                         next;
 501                 }
 502                 my $content=$res->content;
 503                 my $f=eval{XML::Feed->parse(\$content)};
 504                 if ($@) {
 505                         # One common cause of XML::Feed crashing is a feed
 506                         # that contains invalid UTF-8 sequences. Convert
 507                         # feed to ascii to try to work around.
 508                         $feed->{message}.=" ".sprintf(gettext("(invalid UTF-8 stripped from feed)"));
 509                         $f=eval {
 510                                 $content=Encode::decode_utf8($content, 0);
 511                                 XML::Feed->parse(\$content)
 512                         };
 513                 }
 514                 if ($@) {
 515                         # Another possibility is badly escaped entities.
 516                         $feed->{message}.=" ".sprintf(gettext("(feed entities escaped)"));
 517                         $content=~s/\&(?!amp)(\w+);/&amp;$1;/g;
 518                         $f=eval {
 519                                 $content=Encode::decode_utf8($content, 0);
 520                                 XML::Feed->parse(\$content)
 521                         };
 522                 }
 523                 if ($@) {
 524                         $feed->{message}=gettext("feed crashed XML::Feed!")." ($@)";
 525                         $feed->{error}=1;
 526                         debug($feed->{message});
 527                         next;
 528                 }
 529                 if (! $f) {
 530                         $feed->{message}=XML::Feed->errstr;
 531                         $feed->{error}=1;
 532                         debug($feed->{message});
 533                         next;
 534                 }
 535
 536                 foreach my $entry ($f->entries) {
 537                         my $c=$entry->content;
 538                         # atom feeds may have no content, only a summary
 539                         if (! defined $c && ref $entry->summary) {
 540                                 $c=$entry->summary;
 541                         }
 542
 543                         add_page(
 544                                 feed => $feed,
 545                                 copyright => $f->copyright,
 546                                 title => defined $entry->title ? decode_entities($entry->title) : "untitled",
 547                                 link => $entry->link,
 548                                 content => (defined $c && defined $c->body) ? $c->body : "",
 549                                 guid => defined $entry->id ? $entry->id : time."_".$feed->{name},
 550                                 ctime => $entry->issued ? ($entry->issued->epoch || time) : time,
 551                                 base => (defined $c && $c->can("base")) ? $c->base : undef,
 552                         );
 553                 }
 554         }
 555 }
 556
 557 sub add_page (@) {
 558         my %params=@_;
 559
 560         my $feed=$params{feed};
 561         my $guid={};
 562         my $mtime;
 563         if (exists $guids{$params{guid}}) {
 564                 # updating an existing post
 565                 $guid=$guids{$params{guid}};
 566                 return if $guid->{expired};
 567         }
 568         else {
 569                 # new post
 570                 $guid->{guid}=$params{guid};
 571                 $guids{$params{guid}}=$guid;
 572                 $mtime=$params{ctime};
 573                 $feed->{numposts}++;
 574                 $feed->{newposts}++;
 575
 576                 # assign it an unused page
 577                 my $page=titlepage($params{title});
 578                 # escape slashes and periods in title so it doesn't specify
 579                 # directory name or trigger ".." disallowing code.
 580                 $page=~s!([/.])!"__".ord($1)."__"!eg;
 581                 $page=$feed->{dir}."/".$page;
 582                 ($page)=$page=~/$config{wiki_file_regexp}/;
 583                 if (! defined $page || ! length $page) {
 584                         $page=$feed->{dir}."/item";
 585                 }
 586                 my $c="";
 587                 while (exists $IkiWiki::pagecase{lc $page.$c} ||
 588                        -e "$config{srcdir}/".htmlfn($page.$c)) {
 589                         $c++
 590                 }
 591
 592                 # Make sure that the file name isn't too long.
 593                 # NB: This doesn't check for path length limits.
 594                 my $max=POSIX::pathconf($config{srcdir}, &POSIX::_PC_NAME_MAX);
 595                 if (defined $max && length(htmlfn($page)) >= $max) {
 596                         $c="";
 597                         $page=$feed->{dir}."/item";
 598                         while (exists $IkiWiki::pagecase{lc $page.$c} ||
 599                                -e "$config{srcdir}/".htmlfn($page.$c)) {
 600                                 $c++
 601                         }
 602                 }
 603
 604                 $guid->{page}=$page;
 605                 debug(sprintf(gettext("creating new page %s"), $page));
 606         }
 607         $guid->{feed}=$feed->{name};
 608
 609         # To write or not to write? Need to avoid writing unchanged pages
 610         # to avoid unneccessary rebuilding. The mtime from rss cannot be
 611         # trusted; let's use a digest.
 612         eval q{use Digest::MD5 'md5_hex'};
 613         error($@) if $@;
 614         require Encode;
 615         my $digest=md5_hex(Encode::encode_utf8($params{content}));
 616         return unless ! exists $guid->{md5} || $guid->{md5} ne $digest || $config{rebuild};
 617         $guid->{md5}=$digest;
 618
 619         # Create the page.
 620         my $template=template($feed->{template}, blind_cache => 1);
 621         $template->param(title => $params{title})
 622                 if defined $params{title} && length($params{title});
 623         $template->param(content => wikiescape(htmlabs($params{content},
 624                 defined $params{base} ? $params{base} : $feed->{feedurl})));
 625         $template->param(name => $feed->{name});
 626         $template->param(url => $feed->{url});
 627         $template->param(copyright => $params{copyright})
 628                 if defined $params{copyright} && length $params{copyright};
 629         $template->param(permalink => urlabs($params{link}, $feed->{feedurl}))
 630                 if defined $params{link};
 631         if (ref $feed->{tags}) {
 632                 $template->param(tags => [map { tag => $_ }, @{$feed->{tags}}]);
 633         }
 634         writefile(htmlfn($guid->{page}), $config{srcdir},
 635                 $template->output);
 636
 637         if (defined $mtime && $mtime <= time) {
 638                 # Set the mtime, this lets the build process get the right
 639                 # creation time on record for the new page.
 640                 utime $mtime, $mtime, "$config{srcdir}/".htmlfn($guid->{page});
 641                 # Store it in pagectime for expiry code to use also.
 642                 $IkiWiki::pagectime{$guid->{page}}=$mtime;
 643         }
 644         else {
 645                 # Dummy value for expiry code.
 646                 $IkiWiki::pagectime{$guid->{page}}=time;
 647         }
 648 }
 649
 650 sub wikiescape ($) {
 651         # escape accidental wikilinks and preprocessor stuff
 652         return encode_entities(shift, '\[\]');
 653 }
 654
 655 sub urlabs ($$) {
 656         my $url=shift;
 657         my $urlbase=shift;
 658
 659         URI->new_abs($url, $urlbase)->as_string;
 660 }
 661
 662 sub htmlabs ($$) {
 663         # Convert links in html from relative to absolute.
 664         # Note that this is a heuristic, which is not specified by the rss
 665         # spec and may not be right for all feeds. Also, see Debian
 666         # bug #381359.
 667         my $html=shift;
 668         my $urlbase=shift;
 669
 670         my $ret="";
 671         my $p = HTML::Parser->new(api_version => 3);
 672         $p->handler(default => sub { $ret.=join("", @_) }, "text");
 673         $p->handler(start => sub {
 674                 my ($tagname, $pos, $text) = @_;
 675                 if (ref $HTML::Tagset::linkElements{$tagname}) {
 676                         while (4 <= @$pos) {
 677                                 # use attribute sets from right to left
 678                                 # to avoid invalidating the offsets
 679                                 # when replacing the values
 680                                 my($k_offset, $k_len, $v_offset, $v_len) =
 681                                         splice(@$pos, -4);
 682                                 my $attrname = lc(substr($text, $k_offset, $k_len));
 683                                 next unless grep { $_ eq $attrname } @{$HTML::Tagset::linkElements{$tagname}};
 684                                 next unless $v_offset; # 0 v_offset means no value
 685                                 my $v = substr($text, $v_offset, $v_len);
 686                                 $v =~ s/^([\'\"])(.*)\1$/$2/;
 687                                 my $new_v=urlabs($v, $urlbase);
 688                                 $new_v =~ s/\"/&quot;/g; # since we quote with ""
 689                                 substr($text, $v_offset, $v_len) = qq("$new_v");
 690                         }
 691                 }
 692                 $ret.=$text;
 693         }, "tagname, tokenpos, text");
 694         $p->parse($html);
 695         $p->eof;
 696
 697         return $ret;
 698 }
 699
 700 sub htmlfn ($) {
 701         return shift().".".($config{aggregateinternal} ? "_aggregated" : $config{htmlext});
 702 }
 703
 704 my $aggregatelock;
 705
 706 sub lockaggregate () {
 707         # Take an exclusive lock to prevent multiple concurrent aggregators.
 708         # Returns true if the lock was aquired.
 709         if (! -d $config{wikistatedir}) {
 710                 mkdir($config{wikistatedir});
 711         }
 712         open($aggregatelock, '>', "$config{wikistatedir}/aggregatelock") ||
 713                 error ("cannot open to $config{wikistatedir}/aggregatelock: $!");
 714         if (! flock($aggregatelock, 2 | 4)) { # LOCK_EX | LOCK_NB
 715                 close($aggregatelock) || error("failed closing aggregatelock: $!");
 716                 return 0;
 717         }
 718         return 1;
 719 }
 720
 721 sub unlockaggregate () {
 722         return close($aggregatelock) if $aggregatelock;
 723         return;
 724 }
 725
 726 1