IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use URI::Escape q{uri_escape_utf8};
   9 use POSIX;
  10 use open qw{:utf8 :std};
  11
  12 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  13             %pagestate %renderedfiles %oldrenderedfiles %pagesources
  14             %destsources %depends %hooks %forcerebuild $gettext_obj};
  15
  16 use Exporter q{import};
  17 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  18                  bestlink htmllink readfile writefile pagetype srcfile pagename
  19                  displaytime will_render gettext urlto targetpage
  20                  add_underlay
  21                  %config %links %pagestate %renderedfiles
  22                  %pagesources %destsources);
  23 our $VERSION = 2.00; # plugin interface version, next is ikiwiki version
  24 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  25 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  26
  27 # Optimisation.
  28 use Memoize;
  29 memoize("abs2rel");
  30 memoize("pagespec_translate");
  31 memoize("file_pruned");
  32
  33 sub defaultconfig () { #{{{
  34         return
  35         wiki_file_prune_regexps => [qr/(^|\/)\.\.(\/|$)/, qr/^\./, qr/\/\./,
  36                 qr/\.x?html?$/, qr/\.ikiwiki-new$/,
  37                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
  38                 qr/(^|\/)_MTN\//,
  39                 qr/\.dpkg-tmp$/],
  40         wiki_link_regexp => qr{
  41                 \[\[                    # beginning of link
  42                 (?:
  43                         ([^\]\|\n\s]+)  # 1: link text
  44                         \|              # followed by '|'
  45                 )?                      # optional
  46
  47                 ([^\s\]#]+)             # 2: page to link to
  48                 (?:
  49                         \#              # '#', beginning of anchor
  50                         ([^\s\]]+)      # 3: anchor text
  51                 )?                      # optional
  52
  53                 \]\]                    # end of link
  54         }x,
  55         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  56         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  57         verbose => 0,
  58         syslog => 0,
  59         wikiname => "wiki",
  60         default_pageext => "mdwn",
  61         htmlext => "html",
  62         cgi => 0,
  63         post_commit => 0,
  64         rcs => '',
  65         notify => 0,
  66         url => '',
  67         cgiurl => '',
  68         historyurl => '',
  69         diffurl => '',
  70         rss => 0,
  71         atom => 0,
  72         discussion => 1,
  73         rebuild => 0,
  74         refresh => 0,
  75         getctime => 0,
  76         w3mmode => 0,
  77         wrapper => undef,
  78         wrappermode => undef,
  79         svnrepo => undef,
  80         svnpath => "trunk",
  81         gitorigin_branch => "origin",
  82         gitmaster_branch => "master",
  83         srcdir => undef,
  84         destdir => undef,
  85         pingurl => [],
  86         templatedir => "$installdir/share/ikiwiki/templates",
  87         underlaydir => "$installdir/share/ikiwiki/basewiki",
  88         underlaydirs => [],
  89         setup => undef,
  90         adminuser => undef,
  91         adminemail => undef,
  92         plugin => [qw{mdwn inline htmlscrubber passwordauth openid signinedit
  93                       lockedit conditional}],
  94         libdir => undef,
  95         timeformat => '%c',
  96         locale => undef,
  97         sslcookie => 0,
  98         httpauth => 0,
  99         userdir => "",
 100         usedirs => 1,
 101         numbacklinks => 10,
 102         account_creation_password => "",
 103 } #}}}
 104
 105 sub checkconfig () { #{{{
 106         # locale stuff; avoid LC_ALL since it overrides everything
 107         if (defined $ENV{LC_ALL}) {
 108                 $ENV{LANG} = $ENV{LC_ALL};
 109                 delete $ENV{LC_ALL};
 110         }
 111         if (defined $config{locale}) {
 112                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 113                         $ENV{LANG}=$config{locale};
 114                         $gettext_obj=undef;
 115                 }
 116         }
 117
 118         if ($config{w3mmode}) {
 119                 eval q{use Cwd q{abs_path}};
 120                 error($@) if $@;
 121                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 122                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 123                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 124                         unless $config{cgiurl} =~ m!file:///!;
 125                 $config{url}="file://".$config{destdir};
 126         }
 127
 128         if ($config{cgi} && ! length $config{url}) {
 129                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 130         }
 131
 132         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 133                 unless exists $config{wikistatedir};
 134
 135         if ($config{rcs}) {
 136                 eval qq{use IkiWiki::Rcs::$config{rcs}};
 137                 if ($@) {
 138                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 139                 }
 140         }
 141         else {
 142                 require IkiWiki::Rcs::Stub;
 143         }
 144
 145         if (exists $config{umask}) {
 146                 umask(possibly_foolish_untaint($config{umask}));
 147         }
 148
 149         run_hooks(checkconfig => sub { shift->() });
 150
 151         return 1;
 152 } #}}}
 153
 154 sub loadplugins () { #{{{
 155         if (defined $config{libdir}) {
 156                 unshift @INC, possibly_foolish_untaint($config{libdir});
 157         }
 158
 159         loadplugin($_) foreach @{$config{plugin}};
 160
 161         run_hooks(getopt => sub { shift->() });
 162         if (grep /^-/, @ARGV) {
 163                 print STDERR "Unknown option: $_\n"
 164                         foreach grep /^-/, @ARGV;
 165                 usage();
 166         }
 167
 168         return 1;
 169 } #}}}
 170
 171 sub loadplugin ($) { #{{{
 172         my $plugin=shift;
 173
 174         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 175
 176         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 177                          "$installdir/lib/ikiwiki") {
 178                 if (defined $dir && -x "$dir/plugins/$plugin") {
 179                         require IkiWiki::Plugin::external;
 180                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 181                         return 1;
 182                 }
 183         }
 184
 185         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 186         eval qq{use $mod};
 187         if ($@) {
 188                 error("Failed to load plugin $mod: $@");
 189         }
 190         return 1;
 191 } #}}}
 192
 193 sub error ($;$) { #{{{
 194         my $message=shift;
 195         my $cleaner=shift;
 196         if ($config{cgi}) {
 197                 print "Content-type: text/html\n\n";
 198                 print misctemplate(gettext("Error"),
 199                         "<p>".gettext("Error").": $message</p>");
 200         }
 201         log_message('err' => $message) if $config{syslog};
 202         if (defined $cleaner) {
 203                 $cleaner->();
 204         }
 205         die $message."\n";
 206 } #}}}
 207
 208 sub debug ($) { #{{{
 209         return unless $config{verbose};
 210         return log_message(debug => @_);
 211 } #}}}
 212
 213 my $log_open=0;
 214 sub log_message ($$) { #{{{
 215         my $type=shift;
 216
 217         if ($config{syslog}) {
 218                 require Sys::Syslog;
 219                 if (! $log_open) {
 220                         Sys::Syslog::setlogsock('unix');
 221                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 222                         $log_open=1;
 223                 }
 224                 return eval {
 225                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 226                 };
 227         }
 228         elsif (! $config{cgi}) {
 229                 return print "@_\n";
 230         }
 231         else {
 232                 return print STDERR "@_\n";
 233         }
 234 } #}}}
 235
 236 sub possibly_foolish_untaint ($) { #{{{
 237         my $tainted=shift;
 238         my ($untainted)=$tainted=~/(.*)/s;
 239         return $untainted;
 240 } #}}}
 241
 242 sub basename ($) { #{{{
 243         my $file=shift;
 244
 245         $file=~s!.*/+!!;
 246         return $file;
 247 } #}}}
 248
 249 sub dirname ($) { #{{{
 250         my $file=shift;
 251
 252         $file=~s!/*[^/]+$!!;
 253         return $file;
 254 } #}}}
 255
 256 sub pagetype ($) { #{{{
 257         my $page=shift;
 258
 259         if ($page =~ /\.([^.]+)$/) {
 260                 return $1 if exists $hooks{htmlize}{$1};
 261         }
 262         return;
 263 } #}}}
 264
 265 sub pagename ($) { #{{{
 266         my $file=shift;
 267
 268         my $type=pagetype($file);
 269         my $page=$file;
 270         $page=~s/\Q.$type\E*$// if defined $type;
 271         return $page;
 272 } #}}}
 273
 274 sub targetpage ($$) { #{{{
 275         my $page=shift;
 276         my $ext=shift;
 277
 278         if (! $config{usedirs} || $page =~ /^index$/ ) {
 279                 return $page.".".$ext;
 280         } else {
 281                 return $page."/index.".$ext;
 282         }
 283 } #}}}
 284
 285 sub htmlpage ($) { #{{{
 286         my $page=shift;
 287
 288         return targetpage($page, $config{htmlext});
 289 } #}}}
 290
 291 sub srcfile ($) { #{{{
 292         my $file=shift;
 293
 294         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 295         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 296                 return "$dir/$file" if -e "$dir/$file";
 297         }
 298         error("internal error: $file cannot be found in $config{srcdir} or underlay");
 299         return;
 300 } #}}}
 301
 302 sub add_underlay ($) { #{{{
 303         my $dir=shift;
 304
 305         if ($dir=~/^\//) {
 306                 unshift @{$config{underlaydirs}}, $dir;
 307         }
 308         else {
 309                 unshift @{$config{underlaydirs}}, "$config{underlaydir}/../$dir";
 310         }
 311
 312         return 1;
 313 } #}}}
 314
 315 sub readfile ($;$$) { #{{{
 316         my $file=shift;
 317         my $binary=shift;
 318         my $wantfd=shift;
 319
 320         if (-l $file) {
 321                 error("cannot read a symlink ($file)");
 322         }
 323
 324         local $/=undef;
 325         open (my $in, "<", $file) || error("failed to read $file: $!");
 326         binmode($in) if ($binary);
 327         return \*$in if $wantfd;
 328         my $ret=<$in>;
 329         close $in || error("failed to read $file: $!");
 330         return $ret;
 331 } #}}}
 332
 333 sub writefile ($$$;$$) { #{{{
 334         my $file=shift; # can include subdirs
 335         my $destdir=shift; # directory to put file in
 336         my $content=shift;
 337         my $binary=shift;
 338         my $writer=shift;
 339
 340         my $test=$file;
 341         while (length $test) {
 342                 if (-l "$destdir/$test") {
 343                         error("cannot write to a symlink ($test)");
 344                 }
 345                 $test=dirname($test);
 346         }
 347         my $newfile="$destdir/$file.ikiwiki-new";
 348         if (-l $newfile) {
 349                 error("cannot write to a symlink ($newfile)");
 350         }
 351
 352         my $dir=dirname($newfile);
 353         if (! -d $dir) {
 354                 my $d="";
 355                 foreach my $s (split(m!/+!, $dir)) {
 356                         $d.="$s/";
 357                         if (! -d $d) {
 358                                 mkdir($d) || error("failed to create directory $d: $!");
 359                         }
 360                 }
 361         }
 362
 363         my $cleanup = sub { unlink($newfile) };
 364         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 365         binmode($out) if ($binary);
 366         if ($writer) {
 367                 $writer->(\*$out, $cleanup);
 368         }
 369         else {
 370                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 371         }
 372         close $out || error("failed saving $newfile: $!", $cleanup);
 373         rename($newfile, "$destdir/$file") ||
 374                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 375
 376         return 1;
 377 } #}}}
 378
 379 my %cleared;
 380 sub will_render ($$;$) { #{{{
 381         my $page=shift;
 382         my $dest=shift;
 383         my $clear=shift;
 384
 385         # Important security check.
 386         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 387             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 388                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 389         }
 390
 391         if (! $clear || $cleared{$page}) {
 392                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 393         }
 394         else {
 395                 foreach my $old (@{$renderedfiles{$page}}) {
 396                         delete $destsources{$old};
 397                 }
 398                 $renderedfiles{$page}=[$dest];
 399                 $cleared{$page}=1;
 400         }
 401         $destsources{$dest}=$page;
 402
 403         return 1;
 404 } #}}}
 405
 406 sub bestlink ($$) { #{{{
 407         my $page=shift;
 408         my $link=shift;
 409
 410         my $cwd=$page;
 411         if ($link=~s/^\/+//) {
 412                 # absolute links
 413                 $cwd="";
 414         }
 415         $link=~s/\/$//;
 416
 417         do {
 418                 my $l=$cwd;
 419                 $l.="/" if length $l;
 420                 $l.=$link;
 421
 422                 if (exists $links{$l}) {
 423                         return $l;
 424                 }
 425                 elsif (exists $pagecase{lc $l}) {
 426                         return $pagecase{lc $l};
 427                 }
 428         } while $cwd=~s!/?[^/]+$!!;
 429
 430         if (length $config{userdir}) {
 431                 my $l = "$config{userdir}/".lc($link);
 432                 if (exists $links{$l}) {
 433                         return $l;
 434                 }
 435                 elsif (exists $pagecase{lc $l}) {
 436                         return $pagecase{lc $l};
 437                 }
 438         }
 439
 440         #print STDERR "warning: page $page, broken link: $link\n";
 441         return "";
 442 } #}}}
 443
 444 sub isinlinableimage ($) { #{{{
 445         my $file=shift;
 446
 447         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 448 } #}}}
 449
 450 sub pagetitle ($;$) { #{{{
 451         my $page=shift;
 452         my $unescaped=shift;
 453
 454         if ($unescaped) {
 455                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 456         }
 457         else {
 458                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 459         }
 460
 461         return $page;
 462 } #}}}
 463
 464 sub titlepage ($) { #{{{
 465         my $title=shift;
 466         $title=~s/([^-[:alnum:]:+\/.])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 467         return $title;
 468 } #}}}
 469
 470 sub linkpage ($) { #{{{
 471         my $link=shift;
 472         $link=~s/([^-[:alnum:]:+\/._])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 473         return $link;
 474 } #}}}
 475
 476 sub cgiurl (@) { #{{{
 477         my %params=@_;
 478
 479         return $config{cgiurl}."?".
 480                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 481 } #}}}
 482
 483 sub baseurl (;$) { #{{{
 484         my $page=shift;
 485
 486         return "$config{url}/" if ! defined $page;
 487
 488         $page=htmlpage($page);
 489         $page=~s/[^\/]+$//;
 490         $page=~s/[^\/]+\//..\//g;
 491         return $page;
 492 } #}}}
 493
 494 sub abs2rel ($$) { #{{{
 495         # Work around very innefficient behavior in File::Spec if abs2rel
 496         # is passed two relative paths. It's much faster if paths are
 497         # absolute! (Debian bug #376658; fixed in debian unstable now)
 498         my $path="/".shift;
 499         my $base="/".shift;
 500
 501         require File::Spec;
 502         my $ret=File::Spec->abs2rel($path, $base);
 503         $ret=~s/^// if defined $ret;
 504         return $ret;
 505 } #}}}
 506
 507 sub displaytime ($;$) { #{{{
 508         my $time=shift;
 509         my $format=shift;
 510         if (! defined $format) {
 511                 $format=$config{timeformat};
 512         }
 513
 514         # strftime doesn't know about encodings, so make sure
 515         # its output is properly treated as utf8
 516         return decode_utf8(POSIX::strftime($format, localtime($time)));
 517 } #}}}
 518
 519 sub beautify_url ($) { #{{{
 520         my $url=shift;
 521
 522         if ($config{usedirs}) {
 523                 $url =~ s!/index.$config{htmlext}$!/!;
 524         }
 525         $url =~ s!^$!./!; # Browsers don't like empty links...
 526
 527         return $url;
 528 } #}}}
 529
 530 sub urlto ($$) { #{{{
 531         my $to=shift;
 532         my $from=shift;
 533
 534         if (! length $to) {
 535                 return beautify_url(baseurl($from));
 536         }
 537
 538         if (! $destsources{$to}) {
 539                 $to=htmlpage($to);
 540         }
 541
 542         my $link = abs2rel($to, dirname(htmlpage($from)));
 543
 544         return beautify_url($link);
 545 } #}}}
 546
 547 sub htmllink ($$$;@) { #{{{
 548         my $lpage=shift; # the page doing the linking
 549         my $page=shift; # the page that will contain the link (different for inline)
 550         my $link=shift;
 551         my %opts=@_;
 552
 553         $link=~s/\/$//;
 554
 555         my $bestlink;
 556         if (! $opts{forcesubpage}) {
 557                 $bestlink=bestlink($lpage, $link);
 558         }
 559         else {
 560                 $bestlink="$lpage/".lc($link);
 561         }
 562
 563         my $linktext;
 564         if (defined $opts{linktext}) {
 565                 $linktext=$opts{linktext};
 566         }
 567         else {
 568                 $linktext=pagetitle(basename($link));
 569         }
 570
 571         return "<span class=\"selflink\">$linktext</span>"
 572                 if length $bestlink && $page eq $bestlink &&
 573                    ! defined $opts{anchor};
 574
 575         if (! $destsources{$bestlink}) {
 576                 $bestlink=htmlpage($bestlink);
 577
 578                 if (! $destsources{$bestlink}) {
 579                         return $linktext unless length $config{cgiurl};
 580                         return "<span class=\"createlink\"><a href=\"".
 581                                 cgiurl(
 582                                         do => "create",
 583                                         page => pagetitle(lc($link), 1),
 584                                         from => $lpage
 585                                 ).
 586                                 "\">?</a>$linktext</span>"
 587                 }
 588         }
 589
 590         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
 591         $bestlink=beautify_url($bestlink);
 592
 593         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
 594                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 595         }
 596
 597         if (defined $opts{anchor}) {
 598                 $bestlink.="#".$opts{anchor};
 599         }
 600
 601         my @attrs;
 602         if (defined $opts{rel}) {
 603                 push @attrs, ' rel="'.$opts{rel}.'"';
 604         }
 605         if (defined $opts{class}) {
 606                 push @attrs, ' class="'.$opts{class}.'"';
 607         }
 608
 609         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
 610 } #}}}
 611
 612 sub htmlize ($$$) { #{{{
 613         my $page=shift;
 614         my $type=shift;
 615         my $content=shift;
 616
 617         if (exists $hooks{htmlize}{$type}) {
 618                 $content=$hooks{htmlize}{$type}{call}->(
 619                         page => $page,
 620                         content => $content,
 621                 );
 622         }
 623         else {
 624                 error("htmlization of $type not supported");
 625         }
 626
 627         run_hooks(sanitize => sub {
 628                 $content=shift->(
 629                         page => $page,
 630                         content => $content,
 631                 );
 632         });
 633
 634         return $content;
 635 } #}}}
 636
 637 sub linkify ($$$) { #{{{
 638         my $lpage=shift; # the page containing the links
 639         my $page=shift; # the page the link will end up on (different for inline)
 640         my $content=shift;
 641
 642         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 643                 defined $2
 644                         ? ( $1
 645                                 ? "[[$2|$3".($4 ? "#$4" : "")."]]"
 646                                 : htmllink($lpage, $page, linkpage($3),
 647                                         anchor => $4, linktext => pagetitle($2)))
 648                         : ( $1
 649                                 ? "[[$3".($4 ? "#$4" : "")."]]"
 650                                 : htmllink($lpage, $page, linkpage($3),
 651                                         anchor => $4))
 652         }eg;
 653
 654         return $content;
 655 } #}}}
 656
 657 my %preprocessing;
 658 our $preprocess_preview=0;
 659 sub preprocess ($$$;$$) { #{{{
 660         my $page=shift; # the page the data comes from
 661         my $destpage=shift; # the page the data will appear in (different for inline)
 662         my $content=shift;
 663         my $scan=shift;
 664         my $preview=shift;
 665
 666         # Using local because it needs to be set within any nested calls
 667         # of this function.
 668         local $preprocess_preview=$preview if defined $preview;
 669
 670         my $handle=sub {
 671                 my $escape=shift;
 672                 my $command=shift;
 673                 my $params=shift;
 674                 if (length $escape) {
 675                         return "[[$command $params]]";
 676                 }
 677                 elsif (exists $hooks{preprocess}{$command}) {
 678                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 679                         # Note: preserve order of params, some plugins may
 680                         # consider it significant.
 681                         my @params;
 682                         while ($params =~ m{
 683                                 (?:([-\w]+)=)?          # 1: named parameter key?
 684                                 (?:
 685                                         """(.*?)"""     # 2: triple-quoted value
 686                                 |
 687                                         "([^"]+)"       # 3: single-quoted value
 688                                 |
 689                                         (\S+)           # 4: unquoted value
 690                                 )
 691                                 (?:\s+|$)               # delimiter to next param
 692                         }sgx) {
 693                                 my $key=$1;
 694                                 my $val;
 695                                 if (defined $2) {
 696                                         $val=$2;
 697                                         $val=~s/\r\n/\n/mg;
 698                                         $val=~s/^\n+//g;
 699                                         $val=~s/\n+$//g;
 700                                 }
 701                                 elsif (defined $3) {
 702                                         $val=$3;
 703                                 }
 704                                 elsif (defined $4) {
 705                                         $val=$4;
 706                                 }
 707
 708                                 if (defined $key) {
 709                                         push @params, $key, $val;
 710                                 }
 711                                 else {
 712                                         push @params, $val, '';
 713                                 }
 714                         }
 715                         if ($preprocessing{$page}++ > 3) {
 716                                 # Avoid loops of preprocessed pages preprocessing
 717                                 # other pages that preprocess them, etc.
 718                                 #translators: The first parameter is a
 719                                 #translators: preprocessor directive name,
 720                                 #translators: the second a page name, the
 721                                 #translators: third a number.
 722                                 return "[[".sprintf(gettext("%s preprocessing loop detected on %s at depth %i"),
 723                                         $command, $page, $preprocessing{$page}).
 724                                 "]]";
 725                         }
 726                         my $ret=$hooks{preprocess}{$command}{call}->(
 727                                 @params,
 728                                 page => $page,
 729                                 destpage => $destpage,
 730                                 preview => $preprocess_preview,
 731                         );
 732                         $preprocessing{$page}--;
 733                         return $ret;
 734                 }
 735                 else {
 736                         return "[[$command $params]]";
 737                 }
 738         };
 739
 740         $content =~ s{
 741                 (\\?)           # 1: escape?
 742                 \[\[            # directive open
 743                 ([-\w]+)        # 2: command
 744                 \s+
 745                 (               # 3: the parameters..
 746                         (?:
 747                                 (?:[-\w]+=)?            # named parameter key?
 748                                 (?:
 749                                         """.*?"""       # triple-quoted value
 750                                         |
 751                                         "[^"]+"         # single-quoted value
 752                                         |
 753                                         [^\s\]]+        # unquoted value
 754                                 )
 755                                 \s*                     # whitespace or end
 756                                                         # of directive
 757                         )
 758                 *)              # 0 or more parameters
 759                 \]\]            # directive closed
 760         }{$handle->($1, $2, $3)}sexg;
 761         return $content;
 762 } #}}}
 763
 764 sub filter ($$$) { #{{{
 765         my $page=shift;
 766         my $destpage=shift;
 767         my $content=shift;
 768
 769         run_hooks(filter => sub {
 770                 $content=shift->(page => $page, destpage => $destpage,
 771                         content => $content);
 772         });
 773
 774         return $content;
 775 } #}}}
 776
 777 sub indexlink () { #{{{
 778         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 779 } #}}}
 780
 781 my $wikilock;
 782
 783 sub lockwiki (;$) { #{{{
 784         my $wait=@_ ? shift : 1;
 785         # Take an exclusive lock on the wiki to prevent multiple concurrent
 786         # run issues. The lock will be dropped on program exit.
 787         if (! -d $config{wikistatedir}) {
 788                 mkdir($config{wikistatedir});
 789         }
 790         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
 791                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 792         if (! flock($wikilock, 2 | 4)) { # LOCK_EX | LOCK_NB
 793                 if ($wait) {
 794                         debug("wiki seems to be locked, waiting for lock");
 795                         my $wait=600; # arbitrary, but don't hang forever to
 796                                       # prevent process pileup
 797                         for (1..$wait) {
 798                                 return if flock($wikilock, 2 | 4);
 799                                 sleep 1;
 800                         }
 801                         error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 802                 }
 803                 else {
 804                         return 0;
 805                 }
 806         }
 807         return 1;
 808 } #}}}
 809
 810 sub unlockwiki () { #{{{
 811         return close($wikilock) if $wikilock;
 812         return;
 813 } #}}}
 814
 815 my $commitlock;
 816
 817 sub commit_hook_enabled () { #{{{
 818         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
 819                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 820         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
 821                 close($commitlock) || error("failed closing commitlock: $!");
 822                 return 0;
 823         }
 824         close($commitlock) || error("failed closing commitlock: $!");
 825         return 1;
 826 } #}}}
 827
 828 sub disable_commit_hook () { #{{{
 829         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
 830                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 831         if (! flock($commitlock, 2)) { # LOCK_EX
 832                 error("failed to get commit lock");
 833         }
 834         return 1;
 835 } #}}}
 836
 837 sub enable_commit_hook () { #{{{
 838         return close($commitlock) if $commitlock;
 839         return;
 840 } #}}}
 841
 842 sub loadindex () { #{{{
 843         %oldrenderedfiles=%pagectime=();
 844         if (! $config{rebuild}) {
 845                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
 846                         %destsources=%renderedfiles=%pagecase=();
 847         }
 848         open (my $in, "<", "$config{wikistatedir}/index") || return;
 849         while (<$in>) {
 850                 $_=possibly_foolish_untaint($_);
 851                 chomp;
 852                 my %items;
 853                 $items{link}=[];
 854                 $items{dest}=[];
 855                 foreach my $i (split(/ /, $_)) {
 856                         my ($item, $val)=split(/=/, $i, 2);
 857                         push @{$items{$item}}, decode_entities($val);
 858                 }
 859
 860                 next unless exists $items{src}; # skip bad lines for now
 861
 862                 my $page=pagename($items{src}[0]);
 863                 if (! $config{rebuild}) {
 864                         $pagesources{$page}=$items{src}[0];
 865                         $pagemtime{$page}=$items{mtime}[0];
 866                         $oldlinks{$page}=[@{$items{link}}];
 867                         $links{$page}=[@{$items{link}}];
 868                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 869                         $destsources{$_}=$page foreach @{$items{dest}};
 870                         $renderedfiles{$page}=[@{$items{dest}}];
 871                         $pagecase{lc $page}=$page;
 872                         foreach my $k (grep /_/, keys %items) {
 873                                 my ($id, $key)=split(/_/, $k, 2);
 874                                 $pagestate{$page}{decode_entities($id)}{decode_entities($key)}=$items{$k}[0];
 875                         }
 876                 }
 877                 $oldrenderedfiles{$page}=[@{$items{dest}}];
 878                 $pagectime{$page}=$items{ctime}[0];
 879         }
 880         return close($in);
 881 } #}}}
 882
 883 sub saveindex () { #{{{
 884         run_hooks(savestate => sub { shift->() });
 885
 886         my %hookids;
 887         foreach my $type (keys %hooks) {
 888                 $hookids{encode_entities($_)}=1 foreach keys %{$hooks{$type}};
 889         }
 890         my @hookids=sort keys %hookids;
 891
 892         if (! -d $config{wikistatedir}) {
 893                 mkdir($config{wikistatedir});
 894         }
 895         my $newfile="$config{wikistatedir}/index.new";
 896         my $cleanup = sub { unlink($newfile) };
 897         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
 898         foreach my $page (keys %pagemtime) {
 899                 next unless $pagemtime{$page};
 900                 my $line="mtime=$pagemtime{$page} ".
 901                         "ctime=$pagectime{$page} ".
 902                         "src=$pagesources{$page}";
 903                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 904                 my %count;
 905                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 906                 if (exists $depends{$page}) {
 907                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 908                 }
 909                 if (exists $pagestate{$page}) {
 910                         foreach my $id (@hookids) {
 911                                 foreach my $key (keys %{$pagestate{$page}{$id}}) {
 912                                         $line.=' '.$id.'_'.encode_entities($key)."=".encode_entities($pagestate{$page}{$id}{$key});
 913                                 }
 914                         }
 915                 }
 916                 print $out $line."\n" || error("failed writing to $newfile: $!", $cleanup);
 917         }
 918         close $out || error("failed saving to $newfile: $!", $cleanup);
 919         rename($newfile, "$config{wikistatedir}/index") ||
 920                 error("failed renaming $newfile to $config{wikistatedir}/index", $cleanup);
 921
 922         return 1;
 923 } #}}}
 924
 925 sub template_file ($) { #{{{
 926         my $template=shift;
 927
 928         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
 929                 return "$dir/$template" if -e "$dir/$template";
 930         }
 931         return;
 932 } #}}}
 933
 934 sub template_params (@) { #{{{
 935         my $filename=template_file(shift);
 936
 937         if (! defined $filename) {
 938                 return if wantarray;
 939                 return "";
 940         }
 941
 942         my @ret=(
 943                 filter => sub {
 944                         my $text_ref = shift;
 945                         ${$text_ref} = decode_utf8(${$text_ref});
 946                 },
 947                 filename => $filename,
 948                 loop_context_vars => 1,
 949                 die_on_bad_params => 0,
 950                 @_
 951         );
 952         return wantarray ? @ret : {@ret};
 953 } #}}}
 954
 955 sub template ($;@) { #{{{
 956         require HTML::Template;
 957         return HTML::Template->new(template_params(@_));
 958 } #}}}
 959
 960 sub misctemplate ($$;@) { #{{{
 961         my $title=shift;
 962         my $pagebody=shift;
 963
 964         my $template=template("misc.tmpl");
 965         $template->param(
 966                 title => $title,
 967                 indexlink => indexlink(),
 968                 wikiname => $config{wikiname},
 969                 pagebody => $pagebody,
 970                 baseurl => baseurl(),
 971                 @_,
 972         );
 973         run_hooks(pagetemplate => sub {
 974                 shift->(page => "", destpage => "", template => $template);
 975         });
 976         return $template->output;
 977 }#}}}
 978
 979 sub hook (@) { # {{{
 980         my %param=@_;
 981
 982         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 983                 error 'hook requires type, call, and id parameters';
 984         }
 985
 986         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 987
 988         $hooks{$param{type}}{$param{id}}=\%param;
 989         return 1;
 990 } # }}}
 991
 992 sub run_hooks ($$) { # {{{
 993         # Calls the given sub for each hook of the given type,
 994         # passing it the hook function to call.
 995         my $type=shift;
 996         my $sub=shift;
 997
 998         if (exists $hooks{$type}) {
 999                 my @deferred;
1000                 foreach my $id (keys %{$hooks{$type}}) {
1001                         if ($hooks{$type}{$id}{last}) {
1002                                 push @deferred, $id;
1003                                 next;
1004                         }
1005                         $sub->($hooks{$type}{$id}{call});
1006                 }
1007                 foreach my $id (@deferred) {
1008                         $sub->($hooks{$type}{$id}{call});
1009                 }
1010         }
1011
1012         return 1;
1013 } #}}}
1014
1015 sub globlist_to_pagespec ($) { #{{{
1016         my @globlist=split(' ', shift);
1017
1018         my (@spec, @skip);
1019         foreach my $glob (@globlist) {
1020                 if ($glob=~/^!(.*)/) {
1021                         push @skip, $glob;
1022                 }
1023                 else {
1024                         push @spec, $glob;
1025                 }
1026         }
1027
1028         my $spec=join(' or ', @spec);
1029         if (@skip) {
1030                 my $skip=join(' and ', @skip);
1031                 if (length $spec) {
1032                         $spec="$skip and ($spec)";
1033                 }
1034                 else {
1035                         $spec=$skip;
1036                 }
1037         }
1038         return $spec;
1039 } #}}}
1040
1041 sub is_globlist ($) { #{{{
1042         my $s=shift;
1043         return ( $s =~ /[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or" );
1044 } #}}}
1045
1046 sub safequote ($) { #{{{
1047         my $s=shift;
1048         $s=~s/[{}]//g;
1049         return "q{$s}";
1050 } #}}}
1051
1052 sub add_depends ($$) { #{{{
1053         my $page=shift;
1054         my $pagespec=shift;
1055
1056         if (! exists $depends{$page}) {
1057                 $depends{$page}=$pagespec;
1058         }
1059         else {
1060                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
1061         }
1062
1063         return 1;
1064 } # }}}
1065
1066 sub file_pruned ($$) { #{{{
1067         require File::Spec;
1068         my $file=File::Spec->canonpath(shift);
1069         my $base=File::Spec->canonpath(shift);
1070         $file =~ s#^\Q$base\E/+##;
1071
1072         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1073         return $file =~ m/$regexp/ && $file ne $base;
1074 } #}}}
1075
1076 sub gettext { #{{{
1077         # Only use gettext in the rare cases it's needed.
1078         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1079             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1080             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1081                 if (! $gettext_obj) {
1082                         $gettext_obj=eval q{
1083                                 use Locale::gettext q{textdomain};
1084                                 Locale::gettext->domain('ikiwiki')
1085                         };
1086                         if ($@) {
1087                                 print STDERR "$@";
1088                                 $gettext_obj=undef;
1089                                 return shift;
1090                         }
1091                 }
1092                 return $gettext_obj->get(shift);
1093         }
1094         else {
1095                 return shift;
1096         }
1097 } #}}}
1098
1099 sub pagespec_merge ($$) { #{{{
1100         my $a=shift;
1101         my $b=shift;
1102
1103         return $a if $a eq $b;
1104
1105         # Support for old-style GlobLists.
1106         if (is_globlist($a)) {
1107                 $a=globlist_to_pagespec($a);
1108         }
1109         if (is_globlist($b)) {
1110                 $b=globlist_to_pagespec($b);
1111         }
1112
1113         return "($a) or ($b)";
1114 } #}}}
1115
1116 sub pagespec_translate ($) { #{{{
1117         # This assumes that $page is in scope in the function
1118         # that evalulates the translated pagespec code.
1119         my $spec=shift;
1120
1121         # Support for old-style GlobLists.
1122         if (is_globlist($spec)) {
1123                 $spec=globlist_to_pagespec($spec);
1124         }
1125
1126         # Convert spec to perl code.
1127         my $code="";
1128         while ($spec=~m{
1129                 \s*             # ignore whitespace
1130                 (               # 1: match a single word
1131                         \!              # !
1132                 |
1133                         \(              # (
1134                 |
1135                         \)              # )
1136                 |
1137                         \w+\([^\)]*\)   # command(params)
1138                 |
1139                         [^\s()]+        # any other text
1140                 )
1141                 \s*             # ignore whitespace
1142         }igx) {
1143                 my $word=$1;
1144                 if (lc $word eq 'and') {
1145                         $code.=' &&';
1146                 }
1147                 elsif (lc $word eq 'or') {
1148                         $code.=' ||';
1149                 }
1150                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
1151                         $code.=' '.$word;
1152                 }
1153                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
1154                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
1155                                 $code.="IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).", \@params)";
1156                         }
1157                         else {
1158                                 $code.=' 0';
1159                         }
1160                 }
1161                 else {
1162                         $code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \@params)";
1163                 }
1164         }
1165
1166         return $code;
1167 } #}}}
1168
1169 sub pagespec_match ($$;@) { #{{{
1170         my $page=shift;
1171         my $spec=shift;
1172         my @params=@_;
1173
1174         # Backwards compatability with old calling convention.
1175         if (@params == 1) {
1176                 unshift @params, 'location';
1177         }
1178
1179         my $ret=eval pagespec_translate($spec);
1180         return IkiWiki::FailReason->new('syntax error') if $@;
1181         return $ret;
1182 } #}}}
1183
1184 package IkiWiki::FailReason;
1185
1186 use overload ( #{{{
1187         '""'    => sub { ${$_[0]} },
1188         '0+'    => sub { 0 },
1189         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
1190         fallback => 1,
1191 ); #}}}
1192
1193 sub new { #{{{
1194         return bless \$_[1], $_[0];
1195 } #}}}
1196
1197 package IkiWiki::SuccessReason;
1198
1199 use overload ( #{{{
1200         '""'    => sub { ${$_[0]} },
1201         '0+'    => sub { 1 },
1202         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
1203         fallback => 1,
1204 ); #}}}
1205
1206 sub new { #{{{
1207         return bless \$_[1], $_[0];
1208 }; #}}}
1209
1210 package IkiWiki::PageSpec;
1211
1212 sub match_glob ($$;@) { #{{{
1213         my $page=shift;
1214         my $glob=shift;
1215         my %params=@_;
1216
1217         my $from=exists $params{location} ? $params{location} : '';
1218
1219         # relative matching
1220         if ($glob =~ m!^\./!) {
1221                 $from=~s#/?[^/]+$##;
1222                 $glob=~s#^\./##;
1223                 $glob="$from/$glob" if length $from;
1224         }
1225
1226         # turn glob into safe regexp
1227         $glob=quotemeta($glob);
1228         $glob=~s/\\\*/.*/g;
1229         $glob=~s/\\\?/./g;
1230
1231         if ($page=~/^$glob$/i) {
1232                 return IkiWiki::SuccessReason->new("$glob matches $page");
1233         }
1234         else {
1235                 return IkiWiki::FailReason->new("$glob does not match $page");
1236         }
1237 } #}}}
1238
1239 sub match_link ($$;@) { #{{{
1240         my $page=shift;
1241         my $link=lc(shift);
1242         my %params=@_;
1243
1244         my $from=exists $params{location} ? $params{location} : '';
1245
1246         # relative matching
1247         if ($link =~ m!^\.! && defined $from) {
1248                 $from=~s#/?[^/]+$##;
1249                 $link=~s#^\./##;
1250                 $link="$from/$link" if length $from;
1251         }
1252
1253         my $links = $IkiWiki::links{$page};
1254         return IkiWiki::FailReason->new("$page has no links") unless $links && @{$links};
1255         my $bestlink = IkiWiki::bestlink($from, $link);
1256         foreach my $p (@{$links}) {
1257                 if (length $bestlink) {
1258                         return IkiWiki::SuccessReason->new("$page links to $link")
1259                                 if $bestlink eq IkiWiki::bestlink($page, $p);
1260                 }
1261                 else {
1262                         return IkiWiki::SuccessReason->new("$page links to page $p matching $link")
1263                                 if match_glob($p, $link, %params);
1264                 }
1265         }
1266         return IkiWiki::FailReason->new("$page does not link to $link");
1267 } #}}}
1268
1269 sub match_backlink ($$;@) { #{{{
1270         return match_link($_[1], $_[0], @_);
1271 } #}}}
1272
1273 sub match_created_before ($$;@) { #{{{
1274         my $page=shift;
1275         my $testpage=shift;
1276
1277         if (exists $IkiWiki::pagectime{$testpage}) {
1278                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
1279                         return IkiWiki::SuccessReason->new("$page created before $testpage");
1280                 }
1281                 else {
1282                         return IkiWiki::FailReason->new("$page not created before $testpage");
1283                 }
1284         }
1285         else {
1286                 return IkiWiki::FailReason->new("$testpage has no ctime");
1287         }
1288 } #}}}
1289
1290 sub match_created_after ($$;@) { #{{{
1291         my $page=shift;
1292         my $testpage=shift;
1293
1294         if (exists $IkiWiki::pagectime{$testpage}) {
1295                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
1296                         return IkiWiki::SuccessReason->new("$page created after $testpage");
1297                 }
1298                 else {
1299                         return IkiWiki::FailReason->new("$page not created after $testpage");
1300                 }
1301         }
1302         else {
1303                 return IkiWiki::FailReason->new("$testpage has no ctime");
1304         }
1305 } #}}}
1306
1307 sub match_creation_day ($$;@) { #{{{
1308         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
1309                 return IkiWiki::SuccessReason->new('creation_day matched');
1310         }
1311         else {
1312                 return IkiWiki::FailReason->new('creation_day did not match');
1313         }
1314 } #}}}
1315
1316 sub match_creation_month ($$;@) { #{{{
1317         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
1318                 return IkiWiki::SuccessReason->new('creation_month matched');
1319         }
1320         else {
1321                 return IkiWiki::FailReason->new('creation_month did not match');
1322         }
1323 } #}}}
1324
1325 sub match_creation_year ($$;@) { #{{{
1326         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
1327                 return IkiWiki::SuccessReason->new('creation_year matched');
1328         }
1329         else {
1330                 return IkiWiki::FailReason->new('creation_year did not match');
1331         }
1332 } #}}}
1333
1334 sub match_user ($$;@) { #{{{
1335         shift;
1336         my $user=shift;
1337         my %params=@_;
1338
1339         return IkiWiki::FailReason->new('cannot match user')
1340                 unless exists $params{user};
1341         if ($user eq $params{user}) {
1342                 return IkiWiki::SuccessReason->new("user is $user")
1343         }
1344         else {
1345                 return IkiWiki::FailReason->new("user is not $user");
1346         }
1347 } #}}}
1348
1349 1