IkiWiki/Wrapper.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use File::Spec;
   8 use Data::Dumper;
   9 use IkiWiki;
  10
  11 sub gen_wrapper () {
  12         $config{srcdir}=File::Spec->rel2abs($config{srcdir});
  13         $config{destdir}=File::Spec->rel2abs($config{destdir});
  14         my $this=File::Spec->rel2abs($0);
  15         if (! -x $this) {
  16                 error(sprintf(gettext("%s doesn't seem to be executable"), $this));
  17         }
  18
  19         if ($config{setup}) {
  20                 error(gettext("cannot create a wrapper that uses a setup file"));
  21         }
  22         my $wrapper=possibly_foolish_untaint($config{wrapper});
  23         if (! defined $wrapper || ! length $wrapper) {
  24                 error(gettext("wrapper filename not specified"));
  25         }
  26         delete $config{wrapper};
  27
  28         my @envsave;
  29         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
  30                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
  31                        HTTP_COOKIE REMOTE_USER HTTPS REDIRECT_STATUS
  32                        REDIRECT_URL} if $config{cgi};
  33         my $envsave="";
  34         foreach my $var (@envsave) {
  35                 $envsave.=<<"EOF";
  36         if ((s=getenv("$var")))
  37                 addenv("$var", s);
  38 EOF
  39         }
  40
  41         my @wrapper_hooks;
  42         run_hooks(genwrapper => sub { push @wrapper_hooks, shift->() });
  43
  44         my $check_commit_hook="";
  45         my $pre_exec="";
  46         if ($config{post_commit}) {
  47                 # Optimise checking !commit_hook_enabled() ,
  48                 # so that ikiwiki does not have to be started if the
  49                 # hook is disabled.
  50                 #
  51                 # Note that perl's flock may be implemented using fcntl
  52                 # or lockf on some systems. If so, and if there is no
  53                 # interop between the locking systems, the true C flock will
  54                 # always succeed, and this optimisation won't work.
  55                 # The perl code will later correctly check the lock,
  56                 # so the right thing will still happen, though without
  57                 # the benefit of this optimisation.
  58                 $check_commit_hook=<<"EOF";
  59         {
  60                 int fd=open("$config{wikistatedir}/commitlock", O_CREAT | O_RDWR, 0666);
  61                 if (fd != -1) {
  62                         if (flock(fd, LOCK_SH | LOCK_NB) != 0)
  63                                 exit(0);
  64                         close(fd);
  65                 }
  66         }
  67 EOF
  68         }
  69         elsif ($config{cgi}) {
  70                 # Avoid more than one ikiwiki cgi running at a time by
  71                 # taking a cgi lock. Since ikiwiki uses several MB of
  72                 # memory, a pile up of processes could cause thrashing
  73                 # otherwise. The fd of the lock is stored in
  74                 # IKIWIKI_CGILOCK_FD so unlockwiki can close it.
  75                 $pre_exec=<<"EOF";
  76         {
  77                 int fd=open("$config{wikistatedir}/cgilock", O_CREAT | O_RDWR, 0666);
  78                 if (fd != -1 && flock(fd, LOCK_EX) == 0) {
  79                         char *fd_s=malloc(8);
  80                         sprintf(fd_s, "%i", fd);
  81                         setenv("IKIWIKI_CGILOCK_FD", fd_s, 1);
  82                 }
  83         }
  84 EOF
  85         }
  86
  87         $Data::Dumper::Indent=0; # no newlines
  88         my $configstring=Data::Dumper->Dump([\%config], ['*config']);
  89         $configstring=~s/\\/\\\\/g;
  90         $configstring=~s/"/\\"/g;
  91         $configstring=~s/\n/\\n/g;
  92
  93         writefile(basename("$wrapper.c"), dirname($wrapper), <<"EOF");
  94 /* A wrapper for ikiwiki, can be safely made suid. */
  95 #include <stdio.h>
  96 #include <sys/types.h>
  97 #include <sys/stat.h>
  98 #include <fcntl.h>
  99 #include <unistd.h>
 100 #include <stdlib.h>
 101 #include <string.h>
 102 #include <sys/file.h>
 103
 104 extern char **environ;
 105 char *newenviron[$#envsave+6];
 106 int i=0;
 107
 108 void addenv(char *var, char *val) {
 109         char *s=malloc(strlen(var)+1+strlen(val)+1);
 110         if (!s)
 111                 perror("malloc");
 112         sprintf(s, "%s=%s", var, val);
 113         newenviron[i++]=s;
 114 }
 115
 116 int main (int argc, char **argv) {
 117         char *s;
 118
 119 $check_commit_hook
 120 @wrapper_hooks
 121 $envsave
 122         newenviron[i++]="HOME=$ENV{HOME}";
 123         newenviron[i++]="WRAPPED_OPTIONS=$configstring";
 124
 125 #ifdef __TINYC__
 126         if (clearenv() != 0) {
 127                 perror("clearenv");
 128                 exit(1);
 129         }
 130         for (; i>0; i--)
 131                 putenv(newenviron[i-1]);
 132 #else
 133         newenviron[i]=NULL;
 134         environ=newenviron;
 135 #endif
 136
 137         if (setregid(getegid(), -1) != 0 &&
 138             setregid(getegid(), -1) != 0) {
 139                 perror("failed to drop real gid");
 140                 exit(1);
 141         }
 142         if (setreuid(geteuid(), -1) != 0 &&
 143             setreuid(geteuid(), -1) != 0) {
 144                 perror("failed to drop real uid");
 145                 exit(1);
 146         }
 147
 148 $pre_exec
 149         execl("$this", "$this", NULL);
 150         perror("exec $this");
 151         exit(1);
 152 }
 153 EOF
 154
 155         my @cc=exists $ENV{CC} ? possibly_foolish_untaint($ENV{CC}) : 'cc';
 156         push @cc, possibly_foolish_untaint($ENV{CFLAGS}) if exists $ENV{CFLAGS};
 157         if (system(@cc, "$wrapper.c", "-o", "$wrapper.new") != 0) {
 158                 #translators: The parameter is a C filename.
 159                 error(sprintf(gettext("failed to compile %s"), "$wrapper.c"));
 160         }
 161         unlink("$wrapper.c");
 162         if (defined $config{wrappergroup}) {
 163                 my $gid=(getgrnam($config{wrappergroup}))[2];
 164                 if (! defined $gid) {
 165                         error(sprintf("bad wrappergroup"));
 166                 }
 167                 if (! chown(-1, $gid, "$wrapper.new")) {
 168                         error("chown $wrapper.new: $!");
 169                 }
 170         }
 171         if (defined $config{wrappermode} &&
 172             ! chmod(oct($config{wrappermode}), "$wrapper.new")) {
 173                 error("chmod $wrapper.new: $!");
 174         }
 175         if (! rename("$wrapper.new", $wrapper)) {
 176                 error("rename $wrapper.new $wrapper: $!");
 177         }
 178         #translators: The parameter is a filename.
 179         printf(gettext("successfully generated %s"), $wrapper);
 180         print "\n";
 181 }
 182
 183 1