IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use URI::Escape q{uri_escape_utf8};
   9 use POSIX;
  10 use open qw{:utf8 :std};
  11
  12 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  13             %pagestate %renderedfiles %oldrenderedfiles %pagesources
  14             %destsources %depends %hooks %forcerebuild $gettext_obj};
  15
  16 use Exporter q{import};
  17 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  18                  bestlink htmllink readfile writefile pagetype srcfile pagename
  19                  displaytime will_render gettext urlto targetpage
  20                  add_underlay
  21                  %config %links %pagestate %renderedfiles
  22                  %pagesources %destsources);
  23 our $VERSION = 2.00; # plugin interface version, next is ikiwiki version
  24 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  25 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  26
  27 # Optimisation.
  28 use Memoize;
  29 memoize("abs2rel");
  30 memoize("pagespec_translate");
  31 memoize("file_pruned");
  32
  33 sub defaultconfig () { #{{{
  34         return
  35         wiki_file_prune_regexps => [qr/(^|\/)\.\.(\/|$)/, qr/^\./, qr/\/\./,
  36                 qr/\.x?html?$/, qr/\.ikiwiki-new$/,
  37                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
  38                 qr/(^|\/)_MTN\//,
  39                 qr/\.dpkg-tmp$/],
  40         wiki_link_regexp => qr{
  41                 \[\[                    # beginning of link
  42                 (?:
  43                         ([^\]\|\n\s]+)  # 1: link text
  44                         \|              # followed by '|'
  45                 )?                      # optional
  46
  47                 ([^\s\]#]+)             # 2: page to link to
  48                 (?:
  49                         \#              # '#', beginning of anchor
  50                         ([^\s\]]+)      # 3: anchor text
  51                 )?                      # optional
  52
  53                 \]\]                    # end of link
  54         }x,
  55         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  56         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  57         verbose => 0,
  58         syslog => 0,
  59         wikiname => "wiki",
  60         default_pageext => "mdwn",
  61         htmlext => "html",
  62         cgi => 0,
  63         post_commit => 0,
  64         rcs => '',
  65         notify => 0,
  66         url => '',
  67         cgiurl => '',
  68         historyurl => '',
  69         diffurl => '',
  70         rss => 0,
  71         atom => 0,
  72         discussion => 1,
  73         rebuild => 0,
  74         refresh => 0,
  75         getctime => 0,
  76         w3mmode => 0,
  77         wrapper => undef,
  78         wrappermode => undef,
  79         svnrepo => undef,
  80         svnpath => "trunk",
  81         gitorigin_branch => "origin",
  82         gitmaster_branch => "master",
  83         srcdir => undef,
  84         destdir => undef,
  85         pingurl => [],
  86         templatedir => "$installdir/share/ikiwiki/templates",
  87         underlaydir => "$installdir/share/ikiwiki/basewiki",
  88         underlaydirs => [],
  89         setup => undef,
  90         adminuser => undef,
  91         adminemail => undef,
  92         plugin => [qw{mdwn inline htmlscrubber passwordauth openid signinedit
  93                       lockedit conditional}],
  94         libdir => undef,
  95         timeformat => '%c',
  96         locale => undef,
  97         sslcookie => 0,
  98         httpauth => 0,
  99         userdir => "",
 100         usedirs => 1,
 101         numbacklinks => 10,
 102         account_creation_password => "",
 103 } #}}}
 104
 105 sub checkconfig () { #{{{
 106         # locale stuff; avoid LC_ALL since it overrides everything
 107         if (defined $ENV{LC_ALL}) {
 108                 $ENV{LANG} = $ENV{LC_ALL};
 109                 delete $ENV{LC_ALL};
 110         }
 111         if (defined $config{locale}) {
 112                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 113                         $ENV{LANG}=$config{locale};
 114                         $gettext_obj=undef;
 115                 }
 116         }
 117
 118         if ($config{w3mmode}) {
 119                 eval q{use Cwd q{abs_path}};
 120                 error($@) if $@;
 121                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 122                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 123                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 124                         unless $config{cgiurl} =~ m!file:///!;
 125                 $config{url}="file://".$config{destdir};
 126         }
 127
 128         if ($config{cgi} && ! length $config{url}) {
 129                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 130         }
 131
 132         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 133                 unless exists $config{wikistatedir};
 134
 135         if ($config{rcs}) {
 136                 eval qq{use IkiWiki::Rcs::$config{rcs}};
 137                 if ($@) {
 138                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 139                 }
 140         }
 141         else {
 142                 require IkiWiki::Rcs::Stub;
 143         }
 144
 145         if (exists $config{umask}) {
 146                 umask(possibly_foolish_untaint($config{umask}));
 147         }
 148
 149         run_hooks(checkconfig => sub { shift->() });
 150
 151         return 1;
 152 } #}}}
 153
 154 sub loadplugins () { #{{{
 155         if (defined $config{libdir}) {
 156                 unshift @INC, possibly_foolish_untaint($config{libdir});
 157         }
 158
 159         loadplugin($_) foreach @{$config{plugin}};
 160
 161         run_hooks(getopt => sub { shift->() });
 162         if (grep /^-/, @ARGV) {
 163                 print STDERR "Unknown option: $_\n"
 164                         foreach grep /^-/, @ARGV;
 165                 usage();
 166         }
 167
 168         return 1;
 169 } #}}}
 170
 171 sub loadplugin ($) { #{{{
 172         my $plugin=shift;
 173
 174         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 175
 176         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 177                          "$installdir/lib/ikiwiki") {
 178                 if (defined $dir && -x "$dir/plugins/$plugin") {
 179                         require IkiWiki::Plugin::external;
 180                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 181                         return 1;
 182                 }
 183         }
 184
 185         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 186         eval qq{use $mod};
 187         if ($@) {
 188                 error("Failed to load plugin $mod: $@");
 189         }
 190         return 1;
 191 } #}}}
 192
 193 sub error ($;$) { #{{{
 194         my $message=shift;
 195         my $cleaner=shift;
 196         if ($config{cgi}) {
 197                 print "Content-type: text/html\n\n";
 198                 print misctemplate(gettext("Error"),
 199                         "<p>".gettext("Error").": $message</p>");
 200         }
 201         log_message('err' => $message) if $config{syslog};
 202         if (defined $cleaner) {
 203                 $cleaner->();
 204         }
 205         die $message."\n";
 206 } #}}}
 207
 208 sub debug ($) { #{{{
 209         return unless $config{verbose};
 210         return log_message(debug => @_);
 211 } #}}}
 212
 213 my $log_open=0;
 214 sub log_message ($$) { #{{{
 215         my $type=shift;
 216
 217         if ($config{syslog}) {
 218                 require Sys::Syslog;
 219                 if (! $log_open) {
 220                         Sys::Syslog::setlogsock('unix');
 221                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 222                         $log_open=1;
 223                 }
 224                 return eval {
 225                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 226                 };
 227         }
 228         elsif (! $config{cgi}) {
 229                 return print "@_\n";
 230         }
 231         else {
 232                 return print STDERR "@_\n";
 233         }
 234 } #}}}
 235
 236 sub possibly_foolish_untaint ($) { #{{{
 237         my $tainted=shift;
 238         my ($untainted)=$tainted=~/(.*)/s;
 239         return $untainted;
 240 } #}}}
 241
 242 sub basename ($) { #{{{
 243         my $file=shift;
 244
 245         $file=~s!.*/+!!;
 246         return $file;
 247 } #}}}
 248
 249 sub dirname ($) { #{{{
 250         my $file=shift;
 251
 252         $file=~s!/*[^/]+$!!;
 253         return $file;
 254 } #}}}
 255
 256 sub pagetype ($) { #{{{
 257         my $page=shift;
 258
 259         if ($page =~ /\.([^.]+)$/) {
 260                 return $1 if exists $hooks{htmlize}{$1};
 261         }
 262         return;
 263 } #}}}
 264
 265 sub pagename ($) { #{{{
 266         my $file=shift;
 267
 268         my $type=pagetype($file);
 269         my $page=$file;
 270         $page=~s/\Q.$type\E*$// if defined $type;
 271         return $page;
 272 } #}}}
 273
 274 sub targetpage ($$) { #{{{
 275         my $page=shift;
 276         my $ext=shift;
 277
 278         if (! $config{usedirs} || $page =~ /^index$/ ) {
 279                 return $page.".".$ext;
 280         } else {
 281                 return $page."/index.".$ext;
 282         }
 283 } #}}}
 284
 285 sub htmlpage ($) { #{{{
 286         my $page=shift;
 287
 288         return targetpage($page, $config{htmlext});
 289 } #}}}
 290
 291 sub srcfile ($) { #{{{
 292         my $file=shift;
 293
 294         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 295         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 296                 return "$dir/$file" if -e "$dir/$file";
 297         }
 298         error("internal error: $file cannot be found in $config{srcdir} or underlay");
 299         return;
 300 } #}}}
 301
 302 sub add_underlay ($) { #{{{
 303         my $dir=shift;
 304
 305         if ($dir=~/^\//) {
 306                 unshift @{$config{underlaydirs}}, $dir;
 307         }
 308         else {
 309                 unshift @{$config{underlaydirs}}, "$config{underlaydir}/../$dir";
 310         }
 311
 312         return 1;
 313 } #}}}
 314
 315 sub readfile ($;$$) { #{{{
 316         my $file=shift;
 317         my $binary=shift;
 318         my $wantfd=shift;
 319
 320         if (-l $file) {
 321                 error("cannot read a symlink ($file)");
 322         }
 323
 324         local $/=undef;
 325         open (my $in, "<", $file) || error("failed to read $file: $!");
 326         binmode($in) if ($binary);
 327         return \*$in if $wantfd;
 328         my $ret=<$in>;
 329         close $in || error("failed to read $file: $!");
 330         return $ret;
 331 } #}}}
 332
 333 sub writefile ($$$;$$) { #{{{
 334         my $file=shift; # can include subdirs
 335         my $destdir=shift; # directory to put file in
 336         my $content=shift;
 337         my $binary=shift;
 338         my $writer=shift;
 339
 340         my $test=$file;
 341         while (length $test) {
 342                 if (-l "$destdir/$test") {
 343                         error("cannot write to a symlink ($test)");
 344                 }
 345                 $test=dirname($test);
 346         }
 347         my $newfile="$destdir/$file.ikiwiki-new";
 348         if (-l $newfile) {
 349                 error("cannot write to a symlink ($newfile)");
 350         }
 351
 352         my $dir=dirname($newfile);
 353         if (! -d $dir) {
 354                 my $d="";
 355                 foreach my $s (split(m!/+!, $dir)) {
 356                         $d.="$s/";
 357                         if (! -d $d) {
 358                                 mkdir($d) || error("failed to create directory $d: $!");
 359                         }
 360                 }
 361         }
 362
 363         my $cleanup = sub { unlink($newfile) };
 364         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 365         binmode($out) if ($binary);
 366         if ($writer) {
 367                 $writer->(\*$out, $cleanup);
 368         }
 369         else {
 370                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 371         }
 372         close $out || error("failed saving $newfile: $!", $cleanup);
 373         rename($newfile, "$destdir/$file") ||
 374                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 375
 376         return 1;
 377 } #}}}
 378
 379 my %cleared;
 380 sub will_render ($$;$) { #{{{
 381         my $page=shift;
 382         my $dest=shift;
 383         my $clear=shift;
 384
 385         # Important security check.
 386         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 387             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 388                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 389         }
 390
 391         if (! $clear || $cleared{$page}) {
 392                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 393         }
 394         else {
 395                 foreach my $old (@{$renderedfiles{$page}}) {
 396                         delete $destsources{$old};
 397                 }
 398                 $renderedfiles{$page}=[$dest];
 399                 $cleared{$page}=1;
 400         }
 401         $destsources{$dest}=$page;
 402
 403         return 1;
 404 } #}}}
 405
 406 sub bestlink ($$) { #{{{
 407         my $page=shift;
 408         my $link=shift;
 409
 410         my $cwd=$page;
 411         if ($link=~s/^\/+//) {
 412                 # absolute links
 413                 $cwd="";
 414         }
 415         $link=~s/\/$//;
 416
 417         do {
 418                 my $l=$cwd;
 419                 $l.="/" if length $l;
 420                 $l.=$link;
 421
 422                 if (exists $links{$l}) {
 423                         return $l;
 424                 }
 425                 elsif (exists $pagecase{lc $l}) {
 426                         return $pagecase{lc $l};
 427                 }
 428         } while $cwd=~s!/?[^/]+$!!;
 429
 430         if (length $config{userdir}) {
 431                 my $l = "$config{userdir}/".lc($link);
 432                 if (exists $links{$l}) {
 433                         return $l;
 434                 }
 435                 elsif (exists $pagecase{lc $l}) {
 436                         return $pagecase{lc $l};
 437                 }
 438         }
 439
 440         #print STDERR "warning: page $page, broken link: $link\n";
 441         return "";
 442 } #}}}
 443
 444 sub isinlinableimage ($) { #{{{
 445         my $file=shift;
 446
 447         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 448 } #}}}
 449
 450 sub pagetitle ($;$) { #{{{
 451         my $page=shift;
 452         my $unescaped=shift;
 453
 454         if ($unescaped) {
 455                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 456         }
 457         else {
 458                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 459         }
 460
 461         return $page;
 462 } #}}}
 463
 464 sub titlepage ($) { #{{{
 465         my $title=shift;
 466         $title=~s/([^-[:alnum:]:+\/.])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 467         return $title;
 468 } #}}}
 469
 470 sub linkpage ($) { #{{{
 471         my $link=shift;
 472         $link=~s/([^-[:alnum:]:+\/._])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 473         return $link;
 474 } #}}}
 475
 476 sub cgiurl (@) { #{{{
 477         my %params=@_;
 478
 479         return $config{cgiurl}."?".
 480                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 481 } #}}}
 482
 483 sub baseurl (;$) { #{{{
 484         my $page=shift;
 485
 486         return "$config{url}/" if ! defined $page;
 487
 488         $page=htmlpage($page);
 489         $page=~s/[^\/]+$//;
 490         $page=~s/[^\/]+\//..\//g;
 491         return $page;
 492 } #}}}
 493
 494 sub abs2rel ($$) { #{{{
 495         # Work around very innefficient behavior in File::Spec if abs2rel
 496         # is passed two relative paths. It's much faster if paths are
 497         # absolute! (Debian bug #376658; fixed in debian unstable now)
 498         my $path="/".shift;
 499         my $base="/".shift;
 500
 501         require File::Spec;
 502         my $ret=File::Spec->abs2rel($path, $base);
 503         $ret=~s/^// if defined $ret;
 504         return $ret;
 505 } #}}}
 506
 507 sub displaytime ($;$) { #{{{
 508         my $time=shift;
 509         my $format=shift;
 510         if (! defined $format) {
 511                 $format=$config{timeformat};
 512         }
 513
 514         # strftime doesn't know about encodings, so make sure
 515         # its output is properly treated as utf8
 516         return decode_utf8(POSIX::strftime($format, localtime($time)));
 517 } #}}}
 518
 519 sub beautify_url ($) { #{{{
 520         my $url=shift;
 521
 522         if ($config{usedirs}) {
 523                 $url =~ s!/index.$config{htmlext}$!/!;
 524         }
 525         $url =~ s!^$!./!; # Browsers don't like empty links...
 526
 527         return $url;
 528 } #}}}
 529
 530 sub urlto ($$) { #{{{
 531         my $to=shift;
 532         my $from=shift;
 533
 534         if (! length $to) {
 535                 return beautify_url(baseurl($from));
 536         }
 537
 538         if (! $destsources{$to}) {
 539                 $to=htmlpage($to);
 540         }
 541
 542         my $link = abs2rel($to, dirname(htmlpage($from)));
 543
 544         return beautify_url($link);
 545 } #}}}
 546
 547 sub htmllink ($$$;@) { #{{{
 548         my $lpage=shift; # the page doing the linking
 549         my $page=shift; # the page that will contain the link (different for inline)
 550         my $link=shift;
 551         my %opts=@_;
 552
 553         $link=~s/\/$//;
 554
 555         my $bestlink;
 556         if (! $opts{forcesubpage}) {
 557                 $bestlink=bestlink($lpage, $link);
 558         }
 559         else {
 560                 $bestlink="$lpage/".lc($link);
 561         }
 562
 563         my $linktext;
 564         if (defined $opts{linktext}) {
 565                 $linktext=$opts{linktext};
 566         }
 567         else {
 568                 $linktext=pagetitle(basename($link));
 569         }
 570
 571         return "<span class=\"selflink\">$linktext</span>"
 572                 if length $bestlink && $page eq $bestlink &&
 573                    ! defined $opts{anchor};
 574
 575         if (! $destsources{$bestlink}) {
 576                 $bestlink=htmlpage($bestlink);
 577
 578                 if (! $destsources{$bestlink}) {
 579                         return $linktext unless length $config{cgiurl};
 580                         return "<span class=\"createlink\"><a href=\"".
 581                                 cgiurl(
 582                                         do => "create",
 583                                         page => pagetitle(lc($link), 1),
 584                                         from => $lpage
 585                                 ).
 586                                 "\">?</a>$linktext</span>"
 587                 }
 588         }
 589
 590         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
 591         $bestlink=beautify_url($bestlink);
 592
 593         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
 594                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 595         }
 596
 597         if (defined $opts{anchor}) {
 598                 $bestlink.="#".$opts{anchor};
 599         }
 600
 601         my @attrs;
 602         if (defined $opts{rel}) {
 603                 push @attrs, ' rel="'.$opts{rel}.'"';
 604         }
 605         if (defined $opts{class}) {
 606                 push @attrs, ' class="'.$opts{class}.'"';
 607         }
 608
 609         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
 610 } #}}}
 611
 612 sub htmlize ($$$) { #{{{
 613         my $page=shift;
 614         my $type=shift;
 615         my $content=shift;
 616
 617         my $oneline = $content !~ /\n/;
 618
 619         if (exists $hooks{htmlize}{$type}) {
 620                 $content=$hooks{htmlize}{$type}{call}->(
 621                         page => $page,
 622                         content => $content,
 623                 );
 624         }
 625         else {
 626                 error("htmlization of $type not supported");
 627         }
 628
 629         run_hooks(sanitize => sub {
 630                 $content=shift->(
 631                         page => $page,
 632                         content => $content,
 633                 );
 634         });
 635
 636         if ($oneline) {
 637                 # hack to get rid of enclosing junk added by markdown
 638                 # and other htmlizers
 639                 $content=~s/^<p>//i;
 640                 $content=~s/<\/p>$//i;
 641                 chomp $content;
 642         }
 643
 644         return $content;
 645 } #}}}
 646
 647 sub linkify ($$$) { #{{{
 648         my $lpage=shift; # the page containing the links
 649         my $page=shift; # the page the link will end up on (different for inline)
 650         my $content=shift;
 651
 652         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 653                 defined $2
 654                         ? ( $1
 655                                 ? "[[$2|$3".($4 ? "#$4" : "")."]]"
 656                                 : htmllink($lpage, $page, linkpage($3),
 657                                         anchor => $4, linktext => pagetitle($2)))
 658                         : ( $1
 659                                 ? "[[$3".($4 ? "#$4" : "")."]]"
 660                                 : htmllink($lpage, $page, linkpage($3),
 661                                         anchor => $4))
 662         }eg;
 663
 664         return $content;
 665 } #}}}
 666
 667 my %preprocessing;
 668 our $preprocess_preview=0;
 669 sub preprocess ($$$;$$) { #{{{
 670         my $page=shift; # the page the data comes from
 671         my $destpage=shift; # the page the data will appear in (different for inline)
 672         my $content=shift;
 673         my $scan=shift;
 674         my $preview=shift;
 675
 676         # Using local because it needs to be set within any nested calls
 677         # of this function.
 678         local $preprocess_preview=$preview if defined $preview;
 679
 680         my $handle=sub {
 681                 my $escape=shift;
 682                 my $command=shift;
 683                 my $params=shift;
 684                 if (length $escape) {
 685                         return "[[$command $params]]";
 686                 }
 687                 elsif (exists $hooks{preprocess}{$command}) {
 688                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 689                         # Note: preserve order of params, some plugins may
 690                         # consider it significant.
 691                         my @params;
 692                         while ($params =~ m{
 693                                 (?:([-\w]+)=)?          # 1: named parameter key?
 694                                 (?:
 695                                         """(.*?)"""     # 2: triple-quoted value
 696                                 |
 697                                         "([^"]+)"       # 3: single-quoted value
 698                                 |
 699                                         (\S+)           # 4: unquoted value
 700                                 )
 701                                 (?:\s+|$)               # delimiter to next param
 702                         }sgx) {
 703                                 my $key=$1;
 704                                 my $val;
 705                                 if (defined $2) {
 706                                         $val=$2;
 707                                         $val=~s/\r\n/\n/mg;
 708                                         $val=~s/^\n+//g;
 709                                         $val=~s/\n+$//g;
 710                                 }
 711                                 elsif (defined $3) {
 712                                         $val=$3;
 713                                 }
 714                                 elsif (defined $4) {
 715                                         $val=$4;
 716                                 }
 717
 718                                 if (defined $key) {
 719                                         push @params, $key, $val;
 720                                 }
 721                                 else {
 722                                         push @params, $val, '';
 723                                 }
 724                         }
 725                         if ($preprocessing{$page}++ > 3) {
 726                                 # Avoid loops of preprocessed pages preprocessing
 727                                 # other pages that preprocess them, etc.
 728                                 #translators: The first parameter is a
 729                                 #translators: preprocessor directive name,
 730                                 #translators: the second a page name, the
 731                                 #translators: third a number.
 732                                 return "[[".sprintf(gettext("%s preprocessing loop detected on %s at depth %i"),
 733                                         $command, $page, $preprocessing{$page}).
 734                                 "]]";
 735                         }
 736                         my $ret;
 737                         if (! $scan) {
 738                                 $ret=$hooks{preprocess}{$command}{call}->(
 739                                         @params,
 740                                         page => $page,
 741                                         destpage => $destpage,
 742                                         preview => $preprocess_preview,
 743                                 );
 744                         }
 745                         else {
 746                                 # use void context during scan pass
 747                                 $hooks{preprocess}{$command}{call}->(
 748                                         @params,
 749                                         page => $page,
 750                                         destpage => $destpage,
 751                                         preview => $preprocess_preview,
 752                                 );
 753                                 $ret="";
 754                         }
 755                         $preprocessing{$page}--;
 756                         return $ret;
 757                 }
 758                 else {
 759                         return "[[$command $params]]";
 760                 }
 761         };
 762
 763         $content =~ s{
 764                 (\\?)           # 1: escape?
 765                 \[\[            # directive open
 766                 ([-\w]+)        # 2: command
 767                 \s+
 768                 (               # 3: the parameters..
 769                         (?:
 770                                 (?:[-\w]+=)?            # named parameter key?
 771                                 (?:
 772                                         """.*?"""       # triple-quoted value
 773                                         |
 774                                         "[^"]+"         # single-quoted value
 775                                         |
 776                                         [^\s\]]+        # unquoted value
 777                                 )
 778                                 \s*                     # whitespace or end
 779                                                         # of directive
 780                         )
 781                 *)              # 0 or more parameters
 782                 \]\]            # directive closed
 783         }{$handle->($1, $2, $3)}sexg;
 784         return $content;
 785 } #}}}
 786
 787 sub filter ($$$) { #{{{
 788         my $page=shift;
 789         my $destpage=shift;
 790         my $content=shift;
 791
 792         run_hooks(filter => sub {
 793                 $content=shift->(page => $page, destpage => $destpage,
 794                         content => $content);
 795         });
 796
 797         return $content;
 798 } #}}}
 799
 800 sub indexlink () { #{{{
 801         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 802 } #}}}
 803
 804 my $wikilock;
 805
 806 sub lockwiki (;$) { #{{{
 807         my $wait=@_ ? shift : 1;
 808         # Take an exclusive lock on the wiki to prevent multiple concurrent
 809         # run issues. The lock will be dropped on program exit.
 810         if (! -d $config{wikistatedir}) {
 811                 mkdir($config{wikistatedir});
 812         }
 813         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
 814                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 815         if (! flock($wikilock, 2 | 4)) { # LOCK_EX | LOCK_NB
 816                 if ($wait) {
 817                         debug("wiki seems to be locked, waiting for lock");
 818                         my $wait=600; # arbitrary, but don't hang forever to
 819                                       # prevent process pileup
 820                         for (1..$wait) {
 821                                 return if flock($wikilock, 2 | 4);
 822                                 sleep 1;
 823                         }
 824                         error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 825                 }
 826                 else {
 827                         return 0;
 828                 }
 829         }
 830         return 1;
 831 } #}}}
 832
 833 sub unlockwiki () { #{{{
 834         return close($wikilock) if $wikilock;
 835         return;
 836 } #}}}
 837
 838 my $commitlock;
 839
 840 sub commit_hook_enabled () { #{{{
 841         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
 842                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 843         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
 844                 close($commitlock) || error("failed closing commitlock: $!");
 845                 return 0;
 846         }
 847         close($commitlock) || error("failed closing commitlock: $!");
 848         return 1;
 849 } #}}}
 850
 851 sub disable_commit_hook () { #{{{
 852         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
 853                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 854         if (! flock($commitlock, 2)) { # LOCK_EX
 855                 error("failed to get commit lock");
 856         }
 857         return 1;
 858 } #}}}
 859
 860 sub enable_commit_hook () { #{{{
 861         return close($commitlock) if $commitlock;
 862         return;
 863 } #}}}
 864
 865 sub loadindex () { #{{{
 866         %oldrenderedfiles=%pagectime=();
 867         if (! $config{rebuild}) {
 868                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
 869                         %destsources=%renderedfiles=%pagecase=();
 870         }
 871         open (my $in, "<", "$config{wikistatedir}/index") || return;
 872         while (<$in>) {
 873                 $_=possibly_foolish_untaint($_);
 874                 chomp;
 875                 my %items;
 876                 $items{link}=[];
 877                 $items{dest}=[];
 878                 foreach my $i (split(/ /, $_)) {
 879                         my ($item, $val)=split(/=/, $i, 2);
 880                         push @{$items{$item}}, decode_entities($val);
 881                 }
 882
 883                 next unless exists $items{src}; # skip bad lines for now
 884
 885                 my $page=pagename($items{src}[0]);
 886                 if (! $config{rebuild}) {
 887                         $pagesources{$page}=$items{src}[0];
 888                         $pagemtime{$page}=$items{mtime}[0];
 889                         $oldlinks{$page}=[@{$items{link}}];
 890                         $links{$page}=[@{$items{link}}];
 891                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 892                         $destsources{$_}=$page foreach @{$items{dest}};
 893                         $renderedfiles{$page}=[@{$items{dest}}];
 894                         $pagecase{lc $page}=$page;
 895                         foreach my $k (grep /_/, keys %items) {
 896                                 my ($id, $key)=split(/_/, $k, 2);
 897                                 $pagestate{$page}{decode_entities($id)}{decode_entities($key)}=$items{$k}[0];
 898                         }
 899                 }
 900                 $oldrenderedfiles{$page}=[@{$items{dest}}];
 901                 $pagectime{$page}=$items{ctime}[0];
 902         }
 903         return close($in);
 904 } #}}}
 905
 906 sub saveindex () { #{{{
 907         run_hooks(savestate => sub { shift->() });
 908
 909         my %hookids;
 910         foreach my $type (keys %hooks) {
 911                 $hookids{encode_entities($_)}=1 foreach keys %{$hooks{$type}};
 912         }
 913         my @hookids=sort keys %hookids;
 914
 915         if (! -d $config{wikistatedir}) {
 916                 mkdir($config{wikistatedir});
 917         }
 918         my $newfile="$config{wikistatedir}/index.new";
 919         my $cleanup = sub { unlink($newfile) };
 920         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
 921         foreach my $page (keys %pagemtime) {
 922                 next unless $pagemtime{$page};
 923                 my $line="mtime=$pagemtime{$page} ".
 924                         "ctime=$pagectime{$page} ".
 925                         "src=$pagesources{$page}";
 926                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 927                 my %count;
 928                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 929                 if (exists $depends{$page}) {
 930                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 931                 }
 932                 if (exists $pagestate{$page}) {
 933                         foreach my $id (@hookids) {
 934                                 foreach my $key (keys %{$pagestate{$page}{$id}}) {
 935                                         $line.=' '.$id.'_'.encode_entities($key)."=".encode_entities($pagestate{$page}{$id}{$key});
 936                                 }
 937                         }
 938                 }
 939                 print $out $line."\n" || error("failed writing to $newfile: $!", $cleanup);
 940         }
 941         close $out || error("failed saving to $newfile: $!", $cleanup);
 942         rename($newfile, "$config{wikistatedir}/index") ||
 943                 error("failed renaming $newfile to $config{wikistatedir}/index", $cleanup);
 944
 945         return 1;
 946 } #}}}
 947
 948 sub template_file ($) { #{{{
 949         my $template=shift;
 950
 951         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
 952                 return "$dir/$template" if -e "$dir/$template";
 953         }
 954         return;
 955 } #}}}
 956
 957 sub template_params (@) { #{{{
 958         my $filename=template_file(shift);
 959
 960         if (! defined $filename) {
 961                 return if wantarray;
 962                 return "";
 963         }
 964
 965         my @ret=(
 966                 filter => sub {
 967                         my $text_ref = shift;
 968                         ${$text_ref} = decode_utf8(${$text_ref});
 969                 },
 970                 filename => $filename,
 971                 loop_context_vars => 1,
 972                 die_on_bad_params => 0,
 973                 @_
 974         );
 975         return wantarray ? @ret : {@ret};
 976 } #}}}
 977
 978 sub template ($;@) { #{{{
 979         require HTML::Template;
 980         return HTML::Template->new(template_params(@_));
 981 } #}}}
 982
 983 sub misctemplate ($$;@) { #{{{
 984         my $title=shift;
 985         my $pagebody=shift;
 986
 987         my $template=template("misc.tmpl");
 988         $template->param(
 989                 title => $title,
 990                 indexlink => indexlink(),
 991                 wikiname => $config{wikiname},
 992                 pagebody => $pagebody,
 993                 baseurl => baseurl(),
 994                 @_,
 995         );
 996         run_hooks(pagetemplate => sub {
 997                 shift->(page => "", destpage => "", template => $template);
 998         });
 999         return $template->output;
1000 }#}}}
1001
1002 sub hook (@) { # {{{
1003         my %param=@_;
1004
1005         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
1006                 error 'hook requires type, call, and id parameters';
1007         }
1008
1009         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
1010
1011         $hooks{$param{type}}{$param{id}}=\%param;
1012         return 1;
1013 } # }}}
1014
1015 sub run_hooks ($$) { # {{{
1016         # Calls the given sub for each hook of the given type,
1017         # passing it the hook function to call.
1018         my $type=shift;
1019         my $sub=shift;
1020
1021         if (exists $hooks{$type}) {
1022                 my @deferred;
1023                 foreach my $id (keys %{$hooks{$type}}) {
1024                         if ($hooks{$type}{$id}{last}) {
1025                                 push @deferred, $id;
1026                                 next;
1027                         }
1028                         $sub->($hooks{$type}{$id}{call});
1029                 }
1030                 foreach my $id (@deferred) {
1031                         $sub->($hooks{$type}{$id}{call});
1032                 }
1033         }
1034
1035         return 1;
1036 } #}}}
1037
1038 sub globlist_to_pagespec ($) { #{{{
1039         my @globlist=split(' ', shift);
1040
1041         my (@spec, @skip);
1042         foreach my $glob (@globlist) {
1043                 if ($glob=~/^!(.*)/) {
1044                         push @skip, $glob;
1045                 }
1046                 else {
1047                         push @spec, $glob;
1048                 }
1049         }
1050
1051         my $spec=join(' or ', @spec);
1052         if (@skip) {
1053                 my $skip=join(' and ', @skip);
1054                 if (length $spec) {
1055                         $spec="$skip and ($spec)";
1056                 }
1057                 else {
1058                         $spec=$skip;
1059                 }
1060         }
1061         return $spec;
1062 } #}}}
1063
1064 sub is_globlist ($) { #{{{
1065         my $s=shift;
1066         return ( $s =~ /[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or" );
1067 } #}}}
1068
1069 sub safequote ($) { #{{{
1070         my $s=shift;
1071         $s=~s/[{}]//g;
1072         return "q{$s}";
1073 } #}}}
1074
1075 sub add_depends ($$) { #{{{
1076         my $page=shift;
1077         my $pagespec=shift;
1078
1079         if (! exists $depends{$page}) {
1080                 $depends{$page}=$pagespec;
1081         }
1082         else {
1083                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
1084         }
1085
1086         return 1;
1087 } # }}}
1088
1089 sub file_pruned ($$) { #{{{
1090         require File::Spec;
1091         my $file=File::Spec->canonpath(shift);
1092         my $base=File::Spec->canonpath(shift);
1093         $file =~ s#^\Q$base\E/+##;
1094
1095         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1096         return $file =~ m/$regexp/ && $file ne $base;
1097 } #}}}
1098
1099 sub gettext { #{{{
1100         # Only use gettext in the rare cases it's needed.
1101         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1102             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1103             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1104                 if (! $gettext_obj) {
1105                         $gettext_obj=eval q{
1106                                 use Locale::gettext q{textdomain};
1107                                 Locale::gettext->domain('ikiwiki')
1108                         };
1109                         if ($@) {
1110                                 print STDERR "$@";
1111                                 $gettext_obj=undef;
1112                                 return shift;
1113                         }
1114                 }
1115                 return $gettext_obj->get(shift);
1116         }
1117         else {
1118                 return shift;
1119         }
1120 } #}}}
1121
1122 sub pagespec_merge ($$) { #{{{
1123         my $a=shift;
1124         my $b=shift;
1125
1126         return $a if $a eq $b;
1127
1128         # Support for old-style GlobLists.
1129         if (is_globlist($a)) {
1130                 $a=globlist_to_pagespec($a);
1131         }
1132         if (is_globlist($b)) {
1133                 $b=globlist_to_pagespec($b);
1134         }
1135
1136         return "($a) or ($b)";
1137 } #}}}
1138
1139 sub pagespec_translate ($) { #{{{
1140         # This assumes that $page is in scope in the function
1141         # that evalulates the translated pagespec code.
1142         my $spec=shift;
1143
1144         # Support for old-style GlobLists.
1145         if (is_globlist($spec)) {
1146                 $spec=globlist_to_pagespec($spec);
1147         }
1148
1149         # Convert spec to perl code.
1150         my $code="";
1151         while ($spec=~m{
1152                 \s*             # ignore whitespace
1153                 (               # 1: match a single word
1154                         \!              # !
1155                 |
1156                         \(              # (
1157                 |
1158                         \)              # )
1159                 |
1160                         \w+\([^\)]*\)   # command(params)
1161                 |
1162                         [^\s()]+        # any other text
1163                 )
1164                 \s*             # ignore whitespace
1165         }igx) {
1166                 my $word=$1;
1167                 if (lc $word eq 'and') {
1168                         $code.=' &&';
1169                 }
1170                 elsif (lc $word eq 'or') {
1171                         $code.=' ||';
1172                 }
1173                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
1174                         $code.=' '.$word;
1175                 }
1176                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
1177                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
1178                                 $code.="IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).", \@params)";
1179                         }
1180                         else {
1181                                 $code.=' 0';
1182                         }
1183                 }
1184                 else {
1185                         $code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \@params)";
1186                 }
1187         }
1188
1189         return $code;
1190 } #}}}
1191
1192 sub pagespec_match ($$;@) { #{{{
1193         my $page=shift;
1194         my $spec=shift;
1195         my @params=@_;
1196
1197         # Backwards compatability with old calling convention.
1198         if (@params == 1) {
1199                 unshift @params, 'location';
1200         }
1201
1202         my $ret=eval pagespec_translate($spec);
1203         return IkiWiki::FailReason->new('syntax error') if $@;
1204         return $ret;
1205 } #}}}
1206
1207 package IkiWiki::FailReason;
1208
1209 use overload ( #{{{
1210         '""'    => sub { ${$_[0]} },
1211         '0+'    => sub { 0 },
1212         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
1213         fallback => 1,
1214 ); #}}}
1215
1216 sub new { #{{{
1217         return bless \$_[1], $_[0];
1218 } #}}}
1219
1220 package IkiWiki::SuccessReason;
1221
1222 use overload ( #{{{
1223         '""'    => sub { ${$_[0]} },
1224         '0+'    => sub { 1 },
1225         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
1226         fallback => 1,
1227 ); #}}}
1228
1229 sub new { #{{{
1230         return bless \$_[1], $_[0];
1231 }; #}}}
1232
1233 package IkiWiki::PageSpec;
1234
1235 sub match_glob ($$;@) { #{{{
1236         my $page=shift;
1237         my $glob=shift;
1238         my %params=@_;
1239
1240         my $from=exists $params{location} ? $params{location} : '';
1241
1242         # relative matching
1243         if ($glob =~ m!^\./!) {
1244                 $from=~s#/?[^/]+$##;
1245                 $glob=~s#^\./##;
1246                 $glob="$from/$glob" if length $from;
1247         }
1248
1249         # turn glob into safe regexp
1250         $glob=quotemeta($glob);
1251         $glob=~s/\\\*/.*/g;
1252         $glob=~s/\\\?/./g;
1253
1254         if ($page=~/^$glob$/i) {
1255                 return IkiWiki::SuccessReason->new("$glob matches $page");
1256         }
1257         else {
1258                 return IkiWiki::FailReason->new("$glob does not match $page");
1259         }
1260 } #}}}
1261
1262 sub match_link ($$;@) { #{{{
1263         my $page=shift;
1264         my $link=lc(shift);
1265         my %params=@_;
1266
1267         my $from=exists $params{location} ? $params{location} : '';
1268
1269         # relative matching
1270         if ($link =~ m!^\.! && defined $from) {
1271                 $from=~s#/?[^/]+$##;
1272                 $link=~s#^\./##;
1273                 $link="$from/$link" if length $from;
1274         }
1275
1276         my $links = $IkiWiki::links{$page};
1277         return IkiWiki::FailReason->new("$page has no links") unless $links && @{$links};
1278         my $bestlink = IkiWiki::bestlink($from, $link);
1279         foreach my $p (@{$links}) {
1280                 if (length $bestlink) {
1281                         return IkiWiki::SuccessReason->new("$page links to $link")
1282                                 if $bestlink eq IkiWiki::bestlink($page, $p);
1283                 }
1284                 else {
1285                         return IkiWiki::SuccessReason->new("$page links to page $p matching $link")
1286                                 if match_glob($p, $link, %params);
1287                 }
1288         }
1289         return IkiWiki::FailReason->new("$page does not link to $link");
1290 } #}}}
1291
1292 sub match_backlink ($$;@) { #{{{
1293         return match_link($_[1], $_[0], @_);
1294 } #}}}
1295
1296 sub match_created_before ($$;@) { #{{{
1297         my $page=shift;
1298         my $testpage=shift;
1299
1300         if (exists $IkiWiki::pagectime{$testpage}) {
1301                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
1302                         return IkiWiki::SuccessReason->new("$page created before $testpage");
1303                 }
1304                 else {
1305                         return IkiWiki::FailReason->new("$page not created before $testpage");
1306                 }
1307         }
1308         else {
1309                 return IkiWiki::FailReason->new("$testpage has no ctime");
1310         }
1311 } #}}}
1312
1313 sub match_created_after ($$;@) { #{{{
1314         my $page=shift;
1315         my $testpage=shift;
1316
1317         if (exists $IkiWiki::pagectime{$testpage}) {
1318                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
1319                         return IkiWiki::SuccessReason->new("$page created after $testpage");
1320                 }
1321                 else {
1322                         return IkiWiki::FailReason->new("$page not created after $testpage");
1323                 }
1324         }
1325         else {
1326                 return IkiWiki::FailReason->new("$testpage has no ctime");
1327         }
1328 } #}}}
1329
1330 sub match_creation_day ($$;@) { #{{{
1331         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
1332                 return IkiWiki::SuccessReason->new('creation_day matched');
1333         }
1334         else {
1335                 return IkiWiki::FailReason->new('creation_day did not match');
1336         }
1337 } #}}}
1338
1339 sub match_creation_month ($$;@) { #{{{
1340         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
1341                 return IkiWiki::SuccessReason->new('creation_month matched');
1342         }
1343         else {
1344                 return IkiWiki::FailReason->new('creation_month did not match');
1345         }
1346 } #}}}
1347
1348 sub match_creation_year ($$;@) { #{{{
1349         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
1350                 return IkiWiki::SuccessReason->new('creation_year matched');
1351         }
1352         else {
1353                 return IkiWiki::FailReason->new('creation_year did not match');
1354         }
1355 } #}}}
1356
1357 sub match_user ($$;@) { #{{{
1358         shift;
1359         my $user=shift;
1360         my %params=@_;
1361
1362         return IkiWiki::FailReason->new('cannot match user')
1363                 unless exists $params{user};
1364         if ($user eq $params{user}) {
1365                 return IkiWiki::SuccessReason->new("user is $user")
1366         }
1367         else {
1368                 return IkiWiki::FailReason->new("user is not $user");
1369         }
1370 } #}}}
1371
1372 1