ikiwiki

   1 #!/usr/bin/perl -T
   2
   3 use warnings;
   4 use strict;
   5 use File::Find;
   6 use Memoize;
   7 use File::Spec;
   8
   9 BEGIN {
  10         $blosxom::version="is a proper perl module too much to ask?";
  11         do "/usr/bin/markdown";
  12 }
  13
  14 memoize('pagename');
  15 memoize('bestlink');
  16
  17 sub usage {
  18         die "usage: ikiwiki [options] source dest\n";
  19 }
  20
  21 my $link=qr/\[\[([^\s]+)\]\]/;
  22 my $verbose=0;
  23 my $rebuild=0;
  24 my $wikiname="wiki";
  25 if (grep /^-/, @ARGV) {
  26         eval {use Getopt::Long};
  27         GetOptions(
  28                 "wikiname=s" => \$wikiname,
  29                 "verbose|v" => \$verbose,
  30                 "rebuild" => \$rebuild,
  31         ) || usage();
  32 }
  33 usage() unless @ARGV == 2;
  34 my ($srcdir) = shift =~ /(.*)/; # untaint
  35 my ($destdir) = shift =~ /(.*)/; # untaint
  36
  37 my %links;
  38 my %oldlinks;
  39 my %oldpagemtime;
  40 my %renderedfiles;
  41 my %pagesources;
  42
  43 sub error ($) {
  44         die @_;
  45 }
  46
  47 sub debug ($) {
  48         print "@_\n" if $verbose;
  49 }
  50
  51 sub mtime ($) {
  52         my $page=shift;
  53
  54         return (stat($page))[9];
  55 }
  56
  57 sub basename {
  58         my $file=shift;
  59
  60         $file=~s!.*/!!;
  61         return $file;
  62 }
  63
  64 sub dirname {
  65         my $file=shift;
  66
  67         $file=~s!/?[^/]+$!!;
  68         return $file;
  69 }
  70
  71 sub pagetype ($) {
  72         my $page=shift;
  73
  74         if ($page =~ /\.mdwn$/) {
  75                 return ".mdwn";
  76         }
  77         else {
  78                 return "unknown";
  79         }
  80 }
  81
  82 sub pagename ($) {
  83         my $file=shift;
  84
  85         my $type=pagetype($file);
  86         my $page=$file;
  87         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
  88         return $page;
  89 }
  90
  91 sub htmlpage ($) {
  92         my $page=shift;
  93
  94         return $page.".html";
  95 }
  96
  97 sub readpage ($) {
  98         my $page=shift;
  99
 100         local $/=undef;
 101         open (PAGE, "$srcdir/$page") || error("failed to read $page: $!");
 102         my $ret=<PAGE>;
 103         close PAGE;
 104         return $ret;
 105 }
 106
 107 sub writepage ($$) {
 108         my $page=shift;
 109         my $content=shift;
 110
 111         my $dir=dirname("$destdir/$page");
 112         if (! -d $dir) {
 113                 my $d="";
 114                 foreach my $s (split(m!/+!, $dir)) {
 115                         $d.="$s/";
 116                         if (! -d $d) {
 117                                 mkdir($d) || error("failed to create directory $d: $!");
 118                         }
 119                 }
 120         }
 121
 122         open (PAGE, ">$destdir/$page") || error("failed to write $page: $!");
 123         print PAGE $content;
 124         close PAGE;
 125 }
 126
 127 sub findlinks {
 128         my $content=shift;
 129
 130         my @links;
 131         while ($content =~ /$link/g) {
 132                 push @links, lc($1);
 133         }
 134         return @links;
 135 }
 136
 137 # Given a page and the text of a link on the page, determine which existing
 138 # page that link best points to. Prefers pages under a subdirectory with
 139 # the same name as the source page, failing that goes down the directory tree
 140 # to the base looking for matching pages.
 141 sub bestlink ($$) {
 142         my $page=shift;
 143         my $link=lc(shift);
 144
 145         my $cwd=$page;
 146         do {
 147                 my $l=$cwd;
 148                 $l.="/" if length $l;
 149                 $l.=$link;
 150
 151                 if (exists $links{$l}) {
 152                         #debug("for $page, \"$link\", use $l");
 153                         return $l;
 154                 }
 155         } while $cwd=~s!/?[^/]+$!!;
 156
 157         print STDERR "warning: page $page, broken link: $link\n";
 158         return "";
 159 }
 160
 161 sub isinlinableimage ($) {
 162         my $file=shift;
 163
 164         $file=~/\.(png|gif|jpg|jpeg)$/;
 165 }
 166
 167 sub htmllink ($$) {
 168         my $page=shift;
 169         my $link=shift;
 170
 171         my $bestlink=bestlink($page, $link);
 172
 173         return $link if $page eq $bestlink;
 174
 175         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 176                 $bestlink=htmlpage($bestlink);
 177         }
 178         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 179                 return "<a href=\"?\">?</a>$link"
 180         }
 181
 182         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 183
 184         if (isinlinableimage($bestlink)) {
 185                 return "<img src=\"$bestlink\">";
 186         }
 187         return "<a href=\"$bestlink\">$link</a>";
 188 }
 189
 190 sub linkify ($$) {
 191         my $content=shift;
 192         my $file=shift;
 193
 194         $content =~ s/$link/htmllink(pagename($file), $1)/eg;
 195
 196         return $content;
 197 }
 198
 199 sub htmlize ($$) {
 200         my $type=shift;
 201         my $content=shift;
 202
 203         if ($type eq '.mdwn') {
 204                 return Markdown::Markdown($content);
 205         }
 206         else {
 207                 error("htmlization of $type not supported");
 208         }
 209 }
 210
 211 sub linkbacks ($$) {
 212         my $content=shift;
 213         my $page=shift;
 214
 215         my @links;
 216         foreach my $p (keys %links) {
 217                 if (grep { $_ eq $page } @{$links{$p}}) {
 218                         my $href=File::Spec->abs2rel(htmlpage($p), dirname($page));
 219                         push @links, "<a href=\"$href\">$p</a>";
 220                 }
 221         }
 222
 223         $content.="<hr><p>Links: ".join(" ", sort @links)."</p>\n";
 224 }
 225
 226 sub finalize ($$) {
 227         my $content=shift;
 228         my $page=shift;
 229
 230         my $title=basename($page);
 231         $title=~s/_/ /g;
 232
 233         my $pagelink="";
 234         my $path="";
 235         foreach my $dir (reverse split("/", $page)) {
 236                 if (length($pagelink)) {
 237                         $pagelink="<a href=\"$path$dir.html\">$dir</a>/ $pagelink";
 238                 }
 239                 else {
 240                         $pagelink=$dir;
 241                 }
 242                 $path.="../";
 243         }
 244         $path=~s/\.\.\/$/index.html/;
 245         $pagelink="<a href=\"$path\">$wikiname</a>/ $pagelink";
 246
 247         $content="<html>\n<head><title>$title</title></head>\n<body>\n".
 248                   "<h1>$pagelink</h1>\n".
 249                   $content.
 250                   "</body>\n</html>\n";
 251
 252         return $content;
 253 }
 254
 255 sub render ($) {
 256         my $file=shift;
 257
 258         my $type=pagetype($file);
 259         my $content=readpage($file);
 260         if ($type ne 'unknown') {
 261                 my $page=pagename($file);
 262
 263                 $links{$page}=[findlinks($content)];
 264
 265                 $content=linkify($content, $file);
 266                 $content=htmlize($type, $content);
 267                 $content=linkbacks($content, $page);
 268                 $content=finalize($content, $page);
 269
 270                 writepage(htmlpage($page), $content);
 271                 $oldpagemtime{$page}=time;
 272                 $renderedfiles{$page}=htmlpage($page);
 273         }
 274         else {
 275                 $links{$file}=[];
 276                 writepage($file, $content);
 277                 $oldpagemtime{$file}=time;
 278                 $renderedfiles{$file}=$file;
 279         }
 280 }
 281
 282 sub loadindex () {
 283         open (IN, "$srcdir/.index") || return;
 284         while (<IN>) {
 285                 ($_)=/(.*)/; # untaint
 286                 chomp;
 287                 my ($mtime, $file, $rendered, @links)=split(' ', $_);
 288                 my $page=pagename($file);
 289                 $pagesources{$page}=$file;
 290                 $oldpagemtime{$page}=$mtime;
 291                 $links{$page}=[@links];
 292                 $oldlinks{$page}=[@links];
 293                 $renderedfiles{$page}=$rendered;
 294         }
 295         close IN;
 296 }
 297
 298 sub saveindex () {
 299         open (OUT, ">$srcdir/.index") || error("cannot write to .index: $!");
 300         foreach my $page (keys %oldpagemtime) {
 301         print OUT "$oldpagemtime{$page} $pagesources{$page} $renderedfiles{$page} ".
 302                   join(" ", @{$links{$page}})."\n"
 303                         if $oldpagemtime{$page};
 304         }
 305         close OUT;
 306 }
 307
 308 sub prune ($) {
 309         my $file=shift;
 310
 311         unlink($file);
 312         my $dir=dirname($file);
 313         while (rmdir($dir)) {
 314                 $dir=dirname($dir);
 315         }
 316 }
 317
 318 sub refresh () {
 319         # Find existing pages.
 320         my %exists;
 321         my @files;
 322         find({
 323                 no_chdir => 1,
 324                 wanted => sub {
 325                         if (/\/\.svn\//) {
 326                                 $File::Find::prune=1;
 327                         }
 328                         elsif (! -d $_ && ! /\.html$/ && ! /\/\./) {
 329                                 my ($f)=/(^[-A-Za-z0-9_.:\/+]+$)/; # untaint
 330                                 if (! defined $f) {
 331                                         warn("skipping bad filename $_\n");
 332                                 }
 333                                 else {
 334                                         $f=~s/^\Q$srcdir\E\/?//;
 335                                         push @files, $f;
 336                                         $exists{pagename($f)}=1;
 337                                 }
 338                         }
 339                 },
 340         }, $srcdir);
 341
 342         my %rendered;
 343
 344         # check for added or removed pages
 345         my @add;
 346         foreach my $file (@files) {
 347                 my $page=pagename($file);
 348                 if (! $oldpagemtime{$page}) {
 349                         debug("new page $page");
 350                         push @add, $file;
 351                         $links{$page}=[];
 352                         $pagesources{$page}=$file;
 353                 }
 354         }
 355         my @del;
 356         foreach my $page (keys %oldpagemtime) {
 357                 if (! $exists{$page}) {
 358                         debug("removing old page $page");
 359                         push @del, $renderedfiles{$page};
 360                         prune($destdir."/".$renderedfiles{$page});
 361                         delete $renderedfiles{$page};
 362                         $oldpagemtime{$page}=0;
 363                 }
 364         }
 365
 366         # render any updated files
 367         foreach my $file (@files) {
 368                 my $page=pagename($file);
 369
 370                 if (! exists $oldpagemtime{$page} ||
 371                     mtime("$srcdir/$file") > $oldpagemtime{$page}) {
 372                         debug("rendering changed file $file");
 373                         render($file);
 374                         $rendered{$file}=1;
 375                 }
 376                 elsif ($rebuild) {
 377                         debug("rebuilding unchanged file $file");
 378                         render($file);
 379                         $rendered{$file}=1;
 380                 }
 381         }
 382
 383         # if any files were added or removed, check to see if each page
 384         # needs an update due to linking to them
 385         if (@add || @del) {
 386 FILE:           foreach my $file (@files) {
 387                         next if $rendered{$file};
 388                         my $page=pagename($file);
 389                         foreach my $f (@add, @del) {
 390                                 my $p=pagename($f);
 391                                 foreach my $link (@{$links{$page}}) {
 392                                         if (bestlink($page, $link) eq $p) {
 393                                                 debug("rendering $file, which links to $p");
 394                                                 render($file);
 395                                                 next FILE;
 396                                         }
 397                                 }
 398                         }
 399                 }
 400         }
 401
 402         # handle linkbacks; if a page has added/removed links, update the
 403         # pages it links to
 404         # TODO: inefficient; pages may get rendered above and again here;
 405         # problem is the linkbacks could be wrong in the first pass render
 406         # above.
 407         if (%rendered) {
 408                 my %linkchanged;
 409                 foreach my $file (keys %rendered, @del) {
 410                         my $pagename=pagename($file);
 411                         if (exists $links{$pagename}) {
 412                                 foreach my $link (@{$links{$pagename}}) {
 413                                         if (! exists $oldlinks{$pagename} ||
 414                                             ! grep { $_ eq $link } @{$oldlinks{$pagename}}) {
 415                                                 $linkchanged{$link}=1;
 416                                         }
 417                                 }
 418                         }
 419                         if (exists $oldlinks{$pagename}) {
 420                                 foreach my $link (@{$oldlinks{$pagename}}) {
 421                                         if (! exists $links{$pagename} ||
 422                                             ! grep { $_ eq $link } @{$links{$pagename}}) {
 423                                                 $linkchanged{$link}=1;
 424                                         }
 425                                 }
 426                         }
 427                 }
 428                 foreach my $link (keys %linkchanged) {
 429                         my $linkfile=$pagesources{$link};
 430                         if (defined $linkfile) {
 431                                 debug("rendering $linkfile, to update its linkbacks");
 432                                 render($linkfile);
 433                         }
 434                 }
 435         }
 436 }
 437
 438 loadindex();
 439 refresh();
 440 saveindex();