IkiWiki/Plugin/git.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::git;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use Encode;
   8 use open qw{:utf8 :std};
   9
  10 my $sha1_pattern     = qr/[0-9a-fA-F]{40}/; # pattern to validate Git sha1sums
  11 my $dummy_commit_msg = 'dummy commit';      # message to skip in recent changes
  12 my $no_chdir=0;
  13
  14 sub import {
  15         hook(type => "checkconfig", id => "git", call => \&checkconfig);
  16         hook(type => "getsetup", id => "git", call => \&getsetup);
  17         hook(type => "genwrapper", id => "git", call => \&genwrapper);
  18         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  19         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  20         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  21         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  22         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  23         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  24         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  25         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  26         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  27         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  28         hook(type => "rcs", id => "rcs_receive", call => \&rcs_receive);
  29 }
  30
  31 sub checkconfig () {
  32         if (! defined $config{gitorigin_branch}) {
  33                 $config{gitorigin_branch}="origin";
  34         }
  35         if (! defined $config{gitmaster_branch}) {
  36                 $config{gitmaster_branch}="master";
  37         }
  38         if (defined $config{git_wrapper} &&
  39             length $config{git_wrapper}) {
  40                 push @{$config{wrappers}}, {
  41                         wrapper => $config{git_wrapper},
  42                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  43                 };
  44         }
  45
  46         if (defined $config{git_test_receive_wrapper} &&
  47             length $config{git_test_receive_wrapper}) {
  48                 push @{$config{wrappers}}, {
  49                         test_receive => 1,
  50                         wrapper => $config{git_test_receive_wrapper},
  51                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  52                 };
  53         }
  54
  55         # Run receive test only if being called by the wrapper, and not
  56         # when generating same.
  57         if ($config{test_receive} && ! exists $config{wrapper}) {
  58                 require IkiWiki::Receive;
  59                 IkiWiki::Receive::test();
  60         }
  61 }
  62
  63 sub getsetup () {
  64         return
  65                 plugin => {
  66                         safe => 0, # rcs plugin
  67                         rebuild => undef,
  68                 },
  69                 git_wrapper => {
  70                         type => "string",
  71                         example => "/git/wiki.git/hooks/post-update",
  72                         description => "git hook to generate",
  73                         safe => 0, # file
  74                         rebuild => 0,
  75                 },
  76                 git_wrappermode => {
  77                         type => "string",
  78                         example => '06755',
  79                         description => "mode for git_wrapper (can safely be made suid)",
  80                         safe => 0,
  81                         rebuild => 0,
  82                 },
  83                 git_test_receive_wrapper => {
  84                         type => "string",
  85                         example => "/git/wiki.git/hooks/pre-receive",
  86                         description => "git pre-receive hook to generate",
  87                         safe => 0, # file
  88                         rebuild => 0,
  89                 },
  90                 untrusted_committers => {
  91                         type => "string",
  92                         example => [],
  93                         description => "unix users whose commits should be checked by the pre-receive hook",
  94                         safe => 0,
  95                         rebuild => 0,
  96                 },
  97                 historyurl => {
  98                         type => "string",
  99                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=history;f=[[file]]",
 100                         description => "gitweb url to show file history ([[file]] substituted)",
 101                         safe => 1,
 102                         rebuild => 1,
 103                 },
 104                 diffurl => {
 105                         type => "string",
 106                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=blobdiff;f=[[file]];h=[[sha1_to]];hp=[[sha1_from]];hb=[[sha1_commit]];hpb=[[sha1_parent]]",
 107                         description => "gitweb url to show a diff ([[file]], [[sha1_to]], [[sha1_from]], [[sha1_commit]], and [[sha1_parent]] substituted)",
 108                         safe => 1,
 109                         rebuild => 1,
 110                 },
 111                 gitorigin_branch => {
 112                         type => "string",
 113                         example => "origin",
 114                         description => "where to pull and push changes (set to empty string to disable)",
 115                         safe => 0, # paranoia
 116                         rebuild => 0,
 117                 },
 118                 gitmaster_branch => {
 119                         type => "string",
 120                         example => "master",
 121                         description => "branch that the wiki is stored in",
 122                         safe => 0, # paranoia
 123                         rebuild => 0,
 124                 },
 125 }
 126
 127 sub genwrapper {
 128         if ($config{test_receive}) {
 129                 require IkiWiki::Receive;
 130                 return IkiWiki::Receive::genwrapper();
 131         }
 132         else {
 133                 return "";
 134         }
 135 }
 136
 137 sub safe_git (&@) {
 138         # Start a child process safely without resorting /bin/sh.
 139         # Return command output or success state (in scalar context).
 140
 141         my ($error_handler, @cmdline) = @_;
 142
 143         my $pid = open my $OUT, "-|";
 144
 145         error("Cannot fork: $!") if !defined $pid;
 146
 147         if (!$pid) {
 148                 # In child.
 149                 # Git commands want to be in wc.
 150                 if (! $no_chdir) {
 151                         chdir $config{srcdir}
 152                             or error("Cannot chdir to $config{srcdir}: $!");
 153                 }
 154                 exec @cmdline or error("Cannot exec '@cmdline': $!");
 155         }
 156         # In parent.
 157
 158         # git output is probably utf-8 encoded, but may contain
 159         # other encodings or invalidly encoded stuff. So do not rely
 160         # on the normal utf-8 IO layer, decode it by hand.
 161         binmode($OUT);
 162
 163         my @lines;
 164         while (<$OUT>) {
 165                 $_=decode_utf8($_, 0);
 166
 167                 chomp;
 168
 169                 push @lines, $_;
 170         }
 171
 172         close $OUT;
 173
 174         $error_handler->("'@cmdline' failed: $!") if $? && $error_handler;
 175
 176         return wantarray ? @lines : ($? == 0);
 177 }
 178 # Convenient wrappers.
 179 sub run_or_die ($@) { safe_git(\&error, @_) }
 180 sub run_or_cry ($@) { safe_git(sub { warn @_ },  @_) }
 181 sub run_or_non ($@) { safe_git(undef,            @_) }
 182
 183
 184 sub merge_past ($$$) {
 185         # Unlike with Subversion, Git cannot make a 'svn merge -rN:M file'.
 186         # Git merge commands work with the committed changes, except in the
 187         # implicit case of '-m' of git checkout(1).  So we should invent a
 188         # kludge here.  In principle, we need to create a throw-away branch
 189         # in preparing for the merge itself.  Since branches are cheap (and
 190         # branching is fast), this shouldn't cost high.
 191         #
 192         # The main problem is the presence of _uncommitted_ local changes.  One
 193         # possible approach to get rid of this situation could be that we first
 194         # make a temporary commit in the master branch and later restore the
 195         # initial state (this is possible since Git has the ability to undo a
 196         # commit, i.e. 'git reset --soft HEAD^').  The method can be summarized
 197         # as follows:
 198         #
 199         #       - create a diff of HEAD:current-sha1
 200         #       - dummy commit
 201         #       - create a dummy branch and switch to it
 202         #       - rewind to past (reset --hard to the current-sha1)
 203         #       - apply the diff and commit
 204         #       - switch to master and do the merge with the dummy branch
 205         #       - make a soft reset (undo the last commit of master)
 206         #
 207         # The above method has some drawbacks: (1) it needs a redundant commit
 208         # just to get rid of local changes, (2) somewhat slow because of the
 209         # required system forks.  Until someone points a more straight method
 210         # (which I would be grateful) I have implemented an alternative method.
 211         # In this approach, we hide all the modified files from Git by renaming
 212         # them (using the 'rename' builtin) and later restore those files in
 213         # the throw-away branch (that is, we put the files themselves instead
 214         # of applying a patch).
 215
 216         my ($sha1, $file, $message) = @_;
 217
 218         my @undo;      # undo stack for cleanup in case of an error
 219         my $conflict;  # file content with conflict markers
 220
 221         eval {
 222                 # Hide local changes from Git by renaming the modified file.
 223                 # Relative paths must be converted to absolute for renaming.
 224                 my ($target, $hidden) = (
 225                     "$config{srcdir}/${file}", "$config{srcdir}/${file}.${sha1}"
 226                 );
 227                 rename($target, $hidden)
 228                     or error("rename '$target' to '$hidden' failed: $!");
 229                 # Ensure to restore the renamed file on error.
 230                 push @undo, sub {
 231                         return if ! -e "$hidden"; # already renamed
 232                         rename($hidden, $target)
 233                             or warn "rename '$hidden' to '$target' failed: $!";
 234                 };
 235
 236                 my $branch = "throw_away_${sha1}"; # supposed to be unique
 237
 238                 # Create a throw-away branch and rewind backward.
 239                 push @undo, sub { run_or_cry('git', 'branch', '-D', $branch) };
 240                 run_or_die('git', 'branch', $branch, $sha1);
 241
 242                 # Switch to throw-away branch for the merge operation.
 243                 push @undo, sub {
 244                         if (!run_or_cry('git', 'checkout', $config{gitmaster_branch})) {
 245                                 run_or_cry('git', 'checkout','-f',$config{gitmaster_branch});
 246                         }
 247                 };
 248                 run_or_die('git', 'checkout', $branch);
 249
 250                 # Put the modified file in _this_ branch.
 251                 rename($hidden, $target)
 252                     or error("rename '$hidden' to '$target' failed: $!");
 253
 254                 # _Silently_ commit all modifications in the current branch.
 255                 run_or_non('git', 'commit', '-m', $message, '-a');
 256                 # ... and re-switch to master.
 257                 run_or_die('git', 'checkout', $config{gitmaster_branch});
 258
 259                 # Attempt to merge without complaining.
 260                 if (!run_or_non('git', 'pull', '--no-commit', '.', $branch)) {
 261                         $conflict = readfile($target);
 262                         run_or_die('git', 'reset', '--hard');
 263                 }
 264         };
 265         my $failure = $@;
 266
 267         # Process undo stack (in reverse order).  By policy cleanup
 268         # actions should normally print a warning on failure.
 269         while (my $handle = pop @undo) {
 270                 $handle->();
 271         }
 272
 273         error("Git merge failed!\n$failure\n") if $failure;
 274
 275         return $conflict;
 276 }
 277
 278 sub parse_diff_tree ($@) {
 279         # Parse the raw diff tree chunk and return the info hash.
 280         # See git-diff-tree(1) for the syntax.
 281
 282         my ($prefix, $dt_ref) = @_;
 283
 284         # End of stream?
 285         return if !defined @{ $dt_ref } ||
 286                   !defined @{ $dt_ref }[0] || !length @{ $dt_ref }[0];
 287
 288         my %ci;
 289         # Header line.
 290         while (my $line = shift @{ $dt_ref }) {
 291                 return if $line !~ m/^(.+) ($sha1_pattern)/;
 292
 293                 my $sha1 = $2;
 294                 $ci{'sha1'} = $sha1;
 295                 last;
 296         }
 297
 298         # Identification lines for the commit.
 299         while (my $line = shift @{ $dt_ref }) {
 300                 # Regexps are semi-stolen from gitweb.cgi.
 301                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
 302                         $ci{'tree'} = $1;
 303                 }
 304                 elsif ($line =~ m/^parent ([0-9a-fA-F]{40})$/) {
 305                         # XXX: collecting in reverse order
 306                         push @{ $ci{'parents'} }, $1;
 307                 }
 308                 elsif ($line =~ m/^(author|committer) (.*) ([0-9]+) (.*)$/) {
 309                         my ($who, $name, $epoch, $tz) =
 310                            ($1,   $2,    $3,     $4 );
 311
 312                         $ci{  $who          } = $name;
 313                         $ci{ "${who}_epoch" } = $epoch;
 314                         $ci{ "${who}_tz"    } = $tz;
 315
 316                         if ($name =~ m/^[^<]+\s+<([^@>]+)/) {
 317                                 $ci{"${who}_username"} = $1;
 318                         }
 319                         elsif ($name =~ m/^([^<]+)\s+<>$/) {
 320                                 $ci{"${who}_username"} = $1;
 321                         }
 322                         else {
 323                                 $ci{"${who}_username"} = $name;
 324                         }
 325                 }
 326                 elsif ($line =~ m/^$/) {
 327                         # Trailing empty line signals next section.
 328                         last;
 329                 }
 330         }
 331
 332         debug("No 'tree' seen in diff-tree output") if !defined $ci{'tree'};
 333
 334         if (defined $ci{'parents'}) {
 335                 $ci{'parent'} = @{ $ci{'parents'} }[0];
 336         }
 337         else {
 338                 $ci{'parent'} = 0 x 40;
 339         }
 340
 341         # Commit message (optional).
 342         while ($dt_ref->[0] =~ /^    /) {
 343                 my $line = shift @{ $dt_ref };
 344                 $line =~ s/^    //;
 345                 push @{ $ci{'comment'} }, $line;
 346         }
 347         shift @{ $dt_ref } if $dt_ref->[0] =~ /^$/;
 348
 349         # Modified files.
 350         while (my $line = shift @{ $dt_ref }) {
 351                 if ($line =~ m{^
 352                         (:+)       # number of parents
 353                         ([^\t]+)\t # modes, sha1, status
 354                         (.*)       # file names
 355                 $}xo) {
 356                         my $num_parents = length $1;
 357                         my @tmp = split(" ", $2);
 358                         my ($file, $file_to) = split("\t", $3);
 359                         my @mode_from = splice(@tmp, 0, $num_parents);
 360                         my $mode_to = shift(@tmp);
 361                         my @sha1_from = splice(@tmp, 0, $num_parents);
 362                         my $sha1_to = shift(@tmp);
 363                         my $status = shift(@tmp);
 364
 365                         # git does not output utf-8 filenames, but instead
 366                         # double-quotes them with the utf-8 characters
 367                         # escaped as \nnn\nnn.
 368                         if ($file =~ m/^"(.*)"$/) {
 369                                 ($file=$1) =~ s/\\([0-7]{1,3})/chr(oct($1))/eg;
 370                         }
 371                         $file =~ s/^\Q$prefix\E//;
 372                         if (length $file) {
 373                                 push @{ $ci{'details'} }, {
 374                                         'file'      => decode("utf8", $file),
 375                                         'sha1_from' => $sha1_from[0],
 376                                         'sha1_to'   => $sha1_to,
 377                                         'mode_from' => $mode_from[0],
 378                                         'mode_to'   => $mode_to,
 379                                         'status'    => $status,
 380                                 };
 381                         }
 382                         next;
 383                 };
 384                 last;
 385         }
 386
 387         return \%ci;
 388 }
 389
 390 sub git_commit_info ($;$) {
 391         # Return an array of commit info hashes of num commits
 392         # starting from the given sha1sum.
 393         my ($sha1, $num) = @_;
 394
 395         my @opts;
 396         push @opts, "--max-count=$num" if defined $num;
 397
 398         my @raw_lines = run_or_die('git', 'log', @opts,
 399                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 400                 '-r', $sha1, '--', '.');
 401         my ($prefix) = run_or_die('git', 'rev-parse', '--show-prefix');
 402
 403         my @ci;
 404         while (my $parsed = parse_diff_tree(($prefix or ""), \@raw_lines)) {
 405                 push @ci, $parsed;
 406         }
 407
 408         warn "Cannot parse commit info for '$sha1' commit" if !@ci;
 409
 410         return wantarray ? @ci : $ci[0];
 411 }
 412
 413 sub git_sha1 (;$) {
 414         # Return head sha1sum (of given file).
 415         my $file = shift || q{--};
 416
 417         # Ignore error since a non-existing file might be given.
 418         my ($sha1) = run_or_non('git', 'rev-list', '--max-count=1', 'HEAD',
 419                 '--', $file);
 420         if ($sha1) {
 421                 ($sha1) = $sha1 =~ m/($sha1_pattern)/; # sha1 is untainted now
 422         } else { debug("Empty sha1sum for '$file'.") }
 423         return defined $sha1 ? $sha1 : q{};
 424 }
 425
 426 sub rcs_update () {
 427         # Update working directory.
 428
 429         if (length $config{gitorigin_branch}) {
 430                 run_or_cry('git', 'pull', $config{gitorigin_branch});
 431         }
 432 }
 433
 434 sub rcs_prepedit ($) {
 435         # Return the commit sha1sum of the file when editing begins.
 436         # This will be later used in rcs_commit if a merge is required.
 437         my ($file) = @_;
 438
 439         return git_sha1($file);
 440 }
 441
 442 sub rcs_commit ($$$;$$) {
 443         # Try to commit the page; returns undef on _success_ and
 444         # a version of the page with the rcs's conflict markers on
 445         # failure.
 446
 447         my ($file, $message, $rcstoken, $user, $ipaddr) = @_;
 448
 449         # Check to see if the page has been changed by someone else since
 450         # rcs_prepedit was called.
 451         my $cur    = git_sha1($file);
 452         my ($prev) = $rcstoken =~ /^($sha1_pattern)$/; # untaint
 453
 454         if (defined $cur && defined $prev && $cur ne $prev) {
 455                 my $conflict = merge_past($prev, $file, $dummy_commit_msg);
 456                 return $conflict if defined $conflict;
 457         }
 458
 459         rcs_add($file);
 460         return rcs_commit_staged($message, $user, $ipaddr);
 461 }
 462
 463 sub rcs_commit_staged ($$$) {
 464         # Commits all staged changes. Changes can be staged using rcs_add,
 465         # rcs_remove, and rcs_rename.
 466         my ($message, $user, $ipaddr)=@_;
 467
 468         # Set the commit author and email to the web committer.
 469         my %env=%ENV;
 470         if (defined $user || defined $ipaddr) {
 471                 my $u=encode_utf8(defined $user ? $user : $ipaddr);
 472                 $ENV{GIT_AUTHOR_NAME}=$u;
 473                 $ENV{GIT_AUTHOR_EMAIL}="$u\@web";
 474         }
 475
 476         $message = IkiWiki::possibly_foolish_untaint($message);
 477         my @opts;
 478         if ($message !~ /\S/) {
 479                 # Force git to allow empty commit messages.
 480                 # (If this version of git supports it.)
 481                 my ($version)=`git --version` =~ /git version (.*)/;
 482                 if ($version ge "1.5.4") {
 483                         push @opts, '--cleanup=verbatim';
 484                 }
 485                 else {
 486                         $message.=".";
 487                 }
 488         }
 489         push @opts, '-q';
 490         # git commit returns non-zero if file has not been really changed.
 491         # so we should ignore its exit status (hence run_or_non).
 492         if (run_or_non('git', 'commit', @opts, '-m', $message)) {
 493                 if (length $config{gitorigin_branch}) {
 494                         run_or_cry('git', 'push', $config{gitorigin_branch});
 495                 }
 496         }
 497
 498         %ENV=%env;
 499         return undef; # success
 500 }
 501
 502 sub rcs_add ($) {
 503         # Add file to archive.
 504
 505         my ($file) = @_;
 506
 507         run_or_cry('git', 'add', $file);
 508 }
 509
 510 sub rcs_remove ($) {
 511         # Remove file from archive.
 512
 513         my ($file) = @_;
 514
 515         run_or_cry('git', 'rm', '-f', $file);
 516 }
 517
 518 sub rcs_rename ($$) {
 519         my ($src, $dest) = @_;
 520
 521         run_or_cry('git', 'mv', '-f', $src, $dest);
 522 }
 523
 524 sub rcs_recentchanges ($) {
 525         # List of recent changes.
 526
 527         my ($num) = @_;
 528
 529         eval q{use Date::Parse};
 530         error($@) if $@;
 531
 532         my @rets;
 533         foreach my $ci (git_commit_info('HEAD', $num || 1)) {
 534                 # Skip redundant commits.
 535                 next if ($ci->{'comment'} && @{$ci->{'comment'}}[0] eq $dummy_commit_msg);
 536
 537                 my ($sha1, $when) = (
 538                         $ci->{'sha1'},
 539                         $ci->{'author_epoch'}
 540                 );
 541
 542                 my @pages;
 543                 foreach my $detail (@{ $ci->{'details'} }) {
 544                         my $file = $detail->{'file'};
 545
 546                         my $diffurl = defined $config{'diffurl'} ? $config{'diffurl'} : "";
 547                         $diffurl =~ s/\[\[file\]\]/$file/go;
 548                         $diffurl =~ s/\[\[sha1_parent\]\]/$ci->{'parent'}/go;
 549                         $diffurl =~ s/\[\[sha1_from\]\]/$detail->{'sha1_from'}/go;
 550                         $diffurl =~ s/\[\[sha1_to\]\]/$detail->{'sha1_to'}/go;
 551                         $diffurl =~ s/\[\[sha1_commit\]\]/$sha1/go;
 552
 553                         push @pages, {
 554                                 page => pagename($file),
 555                                 diffurl => $diffurl,
 556                         };
 557                 }
 558
 559                 my @messages;
 560                 my $pastblank=0;
 561                 foreach my $line (@{$ci->{'comment'}}) {
 562                         $pastblank=1 if $line eq '';
 563                         next if $pastblank && $line=~m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i;
 564                         push @messages, { line => $line };
 565                 }
 566
 567                 my $user=$ci->{'author_username'};
 568                 my $web_commit = ($ci->{'author'} =~ /\@web>/);
 569
 570                 # compatability code for old web commit messages
 571                 if (! $web_commit &&
 572                       defined $messages[0] &&
 573                       $messages[0]->{line} =~ m/$config{web_commit_regexp}/) {
 574                         $user = defined $2 ? "$2" : "$3";
 575                         $messages[0]->{line} = $4;
 576                         $web_commit=1;
 577                 }
 578
 579                 push @rets, {
 580                         rev        => $sha1,
 581                         user       => $user,
 582                         committype => $web_commit ? "web" : "git",
 583                         when       => $when,
 584                         message    => [@messages],
 585                         pages      => [@pages],
 586                 } if @pages;
 587
 588                 last if @rets >= $num;
 589         }
 590
 591         return @rets;
 592 }
 593
 594 sub rcs_diff ($) {
 595         my $rev=shift;
 596         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 597         my @lines;
 598         foreach my $line (run_or_non("git", "show", $sha1)) {
 599                 if (@lines || $line=~/^diff --git/) {
 600                         push @lines, $line."\n";
 601                 }
 602         }
 603         if (wantarray) {
 604                 return @lines;
 605         }
 606         else {
 607                 return join("", @lines);
 608         }
 609 }
 610
 611 sub rcs_getctime ($) {
 612         my $file=shift;
 613         # Remove srcdir prefix
 614         $file =~ s/^\Q$config{srcdir}\E\/?//;
 615
 616         my @sha1s = run_or_non('git', 'rev-list', 'HEAD', '--', $file);
 617         my $ci    = git_commit_info($sha1s[$#sha1s], 1);
 618         my $ctime = $ci->{'author_epoch'};
 619         debug("ctime for '$file': ". localtime($ctime));
 620
 621         return $ctime;
 622 }
 623
 624 sub rcs_receive () {
 625         # The wiki may not be the only thing in the git repo.
 626         # Determine if it is in a subdirectory by examining the srcdir,
 627         # and its parents, looking for the .git directory.
 628         my $subdir="";
 629         my $dir=$config{srcdir};
 630         while (! -d "$dir/.git") {
 631                 $subdir=IkiWiki::basename($dir)."/".$subdir;
 632                 $dir=IkiWiki::dirname($dir);
 633                 if (! length $dir) {
 634                         error("cannot determine root of git repo");
 635                 }
 636         }
 637
 638         my @rets;
 639         while (<>) {
 640                 chomp;
 641                 my ($oldrev, $newrev, $refname) = split(' ', $_, 3);
 642
 643                 # only allow changes to gitmaster_branch
 644                 if ($refname !~ /^refs\/heads\/\Q$config{gitmaster_branch}\E$/) {
 645                         error sprintf(gettext("you are not allowed to change %s"), $refname);
 646                 }
 647
 648                 # Avoid chdir when running git here, because the changes
 649                 # are in the master git repo, not the srcdir repo.
 650                 # The pre-recieve hook already puts us in the right place.
 651                 $no_chdir=1;
 652                 my @changes=git_commit_info($oldrev."..".$newrev);
 653                 $no_chdir=0;
 654
 655                 foreach my $ci (@changes) {
 656                         foreach my $detail (@{ $ci->{'details'} }) {
 657                                 my $file = $detail->{'file'};
 658
 659                                 # check that all changed files are in the
 660                                 # subdir
 661                                 if (length $subdir &&
 662                                     ! ($file =~ s/^\Q$subdir\E//)) {
 663                                         error sprintf(gettext("you are not allowed to change %s"), $file);
 664                                 }
 665
 666                                 my ($action, $mode, $path);
 667                                 if ($detail->{'status'} =~ /^[M]+\d*$/) {
 668                                         $action="change";
 669                                         $mode=$detail->{'mode_to'};
 670                                 }
 671                                 elsif ($detail->{'status'} =~ /^[AM]+\d*$/) {
 672                                         $action="add";
 673                                         $mode=$detail->{'mode_to'};
 674                                 }
 675                                 elsif ($detail->{'status'} =~ /^[DAM]+\d*/) {
 676                                         $action="remove";
 677                                         $mode=$detail->{'mode_from'};
 678                                 }
 679                                 else {
 680                                         error "unknown status ".$detail->{'status'};
 681                                 }
 682
 683                                 # test that the file mode is ok
 684                                 if ($mode !~ /^100[64][64][64]$/) {
 685                                         error sprintf(gettext("you cannot act on a file with mode %s"), $mode);
 686                                 }
 687                                 if ($action eq "change") {
 688                                         if ($detail->{'mode_from'} ne $detail->{'mode_to'}) {
 689                                                 error gettext("you are not allowed to change file modes");
 690                                         }
 691                                 }
 692
 693                                 # extract attachment to temp file
 694                                 if (($action eq 'add' || $action eq 'change') &&
 695                                      ! pagetype($file)) {
 696                                         eval q{use File::Temp};
 697                                         die $@ if $@;
 698                                         my $fh;
 699                                         ($fh, $path)=File::Temp::tempfile("XXXXXXXXXX", UNLINK => 1);
 700                                         if (system("git show ".$detail->{sha1_to}." > '$path'") != 0) {
 701                                                 error("failed writing temp file");
 702                                         }
 703                                 }
 704
 705                                 push @rets, {
 706                                         file => $file,
 707                                         action => $action,
 708                                         path => $path,
 709                                 };
 710                         }
 711                 }
 712         }
 713
 714         return reverse @rets;
 715 }
 716
 717 1