IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use Fcntl q{:flock};
   9 use URI::Escape q{uri_escape_utf8};
  10 use POSIX ();
  11 use Storable;
  12 use open qw{:utf8 :std};
  13
  14 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  15         %pagestate %wikistate %renderedfiles %oldrenderedfiles
  16         %pagesources %delpagesources %destsources %depends %depends_simple
  17         @mass_depends %hooks %forcerebuild %loaded_plugins %typedlinks
  18         %oldtypedlinks %autofiles @underlayfiles $lastrev $phase};
  19
  20 use Exporter q{import};
  21 our @EXPORT = qw(hook debug error htmlpage template template_depends
  22         deptype add_depends pagespec_match pagespec_match_list bestlink
  23         htmllink readfile writefile pagetype srcfile pagename
  24         displaytime strftime_utf8 will_render gettext ngettext urlto targetpage
  25         add_underlay pagetitle titlepage linkpage newpagefile
  26         inject add_link add_autofile useragent
  27         %config %links %pagestate %wikistate %renderedfiles
  28         %pagesources %destsources %typedlinks);
  29 our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
  30 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  31 our $installdir='/usr'; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  32
  33 # Page dependency types.
  34 our $DEPEND_CONTENT=1;
  35 our $DEPEND_PRESENCE=2;
  36 our $DEPEND_LINKS=4;
  37
  38 # Phases of processing.
  39 sub PHASE_SCAN () { 0 }
  40 sub PHASE_RENDER () { 1 }
  41 $phase = PHASE_SCAN;
  42
  43 # Optimisation.
  44 use Memoize;
  45 memoize("abs2rel");
  46 memoize("sortspec_translate");
  47 memoize("pagespec_translate");
  48 memoize("template_file");
  49
  50 sub getsetup () {
  51         wikiname => {
  52                 type => "string",
  53                 default => "wiki",
  54                 description => "name of the wiki",
  55                 safe => 1,
  56                 rebuild => 1,
  57         },
  58         adminemail => {
  59                 type => "string",
  60                 default => undef,
  61                 example => 'me@example.com',
  62                 description => "contact email for wiki",
  63                 safe => 1,
  64                 rebuild => 0,
  65         },
  66         adminuser => {
  67                 type => "string",
  68                 default => [],
  69                 description => "users who are wiki admins",
  70                 safe => 1,
  71                 rebuild => 0,
  72         },
  73         banned_users => {
  74                 type => "string",
  75                 default => [],
  76                 description => "users who are banned from the wiki",
  77                 safe => 1,
  78                 rebuild => 0,
  79         },
  80         srcdir => {
  81                 type => "string",
  82                 default => undef,
  83                 example => "$ENV{HOME}/wiki",
  84                 description => "where the source of the wiki is located",
  85                 safe => 0, # path
  86                 rebuild => 1,
  87         },
  88         destdir => {
  89                 type => "string",
  90                 default => undef,
  91                 example => "/var/www/wiki",
  92                 description => "where to build the wiki",
  93                 safe => 0, # path
  94                 rebuild => 1,
  95         },
  96         url => {
  97                 type => "string",
  98                 default => '',
  99                 example => "http://example.com/wiki",
 100                 description => "base url to the wiki",
 101                 safe => 1,
 102                 rebuild => 1,
 103         },
 104         cgiurl => {
 105                 type => "string",
 106                 default => '',
 107                 example => "http://example.com/wiki/ikiwiki.cgi",
 108                 description => "url to the ikiwiki.cgi",
 109                 safe => 1,
 110                 rebuild => 1,
 111         },
 112         reverse_proxy => {
 113                 type => "boolean",
 114                 default => 0,
 115                 description => "do not adjust cgiurl if CGI is accessed via different URL",
 116                 advanced => 0,
 117                 safe => 1,
 118                 rebuild => 0, # only affects CGI requests
 119         },
 120         cgi_wrapper => {
 121                 type => "string",
 122                 default => '',
 123                 example => "/var/www/wiki/ikiwiki.cgi",
 124                 description => "filename of cgi wrapper to generate",
 125                 safe => 0, # file
 126                 rebuild => 0,
 127         },
 128         cgi_wrappermode => {
 129                 type => "string",
 130                 default => '06755',
 131                 description => "mode for cgi_wrapper (can safely be made suid)",
 132                 safe => 0,
 133                 rebuild => 0,
 134         },
 135         cgi_overload_delay => {
 136                 type => "string",
 137                 default => '',
 138                 example => "10",
 139                 description => "number of seconds to delay CGI requests when overloaded",
 140                 safe => 1,
 141                 rebuild => 0,
 142         },
 143         cgi_overload_message => {
 144                 type => "string",
 145                 default => '',
 146                 example => "Please wait",
 147                 description => "message to display when overloaded (may contain html)",
 148                 safe => 1,
 149                 rebuild => 0,
 150         },
 151         only_committed_changes => {
 152                 type => "boolean",
 153                 default => 0,
 154                 description => "enable optimization of only refreshing committed changes?",
 155                 safe => 1,
 156                 rebuild => 0,
 157         },
 158         rcs => {
 159                 type => "string",
 160                 default => '',
 161                 description => "rcs backend to use",
 162                 safe => 0, # don't allow overriding
 163                 rebuild => 0,
 164         },
 165         default_plugins => {
 166                 type => "internal",
 167                 default => [qw{mdwn link inline meta htmlscrubber passwordauth
 168                                 openid signinedit lockedit conditional
 169                                 recentchanges parentlinks editpage
 170                                 templatebody}],
 171                 description => "plugins to enable by default",
 172                 safe => 0,
 173                 rebuild => 1,
 174         },
 175         add_plugins => {
 176                 type => "string",
 177                 default => [],
 178                 description => "plugins to add to the default configuration",
 179                 safe => 1,
 180                 rebuild => 1,
 181         },
 182         disable_plugins => {
 183                 type => "string",
 184                 default => [],
 185                 description => "plugins to disable",
 186                 safe => 1,
 187                 rebuild => 1,
 188         },
 189         templatedir => {
 190                 type => "string",
 191                 default => "$installdir/share/ikiwiki/templates",
 192                 description => "additional directory to search for template files",
 193                 advanced => 1,
 194                 safe => 0, # path
 195                 rebuild => 1,
 196         },
 197         underlaydir => {
 198                 type => "string",
 199                 default => "$installdir/share/ikiwiki/basewiki",
 200                 description => "base wiki source location",
 201                 advanced => 1,
 202                 safe => 0, # path
 203                 rebuild => 0,
 204         },
 205         underlaydirbase => {
 206                 type => "internal",
 207                 default => "$installdir/share/ikiwiki",
 208                 description => "parent directory containing additional underlays",
 209                 safe => 0,
 210                 rebuild => 0,
 211         },
 212         wrappers => {
 213                 type => "internal",
 214                 default => [],
 215                 description => "wrappers to generate",
 216                 safe => 0,
 217                 rebuild => 0,
 218         },
 219         underlaydirs => {
 220                 type => "internal",
 221                 default => [],
 222                 description => "additional underlays to use",
 223                 safe => 0,
 224                 rebuild => 0,
 225         },
 226         verbose => {
 227                 type => "boolean",
 228                 example => 1,
 229                 description => "display verbose messages?",
 230                 safe => 1,
 231                 rebuild => 0,
 232         },
 233         syslog => {
 234                 type => "boolean",
 235                 example => 1,
 236                 description => "log to syslog?",
 237                 safe => 1,
 238                 rebuild => 0,
 239         },
 240         usedirs => {
 241                 type => "boolean",
 242                 default => 1,
 243                 description => "create output files named page/index.html?",
 244                 safe => 0, # changing requires manual transition
 245                 rebuild => 1,
 246         },
 247         prefix_directives => {
 248                 type => "boolean",
 249                 default => 1,
 250                 description => "use '!'-prefixed preprocessor directives?",
 251                 safe => 0, # changing requires manual transition
 252                 rebuild => 1,
 253         },
 254         indexpages => {
 255                 type => "boolean",
 256                 default => 0,
 257                 description => "use page/index.mdwn source files",
 258                 safe => 1,
 259                 rebuild => 1,
 260         },
 261         discussion => {
 262                 type => "boolean",
 263                 default => 1,
 264                 description => "enable Discussion pages?",
 265                 safe => 1,
 266                 rebuild => 1,
 267         },
 268         discussionpage => {
 269                 type => "string",
 270                 default => gettext("Discussion"),
 271                 description => "name of Discussion pages",
 272                 safe => 1,
 273                 rebuild => 1,
 274         },
 275         html5 => {
 276                 type => "boolean",
 277                 default => 0,
 278                 description => "use elements new in HTML5 like <section>?",
 279                 advanced => 0,
 280                 safe => 1,
 281                 rebuild => 1,
 282         },
 283         sslcookie => {
 284                 type => "boolean",
 285                 default => 0,
 286                 description => "only send cookies over SSL connections?",
 287                 advanced => 1,
 288                 safe => 1,
 289                 rebuild => 0,
 290         },
 291         default_pageext => {
 292                 type => "string",
 293                 default => "mdwn",
 294                 description => "extension to use for new pages",
 295                 safe => 0, # not sanitized
 296                 rebuild => 0,
 297         },
 298         htmlext => {
 299                 type => "string",
 300                 default => "html",
 301                 description => "extension to use for html files",
 302                 safe => 0, # not sanitized
 303                 rebuild => 1,
 304         },
 305         timeformat => {
 306                 type => "string",
 307                 default => '%c',
 308                 description => "strftime format string to display date",
 309                 advanced => 1,
 310                 safe => 1,
 311                 rebuild => 1,
 312         },
 313         locale => {
 314                 type => "string",
 315                 default => undef,
 316                 example => "en_US.UTF-8",
 317                 description => "UTF-8 locale to use",
 318                 advanced => 1,
 319                 safe => 0,
 320                 rebuild => 1,
 321         },
 322         userdir => {
 323                 type => "string",
 324                 default => "",
 325                 example => "users",
 326                 description => "put user pages below specified page",
 327                 safe => 1,
 328                 rebuild => 1,
 329         },
 330         numbacklinks => {
 331                 type => "integer",
 332                 default => 10,
 333                 description => "how many backlinks to show before hiding excess (0 to show all)",
 334                 safe => 1,
 335                 rebuild => 1,
 336         },
 337         hardlink => {
 338                 type => "boolean",
 339                 default => 0,
 340                 description => "attempt to hardlink source files? (optimisation for large files)",
 341                 advanced => 1,
 342                 safe => 0, # paranoia
 343                 rebuild => 0,
 344         },
 345         umask => {
 346                 type => "string",
 347                 example => "public",
 348                 description => "force ikiwiki to use a particular umask (keywords public, group or private, or a number)",
 349                 advanced => 1,
 350                 safe => 0, # paranoia
 351                 rebuild => 0,
 352         },
 353         wrappergroup => {
 354                 type => "string",
 355                 example => "ikiwiki",
 356                 description => "group for wrappers to run in",
 357                 advanced => 1,
 358                 safe => 0, # paranoia
 359                 rebuild => 0,
 360         },
 361         libdirs => {
 362                 type => "string",
 363                 default => [],
 364                 example => ["$ENV{HOME}/.local/share/ikiwiki"],
 365                 description => "extra library and plugin directories",
 366                 advanced => 1,
 367                 safe => 0, # directory
 368                 rebuild => 0,
 369         },
 370         libdir => {
 371                 type => "string",
 372                 default => "",
 373                 example => "$ENV{HOME}/.ikiwiki/",
 374                 description => "extra library and plugin directory (searched after libdirs)",
 375                 advanced => 1,
 376                 safe => 0, # directory
 377                 rebuild => 0,
 378         },
 379         ENV => {
 380                 type => "string",
 381                 default => {},
 382                 description => "environment variables",
 383                 safe => 0, # paranoia
 384                 rebuild => 0,
 385         },
 386         timezone => {
 387                 type => "string",
 388                 default => "",
 389                 example => "US/Eastern",
 390                 description => "time zone name",
 391                 safe => 1,
 392                 rebuild => 1,
 393         },
 394         include => {
 395                 type => "string",
 396                 default => undef,
 397                 example => '^\.htaccess$',
 398                 description => "regexp of normally excluded files to include",
 399                 advanced => 1,
 400                 safe => 0, # regexp
 401                 rebuild => 1,
 402         },
 403         exclude => {
 404                 type => "string",
 405                 default => undef,
 406                 example => '^(*\.private|Makefile)$',
 407                 description => "regexp of files that should be skipped",
 408                 advanced => 1,
 409                 safe => 0, # regexp
 410                 rebuild => 1,
 411         },
 412         wiki_file_prune_regexps => {
 413                 type => "internal",
 414                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\//, qr/^\./, qr/\/\./,
 415                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 416                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 417                         qr/(^|\/)_MTN\//, qr/(^|\/)_darcs\//,
 418                         qr/(^|\/)CVS\//, qr/\.dpkg-tmp$/],
 419                 description => "regexps of source files to ignore",
 420                 safe => 0,
 421                 rebuild => 1,
 422         },
 423         wiki_file_chars => {
 424                 type => "string",
 425                 description => "specifies the characters that are allowed in source filenames",
 426                 default => "-[:alnum:]+/.:_",
 427                 safe => 0,
 428                 rebuild => 1,
 429         },
 430         wiki_file_regexp => {
 431                 type => "internal",
 432                 description => "regexp of legal source files",
 433                 safe => 0,
 434                 rebuild => 1,
 435         },
 436         web_commit_regexp => {
 437                 type => "internal",
 438                 default => qr/^web commit (by (.*?(?=: |$))|from ([0-9a-fA-F:.]+[0-9a-fA-F])):?(.*)/,
 439                 description => "regexp to parse web commits from logs",
 440                 safe => 0,
 441                 rebuild => 0,
 442         },
 443         cgi => {
 444                 type => "internal",
 445                 default => 0,
 446                 description => "run as a cgi",
 447                 safe => 0,
 448                 rebuild => 0,
 449         },
 450         cgi_disable_uploads => {
 451                 type => "internal",
 452                 default => 1,
 453                 description => "whether CGI should accept file uploads",
 454                 safe => 0,
 455                 rebuild => 0,
 456         },
 457         post_commit => {
 458                 type => "internal",
 459                 default => 0,
 460                 description => "run as a post-commit hook",
 461                 safe => 0,
 462                 rebuild => 0,
 463         },
 464         rebuild => {
 465                 type => "internal",
 466                 default => 0,
 467                 description => "running in rebuild mode",
 468                 safe => 0,
 469                 rebuild => 0,
 470         },
 471         setup => {
 472                 type => "internal",
 473                 default => undef,
 474                 description => "running in setup mode",
 475                 safe => 0,
 476                 rebuild => 0,
 477         },
 478         clean => {
 479                 type => "internal",
 480                 default => 0,
 481                 description => "running in clean mode",
 482                 safe => 0,
 483                 rebuild => 0,
 484         },
 485         refresh => {
 486                 type => "internal",
 487                 default => 0,
 488                 description => "running in refresh mode",
 489                 safe => 0,
 490                 rebuild => 0,
 491         },
 492         test_receive => {
 493                 type => "internal",
 494                 default => 0,
 495                 description => "running in receive test mode",
 496                 safe => 0,
 497                 rebuild => 0,
 498         },
 499         wrapper_background_command => {
 500                 type => "internal",
 501                 default => '',
 502                 description => "background shell command to run",
 503                 safe => 0,
 504                 rebuild => 0,
 505         },
 506         gettime => {
 507                 type => "internal",
 508                 description => "running in gettime mode",
 509                 safe => 0,
 510                 rebuild => 0,
 511         },
 512         w3mmode => {
 513                 type => "internal",
 514                 default => 0,
 515                 description => "running in w3mmode",
 516                 safe => 0,
 517                 rebuild => 0,
 518         },
 519         wikistatedir => {
 520                 type => "internal",
 521                 default => undef,
 522                 description => "path to the .ikiwiki directory holding ikiwiki state",
 523                 safe => 0,
 524                 rebuild => 0,
 525         },
 526         setupfile => {
 527                 type => "internal",
 528                 default => undef,
 529                 description => "path to setup file",
 530                 safe => 0,
 531                 rebuild => 0,
 532         },
 533         setuptype => {
 534                 type => "internal",
 535                 default => "Yaml",
 536                 description => "perl class to use to dump setup file",
 537                 safe => 0,
 538                 rebuild => 0,
 539         },
 540         allow_symlinks_before_srcdir => {
 541                 type => "boolean",
 542                 default => 0,
 543                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 544                 safe => 0,
 545                 rebuild => 0,
 546         },
 547         cookiejar => {
 548                 type => "string",
 549                 default => { file => "$ENV{HOME}/.ikiwiki/cookies" },
 550                 description => "cookie control",
 551                 safe => 0, # hooks into perl module internals
 552                 rebuild => 0,
 553         },
 554         useragent => {
 555                 type => "string",
 556                 default => "ikiwiki/$version",
 557                 example => "Wget/1.13.4 (linux-gnu)",
 558                 description => "set custom user agent string for outbound HTTP requests e.g. when fetching aggregated RSS feeds",
 559                 safe => 0,
 560                 rebuild => 0,
 561         },
 562         responsive_layout => {
 563                 type => "boolean",
 564                 default => 1,
 565                 description => "theme has a responsive layout? (mobile-optimized)",
 566                 safe => 1,
 567                 rebuild => 1,
 568         },
 569         deterministic => {
 570                 type => "boolean",
 571                 default => 0,
 572                 description => "try harder to produce deterministic output",
 573                 safe => 1,
 574                 rebuild => 1,
 575                 advanced => 1,
 576         },
 577 }
 578
 579 sub getlibdirs () {
 580         my @libdirs;
 581         if ($config{libdirs}) {
 582                 @libdirs = @{$config{libdirs}};
 583         }
 584         if (length $config{libdir}) {
 585                 push @libdirs, $config{libdir};
 586         }
 587         return @libdirs;
 588 }
 589
 590 sub defaultconfig () {
 591         my %s=getsetup();
 592         my @ret;
 593         foreach my $key (keys %s) {
 594                 push @ret, $key, $s{$key}->{default};
 595         }
 596         return @ret;
 597 }
 598
 599 # URL to top of wiki as a path starting with /, valid from any wiki page or
 600 # the CGI; if that's not possible, an absolute URL. Either way, it ends with /
 601 my $local_url;
 602 # URL to CGI script, similar to $local_url
 603 my $local_cgiurl;
 604
 605 sub checkconfig () {
 606         # locale stuff; avoid LC_ALL since it overrides everything
 607         if (defined $ENV{LC_ALL}) {
 608                 $ENV{LANG} = $ENV{LC_ALL};
 609                 delete $ENV{LC_ALL};
 610         }
 611         if (defined $config{locale}) {
 612                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 613                         $ENV{LANG}=$config{locale};
 614                         define_gettext();
 615                 }
 616         }
 617
 618         if (! defined $config{wiki_file_regexp}) {
 619                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 620         }
 621
 622         if (ref $config{ENV} eq 'HASH') {
 623                 foreach my $val (keys %{$config{ENV}}) {
 624                         $ENV{$val}=$config{ENV}{$val};
 625                 }
 626         }
 627         if (defined $config{timezone} && length $config{timezone}) {
 628                 $ENV{TZ}=$config{timezone};
 629         }
 630         elsif (defined $ENV{TZ} && length $ENV{TZ}) {
 631                 $config{timezone}=$ENV{TZ};
 632         }
 633         else {
 634                 eval q{use Config qw()};
 635                 error($@) if $@;
 636
 637                 if ($Config::Config{d_gnulibc} && -e '/etc/localtime') {
 638                         $config{timezone}=$ENV{TZ}=':/etc/localtime';
 639                 }
 640                 else {
 641                         $config{timezone}=$ENV{TZ}='GMT';
 642                 }
 643         }
 644
 645         if ($config{w3mmode}) {
 646                 eval q{use Cwd q{abs_path}};
 647                 error($@) if $@;
 648                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 649                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 650                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 651                         unless $config{cgiurl} =~ m!file:///!;
 652                 $config{url}="file://".$config{destdir};
 653         }
 654
 655         if ($config{cgi} && ! length $config{url}) {
 656                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 657         }
 658
 659         if (defined $config{url} && length $config{url}) {
 660                 eval q{use URI};
 661                 my $baseurl = URI->new($config{url});
 662
 663                 $local_url = $baseurl->path . "/";
 664                 $local_cgiurl = undef;
 665
 666                 if (length $config{cgiurl}) {
 667                         my $cgiurl = URI->new($config{cgiurl});
 668
 669                         $local_cgiurl = $cgiurl->path;
 670
 671                         if ($cgiurl->scheme eq 'https' &&
 672                                 $baseurl->scheme eq 'http') {
 673                                 # We assume that the same content is available
 674                                 # over both http and https, because if it
 675                                 # wasn't, accessing the static content
 676                                 # from the CGI would be mixed-content,
 677                                 # which would be a security flaw.
 678
 679                                 if ($cgiurl->authority ne $baseurl->authority) {
 680                                         # use protocol-relative URL for
 681                                         # static content
 682                                         $local_url = "$config{url}/";
 683                                         $local_url =~ s{^http://}{//};
 684                                 }
 685                                 # else use host-relative URL for static content
 686
 687                                 # either way, CGI needs to be absolute
 688                                 $local_cgiurl = $config{cgiurl};
 689                         }
 690                         elsif ($cgiurl->scheme ne $baseurl->scheme) {
 691                                 # too far apart, fall back to absolute URLs
 692                                 $local_url = "$config{url}/";
 693                                 $local_cgiurl = $config{cgiurl};
 694                         }
 695                         elsif ($cgiurl->authority ne $baseurl->authority) {
 696                                 # slightly too far apart, fall back to
 697                                 # protocol-relative URLs
 698                                 $local_url = "$config{url}/";
 699                                 $local_url =~ s{^https?://}{//};
 700                                 $local_cgiurl = $config{cgiurl};
 701                                 $local_cgiurl =~ s{^https?://}{//};
 702                         }
 703                         # else keep host-relative URLs
 704                 }
 705
 706                 $local_url =~ s{//$}{/};
 707         }
 708         else {
 709                 $local_cgiurl = $config{cgiurl};
 710         }
 711
 712         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 713                 unless exists $config{wikistatedir} && defined $config{wikistatedir};
 714
 715         if (defined $config{umask}) {
 716                 my $u = possibly_foolish_untaint($config{umask});
 717
 718                 if ($u =~ m/^\d+$/) {
 719                         umask($u);
 720                 }
 721                 elsif ($u eq 'private') {
 722                         umask(077);
 723                 }
 724                 elsif ($u eq 'group') {
 725                         umask(027);
 726                 }
 727                 elsif ($u eq 'public') {
 728                         umask(022);
 729                 }
 730                 else {
 731                         error(sprintf(gettext("unsupported umask setting %s"), $u));
 732                 }
 733         }
 734
 735         run_hooks(checkconfig => sub { shift->() });
 736
 737         return 1;
 738 }
 739
 740 sub listplugins () {
 741         my %ret;
 742
 743         foreach my $dir (@INC, getlibdirs()) {
 744                 next unless defined $dir && length $dir;
 745                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 746                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 747                         $ret{$plugin}=1;
 748                 }
 749         }
 750         foreach my $dir (getlibdirs(), "$installdir/lib/ikiwiki") {
 751                 next unless defined $dir && length $dir;
 752                 foreach my $file (glob("$dir/plugins/*")) {
 753                         $ret{basename($file)}=1 if -x $file;
 754                 }
 755         }
 756
 757         return keys %ret;
 758 }
 759
 760 sub loadplugins () {
 761         foreach my $dir (getlibdirs()) {
 762                 unshift @INC, possibly_foolish_untaint($dir);
 763         }
 764
 765         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 766                 loadplugin($plugin);
 767         }
 768
 769         if ($config{rcs}) {
 770                 if (exists $hooks{rcs}) {
 771                         error(gettext("cannot use multiple rcs plugins"));
 772                 }
 773                 loadplugin($config{rcs});
 774         }
 775         if (! exists $hooks{rcs}) {
 776                 loadplugin("norcs");
 777         }
 778
 779         run_hooks(getopt => sub { shift->() });
 780         if (grep /^-/, @ARGV) {
 781                 print STDERR "Unknown option (or missing parameter): $_\n"
 782                         foreach grep /^-/, @ARGV;
 783                 usage();
 784         }
 785
 786         return 1;
 787 }
 788
 789 sub loadplugin ($;$) {
 790         my $plugin=shift;
 791         my $force=shift;
 792
 793         return if ! $force && grep { $_ eq $plugin} @{$config{disable_plugins}};
 794
 795         foreach my $possiblytainteddir (getlibdirs(), "$installdir/lib/ikiwiki") {
 796                 my $dir = possibly_foolish_untaint($possiblytainteddir);
 797                 if (defined $dir && -x "$dir/plugins/$plugin") {
 798                         eval { require IkiWiki::Plugin::external };
 799                         if ($@) {
 800                                 my $reason=$@;
 801                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 802                         }
 803                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 804                         $loaded_plugins{$plugin}=1;
 805                         return 1;
 806                 }
 807         }
 808
 809         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 810         eval qq{use $mod};
 811         if ($@) {
 812                 error("Failed to load plugin $mod: $@");
 813         }
 814         $loaded_plugins{$plugin}=1;
 815         return 1;
 816 }
 817
 818 sub error ($;$) {
 819         my $message=shift;
 820         my $cleaner=shift;
 821         log_message('err' => $message) if $config{syslog};
 822         if (defined $cleaner) {
 823                 $cleaner->();
 824         }
 825         die $message."\n";
 826 }
 827
 828 sub debug ($) {
 829         return unless $config{verbose};
 830         return log_message(debug => @_);
 831 }
 832
 833 my $log_open=0;
 834 my $log_failed=0;
 835 sub log_message ($$) {
 836         my $type=shift;
 837
 838         if ($config{syslog}) {
 839                 require Sys::Syslog;
 840                 if (! $log_open) {
 841                         Sys::Syslog::setlogsock('unix');
 842                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 843                         $log_open=1;
 844                 }
 845                 eval {
 846                         my $message = "[$config{wikiname}] ".join(" ", @_);
 847                         utf8::encode($message);
 848                         Sys::Syslog::syslog($type, "%s", $message);
 849                 };
 850                 if ($@) {
 851                     print STDERR "failed to syslog: $@" unless $log_failed;
 852                     $log_failed=1;
 853                     print STDERR "@_\n";
 854                 }
 855                 return $@;
 856         }
 857         elsif (! $config{cgi}) {
 858                 return print "@_\n";
 859         }
 860         else {
 861                 return print STDERR "@_\n";
 862         }
 863 }
 864
 865 sub possibly_foolish_untaint ($) {
 866         my $tainted=shift;
 867         my ($untainted)=$tainted=~/(.*)/s;
 868         return $untainted;
 869 }
 870
 871 sub basename ($) {
 872         my $file=shift;
 873
 874         $file=~s!.*/+!!;
 875         return $file;
 876 }
 877
 878 sub dirname ($) {
 879         my $file=shift;
 880
 881         $file=~s!/*[^/]+$!!;
 882         return $file;
 883 }
 884
 885 sub isinternal ($) {
 886         my $page=shift;
 887         return exists $pagesources{$page} &&
 888                 $pagesources{$page} =~ /\._([^.]+)$/;
 889 }
 890
 891 sub pagetype ($) {
 892         my $file=shift;
 893
 894         if ($file =~ /\.([^.]+)$/) {
 895                 return $1 if exists $hooks{htmlize}{$1};
 896         }
 897         my $base=basename($file);
 898         if (exists $hooks{htmlize}{$base} &&
 899             $hooks{htmlize}{$base}{noextension}) {
 900                 return $base;
 901         }
 902         return;
 903 }
 904
 905 my %pagename_cache;
 906
 907 sub pagename ($) {
 908         my $file=shift;
 909
 910         if (exists $pagename_cache{$file}) {
 911                 return $pagename_cache{$file};
 912         }
 913
 914         my $type=pagetype($file);
 915         my $page=$file;
 916         $page=~s/\Q.$type\E*$//
 917                 if defined $type && !$hooks{htmlize}{$type}{keepextension}
 918                         && !$hooks{htmlize}{$type}{noextension};
 919         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 920                 $page=$1;
 921         }
 922
 923         $pagename_cache{$file} = $page;
 924         return $page;
 925 }
 926
 927 sub newpagefile ($$) {
 928         my $page=shift;
 929         my $type=shift;
 930
 931         if (! $config{indexpages} || $page eq 'index') {
 932                 return $page.".".$type;
 933         }
 934         else {
 935                 return $page."/index.".$type;
 936         }
 937 }
 938
 939 sub targetpage ($$;$) {
 940         my $page=shift;
 941         my $ext=shift;
 942         my $filename=shift;
 943
 944         if (defined $filename) {
 945                 return $page."/".$filename.".".$ext;
 946         }
 947         elsif (! $config{usedirs} || $page eq 'index') {
 948                 return $page.".".$ext;
 949         }
 950         else {
 951                 return $page."/index.".$ext;
 952         }
 953 }
 954
 955 sub htmlpage ($) {
 956         my $page=shift;
 957
 958         return targetpage($page, $config{htmlext});
 959 }
 960
 961 sub srcfile_stat {
 962         my $file=shift;
 963         my $nothrow=shift;
 964
 965         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 966         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 967                 return "$dir/$file", stat(_) if -e "$dir/$file";
 968         }
 969         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 970         return;
 971 }
 972
 973 sub srcfile ($;$) {
 974         return (srcfile_stat(@_))[0];
 975 }
 976
 977 sub add_literal_underlay ($) {
 978         my $dir=shift;
 979
 980         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 981                 unshift @{$config{underlaydirs}}, $dir;
 982         }
 983 }
 984
 985 sub add_underlay ($) {
 986         my $dir = shift;
 987
 988         if ($dir !~ /^\//) {
 989                 $dir="$config{underlaydirbase}/$dir";
 990         }
 991
 992         add_literal_underlay($dir);
 993         # why does it return 1? we just don't know
 994         return 1;
 995 }
 996
 997 sub readfile ($;$$) {
 998         my $file=shift;
 999         my $binary=shift;
1000         my $wantfd=shift;
1001
1002         if (-l $file) {
1003                 error("cannot read a symlink ($file)");
1004         }
1005
1006         local $/=undef;
1007         open (my $in, "<", $file) || error("failed to read $file: $!");
1008         binmode($in) if ($binary);
1009         return \*$in if $wantfd;
1010         my $ret=<$in>;
1011         # check for invalid utf-8, and toss it back to avoid crashes
1012         if (! utf8::valid($ret)) {
1013                 $ret=encode_utf8($ret);
1014         }
1015         close $in || error("failed to read $file: $!");
1016         return $ret;
1017 }
1018
1019 sub prep_writefile ($$) {
1020         my $file=shift;
1021         my $destdir=shift;
1022
1023         my $test=$file;
1024         while (length $test) {
1025                 if (-l "$destdir/$test") {
1026                         error("cannot write to a symlink ($test)");
1027                 }
1028                 if (-f _ && $test ne $file) {
1029                         # Remove conflicting file.
1030                         foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
1031                                 foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
1032                                         if ($f eq $test) {
1033                                                 unlink("$destdir/$test");
1034                                                 last;
1035                                         }
1036                                 }
1037                         }
1038                 }
1039                 $test=dirname($test);
1040         }
1041
1042         my $dir=dirname("$destdir/$file");
1043         if (! -d $dir) {
1044                 my $d="";
1045                 foreach my $s (split(m!/+!, $dir)) {
1046                         $d.="$s/";
1047                         if (! -d $d) {
1048                                 mkdir($d) || error("failed to create directory $d: $!");
1049                         }
1050                 }
1051         }
1052
1053         return 1;
1054 }
1055
1056 sub writefile ($$$;$$) {
1057         my $file=shift; # can include subdirs
1058         my $destdir=shift; # directory to put file in
1059         my $content=shift;
1060         my $binary=shift;
1061         my $writer=shift;
1062
1063         prep_writefile($file, $destdir);
1064
1065         my $newfile="$destdir/$file.ikiwiki-new";
1066         if (-l $newfile) {
1067                 error("cannot write to a symlink ($newfile)");
1068         }
1069
1070         my $cleanup = sub { unlink($newfile) };
1071         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
1072         binmode($out) if ($binary);
1073         if ($writer) {
1074                 $writer->(\*$out, $cleanup);
1075         }
1076         else {
1077                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
1078         }
1079         close $out || error("failed saving $newfile: $!", $cleanup);
1080         rename($newfile, "$destdir/$file") ||
1081                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
1082
1083         return 1;
1084 }
1085
1086 my %cleared;
1087 sub will_render ($$;$) {
1088         my $page=shift;
1089         my $dest=shift;
1090         my $clear=shift;
1091
1092         # Important security check for independently created files.
1093         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
1094             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
1095                 my $from_other_page=0;
1096                 # Expensive, but rarely runs.
1097                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
1098                         if (grep {
1099                                 $_ eq $dest ||
1100                                 dirname($_) eq $dest
1101                             } @{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
1102                                 $from_other_page=1;
1103                                 last;
1104                         }
1105                 }
1106
1107                 error("$config{destdir}/$dest independently created, not overwriting with version from $page")
1108                         unless $from_other_page;
1109         }
1110
1111         # If $dest exists as a directory, remove conflicting files in it
1112         # rendered from other pages.
1113         if (-d _) {
1114                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
1115                         foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
1116                                 if (dirname($f) eq $dest) {
1117                                         unlink("$config{destdir}/$f");
1118                                         rmdir(dirname("$config{destdir}/$f"));
1119                                 }
1120                         }
1121                 }
1122         }
1123
1124         if (! $clear || $cleared{$page}) {
1125                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
1126         }
1127         else {
1128                 foreach my $old (@{$renderedfiles{$page}}) {
1129                         delete $destsources{$old};
1130                 }
1131                 $renderedfiles{$page}=[$dest];
1132                 $cleared{$page}=1;
1133         }
1134         $destsources{$dest}=$page;
1135
1136         return 1;
1137 }
1138
1139 sub bestlink ($$) {
1140         my $page=shift;
1141         my $link=shift;
1142
1143         my $cwd=$page;
1144         if ($link=~s/^\/+//) {
1145                 # absolute links
1146                 $cwd="";
1147         }
1148         $link=~s/\/$//;
1149
1150         do {
1151                 my $l=$cwd;
1152                 $l.="/" if length $l;
1153                 $l.=$link;
1154
1155                 if (exists $pagesources{$l}) {
1156                         return $l;
1157                 }
1158                 elsif (exists $pagecase{lc $l}) {
1159                         return $pagecase{lc $l};
1160                 }
1161         } while $cwd=~s{/?[^/]+$}{};
1162
1163         if (length $config{userdir}) {
1164                 my $l = "$config{userdir}/".lc($link);
1165                 if (exists $pagesources{$l}) {
1166                         return $l;
1167                 }
1168                 elsif (exists $pagecase{lc $l}) {
1169                         return $pagecase{lc $l};
1170                 }
1171         }
1172
1173         #print STDERR "warning: page $page, broken link: $link\n";
1174         return "";
1175 }
1176
1177 sub isinlinableimage ($) {
1178         my $file=shift;
1179
1180         return $file =~ /\.(png|gif|jpg|jpeg|svg)$/i;
1181 }
1182
1183 sub pagetitle ($;$) {
1184         my $page=shift;
1185         my $unescaped=shift;
1186
1187         if ($unescaped) {
1188                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
1189         }
1190         else {
1191                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
1192         }
1193
1194         return $page;
1195 }
1196
1197 sub titlepage ($) {
1198         my $title=shift;
1199         # support use w/o %config set
1200         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1201         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1202         return $title;
1203 }
1204
1205 sub linkpage ($) {
1206         my $link=shift;
1207         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1208         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1209         return $link;
1210 }
1211
1212 sub cgiurl (@) {
1213         my %params=@_;
1214
1215         my $cgiurl=$local_cgiurl;
1216
1217         if (exists $params{cgiurl}) {
1218                 $cgiurl=$params{cgiurl};
1219                 delete $params{cgiurl};
1220         }
1221
1222         unless (%params) {
1223                 return $cgiurl;
1224         }
1225
1226         return $cgiurl."?".
1227                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), sort(keys %params));
1228 }
1229
1230 sub cgiurl_abs (@) {
1231         eval q{use URI};
1232         URI->new_abs(cgiurl(@_), $config{cgiurl});
1233 }
1234
1235 sub baseurl (;$) {
1236         my $page=shift;
1237
1238         return $local_url if ! defined $page;
1239
1240         $page=htmlpage($page);
1241         $page=~s/[^\/]+$//;
1242         $page=~s/[^\/]+\//..\//g;
1243         return $page;
1244 }
1245
1246 sub urlabs ($$) {
1247         my $url=shift;
1248         my $urlbase=shift;
1249
1250         return $url unless defined $urlbase && length $urlbase;
1251
1252         eval q{use URI};
1253         URI->new_abs($url, $urlbase)->as_string;
1254 }
1255
1256 sub abs2rel ($$) {
1257         # Work around very innefficient behavior in File::Spec if abs2rel
1258         # is passed two relative paths. It's much faster if paths are
1259         # absolute! (Debian bug #376658; fixed in debian unstable now)
1260         my $path="/".shift;
1261         my $base="/".shift;
1262
1263         require File::Spec;
1264         my $ret=File::Spec->abs2rel($path, $base);
1265         $ret=~s/^// if defined $ret;
1266         return $ret;
1267 }
1268
1269 sub displaytime ($;$$) {
1270         # Plugins can override this function to mark up the time to
1271         # display.
1272         my $time=formattime($_[0], $_[1]);
1273         if ($config{html5}) {
1274                 return '<time datetime="'.date_3339($_[0]).'"'.
1275                         ($_[2] ? ' pubdate="pubdate"' : '').
1276                         '>'.$time.'</time>';
1277         }
1278         else {
1279                 return '<span class="date">'.$time.'</span>';
1280         }
1281 }
1282
1283 sub formattime ($;$) {
1284         # Plugins can override this function to format the time.
1285         my $time=shift;
1286         my $format=shift;
1287         if (! defined $format) {
1288                 $format=$config{timeformat};
1289         }
1290
1291         return strftime_utf8($format, localtime($time));
1292 }
1293
1294 my $strftime_encoding;
1295 sub strftime_utf8 {
1296         # strftime doesn't know about encodings, so make sure
1297         # its output is properly treated as utf8.
1298         # Note that this does not handle utf-8 in the format string.
1299         ($strftime_encoding) = POSIX::setlocale(&POSIX::LC_TIME) =~ m#\.([^@]+)#
1300                 unless defined $strftime_encoding;
1301         $strftime_encoding
1302                 ? Encode::decode($strftime_encoding, POSIX::strftime(@_))
1303                 : POSIX::strftime(@_);
1304 }
1305
1306 sub date_3339 ($) {
1307         my $time=shift;
1308
1309         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
1310         POSIX::setlocale(&POSIX::LC_TIME, "C");
1311         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
1312         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
1313         return $ret;
1314 }
1315
1316 sub beautify_urlpath ($) {
1317         my $url=shift;
1318
1319         # Ensure url is not an empty link, and if necessary,
1320         # add ./ to avoid colon confusion.
1321         if ($url !~ /^\// && $url !~ /^\.\.?\//) {
1322                 $url="./$url";
1323         }
1324
1325         if ($config{usedirs}) {
1326                 $url =~ s!/index.$config{htmlext}$!/!;
1327         }
1328
1329         return $url;
1330 }
1331
1332 sub urlto ($;$$) {
1333         my $to=shift;
1334         my $from=shift;
1335         my $absolute=shift;
1336
1337         if (! length $to) {
1338                 $to = 'index';
1339         }
1340
1341         if (! $destsources{$to}) {
1342                 $to=htmlpage($to);
1343         }
1344
1345         if ($absolute) {
1346                 return $config{url}.beautify_urlpath("/".$to);
1347         }
1348
1349         if (! defined $from) {
1350                 my $u = $local_url || '';
1351                 $u =~ s{/$}{};
1352                 return $u.beautify_urlpath("/".$to);
1353         }
1354
1355         my $link = abs2rel($to, dirname(htmlpage($from)));
1356
1357         return beautify_urlpath($link);
1358 }
1359
1360 sub isselflink ($$) {
1361         # Plugins can override this function to support special types
1362         # of selflinks.
1363         my $page=shift;
1364         my $link=shift;
1365
1366         return $page eq $link;
1367 }
1368
1369 sub htmllink ($$$;@) {
1370         my $lpage=shift; # the page doing the linking
1371         my $page=shift; # the page that will contain the link (different for inline)
1372         my $link=shift;
1373         my %opts=@_;
1374
1375         $link=~s/\/$//;
1376
1377         my $bestlink;
1378         if (! $opts{forcesubpage}) {
1379                 $bestlink=bestlink($lpage, $link);
1380         }
1381         else {
1382                 $bestlink="$lpage/".lc($link);
1383         }
1384
1385         my $linktext;
1386         if (defined $opts{linktext}) {
1387                 $linktext=$opts{linktext};
1388         }
1389         else {
1390                 $linktext=pagetitle(basename($link));
1391         }
1392
1393         return "<span class=\"selflink\">$linktext</span>"
1394                 if length $bestlink && isselflink($page, $bestlink) &&
1395                    ! defined $opts{anchor};
1396
1397         if (! $destsources{$bestlink}) {
1398                 $bestlink=htmlpage($bestlink);
1399
1400                 if (! $destsources{$bestlink}) {
1401                         my $cgilink = "";
1402                         if (length $config{cgiurl}) {
1403                                 $cgilink = "<a href=\"".
1404                                         cgiurl(
1405                                                 do => "create",
1406                                                 page => $link,
1407                                                 from => $lpage
1408                                         )."\" rel=\"nofollow\">?</a>";
1409                         }
1410                         return "<span class=\"createlink\">$cgilink$linktext</span>"
1411                 }
1412         }
1413
1414         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1415         $bestlink=beautify_urlpath($bestlink);
1416
1417         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1418                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1419         }
1420
1421         if (defined $opts{anchor}) {
1422                 $bestlink.="#".$opts{anchor};
1423         }
1424
1425         my @attrs;
1426         foreach my $attr (qw{rel class title}) {
1427                 if (defined $opts{$attr}) {
1428                         push @attrs, " $attr=\"$opts{$attr}\"";
1429                 }
1430         }
1431
1432         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1433 }
1434
1435 sub userpage ($) {
1436         my $user=shift;
1437         return length $config{userdir} ? "$config{userdir}/$user" : $user;
1438 }
1439
1440 # Username to display for openid accounts.
1441 sub openiduser ($) {
1442         my $user=shift;
1443
1444         if (defined $user && $user =~ m!^https?://! &&
1445             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
1446                 my $display;
1447
1448                 if (Net::OpenID::VerifiedIdentity->can("DisplayOfURL")) {
1449                         $display = Net::OpenID::VerifiedIdentity::DisplayOfURL($user);
1450                 }
1451                 else {
1452                         # backcompat with old version
1453                         my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
1454                         $display=$oid->display;
1455                 }
1456
1457                 # Convert "user.somehost.com" to "user [somehost.com]"
1458                 # (also "user.somehost.co.uk")
1459                 if ($display !~ /\[/) {
1460                         $display=~s/^([-a-zA-Z0-9]+?)\.([-.a-zA-Z0-9]+\.[a-z]+)$/$1 [$2]/;
1461                 }
1462                 # Convert "http://somehost.com/user" to "user [somehost.com]".
1463                 # (also "https://somehost.com/user/")
1464                 if ($display !~ /\[/) {
1465                         $display=~s/^https?:\/\/(.+)\/([^\/#?]+)\/?(?:[#?].*)?$/$2 [$1]/;
1466                 }
1467                 $display=~s!^https?://!!; # make sure this is removed
1468                 eval q{use CGI 'escapeHTML'};
1469                 error($@) if $@;
1470                 return escapeHTML($display);
1471         }
1472         return;
1473 }
1474
1475 # Username to display for emailauth accounts.
1476 sub emailuser ($) {
1477         my $user=shift;
1478         if (defined $user && $user =~ m/(.+)@/) {
1479                 my $nick=$1;
1480                 # remove any characters from not allowed in wiki files
1481                 # support use w/o %config set
1482                 my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1483                 $nick=~s/[^$chars]/_/g;
1484                 return $nick;
1485         }
1486         return;
1487 }
1488
1489 # Some user information should not be exposed in commit metadata, etc.
1490 # This generates a cloaked form of such information.
1491 sub cloak ($) {
1492         my $user=shift;
1493         # cloak email address using http://xmlns.com/foaf/spec/#term_mbox_sha1sum
1494         if ($user=~m/(.+)@/) {
1495                 my $nick=$1;
1496                 eval q{use Digest::SHA};
1497                 return $user if $@;
1498                 return $nick.'@'.Digest::SHA::sha1_hex("mailto:$user");
1499         }
1500         else {
1501                 return $user;
1502         }
1503 }
1504
1505 sub htmlize ($$$$) {
1506         my $page=shift;
1507         my $destpage=shift;
1508         my $type=shift;
1509         my $content=shift;
1510
1511         my $oneline = $content !~ /\n/;
1512
1513         if (exists $hooks{htmlize}{$type}) {
1514                 $content=$hooks{htmlize}{$type}{call}->(
1515                         page => $page,
1516                         content => $content,
1517                 );
1518         }
1519         else {
1520                 error("htmlization of $type not supported");
1521         }
1522
1523         run_hooks(sanitize => sub {
1524                 $content=shift->(
1525                         page => $page,
1526                         destpage => $destpage,
1527                         content => $content,
1528                 );
1529         });
1530
1531         if ($oneline) {
1532                 # hack to get rid of enclosing junk added by markdown
1533                 # and other htmlizers/sanitizers
1534                 $content=~s/^<p>//i;
1535                 $content=~s/<\/p>\n*$//i;
1536         }
1537
1538         return $content;
1539 }
1540
1541 sub linkify ($$$) {
1542         my $page=shift;
1543         my $destpage=shift;
1544         my $content=shift;
1545
1546         run_hooks(linkify => sub {
1547                 $content=shift->(
1548                         page => $page,
1549                         destpage => $destpage,
1550                         content => $content,
1551                 );
1552         });
1553
1554         return $content;
1555 }
1556
1557 our %preprocessing;
1558 our $preprocess_preview=0;
1559 sub preprocess ($$$;$$) {
1560         my $page=shift; # the page the data comes from
1561         my $destpage=shift; # the page the data will appear in (different for inline)
1562         my $content=shift;
1563         my $scan=shift;
1564         my $preview=shift;
1565
1566         # Using local because it needs to be set within any nested calls
1567         # of this function.
1568         local $preprocess_preview=$preview if defined $preview;
1569
1570         my $handle=sub {
1571                 my $escape=shift;
1572                 my $prefix=shift;
1573                 my $command=shift;
1574                 my $params=shift;
1575                 $params="" if ! defined $params;
1576
1577                 if (length $escape) {
1578                         return "[[$prefix$command $params]]";
1579                 }
1580                 elsif (exists $hooks{preprocess}{$command}) {
1581                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1582                         # Note: preserve order of params, some plugins may
1583                         # consider it significant.
1584                         my @params;
1585                         while ($params =~ m{
1586                                 (?:([-.\w]+)=)?         # 1: named parameter key?
1587                                 (?:
1588                                         """(.*?)"""     # 2: triple-quoted value
1589                                 |
1590                                         "([^"]*?)"      # 3: single-quoted value
1591                                 |
1592                                         '''(.*?)'''     # 4: triple-single-quote
1593                                 |
1594                                         <<([a-zA-Z]+)\n # 5: heredoc start
1595                                         (.*?)\n\5       # 6: heredoc value
1596                                 |
1597                                         (\S+)           # 7: unquoted value
1598                                 )
1599                                 (?:\s+|$)               # delimiter to next param
1600                         }msgx) {
1601                                 my $key=$1;
1602                                 my $val;
1603                                 if (defined $2) {
1604                                         $val=$2;
1605                                         $val=~s/\r\n/\n/mg;
1606                                         $val=~s/^\n+//g;
1607                                         $val=~s/\n+$//g;
1608                                 }
1609                                 elsif (defined $3) {
1610                                         $val=$3;
1611                                 }
1612                                 elsif (defined $4) {
1613                                         $val=$4;
1614                                 }
1615                                 elsif (defined $7) {
1616                                         $val=$7;
1617                                 }
1618                                 elsif (defined $6) {
1619                                         $val=$6;
1620                                 }
1621
1622                                 if (defined $key) {
1623                                         push @params, $key, $val;
1624                                 }
1625                                 else {
1626                                         push @params, $val, '';
1627                                 }
1628                         }
1629                         if ($preprocessing{$page}++ > 8) {
1630                                 # Avoid loops of preprocessed pages preprocessing
1631                                 # other pages that preprocess them, etc.
1632                                 return "[[!$command <span class=\"error\">".
1633                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1634                                                 $page, $preprocessing{$page}).
1635                                         "</span>]]";
1636                         }
1637                         my $ret;
1638                         if (! $scan) {
1639                                 $ret=eval {
1640                                         $hooks{preprocess}{$command}{call}->(
1641                                                 @params,
1642                                                 page => $page,
1643                                                 destpage => $destpage,
1644                                                 preview => $preprocess_preview,
1645                                         );
1646                                 };
1647                                 if ($@) {
1648                                         my $error=$@;
1649                                         chomp $error;
1650                                         $ret="[[!$command <span class=\"error\">".
1651                                                 gettext("Error").": $error"."</span>]]";
1652                                 }
1653                         }
1654                         else {
1655                                 # use void context during scan pass
1656                                 eval {
1657                                         $hooks{preprocess}{$command}{call}->(
1658                                                 @params,
1659                                                 page => $page,
1660                                                 destpage => $destpage,
1661                                                 preview => $preprocess_preview,
1662                                         );
1663                                 };
1664                                 $ret="";
1665                         }
1666                         $preprocessing{$page}--;
1667                         return $ret;
1668                 }
1669                 else {
1670                         return "[[$prefix$command $params]]";
1671                 }
1672         };
1673
1674         my $regex;
1675         if ($config{prefix_directives}) {
1676                 $regex = qr{
1677                         (\\?)           # 1: escape?
1678                         \[\[(!)         # directive open; 2: prefix
1679                         ([-\w]+)        # 3: command
1680                         (               # 4: the parameters..
1681                                 \s+     # Must have space if parameters present
1682                                 (?:
1683                                         (?:[-.\w]+=)?           # named parameter key?
1684                                         (?:
1685                                                 """.*?"""       # triple-quoted value
1686                                                 |
1687                                                 "[^"]*?"        # single-quoted value
1688                                                 |
1689                                                 '''.*?'''       # triple-single-quote
1690                                                 |
1691                                                 <<([a-zA-Z]+)\n # 5: heredoc start
1692                                                 (?:.*?)\n\5     # heredoc value
1693                                                 |
1694                                                 [^"\s\]]+       # unquoted value
1695                                         )
1696                                         \s*                     # whitespace or end
1697                                                                 # of directive
1698                                 )
1699                         *)?             # 0 or more parameters
1700                         \]\]            # directive closed
1701                 }sx;
1702         }
1703         else {
1704                 $regex = qr{
1705                         (\\?)           # 1: escape?
1706                         \[\[(!?)        # directive open; 2: optional prefix
1707                         ([-\w]+)        # 3: command
1708                         \s+
1709                         (               # 4: the parameters..
1710                                 (?:
1711                                         (?:[-.\w]+=)?           # named parameter key?
1712                                         (?:
1713                                                 """.*?"""       # triple-quoted value
1714                                                 |
1715                                                 "[^"]*?"        # single-quoted value
1716                                                 |
1717                                                 '''.*?'''       # triple-single-quote
1718                                                 |
1719                                                 <<([a-zA-Z]+)\n # 5: heredoc start
1720                                                 (?:.*?)\n\5     # heredoc value
1721                                                 |
1722                                                 [^"\s\]]+       # unquoted value
1723                                         )
1724                                         \s*                     # whitespace or end
1725                                                                 # of directive
1726                                 )
1727                         *)              # 0 or more parameters
1728                         \]\]            # directive closed
1729                 }sx;
1730         }
1731
1732         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1733         return $content;
1734 }
1735
1736 sub filter ($$$) {
1737         my $page=shift;
1738         my $destpage=shift;
1739         my $content=shift;
1740
1741         run_hooks(filter => sub {
1742                 $content=shift->(page => $page, destpage => $destpage,
1743                         content => $content);
1744         });
1745
1746         return $content;
1747 }
1748
1749 sub check_canedit ($$$;$) {
1750         my $page=shift;
1751         my $q=shift;
1752         my $session=shift;
1753         my $nonfatal=shift;
1754
1755         my $canedit;
1756         run_hooks(canedit => sub {
1757                 return if defined $canedit;
1758                 my $ret=shift->($page, $q, $session);
1759                 if (defined $ret) {
1760                         if ($ret eq "") {
1761                                 $canedit=1;
1762                         }
1763                         elsif (ref $ret eq 'CODE') {
1764                                 $ret->() unless $nonfatal;
1765                                 $canedit=0;
1766                         }
1767                         elsif (defined $ret) {
1768                                 error($ret) unless $nonfatal;
1769                                 $canedit=0;
1770                         }
1771                 }
1772         });
1773         return defined $canedit ? $canedit : 1;
1774 }
1775
1776 sub check_content (@) {
1777         my %params=@_;
1778
1779         return 1 if ! exists $hooks{checkcontent}; # optimisation
1780
1781         if (exists $pagesources{$params{page}}) {
1782                 my @diff;
1783                 my %old=map { $_ => 1 }
1784                         split("\n", readfile(srcfile($pagesources{$params{page}})));
1785                 foreach my $line (split("\n", $params{content})) {
1786                         push @diff, $line if ! exists $old{$line};
1787                 }
1788                 $params{diff}=join("\n", @diff);
1789         }
1790
1791         my $ok;
1792         run_hooks(checkcontent => sub {
1793                 return if defined $ok;
1794                 my $ret=shift->(%params);
1795                 if (defined $ret) {
1796                         if ($ret eq "") {
1797                                 $ok=1;
1798                         }
1799                         elsif (ref $ret eq 'CODE') {
1800                                 $ret->() unless $params{nonfatal};
1801                                 $ok=0;
1802                         }
1803                         elsif (defined $ret) {
1804                                 error($ret) unless $params{nonfatal};
1805                                 $ok=0;
1806                         }
1807                 }
1808
1809         });
1810         return defined $ok ? $ok : 1;
1811 }
1812
1813 sub check_canchange (@) {
1814         my %params = @_;
1815         my $cgi = $params{cgi};
1816         my $session = $params{session};
1817         my @changes = @{$params{changes}};
1818
1819         my %newfiles;
1820         foreach my $change (@changes) {
1821                 # This untaint is safe because we check file_pruned and
1822                 # wiki_file_regexp.
1823                 my ($file)=$change->{file}=~/$config{wiki_file_regexp}/;
1824                 $file=possibly_foolish_untaint($file);
1825                 if (! defined $file || ! length $file ||
1826                     file_pruned($file)) {
1827                         error(gettext("bad file name %s"), $file);
1828                 }
1829
1830                 my $type=pagetype($file);
1831                 my $page=pagename($file) if defined $type;
1832
1833                 if ($change->{action} eq 'add') {
1834                         $newfiles{$file}=1;
1835                 }
1836
1837                 if ($change->{action} eq 'change' ||
1838                     $change->{action} eq 'add') {
1839                         if (defined $page) {
1840                                 check_canedit($page, $cgi, $session);
1841                                 next;
1842                         }
1843                         else {
1844                                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
1845                                         IkiWiki::Plugin::attachment::check_canattach($session, $file, $change->{path});
1846                                         check_canedit($file, $cgi, $session);
1847                                         next;
1848                                 }
1849                         }
1850                 }
1851                 elsif ($change->{action} eq 'remove') {
1852                         # check_canremove tests to see if the file is present
1853                         # on disk. This will fail when a single commit adds a
1854                         # file and then removes it again. Avoid the problem
1855                         # by not testing the removal in such pairs of changes.
1856                         # (The add is still tested, just to make sure that
1857                         # no data is added to the repo that a web edit
1858                         # could not add.)
1859                         next if $newfiles{$file};
1860
1861                         if (IkiWiki::Plugin::remove->can("check_canremove")) {
1862                                 IkiWiki::Plugin::remove::check_canremove(defined $page ? $page : $file, $cgi, $session);
1863                                 check_canedit(defined $page ? $page : $file, $cgi, $session);
1864                                 next;
1865                         }
1866                 }
1867                 else {
1868                         error "unknown action ".$change->{action};
1869                 }
1870
1871                 error sprintf(gettext("you are not allowed to change %s"), $file);
1872         }
1873 }
1874
1875
1876 my $wikilock;
1877
1878 sub lockwiki () {
1879         # Take an exclusive lock on the wiki to prevent multiple concurrent
1880         # run issues. The lock will be dropped on program exit.
1881         if (! -d $config{wikistatedir}) {
1882                 mkdir($config{wikistatedir});
1883         }
1884         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1885                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1886         if (! flock($wikilock, LOCK_EX | LOCK_NB)) {
1887                 debug("failed to get lock; waiting...");
1888                 if (! flock($wikilock, LOCK_EX)) {
1889                         error("failed to get lock");
1890                 }
1891         }
1892         return 1;
1893 }
1894
1895 sub unlockwiki () {
1896         POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
1897         return close($wikilock) if $wikilock;
1898         return;
1899 }
1900
1901 my $commitlock;
1902
1903 sub commit_hook_enabled () {
1904         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1905                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1906         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1907                 close($commitlock) || error("failed closing commitlock: $!");
1908                 return 0;
1909         }
1910         close($commitlock) || error("failed closing commitlock: $!");
1911         return 1;
1912 }
1913
1914 sub disable_commit_hook () {
1915         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1916                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1917         if (! flock($commitlock, 2)) { # LOCK_EX
1918                 error("failed to get commit lock");
1919         }
1920         return 1;
1921 }
1922
1923 sub enable_commit_hook () {
1924         return close($commitlock) if $commitlock;
1925         return;
1926 }
1927
1928 sub loadindex () {
1929         %oldrenderedfiles=%pagectime=();
1930         my $rebuild=$config{rebuild};
1931         if (! $rebuild) {
1932                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1933                 %destsources=%renderedfiles=%pagecase=%pagestate=
1934                 %depends_simple=%typedlinks=%oldtypedlinks=();
1935         }
1936         my $in;
1937         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1938                 if (-e "$config{wikistatedir}/index") {
1939                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1940                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1941                 }
1942                 else {
1943                         # gettime on first build
1944                         $config{gettime}=1 unless defined $config{gettime};
1945                         return;
1946                 }
1947         }
1948
1949         my $index=Storable::fd_retrieve($in);
1950         if (! defined $index) {
1951                 return 0;
1952         }
1953
1954         my $pages;
1955         if (exists $index->{version} && ! ref $index->{version}) {
1956                 $pages=$index->{page};
1957                 %wikistate=%{$index->{state}};
1958                 # Handle plugins that got disabled by loading a new setup.
1959                 if (exists $config{setupfile}) {
1960                         require IkiWiki::Setup;
1961                         IkiWiki::Setup::disabled_plugins(
1962                                 grep { ! $loaded_plugins{$_} } keys %wikistate);
1963                 }
1964         }
1965         else {
1966                 $pages=$index;
1967                 %wikistate=();
1968         }
1969
1970         foreach my $src (keys %$pages) {
1971                 my $d=$pages->{$src};
1972                 my $page;
1973                 if (exists $d->{page} && ! $rebuild) {
1974                         $page=$d->{page};
1975                 }
1976                 else {
1977                         $page=pagename($src);
1978                 }
1979                 $pagectime{$page}=$d->{ctime};
1980                 $pagesources{$page}=$src;
1981                 if (! $rebuild) {
1982                         $pagemtime{$page}=$d->{mtime};
1983                         $renderedfiles{$page}=$d->{dest};
1984                         if (exists $d->{links} && ref $d->{links}) {
1985                                 $links{$page}=$d->{links};
1986                                 $oldlinks{$page}=[@{$d->{links}}];
1987                         }
1988                         if (ref $d->{depends_simple} eq 'ARRAY') {
1989                                 # old format
1990                                 $depends_simple{$page}={
1991                                         map { $_ => 1 } @{$d->{depends_simple}}
1992                                 };
1993                         }
1994                         elsif (exists $d->{depends_simple}) {
1995                                 $depends_simple{$page}=$d->{depends_simple};
1996                         }
1997                         if (exists $d->{dependslist}) {
1998                                 # old format
1999                                 $depends{$page}={
2000                                         map { $_ => $DEPEND_CONTENT }
2001                                                 @{$d->{dependslist}}
2002                                 };
2003                         }
2004                         elsif (exists $d->{depends} && ! ref $d->{depends}) {
2005                                 # old format
2006                                 $depends{$page}={$d->{depends} => $DEPEND_CONTENT };
2007                         }
2008                         elsif (exists $d->{depends}) {
2009                                 $depends{$page}=$d->{depends};
2010                         }
2011                         if (exists $d->{state}) {
2012                                 $pagestate{$page}=$d->{state};
2013                         }
2014                         if (exists $d->{typedlinks}) {
2015                                 $typedlinks{$page}=$d->{typedlinks};
2016
2017                                 while (my ($type, $links) = each %{$typedlinks{$page}}) {
2018                                         next unless %$links;
2019                                         $oldtypedlinks{$page}{$type} = {%$links};
2020                                 }
2021                         }
2022                 }
2023                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
2024         }
2025         foreach my $page (keys %pagesources) {
2026                 $pagecase{lc $page}=$page;
2027         }
2028         foreach my $page (keys %renderedfiles) {
2029                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
2030         }
2031         $lastrev=$index->{lastrev};
2032         @underlayfiles=@{$index->{underlayfiles}} if ref $index->{underlayfiles};
2033         return close($in);
2034 }
2035
2036 sub saveindex () {
2037         run_hooks(savestate => sub { shift->() });
2038
2039         my @plugins=keys %loaded_plugins;
2040
2041         if (! -d $config{wikistatedir}) {
2042                 mkdir($config{wikistatedir});
2043         }
2044         my $newfile="$config{wikistatedir}/indexdb.new";
2045         my $cleanup = sub { unlink($newfile) };
2046         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
2047
2048         my %index;
2049         foreach my $page (keys %pagemtime) {
2050                 next unless $pagemtime{$page};
2051                 my $src=$pagesources{$page};
2052
2053                 $index{page}{$src}={
2054                         page => $page,
2055                         ctime => $pagectime{$page},
2056                         mtime => $pagemtime{$page},
2057                         dest => $renderedfiles{$page},
2058                         links => $links{$page},
2059                 };
2060
2061                 if (exists $depends{$page}) {
2062                         $index{page}{$src}{depends} = $depends{$page};
2063                 }
2064
2065                 if (exists $depends_simple{$page}) {
2066                         $index{page}{$src}{depends_simple} = $depends_simple{$page};
2067                 }
2068
2069                 if (exists $typedlinks{$page} && %{$typedlinks{$page}}) {
2070                         $index{page}{$src}{typedlinks} = $typedlinks{$page};
2071                 }
2072
2073                 if (exists $pagestate{$page}) {
2074                         $index{page}{$src}{state}=$pagestate{$page};
2075                 }
2076         }
2077
2078         $index{state}={};
2079         foreach my $id (@plugins) {
2080                 $index{state}{$id}={}; # used to detect disabled plugins
2081                 foreach my $key (keys %{$wikistate{$id}}) {
2082                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
2083                 }
2084         }
2085
2086         $index{lastrev}=$lastrev;
2087         $index{underlayfiles}=\@underlayfiles;
2088
2089         $index{version}="3";
2090         my $ret=Storable::nstore_fd(\%index, $out);
2091         return if ! defined $ret || ! $ret;
2092         close $out || error("failed saving to $newfile: $!", $cleanup);
2093         rename($newfile, "$config{wikistatedir}/indexdb") ||
2094                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
2095
2096         return 1;
2097 }
2098
2099 sub template_file ($) {
2100         my $name=shift;
2101
2102         my $tpage=($name =~ s/^\///) ? $name : "templates/$name";
2103         my $template;
2104         if ($name !~ /\.tmpl$/ && exists $pagesources{$tpage}) {
2105                 $template=srcfile($pagesources{$tpage}, 1);
2106                 $name.=".tmpl";
2107         }
2108         else {
2109                 $template=srcfile($tpage, 1);
2110         }
2111
2112         if (defined $template) {
2113                 return $template, $tpage, 1 if wantarray;
2114                 return $template;
2115         }
2116         else {
2117                 $name=~s:/::; # avoid path traversal
2118                 foreach my $dir ($config{templatedir},
2119                                  "$installdir/share/ikiwiki/templates") {
2120                         if (-e "$dir/$name") {
2121                                 $template="$dir/$name";
2122                                 last;
2123                         }
2124                 }
2125                 if (defined $template) {
2126                         return $template, $tpage if wantarray;
2127                         return $template;
2128                 }
2129         }
2130
2131         return;
2132 }
2133
2134 sub template_depends ($$;@) {
2135         my $name=shift;
2136         my $page=shift;
2137
2138         my ($filename, $tpage, $untrusted)=template_file($name);
2139         if (! defined $filename) {
2140                 error(sprintf(gettext("template %s not found"), $name))
2141         }
2142
2143         if (defined $page && defined $tpage) {
2144                 add_depends($page, $tpage);
2145         }
2146
2147         my @opts=(
2148                 filter => sub {
2149                         my $text_ref = shift;
2150                         ${$text_ref} = decode_utf8(${$text_ref});
2151                         run_hooks(readtemplate => sub {
2152                                 ${$text_ref} = shift->(
2153                                         id => $name,
2154                                         page => $tpage,
2155                                         content => ${$text_ref},
2156                                         untrusted => $untrusted,
2157                                 );
2158                         });
2159                 },
2160                 loop_context_vars => 1,
2161                 die_on_bad_params => 0,
2162                 parent_global_vars => 1,
2163                 filename => $filename,
2164                 @_,
2165                 ($untrusted ? (no_includes => 1) : ()),
2166         );
2167         return @opts if wantarray;
2168
2169         require HTML::Template;
2170         return HTML::Template->new(@opts);
2171 }
2172
2173 sub template ($;@) {
2174         template_depends(shift, undef, @_);
2175 }
2176
2177 sub templateactions ($$) {
2178         my $template=shift;
2179         my $page=shift;
2180
2181         my $have_actions=0;
2182         my @actions;
2183         run_hooks(pageactions => sub {
2184                 push @actions, map { { action => $_ } }
2185                         grep { defined } shift->(page => $page);
2186         });
2187         $template->param(actions => \@actions);
2188
2189         if ($config{cgiurl} && exists $hooks{auth}) {
2190                 $template->param(prefsurl => cgiurl(do => "prefs"));
2191                 $have_actions=1;
2192         }
2193
2194         if ($have_actions || @actions) {
2195                 $template->param(have_actions => 1);
2196         }
2197 }
2198
2199 sub hook (@) {
2200         my %param=@_;
2201
2202         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
2203                 error 'hook requires type, call, and id parameters';
2204         }
2205
2206         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
2207
2208         $hooks{$param{type}}{$param{id}}=\%param;
2209         return 1;
2210 }
2211
2212 sub run_hooks ($$) {
2213         # Calls the given sub for each hook of the given type,
2214         # passing it the hook function to call.
2215         my $type=shift;
2216         my $sub=shift;
2217
2218         if (exists $hooks{$type}) {
2219                 my (@first, @middle, @last);
2220                 foreach my $id (keys %{$hooks{$type}}) {
2221                         if ($hooks{$type}{$id}{first}) {
2222                                 push @first, $id;
2223                         }
2224                         elsif ($hooks{$type}{$id}{last}) {
2225                                 push @last, $id;
2226                         }
2227                         else {
2228                                 push @middle, $id;
2229                         }
2230                 }
2231                 foreach my $id (@first, @middle, @last) {
2232                         $sub->($hooks{$type}{$id}{call});
2233                 }
2234         }
2235
2236         return 1;
2237 }
2238
2239 sub rcs_update () {
2240         $hooks{rcs}{rcs_update}{call}->(@_);
2241 }
2242
2243 sub rcs_prepedit ($) {
2244         $hooks{rcs}{rcs_prepedit}{call}->(@_);
2245 }
2246
2247 sub rcs_commit (@) {
2248         $hooks{rcs}{rcs_commit}{call}->(@_);
2249 }
2250
2251 sub rcs_commit_staged (@) {
2252         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
2253 }
2254
2255 sub rcs_add ($) {
2256         $hooks{rcs}{rcs_add}{call}->(@_);
2257 }
2258
2259 sub rcs_remove ($) {
2260         $hooks{rcs}{rcs_remove}{call}->(@_);
2261 }
2262
2263 sub rcs_rename ($$) {
2264         $hooks{rcs}{rcs_rename}{call}->(@_);
2265 }
2266
2267 sub rcs_recentchanges ($) {
2268         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
2269 }
2270
2271 sub rcs_diff ($;$) {
2272         $hooks{rcs}{rcs_diff}{call}->(@_);
2273 }
2274
2275 sub rcs_getctime ($) {
2276         $hooks{rcs}{rcs_getctime}{call}->(@_);
2277 }
2278
2279 sub rcs_getmtime ($) {
2280         $hooks{rcs}{rcs_getmtime}{call}->(@_);
2281 }
2282
2283 sub rcs_receive () {
2284         $hooks{rcs}{rcs_receive}{call}->();
2285 }
2286
2287 sub add_depends ($$;$) {
2288         my $page=shift;
2289         my $pagespec=shift;
2290         my $deptype=shift || $DEPEND_CONTENT;
2291
2292         # Is the pagespec a simple page name?
2293         if ($pagespec =~ /$config{wiki_file_regexp}/ &&
2294             $pagespec !~ /[\s*?()!]/) {
2295                 $depends_simple{$page}{lc $pagespec} |= $deptype;
2296                 return 1;
2297         }
2298
2299         # Add explicit dependencies for influences.
2300         my $sub=pagespec_translate($pagespec);
2301         return unless defined $sub;
2302         foreach my $p (keys %pagesources) {
2303                 my $r=$sub->($p, location => $page);
2304                 my $i=$r->influences;
2305                 my $static=$r->influences_static;
2306                 foreach my $k (keys %$i) {
2307                         next unless $r || $static || $k eq $page;
2308                         $depends_simple{$page}{lc $k} |= $i->{$k};
2309                 }
2310                 last if $static;
2311         }
2312
2313         $depends{$page}{$pagespec} |= $deptype;
2314         return 1;
2315 }
2316
2317 sub deptype (@) {
2318         my $deptype=0;
2319         foreach my $type (@_) {
2320                 if ($type eq 'presence') {
2321                         $deptype |= $DEPEND_PRESENCE;
2322                 }
2323                 elsif ($type eq 'links') {
2324                         $deptype |= $DEPEND_LINKS;
2325                 }
2326                 elsif ($type eq 'content') {
2327                         $deptype |= $DEPEND_CONTENT;
2328                 }
2329         }
2330         return $deptype;
2331 }
2332
2333 my $file_prune_regexp;
2334 sub file_pruned ($) {
2335         my $file=shift;
2336
2337         if (defined $config{include} && length $config{include}) {
2338                 return 0 if $file =~ m/$config{include}/;
2339         }
2340
2341         if (! defined $file_prune_regexp) {
2342                 $file_prune_regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
2343                 $file_prune_regexp=qr/$file_prune_regexp/;
2344         }
2345         return $file =~ m/$file_prune_regexp/;
2346 }
2347
2348 sub define_gettext () {
2349         # If translation is needed, redefine the gettext function to do it.
2350         # Otherwise, it becomes a quick no-op.
2351         my $gettext_obj;
2352         my $getobj;
2353         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
2354             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
2355             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
2356                 $getobj=sub {
2357                         $gettext_obj=eval q{
2358                                 use Locale::gettext q{textdomain};
2359                                 Locale::gettext->domain('ikiwiki')
2360                         };
2361                 };
2362         }
2363
2364         no warnings 'redefine';
2365         *gettext=sub {
2366                 $getobj->() if $getobj;
2367                 if ($gettext_obj) {
2368                         $gettext_obj->get(shift);
2369                 }
2370                 else {
2371                         return shift;
2372                 }
2373         };
2374         *ngettext=sub {
2375                 $getobj->() if $getobj;
2376                 if ($gettext_obj) {
2377                         $gettext_obj->nget(@_);
2378                 }
2379                 else {
2380                         return ($_[2] == 1 ? $_[0] : $_[1])
2381                 }
2382         };
2383 }
2384
2385 sub gettext {
2386         define_gettext();
2387         gettext(@_);
2388 }
2389
2390 sub ngettext {
2391         define_gettext();
2392         ngettext(@_);
2393 }
2394
2395 sub yesno ($) {
2396         my $val=shift;
2397
2398         return (defined $val && (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
2399 }
2400
2401 sub inject {
2402         # Injects a new function into the symbol table to replace an
2403         # exported function.
2404         my %params=@_;
2405
2406         # This is deep ugly perl foo, beware.
2407         no strict;
2408         no warnings;
2409         if (! defined $params{parent}) {
2410                 $params{parent}='::';
2411                 $params{old}=\&{$params{name}};
2412                 $params{name}=~s/.*:://;
2413         }
2414         my $parent=$params{parent};
2415         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
2416                 $ns = $params{parent} . $ns;
2417                 inject(%params, parent => $ns) unless $ns eq '::main::';
2418                 *{$ns . $params{name}} = $params{call}
2419                         if exists ${$ns}{$params{name}} &&
2420                            \&{${$ns}{$params{name}}} == $params{old};
2421         }
2422         use strict;
2423         use warnings;
2424 }
2425
2426 sub add_link ($$;$) {
2427         my $page=shift;
2428         my $link=shift;
2429         my $type=shift;
2430
2431         push @{$links{$page}}, $link
2432                 unless grep { $_ eq $link } @{$links{$page}};
2433
2434         if (defined $type) {
2435                 $typedlinks{$page}{$type}{$link} = 1;
2436         }
2437 }
2438
2439 sub add_autofile ($$$) {
2440         my $file=shift;
2441         my $plugin=shift;
2442         my $generator=shift;
2443
2444         $autofiles{$file}{plugin}=$plugin;
2445         $autofiles{$file}{generator}=$generator;
2446 }
2447
2448 sub useragent () {
2449         return LWP::UserAgent->new(
2450                 cookie_jar => $config{cookiejar},
2451                 env_proxy => 1,         # respect proxy env vars
2452                 agent => $config{useragent},
2453         );
2454 }
2455
2456 sub sortspec_translate ($$) {
2457         my $spec = shift;
2458         my $reverse = shift;
2459
2460         my $code = "";
2461         my @data;
2462         while ($spec =~ m{
2463                 \s*
2464                 (-?)            # group 1: perhaps negated
2465                 \s*
2466                 (               # group 2: a word
2467                         \w+\([^\)]*\)   # command(params)
2468                         |
2469                         [^\s]+          # or anything else
2470                 )
2471                 \s*
2472         }gx) {
2473                 my $negated = $1;
2474                 my $word = $2;
2475                 my $params = undef;
2476
2477                 if ($word =~ m/^(\w+)\((.*)\)$/) {
2478                         # command with parameters
2479                         $params = $2;
2480                         $word = $1;
2481                 }
2482                 elsif ($word !~ m/^\w+$/) {
2483                         error(sprintf(gettext("invalid sort type %s"), $word));
2484                 }
2485
2486                 if (length $code) {
2487                         $code .= " || ";
2488                 }
2489
2490                 if ($negated) {
2491                         $code .= "-";
2492                 }
2493
2494                 if (exists $IkiWiki::SortSpec::{"cmp_$word"}) {
2495                         if (defined $params) {
2496                                 push @data, $params;
2497                                 $code .= "IkiWiki::SortSpec::cmp_$word(\$data[$#data])";
2498                         }
2499                         else {
2500                                 $code .= "IkiWiki::SortSpec::cmp_$word(undef)";
2501                         }
2502                 }
2503                 else {
2504                         error(sprintf(gettext("unknown sort type %s"), $word));
2505                 }
2506         }
2507
2508         if (! length $code) {
2509                 # undefined sorting method... sort arbitrarily
2510                 return sub { 0 };
2511         }
2512
2513         if ($reverse) {
2514                 $code="-($code)";
2515         }
2516
2517         no warnings;
2518         return eval 'sub { '.$code.' }';
2519 }
2520
2521 sub pagespec_translate ($) {
2522         my $spec=shift;
2523
2524         # Convert spec to perl code.
2525         my $code="";
2526         my @data;
2527         while ($spec=~m{
2528                 \s*             # ignore whitespace
2529                 (               # 1: match a single word
2530                         \!              # !
2531                 |
2532                         \(              # (
2533                 |
2534                         \)              # )
2535                 |
2536                         \w+\([^\)]*\)   # command(params)
2537                 |
2538                         [^\s()]+        # any other text
2539                 )
2540                 \s*             # ignore whitespace
2541         }gx) {
2542                 my $word=$1;
2543                 if (lc $word eq 'and') {
2544                         $code.=' &';
2545                 }
2546                 elsif (lc $word eq 'or') {
2547                         $code.=' |';
2548                 }
2549                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
2550                         $code.=' '.$word;
2551                 }
2552                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
2553                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
2554                                 push @data, $2;
2555                                 $code.="IkiWiki::PageSpec::match_$1(\$page, \$data[$#data], \@_)";
2556                         }
2557                         else {
2558                                 push @data, qq{unknown function in pagespec "$word"};
2559                                 $code.="IkiWiki::ErrorReason->new(\$data[$#data])";
2560                         }
2561                 }
2562                 else {
2563                         push @data, $word;
2564                         $code.=" IkiWiki::PageSpec::match_glob(\$page, \$data[$#data], \@_)";
2565                 }
2566         }
2567
2568         if (! length $code) {
2569                 $code="IkiWiki::FailReason->new('empty pagespec')";
2570         }
2571
2572         no warnings;
2573         return eval 'sub { my $page=shift; '.$code.' }';
2574 }
2575
2576 sub pagespec_match ($$;@) {
2577         my $page=shift;
2578         my $spec=shift;
2579         my @params=@_;
2580
2581         # Backwards compatability with old calling convention.
2582         if (@params == 1) {
2583                 unshift @params, 'location';
2584         }
2585
2586         my $sub=pagespec_translate($spec);
2587         return IkiWiki::ErrorReason->new("syntax error in pagespec \"$spec\"")
2588                 if ! defined $sub;
2589         return $sub->($page, @params);
2590 }
2591
2592 # e.g. @pages = sort_pages("title", \@pages, reverse => "yes")
2593 #
2594 # Not exported yet, but could be in future if it is generally useful.
2595 # Note that this signature is not the same as IkiWiki::SortSpec::sort_pages,
2596 # which is "more internal".
2597 sub sort_pages ($$;@) {
2598         my $sort = shift;
2599         my $list = shift;
2600         my %params = @_;
2601         $sort = sortspec_translate($sort, $params{reverse});
2602         return IkiWiki::SortSpec::sort_pages($sort, @$list);
2603 }
2604
2605 sub pagespec_match_list ($$;@) {
2606         my $page=shift;
2607         my $pagespec=shift;
2608         my %params=@_;
2609
2610         # Backwards compatability with old calling convention.
2611         if (ref $page) {
2612                 print STDERR "warning: a plugin (".caller().") is using pagespec_match_list in an obsolete way, and needs to be updated\n";
2613                 $params{list}=$page;
2614                 $page=$params{location}; # ugh!
2615         }
2616
2617         my $sub=pagespec_translate($pagespec);
2618         error "syntax error in pagespec \"$pagespec\""
2619                 if ! defined $sub;
2620         my $sort=sortspec_translate($params{sort}, $params{reverse})
2621                 if defined $params{sort};
2622
2623         my @candidates;
2624         if (exists $params{list}) {
2625                 @candidates=exists $params{filter}
2626                         ? grep { ! $params{filter}->($_) } @{$params{list}}
2627                         : @{$params{list}};
2628         }
2629         else {
2630                 @candidates=exists $params{filter}
2631                         ? grep { ! $params{filter}->($_) } keys %pagesources
2632                         : keys %pagesources;
2633         }
2634
2635         # clear params, remainder is passed to pagespec
2636         $depends{$page}{$pagespec} |= ($params{deptype} || $DEPEND_CONTENT);
2637         my $num=$params{num};
2638         delete @params{qw{num deptype reverse sort filter list}};
2639
2640         # when only the top matches will be returned, it's efficient to
2641         # sort before matching to pagespec,
2642         if (defined $num && defined $sort) {
2643                 @candidates=IkiWiki::SortSpec::sort_pages(
2644                         $sort, @candidates);
2645         }
2646
2647         my @matches;
2648         my $firstfail;
2649         my $count=0;
2650         my $accum=IkiWiki::SuccessReason->new();
2651         foreach my $p (@candidates) {
2652                 my $r=$sub->($p, %params, location => $page);
2653                 error(sprintf(gettext("cannot match pages: %s"), $r))
2654                         if $r->isa("IkiWiki::ErrorReason");
2655                 unless ($r || $r->influences_static) {
2656                         $r->remove_influence($p);
2657                 }
2658                 $accum |= $r;
2659                 if ($r) {
2660                         push @matches, $p;
2661                         last if defined $num && ++$count == $num;
2662                 }
2663         }
2664
2665         # Add simple dependencies for accumulated influences.
2666         my $i=$accum->influences;
2667         foreach my $k (keys %$i) {
2668                 $depends_simple{$page}{lc $k} |= $i->{$k};
2669         }
2670
2671         # when all matches will be returned, it's efficient to
2672         # sort after matching
2673         if (! defined $num && defined $sort) {
2674                 return IkiWiki::SortSpec::sort_pages(
2675                         $sort, @matches);
2676         }
2677         else {
2678                 return @matches;
2679         }
2680 }
2681
2682 sub pagespec_valid ($) {
2683         my $spec=shift;
2684
2685         return defined pagespec_translate($spec);
2686 }
2687
2688 sub glob2re ($) {
2689         my $re=quotemeta(shift);
2690         $re=~s/\\\*/.*/g;
2691         $re=~s/\\\?/./g;
2692         return qr/^$re$/i;
2693 }
2694
2695 package IkiWiki::FailReason;
2696
2697 use overload (
2698         '""'    => sub { $_[0][0] },
2699         '0+'    => sub { 0 },
2700         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
2701         '&'     => sub { $_[0]->merge_influences($_[1], 1); $_[0] },
2702         '|'     => sub { $_[1]->merge_influences($_[0]); $_[1] },
2703         fallback => 1,
2704 );
2705
2706 our @ISA = 'IkiWiki::SuccessReason';
2707
2708 package IkiWiki::SuccessReason;
2709
2710 # A blessed array-ref:
2711 #
2712 # [0]: human-readable reason for success (or, in FailReason subclass, failure)
2713 # [1]{""}:
2714 #      - if absent or false, the influences of this evaluation are "static",
2715 #        see the influences_static method
2716 #      - if true, they are dynamic (not static)
2717 # [1]{any other key}:
2718 #      the dependency types of influences, as returned by the influences method
2719
2720 use overload (
2721         # in string context, it's the human-readable reason
2722         '""'    => sub { $_[0][0] },
2723         # in boolean context, SuccessReason is 1 and FailReason is 0
2724         '0+'    => sub { 1 },
2725         # negating a result gives the opposite result with the same influences
2726         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
2727         # A & B = (A ? B : A) with the influences of both
2728         '&'     => sub { $_[1]->merge_influences($_[0], 1); $_[1] },
2729         # A | B = (A ? A : B) with the influences of both
2730         '|'     => sub { $_[0]->merge_influences($_[1]); $_[0] },
2731         fallback => 1,
2732 );
2733
2734 # SuccessReason->new("human-readable reason", page => deptype, ...)
2735
2736 sub new {
2737         my $class = shift;
2738         my $value = shift;
2739         return bless [$value, {@_}], $class;
2740 }
2741
2742 # influences(): return a reference to a copy of the hash
2743 # { page => dependency type } describing the pages that indirectly influenced
2744 # this result, but would not cause a dependency through ikiwiki's core
2745 # dependency logic.
2746 #
2747 # See [[todo/dependency_types]] for extensive discussion of what this means.
2748 #
2749 # influences(page => deptype, ...): remove all influences, replace them
2750 # with the arguments, and return a reference to a copy of the new influences.
2751
2752 sub influences {
2753         my $this=shift;
2754         $this->[1]={@_} if @_;
2755         my %i=%{$this->[1]};
2756         delete $i{""};
2757         return \%i;
2758 }
2759
2760 # True if this result has the same influences whichever page it matches,
2761 # For instance, whether bar matches backlink(foo) is influenced only by
2762 # the set of links in foo, so its only influence is { foo => DEPEND_LINKS },
2763 # which does not mention bar anywhere.
2764 #
2765 # False if this result would have different influences when matching
2766 # different pages. For instance, when testing whether link(foo) matches bar,
2767 # { bar => DEPEND_LINKS } is an influence on that result, because changing
2768 # bar's links could change the outcome; so its influences are not the same
2769 # as when testing whether link(foo) matches baz.
2770 #
2771 # Static influences are one of the things that make pagespec_match_list
2772 # more efficient than repeated calls to pagespec_match.
2773
2774 sub influences_static {
2775         return ! $_[0][1]->{""};
2776 }
2777
2778 # Change the influences of $this to be the influences of "$this & $other"
2779 # or "$this | $other".
2780 #
2781 # If both $this and $other are either successful or have influences,
2782 # or this is an "or" operation, the result has all the influences from
2783 # either of the arguments. It has dynamic influences if either argument
2784 # has dynamic influences.
2785 #
2786 # If this is an "and" operation, and at least one argument is a
2787 # FailReason with no influences, the result has no influences, and they
2788 # are not dynamic. For instance, link(foo) matching bar is influenced
2789 # by bar, but enabled(ddate) has no influences. Suppose ddate is disabled;
2790 # then (link(foo) and enabled(ddate)) not matching bar is not influenced by
2791 # bar, because it would be false however often you edit bar.
2792
2793 sub merge_influences {
2794         my $this=shift;
2795         my $other=shift;
2796         my $anded=shift;
2797
2798         # This "if" is odd because it needs to avoid negating $this
2799         # or $other, which would alter the objects in-place. Be careful.
2800         if (! $anded || (($this || %{$this->[1]}) &&
2801                          ($other || %{$other->[1]}))) {
2802                 foreach my $influence (keys %{$other->[1]}) {
2803                         $this->[1]{$influence} |= $other->[1]{$influence};
2804                 }
2805         }
2806         else {
2807                 # influence blocker
2808                 $this->[1]={};
2809         }
2810 }
2811
2812 # Change $this so it is not considered to be influenced by $torm.
2813
2814 sub remove_influence {
2815         my $this=shift;
2816         my $torm=shift;
2817
2818         delete $this->[1]{$torm};
2819 }
2820
2821 package IkiWiki::ErrorReason;
2822
2823 our @ISA = 'IkiWiki::FailReason';
2824
2825 package IkiWiki::PageSpec;
2826
2827 sub derel ($$) {
2828         my $path=shift;
2829         my $from=shift;
2830
2831         if ($path =~ m!^\.(/|$)!) {
2832                 if ($1) {
2833                         $from=~s#/?[^/]+$## if defined $from;
2834                         $path=~s#^\./##;
2835                         $path="$from/$path" if defined $from && length $from;
2836                 }
2837                 else {
2838                         $path = $from;
2839                         $path = "" unless defined $path;
2840                 }
2841         }
2842
2843         return $path;
2844 }
2845
2846 my %glob_cache;
2847
2848 sub match_glob ($$;@) {
2849         my $page=shift;
2850         my $glob=shift;
2851         my %params=@_;
2852
2853         $glob=derel($glob, $params{location});
2854
2855         # Instead of converting the glob to a regex every time,
2856         # cache the compiled regex to save time.
2857         my $re=$glob_cache{$glob};
2858         unless (defined $re) {
2859                 $glob_cache{$glob} = $re = IkiWiki::glob2re($glob);
2860         }
2861         if ($page =~ $re) {
2862                 if (! IkiWiki::isinternal($page) || $params{internal}) {
2863                         return IkiWiki::SuccessReason->new("$glob matches $page");
2864                 }
2865                 else {
2866                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
2867                 }
2868         }
2869         else {
2870                 return IkiWiki::FailReason->new("$glob does not match $page");
2871         }
2872 }
2873
2874 sub match_internal ($$;@) {
2875         return match_glob(shift, shift, @_, internal => 1)
2876 }
2877
2878 sub match_page ($$;@) {
2879         my $page=shift;
2880         my $match=match_glob($page, shift, @_);
2881         if ($match) {
2882                 my $source=exists $IkiWiki::pagesources{$page} ?
2883                         $IkiWiki::pagesources{$page} :
2884                         $IkiWiki::delpagesources{$page};
2885                 my $type=defined $source ? IkiWiki::pagetype($source) : undef;
2886                 if (! defined $type) {
2887                         return IkiWiki::FailReason->new("$page is not a page");
2888                 }
2889         }
2890         return $match;
2891 }
2892
2893 sub match_link ($$;@) {
2894         my $page=shift;
2895         my $link=lc(shift);
2896         my %params=@_;
2897
2898         $link=derel($link, $params{location});
2899         my $from=exists $params{location} ? $params{location} : '';
2900         my $linktype=$params{linktype};
2901         my $qualifier='';
2902         if (defined $linktype) {
2903                 $qualifier=" with type $linktype";
2904         }
2905
2906         my $links = $IkiWiki::links{$page};
2907         return IkiWiki::FailReason->new("$page has no links", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2908                 unless $links && @{$links};
2909         my $bestlink = IkiWiki::bestlink($from, $link);
2910         foreach my $p (@{$links}) {
2911                 next unless (! defined $linktype || exists $IkiWiki::typedlinks{$page}{$linktype}{$p});
2912
2913                 if (length $bestlink) {
2914                         if ($bestlink eq IkiWiki::bestlink($page, $p)) {
2915                                 return IkiWiki::SuccessReason->new("$page links to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2916                         }
2917                 }
2918                 else {
2919                         if (match_glob($p, $link, %params)) {
2920                                 return IkiWiki::SuccessReason->new("$page links to page $p$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2921                         }
2922                         my ($p_rel)=$p=~/^\/?(.*)/;
2923                         $link=~s/^\///;
2924                         if (match_glob($p_rel, $link, %params)) {
2925                                 return IkiWiki::SuccessReason->new("$page links to page $p_rel$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2926                         }
2927                 }
2928         }
2929         return IkiWiki::FailReason->new("$page does not link to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1);
2930 }
2931
2932 sub match_backlink ($$;@) {
2933         my $page=shift;
2934         my $testpage=shift;
2935         my %params=@_;
2936         if ($testpage eq '.') {
2937                 $testpage = $params{'location'}
2938         }
2939         my $ret=match_link($testpage, $page, @_);
2940         $ret->influences($testpage => $IkiWiki::DEPEND_LINKS);
2941         return $ret;
2942 }
2943
2944 sub match_created_before ($$;@) {
2945         my $page=shift;
2946         my $testpage=shift;
2947         my %params=@_;
2948
2949         $testpage=derel($testpage, $params{location});
2950
2951         if (exists $IkiWiki::pagectime{$testpage}) {
2952                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
2953                         return IkiWiki::SuccessReason->new("$page created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2954                 }
2955                 else {
2956                         return IkiWiki::FailReason->new("$page not created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2957                 }
2958         }
2959         else {
2960                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2961         }
2962 }
2963
2964 sub match_created_after ($$;@) {
2965         my $page=shift;
2966         my $testpage=shift;
2967         my %params=@_;
2968
2969         $testpage=derel($testpage, $params{location});
2970
2971         if (exists $IkiWiki::pagectime{$testpage}) {
2972                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
2973                         return IkiWiki::SuccessReason->new("$page created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2974                 }
2975                 else {
2976                         return IkiWiki::FailReason->new("$page not created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2977                 }
2978         }
2979         else {
2980                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2981         }
2982 }
2983
2984 sub match_creation_day ($$;@) {
2985         my $page=shift;
2986         my $d=shift;
2987         if ($d !~ /^\d+$/) {
2988                 return IkiWiki::ErrorReason->new("invalid day $d");
2989         }
2990         if ((localtime($IkiWiki::pagectime{$page}))[3] == $d) {
2991                 return IkiWiki::SuccessReason->new('creation_day matched');
2992         }
2993         else {
2994                 return IkiWiki::FailReason->new('creation_day did not match');
2995         }
2996 }
2997
2998 sub match_creation_month ($$;@) {
2999         my $page=shift;
3000         my $m=shift;
3001         if ($m !~ /^\d+$/) {
3002                 return IkiWiki::ErrorReason->new("invalid month $m");
3003         }
3004         if ((localtime($IkiWiki::pagectime{$page}))[4] + 1 == $m) {
3005                 return IkiWiki::SuccessReason->new('creation_month matched');
3006         }
3007         else {
3008                 return IkiWiki::FailReason->new('creation_month did not match');
3009         }
3010 }
3011
3012 sub match_creation_year ($$;@) {
3013         my $page=shift;
3014         my $y=shift;
3015         if ($y !~ /^\d+$/) {
3016                 return IkiWiki::ErrorReason->new("invalid year $y");
3017         }
3018         if ((localtime($IkiWiki::pagectime{$page}))[5] + 1900 == $y) {
3019                 return IkiWiki::SuccessReason->new('creation_year matched');
3020         }
3021         else {
3022                 return IkiWiki::FailReason->new('creation_year did not match');
3023         }
3024 }
3025
3026 sub match_user ($$;@) {
3027         shift;
3028         my $user=shift;
3029         my %params=@_;
3030
3031         if (! exists $params{user}) {
3032                 return IkiWiki::ErrorReason->new("no user specified");
3033         }
3034
3035         my $regexp=IkiWiki::glob2re($user);
3036
3037         if (defined $params{user} && $params{user}=~$regexp) {
3038                 return IkiWiki::SuccessReason->new("user is $user");
3039         }
3040         elsif (! defined $params{user}) {
3041                 return IkiWiki::FailReason->new("not logged in");
3042         }
3043         else {
3044                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
3045         }
3046 }
3047
3048 sub match_admin ($$;@) {
3049         shift;
3050         shift;
3051         my %params=@_;
3052
3053         if (! exists $params{user}) {
3054                 return IkiWiki::ErrorReason->new("no user specified");
3055         }
3056
3057         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
3058                 return IkiWiki::SuccessReason->new("user is an admin");
3059         }
3060         elsif (! defined $params{user}) {
3061                 return IkiWiki::FailReason->new("not logged in");
3062         }
3063         else {
3064                 return IkiWiki::FailReason->new("user is not an admin");
3065         }
3066 }
3067
3068 sub match_ip ($$;@) {
3069         shift;
3070         my $ip=shift;
3071         my %params=@_;
3072
3073         if (! exists $params{ip}) {
3074                 return IkiWiki::ErrorReason->new("no IP specified");
3075         }
3076
3077         my $regexp=IkiWiki::glob2re(lc $ip);
3078
3079         if (defined $params{ip} && lc $params{ip}=~$regexp) {
3080                 return IkiWiki::SuccessReason->new("IP is $ip");
3081         }
3082         else {
3083                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
3084         }
3085 }
3086
3087 package IkiWiki::SortSpec;
3088
3089 # This is in the SortSpec namespace so that the $a and $b that sort() uses
3090 # are easily available in this namespace, for cmp functions to use them.
3091 sub sort_pages {
3092         my $f=shift;
3093         sort $f @_
3094 }
3095
3096 sub cmp_title {
3097         IkiWiki::pagetitle(IkiWiki::basename($a))
3098         cmp
3099         IkiWiki::pagetitle(IkiWiki::basename($b))
3100 }
3101
3102 sub cmp_path { IkiWiki::pagetitle($a) cmp IkiWiki::pagetitle($b) }
3103 sub cmp_mtime { $IkiWiki::pagemtime{$b} <=> $IkiWiki::pagemtime{$a} }
3104 sub cmp_age { $IkiWiki::pagectime{$b} <=> $IkiWiki::pagectime{$a} }
3105
3106 1