IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                         section => "core",
  53                 },
  54                 rss => {
  55                         type => "boolean",
  56                         example => 0,
  57                         description => "enable rss feeds by default?",
  58                         safe => 1,
  59                         rebuild => 1,
  60                 },
  61                 atom => {
  62                         type => "boolean",
  63                         example => 0,
  64                         description => "enable atom feeds by default?",
  65                         safe => 1,
  66                         rebuild => 1,
  67                 },
  68                 allowrss => {
  69                         type => "boolean",
  70                         example => 0,
  71                         description => "allow rss feeds to be used?",
  72                         safe => 1,
  73                         rebuild => 1,
  74                 },
  75                 allowatom => {
  76                         type => "boolean",
  77                         example => 0,
  78                         description => "allow atom feeds to be used?",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 pingurl => {
  83                         type => "string",
  84                         example => "http://rpc.technorati.com/rpc/ping",
  85                         description => "urls to ping (using XML-RPC) on feed update",
  86                         safe => 1,
  87                         rebuild => 0,
  88                 },
  89 }
  90
  91 sub checkconfig () {
  92         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  93                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  94         }
  95         if ($config{rss}) {
  96                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  97         }
  98         if ($config{atom}) {
  99                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
 100         }
 101         if (! exists $config{pingurl}) {
 102                 $config{pingurl}=[];
 103         }
 104 }
 105
 106 sub format (@) {
 107         my %params=@_;
 108
 109         # Fill in the inline content generated earlier. This is actually an
 110         # optimisation.
 111         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 112                 delete @inline[$1,]
 113         }eg;
 114         return $params{content};
 115 }
 116
 117 sub sessioncgi ($$) {
 118         my $q=shift;
 119         my $session=shift;
 120
 121         if ($q->param('do') eq 'blog') {
 122                 my $page=titlepage(decode_utf8($q->param('title')));
 123                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 124                 # if the page already exists, munge it to be unique
 125                 my $from=$q->param('from');
 126                 my $add="";
 127                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 128                         $add=1 unless length $add;
 129                         $add++;
 130                 }
 131                 $q->param('page', $page.$add);
 132                 # now go create the page
 133                 $q->param('do', 'create');
 134                 # make sure the editpage plugin in loaded
 135                 if (IkiWiki->can("cgi_editpage")) {
 136                         IkiWiki::cgi_editpage($q, $session);
 137                 }
 138                 else {
 139                         error(gettext("page editing not allowed"));
 140                 }
 141                 exit;
 142         }
 143 }
 144
 145 # Back to ikiwiki namespace for the rest, this code is very much
 146 # internal to ikiwiki even though it's separated into a plugin.
 147 package IkiWiki;
 148
 149 my %toping;
 150 my %feedlinks;
 151
 152 sub preprocess_inline (@) {
 153         my %params=@_;
 154
 155         if (! exists $params{pages} && ! exists $params{pagenames}) {
 156                 error gettext("missing pages parameter");
 157         }
 158         my $raw=yesno($params{raw});
 159         my $archive=yesno($params{archive});
 160         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 161         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 162         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 163         my $feeds=! $nested && (exists $params{feeds} ? yesno($params{feeds}) : !$quick && ! $raw);
 164         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 165         my $feedonly=yesno($params{feedonly});
 166         if (! exists $params{show} && ! $archive) {
 167                 $params{show}=10;
 168         }
 169         if (! exists $params{feedshow} && exists $params{show}) {
 170                 $params{feedshow}=$params{show};
 171         }
 172         my $desc;
 173         if (exists $params{description}) {
 174                 $desc = $params{description}
 175         }
 176         else {
 177                 $desc = $config{wikiname};
 178         }
 179         my $actions=yesno($params{actions});
 180         if (exists $params{template}) {
 181                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 182         }
 183         else {
 184                 $params{template} = $archive ? "archivepage" : "inlinepage";
 185         }
 186
 187         my @list;
 188
 189         if (exists $params{pagenames}) {
 190                 foreach my $p (qw(sort pages)) {
 191                         if (exists $params{$p}) {
 192                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 193                                         "pagenames", $p);
 194                         }
 195                 }
 196
 197                 @list = map { bestlink($params{page}, $_) }
 198                         split ' ', $params{pagenames};
 199
 200                 if (yesno($params{reverse})) {
 201                         @list=reverse(@list);
 202                 }
 203
 204                 foreach my $p (@list) {
 205                         add_depends($params{page}, $p, deptype($quick ? "presence" : "content"));
 206                 }
 207         }
 208         else {
 209                 my $num=0;
 210                 if ($params{show}) {
 211                         $num=$params{show};
 212                 }
 213                 if ($params{feedshow} && $num < $params{feedshow} && $num > 0) {
 214                         $num=$params{feedshow};
 215                 }
 216                 if ($params{skip} && $num) {
 217                         $num+=$params{skip};
 218                 }
 219
 220                 @list = pagespec_match_list($params{page}, $params{pages},
 221                         deptype => deptype($quick ? "presence" : "content"),
 222                         filter => sub { $_[0] eq $params{page} },
 223                         sort => exists $params{sort} ? $params{sort} : "age",
 224                         reverse => yesno($params{reverse}),
 225                         ($num ? (num => $num) : ()),
 226                 );
 227         }
 228
 229         if (exists $params{skip}) {
 230                 @list=@list[$params{skip} .. $#list];
 231         }
 232
 233         my @feedlist;
 234         if ($feeds) {
 235                 if (exists $params{feedshow} &&
 236                     $params{feedshow} && @list > $params{feedshow}) {
 237                         @feedlist=@list[0..$params{feedshow} - 1];
 238                 }
 239                 else {
 240                         @feedlist=@list;
 241                 }
 242         }
 243
 244         if ($params{show} && @list > $params{show}) {
 245                 @list=@list[0..$params{show} - 1];
 246         }
 247
 248         if ($feeds && exists $params{feedpages}) {
 249                 @feedlist = pagespec_match_list(
 250                         $params{page}, "($params{pages}) and ($params{feedpages})",
 251                         deptype => deptype($quick ? "presence" : "content"),
 252                         list => \@feedlist,
 253                 );
 254         }
 255
 256         my ($feedbase, $feednum);
 257         if ($feeds) {
 258                 # Ensure that multiple feeds on a page go to unique files.
 259
 260                 # Feedfile can lead to conflicts if usedirs is not enabled,
 261                 # so avoid supporting it in that case.
 262                 delete $params{feedfile} if ! $config{usedirs};
 263                 # Tight limits on legal feedfiles, to avoid security issues
 264                 # and conflicts.
 265                 if (defined $params{feedfile}) {
 266                         if ($params{feedfile} =~ /\// ||
 267                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 268                                 error("illegal feedfile");
 269                         }
 270                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 271                 }
 272                 $feedbase=targetpage($params{destpage}, "", $params{feedfile});
 273
 274                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 275                 if (exists $knownfeeds{$feedid}) {
 276                         $feednum=$knownfeeds{$feedid};
 277                 }
 278                 else {
 279                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 280                                 if ($feeds) {
 281                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 282                                 }
 283                         }
 284                         else {
 285                                 $feednum=$knownfeeds{$feedid}="";
 286                                 if ($feeds) {
 287                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 288                                 }
 289                         }
 290                 }
 291         }
 292
 293         my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
 294         my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
 295
 296         my $ret="";
 297
 298         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 299             (exists $params{postform} && yesno($params{postform}))) &&
 300             IkiWiki->can("cgi_editpage")) {
 301                 # Add a blog post form, with feed buttons.
 302                 my $formtemplate=template_depends("blogpost.tmpl", $params{page}, blind_cache => 1);
 303                 $formtemplate->param(cgiurl => $config{cgiurl});
 304                 $formtemplate->param(rootpage => rootpage(%params));
 305                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 306                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 307                 if (exists $params{postformtext}) {
 308                         $formtemplate->param(postformtext =>
 309                                 $params{postformtext});
 310                 }
 311                 else {
 312                         $formtemplate->param(postformtext =>
 313                                 gettext("Add a new post titled:"));
 314                 }
 315                 $ret.=$formtemplate->output;
 316
 317                 # The post form includes the feed buttons, so
 318                 # emptyfeeds cannot be hidden.
 319                 $emptyfeeds=1;
 320         }
 321         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 322                 # Add feed buttons.
 323                 my $linktemplate=template_depends("feedlink.tmpl", $params{page}, blind_cache => 1);
 324                 $linktemplate->param(rssurl => $rssurl) if $rss;
 325                 $linktemplate->param(atomurl => $atomurl) if $atom;
 326                 $ret.=$linktemplate->output;
 327         }
 328
 329         if (! $feedonly) {
 330                 my $template;
 331                 if (! $raw) {
 332                         eval {
 333                                 $template=template_depends($params{template}.".tmpl", $params{page},
 334                                         blind_cache => 1);
 335                         };
 336                         if ($@ || ! $template) {
 337                                 error sprintf(gettext("nonexistant template %s.tmpl"), $params{template});
 338                         }
 339                 }
 340                 my $needcontent=$raw || (!($archive && $quick) && $template->query(name => 'content'));
 341
 342                 foreach my $page (@list) {
 343                         my $file = $pagesources{$page};
 344                         my $type = pagetype($file);
 345                         if (! $raw) {
 346                                 if ($needcontent) {
 347                                         # Get the content before populating the
 348                                         # template, since getting the content uses
 349                                         # the same template if inlines are nested.
 350                                         my $content=get_inline_content($page, $params{destpage});
 351                                         $template->param(content => $content);
 352                                 }
 353                                 $template->param(pageurl => urlto($page, $params{destpage}));
 354                                 $template->param(inlinepage => $page);
 355                                 $template->param(title => pagetitle(basename($page)));
 356                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}));
 357                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 358                                 $template->param(first => 1) if $page eq $list[0];
 359                                 $template->param(last => 1) if $page eq $list[$#list];
 360
 361                                 if ($actions) {
 362                                         my $file = $pagesources{$page};
 363                                         my $type = pagetype($file);
 364                                         if ($config{discussion}) {
 365                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 366                                                     (length $config{cgiurl} ||
 367                                                      exists $pagesources{$page."/".lc($config{discussionpage})})) {
 368                                                         $template->param(have_actions => 1);
 369                                                         $template->param(discussionlink =>
 370                                                                 htmllink($page,
 371                                                                         $params{destpage},
 372                                                                         $config{discussionpage},
 373                                                                         noimageinline => 1,
 374                                                                         forcesubpage => 1));
 375                                                 }
 376                                         }
 377                                         if (length $config{cgiurl} &&
 378                                             defined $type &&
 379                                             IkiWiki->can("cgi_editpage")) {
 380                                                 $template->param(have_actions => 1);
 381                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 382
 383                                         }
 384                                 }
 385
 386                                 run_hooks(pagetemplate => sub {
 387                                         shift->(page => $page, destpage => $params{destpage},
 388                                                 template => $template,);
 389                                 });
 390
 391                                 $ret.=$template->output;
 392                                 $template->clear_params;
 393                         }
 394                         else {
 395                                 if (defined $type) {
 396                                         $ret.="\n".
 397                                               linkify($page, $params{destpage},
 398                                               preprocess($page, $params{destpage},
 399                                               filter($page, $params{destpage},
 400                                               readfile(srcfile($file)))));
 401                                 }
 402                                 else {
 403                                         $ret.="\n".
 404                                               readfile(srcfile($file));
 405                                 }
 406                         }
 407                 }
 408         }
 409
 410         if ($feeds && ($emptyfeeds || @feedlist)) {
 411                 if ($rss) {
 412                         my $rssp=$feedbase."rss".$feednum;
 413                         will_render($params{destpage}, $rssp);
 414                         if (! $params{preview}) {
 415                                 writefile($rssp, $config{destdir},
 416                                         genfeed("rss",
 417                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
 418                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 419                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
 420                         }
 421                 }
 422                 if ($atom) {
 423                         my $atomp=$feedbase."atom".$feednum;
 424                         will_render($params{destpage}, $atomp);
 425                         if (! $params{preview}) {
 426                                 writefile($atomp, $config{destdir},
 427                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
 428                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 429                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
 430                         }
 431                 }
 432         }
 433
 434         clear_inline_content_cache();
 435
 436         return $ret if $raw || $nested;
 437         push @inline, $ret;
 438         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 439 }
 440
 441 sub pagetemplate_inline (@) {
 442         my %params=@_;
 443         my $page=$params{page};
 444         my $template=$params{template};
 445
 446         $template->param(feedlinks => $feedlinks{$page})
 447                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 448 }
 449
 450 {
 451 my %inline_content;
 452 my $cached_destpage="";
 453
 454 sub get_inline_content ($$) {
 455         my $page=shift;
 456         my $destpage=shift;
 457
 458         if (exists $inline_content{$page} && $cached_destpage eq $destpage) {
 459                 return $inline_content{$page};
 460         }
 461
 462         my $file=$pagesources{$page};
 463         my $type=pagetype($file);
 464         my $ret="";
 465         if (defined $type) {
 466                 $nested++;
 467                 $ret=htmlize($page, $destpage, $type,
 468                        linkify($page, $destpage,
 469                        preprocess($page, $destpage,
 470                        filter($page, $destpage,
 471                        readfile(srcfile($file))))));
 472                 $nested--;
 473         }
 474
 475         if ($cached_destpage ne $destpage) {
 476                 clear_inline_content_cache();
 477                 $cached_destpage=$destpage;
 478         }
 479         return $inline_content{$page}=$ret;
 480 }
 481
 482 sub clear_inline_content_cache () {
 483         %inline_content=();
 484 }
 485
 486 }
 487
 488 sub date_822 ($) {
 489         my $time=shift;
 490
 491         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 492         POSIX::setlocale(&POSIX::LC_TIME, "C");
 493         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 494         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 495         return $ret;
 496 }
 497
 498 sub date_3339 ($) {
 499         my $time=shift;
 500
 501         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 502         POSIX::setlocale(&POSIX::LC_TIME, "C");
 503         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
 504         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 505         return $ret;
 506 }
 507
 508 sub absolute_urls ($$) {
 509         # sucky sub because rss sucks
 510         my $content=shift;
 511         my $baseurl=shift;
 512
 513         my $url=$baseurl;
 514         $url=~s/[^\/]+$//;
 515
 516         # what is the non path part of the url?
 517         my $top_uri = URI->new($url);
 518         $top_uri->path_query(""); # reset the path
 519         my $urltop = $top_uri->as_string;
 520
 521         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
 522         # relative to another wiki page
 523         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)([^\/][^"]*)"/$1 href="$url$2"/mig;
 524         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)([^\/][^"]*)"/$1 src="$url$2"/mig;
 525         # relative to the top of the site
 526         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)(\/[^"]*)"/$1 href="$urltop$2"/mig;
 527         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)(\/[^"]*)"/$1 src="$urltop$2"/mig;
 528         return $content;
 529 }
 530
 531 sub genfeed ($$$$$@) {
 532         my $feedtype=shift;
 533         my $feedurl=shift;
 534         my $feeddesc=shift;
 535         my $guid=shift;
 536         my $page=shift;
 537         my @pages=@_;
 538
 539         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 540
 541         my $itemtemplate=template_depends($feedtype."item.tmpl", $page, blind_cache => 1);
 542         my $content="";
 543         my $lasttime = 0;
 544         foreach my $p (@pages) {
 545                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 546                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 547
 548                 $itemtemplate->param(
 549                         title => pagetitle(basename($p)),
 550                         url => $u,
 551                         permalink => $u,
 552                         cdate_822 => date_822($pagectime{$p}),
 553                         mdate_822 => date_822($pagemtime{$p}),
 554                         cdate_3339 => date_3339($pagectime{$p}),
 555                         mdate_3339 => date_3339($pagemtime{$p}),
 556                 );
 557
 558                 if (exists $pagestate{$p}) {
 559                         if (exists $pagestate{$p}{meta}{guid}) {
 560                                 eval q{use HTML::Entities};
 561                                 $itemtemplate->param(guid => HTML::Entities::encode_numeric($pagestate{$p}{meta}{guid}));
 562                         }
 563
 564                         if (exists $pagestate{$p}{meta}{updated}) {
 565                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 566                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 567                         }
 568                 }
 569
 570                 if ($itemtemplate->query(name => "enclosure")) {
 571                         my $file=$pagesources{$p};
 572                         my $type=pagetype($file);
 573                         if (defined $type) {
 574                                 $itemtemplate->param(content => $pcontent);
 575                         }
 576                         else {
 577                                 my $size=(srcfile_stat($file))[8];
 578                                 my $mime="unknown";
 579                                 eval q{use File::MimeInfo};
 580                                 if (! $@) {
 581                                         $mime = mimetype($file);
 582                                 }
 583                                 $itemtemplate->param(
 584                                         enclosure => $u,
 585                                         type => $mime,
 586                                         length => $size,
 587                                 );
 588                         }
 589                 }
 590                 else {
 591                         $itemtemplate->param(content => $pcontent);
 592                 }
 593
 594                 run_hooks(pagetemplate => sub {
 595                         shift->(page => $p, destpage => $page,
 596                                 template => $itemtemplate);
 597                 });
 598
 599                 $content.=$itemtemplate->output;
 600                 $itemtemplate->clear_params;
 601
 602                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 603         }
 604
 605         my $template=template_depends($feedtype."page.tmpl", $page, blind_cache => 1);
 606         $template->param(
 607                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 608                 wikiname => $config{wikiname},
 609                 pageurl => $url,
 610                 content => $content,
 611                 feeddesc => $feeddesc,
 612                 guid => $guid,
 613                 feeddate => date_3339($lasttime),
 614                 feedurl => $feedurl,
 615                 version => $IkiWiki::version,
 616         );
 617         run_hooks(pagetemplate => sub {
 618                 shift->(page => $page, destpage => $page,
 619                         template => $template);
 620         });
 621
 622         return $template->output;
 623 }
 624
 625 sub pingurl (@) {
 626         return unless @{$config{pingurl}} && %toping;
 627
 628         eval q{require RPC::XML::Client};
 629         if ($@) {
 630                 debug(gettext("RPC::XML::Client not found, not pinging"));
 631                 return;
 632         }
 633
 634         # daemonize here so slow pings don't slow down wiki updates
 635         defined(my $pid = fork) or error("Can't fork: $!");
 636         return if $pid;
 637         chdir '/';
 638         POSIX::setsid() or error("Can't start a new session: $!");
 639         open STDIN, '/dev/null';
 640         open STDOUT, '>/dev/null';
 641         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 642
 643         # Don't need to keep a lock on the wiki as a daemon.
 644         IkiWiki::unlockwiki();
 645
 646         foreach my $page (keys %toping) {
 647                 my $title=pagetitle(basename($page), 0);
 648                 my $url=urlto($page, "", 1);
 649                 foreach my $pingurl (@{$config{pingurl}}) {
 650                         debug("Pinging $pingurl for $page");
 651                         eval {
 652                                 my $client = RPC::XML::Client->new($pingurl);
 653                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 654                                         $title, $url);
 655                                 my $res = $client->send_request($req);
 656                                 if (! ref $res) {
 657                                         error("Did not receive response to ping");
 658                                 }
 659                                 my $r=$res->value;
 660                                 if (! exists $r->{flerror} || $r->{flerror}) {
 661                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 662                                 }
 663                         };
 664                         if ($@) {
 665                                 error "Ping failed: $@";
 666                         }
 667                 }
 668         }
 669
 670         exit 0; # daemon done
 671 }
 672
 673
 674 sub rootpage (@) {
 675         my %params=@_;
 676
 677         my $rootpage;
 678         if (exists $params{rootpage}) {
 679                 $rootpage=bestlink($params{page}, $params{rootpage});
 680                 if (!length $rootpage) {
 681                         $rootpage=$params{rootpage};
 682                 }
 683         }
 684         else {
 685                 $rootpage=$params{page};
 686         }
 687         return $rootpage;
 688 }
 689
 690 1