From: Simon McVittie <smcv@debian.org>
Date: Sat, 22 Jan 2011 22:35:37 +0000 (+0000)
Subject: Merge branch 'ready/autoindex-autofile' into HEAD
X-Git-Tag: 3.20110225~79^2~4
X-Git-Url: http://git.vanrenterghem.biz/git.ikiwiki.info.git/commitdiff_plain/594a9194561ad373a31a7d34c6b5c7a84ec417a0?hp=8ee9eabb1c5314f51641aaec4cb45d5c2d0fa7b8

Merge branch 'ready/autoindex-autofile' into HEAD
---

diff --git a/IkiWiki/Plugin/transient.pm b/IkiWiki/Plugin/transient.pm
new file mode 100644
index 000000000..c482b8552
--- /dev/null
+++ b/IkiWiki/Plugin/transient.pm
@@ -0,0 +1,49 @@
+#!/usr/bin/perl
+package IkiWiki::Plugin::transient;
+
+use warnings;
+use strict;
+use IkiWiki 3.00;
+
+sub import {
+	hook(type => "getsetup", id => "transient",  call => \&getsetup);
+	hook(type => "checkconfig", id => "transient", call => \&checkconfig);
+	hook(type => "change", id => "transient", call => \&change);
+}
+
+sub getsetup () {
+	return
+		plugin => {
+			# this plugin is safe but only makes sense as a
+			# dependency; similarly, it needs a rebuild but
+			# only if something else does
+			safe => 0,
+			rebuild => 0,
+		},
+}
+
+our $transientdir;
+
+sub checkconfig () {
+	eval q{use Cwd 'abs_path'};
+	error($@) if $@;
+	$transientdir = abs_path($config{wikistatedir})."/transient";
+	add_underlay($transientdir);
+}
+
+sub change (@) {
+	foreach my $file (@_) {
+		# If the corresponding file exists in the transient underlay
+		# and isn't actually being used, we can get rid of it.
+		# Assume that the file that just changed has the same extension
+		# as the obsolete transient version: this'll be true for web
+		# edits, and avoids invoking File::Find.
+		my $casualty = "$transientdir/$file";
+		if (srcfile($file) ne $casualty && -e $casualty) {
+			debug(sprintf(gettext("removing transient version of %s"), $file));
+			IkiWiki::prune($casualty);
+		}
+	}
+}
+
+1;