X-Git-Url: http://git.vanrenterghem.biz/git.ikiwiki.info.git/blobdiff_plain/ed25c2abf259ad1e4f307f0656175a90906b93ba..37245a9988d22938a8f13fb89cecc5c23bbed419:/IkiWiki/Plugin/attachment.pm?ds=inline

diff --git a/IkiWiki/Plugin/attachment.pm b/IkiWiki/Plugin/attachment.pm
index ae06922d4..720078be1 100644
--- a/IkiWiki/Plugin/attachment.pm
+++ b/IkiWiki/Plugin/attachment.pm
@@ -11,6 +11,40 @@ sub import { #{{{
 	hook(type => "formbuilder", id => "attachment", call => \&formbuilder);
 } # }}}
 
+sub check_canattach ($$;$) { #{{{
+	my $session=shift;
+	my $dest=shift; # where it's going to be put, under the srcdir
+	my $file=shift; # the path to the attachment currently
+
+	# Don't allow an attachment to be uploaded with the same name as an
+	# existing page.
+	if (exists $pagesources{$dest} && $pagesources{$dest} ne $dest) {
+		error(sprintf(gettext("there is already a page named %s"), $dest));
+	}
+
+	# Use a special pagespec to test that the attachment is valid.
+	my $allowed=1;
+	foreach my $admin (@{$config{adminuser}}) {
+		my $allowed_attachments=IkiWiki::userinfo_get($admin, "allowed_attachments");
+		if (defined $allowed_attachments &&
+		    length $allowed_attachments) {
+			$allowed=pagespec_match($dest,
+				$allowed_attachments,
+				file => $file,
+				user => $session->param("name"),
+				ip => $ENV{REMOTE_ADDR},
+			);
+			last if $allowed;
+		}
+	}
+	if (! $allowed) {
+		error(gettext("prohibited by allowed_attachments")." ($allowed)");
+	}
+	else {
+		return 1;
+	}
+} #}}}
+
 sub checkconfig () { #{{{
 	$config{cgi_disable_uploads}=0;
 } #}}}
@@ -18,13 +52,31 @@ sub checkconfig () { #{{{
 sub formbuilder_setup (@) { #{{{
 	my %params=@_;
 	my $form=$params{form};
+	my $q=$params{cgi};
 
-	if ($form->field("do") eq "edit") {
+	if (defined $form->field("do") && $form->field("do") eq "edit") {
+		# Add attachment field, set type to multipart.
+		$form->enctype(&CGI::MULTIPART);
 		$form->field(name => 'attachment', type => 'file');
 		# These buttons are not put in the usual place, so
 		# are not added to the normal formbuilder button list.
 		$form->tmpl_param("field-upload" => '<input name="_submit" type="submit" value="Upload Attachment" />');
 		$form->tmpl_param("field-link" => '<input name="_submit" type="submit" value="Insert Links" />');
+
+		# Add the javascript from the toggle plugin;
+		# the attachments interface uses it to toggle visibility.
+		require IkiWiki::Plugin::toggle;
+		$form->tmpl_param("javascript" => $IkiWiki::Plugin::toggle::javascript);
+		# Start with the attachments interface toggled invisible,
+		# but if it was used, keep it open.
+		if ($form->submitted ne "Upload Attachment" &&
+		    (! defined $q->param("attachment_select") ||
+		    ! length $q->param("attachment_select"))) {
+			$form->tmpl_param("attachments-class" => "toggleable");
+		}
+		else {
+			$form->tmpl_param("attachments-class" => "toggleable-open");
+		}
 	}
 	elsif ($form->title eq "preferences") {
 		my $session=$params{session};
@@ -32,7 +84,13 @@ sub formbuilder_setup (@) { #{{{
 
 		$form->field(name => "allowed_attachments", size => 50,
 			fieldset => "admin",
-			comment => "(".htmllink("", "", "ikiwiki/PageSpec", noimageinline => 1).")");
+			comment => "(".
+				htmllink("", "", 
+					"ikiwiki/PageSpec/attachment", 
+					noimageinline => 1,
+					linktext => "Enhanced PageSpec",
+				).")"
+		);
 		if (! IkiWiki::is_admin($user_name)) {
 			$form->field(name => "allowed_attachments", type => "hidden");
 		}
@@ -55,7 +113,7 @@ sub formbuilder (@) { #{{{
 	my $form=$params{form};
 	my $q=$params{cgi};
 
-	return if $form->field("do") ne "edit";
+	return if ! defined $form->field("do") || $form->field("do") ne "edit";
 
 	my $filename=$q->param('attachment');
 	if (defined $filename && length $filename &&
@@ -65,8 +123,20 @@ sub formbuilder (@) { #{{{
 		# This is an (apparently undocumented) way to get the name
 		# of the temp file that CGI writes the upload to.
 		my $tempfile=$q->tmpFileName($filename);
-		
-		$filename=IkiWiki::titlepage(
+		if (! defined $tempfile || ! length $tempfile) {
+			# perl 5.8 needs an alternative, awful method
+			if ($q =~ /HASH/ && exists $q->{'.tmpfiles'}) {
+				foreach my $key (keys(%{$q->{'.tmpfiles'}})) {
+					$tempfile=$q->tmpFileName(\$key);
+					last if defined $tempfile && length $tempfile;
+				}
+			}
+			if (! defined $tempfile || ! length $tempfile) {
+				error("CGI::tmpFileName failed to return the uploaded file name");
+			}
+		}
+
+		$filename=IkiWiki::linkpage(
 			IkiWiki::possibly_foolish_untaint(
 				attachment_location($form->field('page')).
 				IkiWiki::basename($filename)));
@@ -77,22 +147,8 @@ sub formbuilder (@) { #{{{
 		# Check that the user is allowed to edit a page with the
 		# name of the attachment.
 		IkiWiki::check_canedit($filename, $q, $session, 1);
-		
-		# Use a special pagespec to test that the attachment is valid.
-		my $allowed=1;
-		foreach my $admin (@{$config{adminuser}}) {
-			my $allowed_attachments=IkiWiki::userinfo_get($admin, "allowed_attachments");
-			if (defined $allowed_attachments &&
-			    length $allowed_attachments) {
-				$allowed=pagespec_match($filename,
-					$allowed_attachments,
-					file => $tempfile);
-				last if $allowed;
-			}
-		}
-		if (! $allowed) {
-			error(gettext("attachment rejected")." ($allowed)");
-		}
+		# And that the attachment itself is acceptable.
+		check_canattach($session, $filename, $tempfile);
 
 		# Needed for fast_file_copy and for rendering below.
 		require IkiWiki::Render;
@@ -108,7 +164,14 @@ sub formbuilder (@) { #{{{
 		else {
 			my $fh=$q->upload('attachment');
 			if (! defined $fh || ! ref $fh) {
-				error("failed to get filehandle");
+				# needed by old CGI versions
+				$fh=$q->param('attachment');
+				if (! defined $fh || ! ref $fh) {
+					# even that doesn't always work,
+					# fall back to opening the tempfile
+					$fh=undef;
+					open($fh, "<", $tempfile) || error("failed to open \"$tempfile\": $!");
+				}
 			}
 			binmode($fh);
 			writefile($filename, $config{srcdir}, undef, 1, sub {
@@ -130,13 +193,15 @@ sub formbuilder (@) { #{{{
 		IkiWiki::saveindex();
 	}
 	elsif ($form->submitted eq "Insert Links") {
+		my $page=quotemeta($q->param("page"));
 		my $add="";
 		foreach my $f ($q->param("attachment_select")) {
+			$f=~s/^$page\///;
 			$add.="[[$f]]\n";
 		}
 		$form->field(name => 'editcontent',
 			value => $form->field('editcontent')."\n\n".$add,
-			force => 1);
+			force => 1) if length $add;
 	}
 	
 	# Generate the attachment list only after having added any new
@@ -144,7 +209,7 @@ sub formbuilder (@) { #{{{
 	$form->tmpl_param("attachment_list" => [attachment_list($form->field('page'))]);
 } # }}}
 
-sub attachment_location ($) {
+sub attachment_location ($) { #{{{
 	my $page=shift;
 	
 	# Put the attachment in a subdir of the page it's attached
@@ -153,9 +218,9 @@ sub attachment_location ($) {
 	$page.="/" if length $page;
 	
 	return $page;
-}
+} #}}}
 
-sub attachment_list ($) {
+sub attachment_list ($) { #{{{
 	my $page=shift;
 	my $loc=attachment_location($page);
 
@@ -165,7 +230,7 @@ sub attachment_list ($) {
 		    $f=~m/^\Q$loc\E[^\/]+$/ &&
 		    -e "$config{srcdir}/$f") {
 			push @ret, {
-				"field-select" => '<input type="checkbox" name="attachment_select" value="'.$f.'">',
+				"field-select" => '<input type="checkbox" name="attachment_select" value="'.$f.'" />',
 				link => htmllink($page, $page, $f, noimageinline => 1),
 				size => humansize((stat(_))[7]),
 				mtime => displaytime($IkiWiki::pagemtime{$f}),
@@ -177,9 +242,9 @@ sub attachment_list ($) {
 	# Sort newer attachments to the top of the list, so a newly-added
 	# attachment appears just before the form used to add it.
 	return sort { $b->{mtime_raw} <=> $a->{mtime_raw} || $a->{link} cmp $b->{link} } @ret;
-}
+} #}}}
 
-my %units=(		# size in bytes
+my %units=( #{{{	# size in bytes
 	B		=> 1,
 	byte		=> 1,
 	KB		=> 2 ** 10,
@@ -211,7 +276,7 @@ my %units=(		# size in bytes
 	# ikiwiki, if you find you need larger data quantities, either modify
 	# yourself to add them, or travel back in time to 2008 and kill me.
 	#   -- Joey
-);
+); #}}}
 
 sub parsesize ($) { #{{{
 	my $size=shift;
@@ -280,6 +345,76 @@ sub match_minsize ($$;@) { #{{{
 	}
 } #}}}
 
+sub match_mimetype ($$;@) { #{{{
+	shift;
+	my $wanted=shift;
+
+	my %params=@_;
+	if (! exists $params{file}) {
+		return IkiWiki::FailReason->new("no file specified");
+	}
+
+	# Use ::magic to get the mime type, the idea is to only trust
+	# data obtained by examining the actual file contents.
+	eval q{use File::MimeInfo::Magic};
+	if ($@) {
+		return IkiWiki::FailReason->new("failed to load File::MimeInfo::Magic ($@); cannot check MIME type");
+	}
+	my $mimetype=File::MimeInfo::Magic::magic($params{file});
+	if (! defined $mimetype) {
+		$mimetype="unknown";
+	}
+
+	my $regexp=IkiWiki::glob2re($wanted);
+	if ($mimetype!~/^$regexp$/i) {
+		return IkiWiki::FailReason->new("file MIME type is $mimetype, not $wanted");
+	}
+	else {
+		return IkiWiki::SuccessReason->new("file MIME type is $mimetype");
+	}
+} #}}}
+
+sub match_virusfree ($$;@) { #{{{
+	shift;
+	my $wanted=shift;
+
+	my %params=@_;
+	if (! exists $params{file}) {
+		return IkiWiki::FailReason->new("no file specified");
+	}
+
+	if (! exists $IkiWiki::config{virus_checker} ||
+	    ! length $IkiWiki::config{virus_checker}) {
+		return IkiWiki::FailReason->new("no virus_checker configured");
+	}
+
+	# The file needs to be fed into the virus checker on stdin,
+	# because the file is not world-readable, and if clamdscan is
+	# used, clamd would fail to read it.
+	eval q{use IPC::Open2};
+	error($@) if $@;
+	open (IN, "<", $params{file}) || return IkiWiki::FailReason->new("failed to read file");
+	binmode(IN);
+	my $sigpipe=0;
+	$SIG{PIPE} = sub { $sigpipe=1 };
+	my $pid=open2(\*CHECKER_OUT, "<&IN", $IkiWiki::config{virus_checker}); 
+	my $reason=<CHECKER_OUT>;
+	chomp $reason;
+	1 while (<CHECKER_OUT>);
+	close(CHECKER_OUT);
+	waitpid $pid, 0;
+	$SIG{PIPE}="DEFAULT";
+	if ($sigpipe || $?) {
+		if (! length $reason) {
+			$reason="virus checker $IkiWiki::config{virus_checker}; failed with no output";
+		}
+		return IkiWiki::FailReason->new("file seems to contain a virus ($reason)");
+	}
+	else {
+		return IkiWiki::SuccessReason->new("file seems virusfree ($reason)");
+	}
+} #}}}
+
 sub match_ispage ($$;@) { #{{{
 	my $filename=shift;
 
@@ -291,4 +426,41 @@ sub match_ispage ($$;@) { #{{{
 	}
 } #}}}
 
+sub match_user ($$;@) { #{{{
+	shift;
+	my $user=shift;
+	my %params=@_;
+	
+	if (! exists $params{user}) {
+		return IkiWiki::FailReason->new("no user specified");
+	}
+
+	if (defined $params{user} && lc $params{user} eq lc $user) {
+		return IkiWiki::SuccessReason->new("user is $user");
+	}
+	elsif (! defined $params{user}) {
+		return IkiWiki::FailReason->new("not logged in");
+	}
+	else {
+		return IkiWiki::FailReason->new("user is $params{user}, not $user");
+	}
+} #}}}
+
+sub match_ip ($$;@) { #{{{
+	shift;
+	my $ip=shift;
+	my %params=@_;
+	
+	if (! exists $params{ip}) {
+		return IkiWiki::FailReason->new("no IP specified");
+	}
+
+	if (defined $params{ip} && lc $params{ip} eq lc $ip) {
+		return IkiWiki::SuccessReason->new("IP is $ip");
+	}
+	else {
+		return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
+	}
+} #}}}
+
 1