<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::smiley;

use warnings;
use strict;
use IkiWiki 2.00;

my %smileys;
my $smiley_regexp;

sub import {
	add_underlay("smiley");
	hook(type =&gt; "getsetup", id =&gt; "smiley", call =&gt; \&amp;getsetup);
	hook(type =&gt; "sanitize", id =&gt; "smiley", call =&gt; \&amp;sanitize);
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			# force a rebuild because turning it off
			# removes the smileys, which would break links
			rebuild =&gt; 1,
		},
}

sub build_regexp () {
	my $list=readfile(srcfile("smileys.mdwn"));
	while ($list =~ m/^\s*\*\s+\\\\([^\s]+)\s+\[\[([^]]+)\]\]/mg) {
		my $smiley=$1;
		my $file=$2;

		$smileys{$smiley}=$file;

		# Add a version with &lt; and &gt; escaped, since they probably
		# will be (by markdown) by the time the sanitize hook runs.
		$smiley=~s/&lt;/&amp;lt;/g;
		$smiley=~s/&gt;/&amp;gt;/g;
		$smileys{$smiley}=$file;
	}
	
	if (! %smileys) {
		debug(gettext("failed to parse any smileys"));
		$smiley_regexp='';
		return;
	}
	
	# sort and reverse so that substrings come after longer strings
	# that contain them, in most cases.
	$smiley_regexp='('.join('|', map { quotemeta }
		reverse sort keys %smileys).')';
	#debug($smiley_regexp);
}

sub sanitize (@) {
	my %params=@_;

	build_regexp() unless defined $smiley_regexp;
	
	$_=$params{content};
	return $_ unless length $smiley_regexp;
			
MATCH:	while (m{(?:^|(?&lt;=\s|&gt;))(\\?)$smiley_regexp(?:(?=\s|&lt;)|$)}g) {
		my $escape=$1;
		my $smiley=$2;
		my $epos=$-[1];
		my $spos=$-[2];
		
		# Smilies are not allowed inside &lt;pre&gt; or &lt;code&gt;.
		# For each tag in turn, match forward to find the next &lt;tag&gt;
		# or &lt;/tag&gt; after the smiley.
		my $pos=pos;
		foreach my $tag ("pre", "code") {
			if (m/&lt;(\/)?\s*$tag\s*&gt;/isg &amp;&amp; defined $1) {
				# &lt;/tag&gt; found first, so the smiley is
				# inside the tag, so do not expand it.
				next MATCH;
			}
			# Reset pos back to where it was before this test.
			pos=$pos;
		}
	
		if ($escape) {
			# Remove escape.
			substr($_, $epos, 1)="";
			pos=$epos+1;
		}
		else {
			# Replace the smiley with its expanded value.
			substr($_, $spos, length($smiley))=
				htmllink($params{page}, $params{destpage},
				         $smileys{$smiley}, linktext =&gt; $smiley);
			pos=$epos+1;
		}
	}

	return $_;
}

1
</pre></body></html>