<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl

package IkiWiki;

use warnings;
use strict;
use IkiWiki;
use Encode;

my %backlinks;
my $backlinks_calculated=0;

sub calculate_backlinks () { #{{{
	return if $backlinks_calculated;
	%backlinks=();
	foreach my $page (keys %links) {
		foreach my $link (@{$links{$page}}) {
			my $bestlink=bestlink($page, $link);
			if (length $bestlink &amp;&amp; $bestlink ne $page) {
				$backlinks{$bestlink}{$page}=1;
			}
		}
	}
	$backlinks_calculated=1;
} #}}}

sub backlinks ($) { #{{{
	my $page=shift;

	calculate_backlinks();

	my @links;
	foreach my $p (keys %{$backlinks{$page}}) {
		my $href=urlto($p, $page);
                
		# Trim common dir prefixes from both pages.
		my $p_trimmed=$p;
		my $page_trimmed=$page;
		my $dir;
		1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &amp;&amp;
		        defined $dir &amp;&amp;
		        $p_trimmed=~s/^\Q$dir\E// &amp;&amp;
		        $page_trimmed=~s/^\Q$dir\E//;
			       
		push @links, { url =&gt; $href, page =&gt; pagetitle($p_trimmed) };
	}
	return @links;
} #}}}

sub parentlinks ($) { #{{{
	my $page=shift;
	
	my @ret;
	my $pagelink="";
	my $path="";
	my $title=$config{wikiname};
	
	foreach my $dir (split("/", $page)) {
		next if $dir eq 'index';
		push @ret, { url =&gt; urlto($path, $page), page =&gt; $title };
		$path.="/".$dir;
		$title=pagetitle($dir);
	}
	return @ret;
} #}}}

sub genpage ($$) { #{{{
	my $page=shift;
	my $content=shift;

	my $templatefile;
	run_hooks(templatefile =&gt; sub {
		return if defined $templatefile;
		my $file=shift-&gt;(page =&gt; $page);
		if (defined $file &amp;&amp; defined template_file($file)) {
			$templatefile=$file;
		}
	});
	my $template=template(defined $templatefile ? $templatefile : 'page.tmpl', blind_cache =&gt; 1);
	my $actions=0;

	if (length $config{cgiurl}) {
		$template-&gt;param(editurl =&gt; cgiurl(do =&gt; "edit", page =&gt; pagetitle($page, 1)));
		$template-&gt;param(prefsurl =&gt; cgiurl(do =&gt; "prefs"));
		$actions++;
	}
		
	if (length $config{historyurl}) {
		my $u=$config{historyurl};
		$u=~s/\[\[file\]\]/$pagesources{$page}/g;
		$template-&gt;param(historyurl =&gt; $u);
		$actions++;
	}
	if ($config{discussion}) {
		my $discussionlink=gettext("discussion");
		if ($page !~ /.*\/\Q$discussionlink\E$/ &amp;&amp;
		   (length $config{cgiurl} ||
		    exists $links{$page."/".$discussionlink})) {
			$template-&gt;param(discussionlink =&gt; htmllink($page, $page, gettext("Discussion"), noimageinline =&gt; 1, forcesubpage =&gt; 1));
			$actions++;
		}
	}

	if ($actions) {
		$template-&gt;param(have_actions =&gt; 1);
	}

	my @backlinks=sort { $a-&gt;{page} cmp $b-&gt;{page} } backlinks($page);
	my ($backlinks, $more_backlinks);
	if (@backlinks &lt;= $config{numbacklinks} || ! $config{numbacklinks}) {
		$backlinks=\@backlinks;
		$more_backlinks=[];
	}
	else {
		$backlinks=[@backlinks[0..$config{numbacklinks}-1]];
		$more_backlinks=[@backlinks[$config{numbacklinks}..$#backlinks]];
	}

	$template-&gt;param(
		title =&gt; $page eq 'index' 
			? $config{wikiname} 
			: pagetitle(basename($page)),
		wikiname =&gt; $config{wikiname},
		parentlinks =&gt; [parentlinks($page)],
		content =&gt; $content,
		backlinks =&gt; $backlinks,
		more_backlinks =&gt; $more_backlinks,
		mtime =&gt; displaytime($pagemtime{$page}),
		ctime =&gt; displaytime($pagectime{$page}),
		baseurl =&gt; baseurl($page),
	);

	run_hooks(pagetemplate =&gt; sub {
		shift-&gt;(page =&gt; $page, destpage =&gt; $page, template =&gt; $template);
	});
	
	$content=$template-&gt;output;

	run_hooks(format =&gt; sub {
		$content=shift-&gt;(
			page =&gt; $page,
			content =&gt; $content,
		);
	});

	return $content;
} #}}}

sub scan ($) { #{{{
	my $file=shift;

	my $type=pagetype($file);
	if (defined $type) {
		my $srcfile=srcfile($file);
		my $content=readfile($srcfile);
		my $page=pagename($file);
		will_render($page, htmlpage($page), 1);

		if ($config{discussion}) {
			# Discussion links are a special case since they're
			# not in the text of the page, but on its template.
			$links{$page}=[ $page."/".gettext("discussion") ];
		}
		else {
			$links{$page}=[];
		}

		run_hooks(scan =&gt; sub {
			shift-&gt;(
				page =&gt; $page,
				content =&gt; $content,
			);
		});

		# Preprocess in scan-only mode.
		preprocess($page, $page, $content, 1);
	}
	else {
		will_render($file, $file, 1);
	}
} #}}}

sub fast_file_copy (@) { #{{{
	my $srcfile=shift;
	my $destfile=shift;
	my $srcfd=shift;
	my $destfd=shift;
	my $cleanup=shift;

	my $blksize = 16384;
	my ($len, $buf, $written);
	while ($len = sysread $srcfd, $buf, $blksize) {
		if (! defined $len) {
			next if $! =~ /^Interrupted/;
			error("failed to read $srcfile: $!", $cleanup);
		}
		my $offset = 0;
		while ($len) {
			defined($written = syswrite $destfd, $buf, $len, $offset)
				or error("failed to write $destfile: $!", $cleanup);
			$len -= $written;
			$offset += $written;
		}
	}
}

sub render ($) { #{{{
	my $file=shift;
	
	my $type=pagetype($file);
	my $srcfile=srcfile($file);
	if (defined $type) {
		my $page=pagename($file);
		delete $depends{$page};
		will_render($page, htmlpage($page), 1);
		return if $type=~/^_/;
		
		my $content=htmlize($page, $page, $type,
			linkify($page, $page,
			preprocess($page, $page,
			filter($page, $page,
			readfile($srcfile)))));
		
		my $output=htmlpage($page);
		writefile($output, $config{destdir}, genpage($page, $content));
	}
	else {
		delete $depends{$file};
		will_render($file, $file, 1);
		
		if ($config{hardlink}) {
			prep_writefile($file, $config{destdir});
			unlink($config{destdir}."/".$file);
			if (link($srcfile, $config{destdir}."/".$file)) {
				return;
			}
			# if hardlink fails, fall back to copying
		}
		
		my $srcfd=readfile($srcfile, 1, 1);
		writefile($file, $config{destdir}, undef, 1, sub {
			fast_file_copy($srcfile, $file, $srcfd, @_);
		});
	}
} #}}}

sub prune ($) { #{{{
	my $file=shift;

	unlink($file);
	my $dir=dirname($file);
	while (rmdir($dir)) {
		$dir=dirname($dir);
	}
} #}}}

sub refresh () { #{{{
	# security check, avoid following symlinks in the srcdir path
	my $test=$config{srcdir};
	while (length $test) {
		if (-l $test) {
			error("symlink found in srcdir path ($test)");
		}
		unless ($test=~s/\/+$//) {
			$test=dirname($test);
		}
	}
	
	run_hooks(refresh =&gt; sub { shift-&gt;() });

	# find existing pages
	my %exists;
	my @files;
	eval q{use File::Find};
	error($@) if $@;
	find({
		no_chdir =&gt; 1,
		wanted =&gt; sub {
			$_=decode_utf8($_);
			if (file_pruned($_, $config{srcdir})) {
				$File::Find::prune=1;
			}
			elsif (! -l $_ &amp;&amp; ! -d _) {
				my ($f)=/$config{wiki_file_regexp}/; # untaint
				if (! defined $f) {
					warn(sprintf(gettext("skipping bad filename %s"), $_)."\n");
				}
				else {
					$f=~s/^\Q$config{srcdir}\E\/?//;
					push @files, $f;
					$exists{pagename($f)}=1;
				}
			}
		},
	}, $config{srcdir});
	foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
		find({
			no_chdir =&gt; 1,
			wanted =&gt; sub {
				$_=decode_utf8($_);
				if (file_pruned($_, $dir)) {
					$File::Find::prune=1;
				}
				elsif (! -l $_ &amp;&amp; ! -d _) {
					my ($f)=/$config{wiki_file_regexp}/; # untaint
					if (! defined $f) {
						warn(sprintf(gettext("skipping bad filename %s"), $_)."\n");
					}
					else {
						$f=~s/^\Q$dir\E\/?//;
						# avoid underlaydir
						# override attacks; see
						# security.mdwn
						if (! -l "$config{srcdir}/$f" &amp;&amp; 
						    ! -e _) {
						    	my $page=pagename($f);
							if (! $exists{$page}) {
								push @files, $f;
								$exists{$page}=1;
							}
						}
					}
				}
			},
		}, $dir);
	};

	my (%rendered, @add, @del, @internal);
	# check for added or removed pages
	foreach my $file (@files) {
		my $page=pagename($file);
		$pagesources{$page}=$file;
		if (! $pagemtime{$page}) {
			if (isinternal($page)) {
				push @internal, $file;
			}
			else {
				push @add, $file;
				if ($config{getctime} &amp;&amp; -e "$config{srcdir}/$file") {
					eval {
						my $time=rcs_getctime("$config{srcdir}/$file");
						$pagectime{$page}=$time;
					};
					if ($@) {
						print STDERR $@;
					}
				}
			}
			$pagecase{lc $page}=$page;
			if (! exists $pagectime{$page}) {
				$pagectime{$page}=(srcfile_stat($file))[10];
			}
		}
	}
	foreach my $page (keys %pagemtime) {
		if (! $exists{$page}) {
			if (isinternal($page)) {
				push @internal, $pagesources{$page};
			}
			else {
				debug(sprintf(gettext("removing old page %s"), $page));
				push @del, $pagesources{$page};
			}
			$links{$page}=[];
			$renderedfiles{$page}=[];
			$pagemtime{$page}=0;
			prune($config{destdir}."/".$_)
				foreach @{$oldrenderedfiles{$page}};
			delete $pagesources{$page};
			foreach (keys %destsources) {
				if ($destsources{$_} eq $page) {
					delete $destsources{$_};
				}
			}
		}
	}

	# find changed and new files
	my @needsbuild;
	foreach my $file (@files) {
		my $page=pagename($file);
		my ($srcfile, @stat)=srcfile_stat($file);
		if (! exists $pagemtime{$page} ||
		    $stat[9] &gt; $pagemtime{$page} ||
	    	    $forcerebuild{$page}) {
			$pagemtime{$page}=$stat[9];
			if (isinternal($page)) {
				push @internal, $file;
				# Preprocess internal page in scan-only mode.
				preprocess($page, $page, readfile($srcfile), 1);
			}
			else {
				push @needsbuild, $file;
			}
		}
	}
	run_hooks(needsbuild =&gt; sub { shift-&gt;(\@needsbuild) });

	# scan and render files
	foreach my $file (@needsbuild) {
		debug(sprintf(gettext("scanning %s"), $file));
		scan($file);
	}
	calculate_backlinks();
	foreach my $file (@needsbuild) {
		debug(sprintf(gettext("rendering %s"), $file));
		render($file);
		$rendered{$file}=1;
	}
	foreach my $file (@internal) {
		# internal pages are not rendered
		my $page=pagename($file);
		delete $depends{$page};
		foreach my $old (@{$renderedfiles{$page}}) {
			delete $destsources{$old};
		}
		$renderedfiles{$page}=[];
	}
	
	# rebuild pages that link to added or removed pages
	if (@add || @del) {
		foreach my $f (@add, @del) {
			my $p=pagename($f);
			foreach my $page (keys %{$backlinks{$p}}) {
				my $file=$pagesources{$page};
				next if $rendered{$file};
		   		debug(sprintf(gettext("rendering %s, which links to %s"), $file, $p));
				render($file);
				$rendered{$file}=1;
			}
		}
	}

	if (%rendered || @del || @internal) {
		my @changed=(keys %rendered, @del);

		# rebuild dependant pages
		foreach my $f (@files) {
			next if $rendered{$f};
			my $p=pagename($f);
			if (exists $depends{$p}) {
				# only consider internal files
				# if the page explicitly depends on such files
				foreach my $file (@changed, $depends{$p}=~/internal\(/ ? @internal : ()) {
					next if $f eq $file;
					my $page=pagename($file);
					if (pagespec_match($page, $depends{$p}, location =&gt; $p)) {
						debug(sprintf(gettext("rendering %s, which depends on %s"), $f, $page));
						render($f);
						$rendered{$f}=1;
						last;
					}
				}
			}
		}
		
		# handle backlinks; if a page has added/removed links,
		# update the pages it links to
		my %linkchanged;
		foreach my $file (@changed) {
			my $page=pagename($file);
			
			if (exists $links{$page}) {
				foreach my $link (map { bestlink($page, $_) } @{$links{$page}}) {
					if (length $link &amp;&amp;
					    (! exists $oldlinks{$page} ||
					     ! grep { bestlink($page, $_) eq $link } @{$oldlinks{$page}})) {
						$linkchanged{$link}=1;
					}
				}
			}
			if (exists $oldlinks{$page}) {
				foreach my $link (map { bestlink($page, $_) } @{$oldlinks{$page}}) {
					if (length $link &amp;&amp;
					    (! exists $links{$page} || 
					     ! grep { bestlink($page, $_) eq $link } @{$links{$page}})) {
						$linkchanged{$link}=1;
					}
				}
			}
		}

		foreach my $link (keys %linkchanged) {
		    	my $linkfile=$pagesources{$link};
			if (defined $linkfile) {
				next if $rendered{$linkfile};
				debug(sprintf(gettext("rendering %s, to update its backlinks"), $linkfile));
				render($linkfile);
				$rendered{$linkfile}=1;
			}
		}
	}

	# remove no longer rendered files
	foreach my $src (keys %rendered) {
		my $page=pagename($src);
		foreach my $file (@{$oldrenderedfiles{$page}}) {
			if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
				debug(sprintf(gettext("removing %s, no longer rendered by %s"), $file, $page));
				prune($config{destdir}."/".$file);
			}
		}
	}

	if (@del) {
		run_hooks(delete =&gt; sub { shift-&gt;(@del) });
	}
	if (%rendered) {
		run_hooks(change =&gt; sub { shift-&gt;(keys %rendered) });
	}
} #}}}

sub commandline_render () { #{{{
	lockwiki();
	loadindex();
	unlockwiki();

	my $srcfile=possibly_foolish_untaint($config{render});
	my $file=$srcfile;
	$file=~s/\Q$config{srcdir}\E\/?//;

	my $type=pagetype($file);
	die sprintf(gettext("ikiwiki: cannot render %s"), $srcfile)."\n" unless defined $type;
	my $content=readfile($srcfile);
	my $page=pagename($file);
	$pagesources{$page}=$file;
	$content=filter($page, $page, $content);
	$content=preprocess($page, $page, $content);
	$content=linkify($page, $page, $content);
	$content=htmlize($page, $page, $type, $content);
	$pagemtime{$page}=(stat($srcfile))[9];

	print genpage($page, $content);
	exit 0;
} #}}}

1
</pre></body></html>