<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::rename;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "rename", call =&gt; \&amp;getsetup);
	hook(type =&gt; "formbuilder_setup", id =&gt; "rename", call =&gt; \&amp;formbuilder_setup);
	hook(type =&gt; "formbuilder", id =&gt; "rename", call =&gt; \&amp;formbuilder);
	hook(type =&gt; "sessioncgi", id =&gt; "rename", call =&gt; \&amp;sessioncgi);
	hook(type =&gt; "rename", id =&gt; "rename", call =&gt; \&amp;rename_subpages);
}

sub getsetup () {
	return 
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; 0,
			section =&gt; "web",
		},
}

sub check_canrename ($$$$$$) {
	my $src=shift;
	my $srcfile=shift;
	my $dest=shift;
	my $destfile=shift;
	my $q=shift;
	my $session=shift;

	my $attachment=! defined pagetype($pagesources{$src});

	# Must be a known source file.
	if (! exists $pagesources{$src}) {
		error(sprintf(gettext("%s does not exist"),
			htmllink("", "", $src, noimageinline =&gt; 1)));
	}
	
	# Must exist on disk, and be a regular file.
	if (! -e "$config{srcdir}/$srcfile") {
		error(sprintf(gettext("%s is not in the srcdir, so it cannot be renamed"), $srcfile));
	}
	elsif (-l "$config{srcdir}/$srcfile" &amp;&amp; ! -f _) {
		error(sprintf(gettext("%s is not a file"), $srcfile));
	}

	# Must be editable.
	IkiWiki::check_canedit($src, $q, $session);
	if ($attachment) {
		if (IkiWiki::Plugin::attachment-&gt;can("check_canattach")) {
			IkiWiki::Plugin::attachment::check_canattach($session, $src, "$config{srcdir}/$srcfile");
		}
		else {
			error("renaming of attachments is not allowed");
		}
	}
	
	# Dest checks can be omitted by passing undef.
	if (defined $dest) {
		if ($srcfile eq $destfile) {
			error(gettext("no change to the file name was specified"));
		}

		# Must be a legal filename.
		if (IkiWiki::file_pruned($destfile)) {
			error(sprintf(gettext("illegal name")));
		}

		# Must not be a known source file.
		if ($src ne $dest &amp;&amp; exists $pagesources{$dest}) {
			error(sprintf(gettext("%s already exists"),
				htmllink("", "", $dest, noimageinline =&gt; 1)));
		}
	
		# Must not exist on disk already.
		if (-l "$config{srcdir}/$destfile" || -e _) {
			error(sprintf(gettext("%s already exists on disk"), $destfile));
		}
	
		# Must be editable.
		IkiWiki::check_canedit($dest, $q, $session);
		if ($attachment) {
			# Note that $srcfile is used here, not $destfile,
			# because it wants the current file, to check it.
			IkiWiki::Plugin::attachment::check_canattach($session, $dest, "$config{srcdir}/$srcfile");
		}
	}

	my $canrename;
	IkiWiki::run_hooks(canrename =&gt; sub {
		return if defined $canrename;
		my $ret=shift-&gt;(cgi =&gt; $q, session =&gt; $session,
			src =&gt; $src, srcfile =&gt; $srcfile,
			dest =&gt; $dest, destfile =&gt; $destfile);
		if (defined $ret) {
			if ($ret eq "") {
				$canrename=1;
			}
			elsif (ref $ret eq 'CODE') {
				$ret-&gt;();
				$canrename=0;
			}
			elsif (defined $ret) {
				error($ret);
				$canrename=0;
			}
		}
	});
	return defined $canrename ? $canrename : 1;
}

sub rename_form ($$$) {
	my $q=shift;
	my $session=shift;
	my $page=shift;

	eval q{use CGI::FormBuilder};
	error($@) if $@;
	my $f = CGI::FormBuilder-&gt;new(
		name =&gt; "rename",
		title =&gt; sprintf(gettext("rename %s"), pagetitle($page)),
		header =&gt; 0,
		charset =&gt; "utf-8",
		method =&gt; 'POST',
		javascript =&gt; 0,
		params =&gt; $q,
		action =&gt; $config{cgiurl},
		stylesheet =&gt; 1,
		fields =&gt; [qw{do page new_name attachment}],
	);
	
	$f-&gt;field(name =&gt; "do", type =&gt; "hidden", value =&gt; "rename", force =&gt; 1);
	$f-&gt;field(name =&gt; "sid", type =&gt; "hidden", value =&gt; $session-&gt;id,
		force =&gt; 1);
	$f-&gt;field(name =&gt; "page", type =&gt; "hidden", value =&gt; $page, force =&gt; 1);
	$f-&gt;field(name =&gt; "new_name", value =&gt; pagetitle($page, 1), size =&gt; 60);
	if (!$q-&gt;param("attachment")) {
		# insert the standard extensions
		my @page_types;
		if (exists $IkiWiki::hooks{htmlize}) {
			foreach my $key (grep { !/^_/ } keys %{$IkiWiki::hooks{htmlize}}) {
				push @page_types, [$key, $IkiWiki::hooks{htmlize}{$key}{longname} || $key];
			}
		}
		@page_types=sort @page_types;
	
		# make sure the current extension is in the list
		my ($ext) = $pagesources{$page}=~/\.([^.]+)$/;
		if (! $IkiWiki::hooks{htmlize}{$ext}) {
			unshift(@page_types, [$ext, $ext]);
		}
	
		$f-&gt;field(name =&gt; "type", type =&gt; 'select',
			options =&gt; \@page_types,
			value =&gt; $ext, force =&gt; 1);
		
		foreach my $p (keys %pagesources) {
			if ($pagesources{$p}=~m/^\Q$page\E\//) {
				$f-&gt;field(name =&gt; "subpages",
					label =&gt; "",
					type =&gt; "checkbox",
					options =&gt; [ [ 1 =&gt; gettext("Also rename SubPages and attachments") ] ],
					value =&gt; 1,
					force =&gt; 1);
				last;
			}
		}
	}
	$f-&gt;field(name =&gt; "attachment", type =&gt; "hidden");

	return $f, ["Rename", "Cancel"];
}

sub rename_start ($$$$) {
	my $q=shift;
	my $session=shift;
	my $attachment=shift;
	my $page=shift;

	check_canrename($page, $pagesources{$page}, undef, undef,
		$q, $session);

   	# Save current form state to allow returning to it later
	# without losing any edits.
	# (But don't save what button was submitted, to avoid
	# looping back to here.)
	# Note: "_submit" is CGI::FormBuilder internals.
	$q-&gt;param(-name =&gt; "_submit", -value =&gt; "");
	$session-&gt;param(postrename =&gt; scalar $q-&gt;Vars);
	IkiWiki::cgi_savesession($session);
	
	if (defined $attachment) {
		$q-&gt;param(-name =&gt; "attachment", -value =&gt; $attachment);
	}
	my ($f, $buttons)=rename_form($q, $session, $page);
	IkiWiki::showform($f, $buttons, $session, $q);
	exit 0;
}

sub postrename ($;$$$) {
	my $session=shift;
	my $src=shift;
	my $dest=shift;
	my $attachment=shift;

	# Load saved form state and return to edit page.
	my $postrename=CGI-&gt;new($session-&gt;param("postrename"));
	$session-&gt;clear("postrename");
	IkiWiki::cgi_savesession($session);

	if (defined $dest) {
		if (! $attachment) {
			# They renamed the page they were editing. This requires
			# fixups to the edit form state.
			# Tweak the edit form to be editing the new page.
			$postrename-&gt;param("page", $dest);
		}

		# Update edit form content to fix any links present
		# on it.
		$postrename-&gt;param("editcontent",
			renamepage_hook($dest, $src, $dest,
				 $postrename-&gt;param("editcontent")));

		# Get a new edit token; old was likely invalidated.
		$postrename-&gt;param("rcsinfo",
			IkiWiki::rcs_prepedit($pagesources{$dest}));
	}

	IkiWiki::cgi_editpage($postrename, $session);
}

sub formbuilder (@) {
	my %params=@_;
	my $form=$params{form};

	if (defined $form-&gt;field("do") &amp;&amp; ($form-&gt;field("do") eq "edit" ||
	    $form-&gt;field("do") eq "create")) {
    		IkiWiki::decode_form_utf8($form);
		my $q=$params{cgi};
		my $session=$params{session};

		if ($form-&gt;submitted eq "Rename" &amp;&amp; $form-&gt;field("do") eq "edit") {
			rename_start($q, $session, 0, $form-&gt;field("page"));
		}
		elsif ($form-&gt;submitted eq "Rename Attachment") {
			my @selected=map { Encode::decode_utf8($_) } $q-&gt;param("attachment_select");
			if (@selected &gt; 1) {
				error(gettext("Only one attachment can be renamed at a time."));
			}
			elsif (! @selected) {
				error(gettext("Please select the attachment to rename."))
			}
			rename_start($q, $session, 1, $selected[0]);
		}
	}
}

my $renamesummary;

sub formbuilder_setup (@) {
	my %params=@_;
	my $form=$params{form};
	my $q=$params{cgi};

	if (defined $form-&gt;field("do") &amp;&amp; ($form-&gt;field("do") eq "edit" ||
	    $form-&gt;field("do") eq "create")) {
		# Rename button for the page, and also for attachments.
		push @{$params{buttons}}, "Rename" if $form-&gt;field("do") eq "edit";
		$form-&gt;tmpl_param("field-rename" =&gt; '&lt;input name="_submit" type="submit" value="Rename Attachment" /&gt;');

		if (defined $renamesummary) {
			$form-&gt;tmpl_param(message =&gt; $renamesummary);
		}
	}
}

sub sessioncgi ($$) {
        my $q=shift;

	if ($q-&gt;param("do") eq 'rename') {
        	my $session=shift;
		my ($form, $buttons)=rename_form($q, $session, Encode::decode_utf8($q-&gt;param("page")));
		IkiWiki::decode_form_utf8($form);

		if ($form-&gt;submitted eq 'Cancel') {
			postrename($session);
		}
		elsif ($form-&gt;submitted eq 'Rename' &amp;&amp; $form-&gt;validate) {
			IkiWiki::checksessionexpiry($q, $session, $q-&gt;param('sid'));

			# Queue of rename actions to perfom.
			my @torename;

			# These untaints are safe because of the checks
			# performed in check_canrename later.
			my $src=$form-&gt;field("page");
			my $srcfile=IkiWiki::possibly_foolish_untaint($pagesources{$src});
			my $dest=IkiWiki::possibly_foolish_untaint(titlepage($form-&gt;field("new_name")));
			my $destfile=$dest;
			if (! $q-&gt;param("attachment")) {
				my $type=$q-&gt;param('type');
				if (defined $type &amp;&amp; length $type &amp;&amp; $IkiWiki::hooks{htmlize}{$type}) {
					$type=IkiWiki::possibly_foolish_untaint($type);
				}
				else {
					my ($ext)=$srcfile=~/\.([^.]+)$/;
					$type=$ext;
				}
				
				$destfile=newpagefile($dest, $type);
			}
			push @torename, {
				src =&gt; $src,
			       	srcfile =&gt; $srcfile,
				dest =&gt; $dest,
			       	destfile =&gt; $destfile,
				required =&gt; 1,
			};

			@torename=rename_hook(
				torename =&gt; \@torename,
				done =&gt; {},
				cgi =&gt; $q,
				session =&gt; $session,
			);

			require IkiWiki::Render;
			IkiWiki::disable_commit_hook() if $config{rcs};
			my %origpagesources=%pagesources;

			# First file renaming.
			foreach my $rename (@torename) {
				if ($rename-&gt;{required}) {
					do_rename($rename, $q, $session);
				}
				else {
					eval {do_rename($rename, $q, $session)};
					if ($@) {
						$rename-&gt;{error}=$@;
						next;
					}
				}

				# Temporarily tweak pagesources to point to
				# the renamed file, in case fixlinks needs
				# to edit it.
				$pagesources{$rename-&gt;{src}}=$rename-&gt;{destfile};
			}
			IkiWiki::rcs_commit_staged(
				message =&gt; sprintf(gettext("rename %s to %s"), $srcfile, $destfile),
				session =&gt; $session,
			) if $config{rcs};

			# Then link fixups.
			foreach my $rename (@torename) {
				next if $rename-&gt;{src} eq $rename-&gt;{dest};
				next if $rename-&gt;{error};
				foreach my $p (fixlinks($rename, $session)) {
					# map old page names to new
					foreach my $r (@torename) {
						next if $rename-&gt;{error};
						if ($r-&gt;{src} eq $p) {
							$p=$r-&gt;{dest};
							last;
						}
					}
					push @{$rename-&gt;{fixedlinks}}, $p;
				}
			}

			# Then refresh.
			%pagesources=%origpagesources;
			if ($config{rcs}) {
				IkiWiki::enable_commit_hook();
				IkiWiki::rcs_update();
			}
			IkiWiki::refresh();
			IkiWiki::saveindex();

			# Find pages with remaining, broken links.
			foreach my $rename (@torename) {
				next if $rename-&gt;{src} eq $rename-&gt;{dest};
				
				foreach my $page (keys %links) {
					my $broken=0;
					foreach my $link (@{$links{$page}}) {
						my $bestlink=bestlink($page, $link);
						if ($bestlink eq $rename-&gt;{src}) {
							push @{$rename-&gt;{brokenlinks}}, $page;
							last;
						}
					}
				}
			}

			# Generate a summary, that will be shown at the top
			# of the edit template.
			$renamesummary="";
			foreach my $rename (@torename) {
				my $template=template("renamesummary.tmpl");
				$template-&gt;param(src =&gt; $rename-&gt;{srcfile});
				$template-&gt;param(dest =&gt; $rename-&gt;{destfile});
				$template-&gt;param(error =&gt; $rename-&gt;{error});
				if ($rename-&gt;{src} ne $rename-&gt;{dest}) {
					$template-&gt;param(brokenlinks_checked =&gt; 1);
					$template-&gt;param(brokenlinks =&gt; linklist($rename-&gt;{dest}, $rename-&gt;{brokenlinks}));
					$template-&gt;param(fixedlinks =&gt; linklist($rename-&gt;{dest}, $rename-&gt;{fixedlinks}));
				}
				$renamesummary.=$template-&gt;output;
			}

			postrename($session, $src, $dest, $q-&gt;param("attachment"));
		}
		else {
			IkiWiki::showform($form, $buttons, $session, $q);
		}

		exit 0;
	}
}

# Add subpages to the list of pages to be renamed, if needed.
sub rename_subpages (@) {
	my %params = @_;

	my %torename = %{$params{torename}};
	my $q = $params{cgi};
	my $src = $torename{src};
	my $srcfile = $torename{src};
	my $dest = $torename{dest};
	my $destfile = $torename{dest};

	return () unless ($q-&gt;param("subpages") &amp;&amp; $src ne $dest);

	my @ret;
	foreach my $p (keys %pagesources) {
		next unless $pagesources{$p}=~m/^\Q$src\E\//;
		# If indexpages is enabled, the srcfile should not be confused
		# with a subpage.
		next if $pagesources{$p} eq $srcfile;

		my $d=$pagesources{$p};
		$d=~s/^\Q$src\E\//$dest\//;
		push @ret, {
			src =&gt; $p,
			srcfile =&gt; $pagesources{$p},
			dest =&gt; pagename($d),
			destfile =&gt; $d,
			required =&gt; 0,
		};
	}
	return @ret;
}

sub linklist {
	# generates a list of links in a form suitable for FormBuilder
	my $dest=shift;
	my $list=shift;
	# converts a list of pages into a list of links
	# in a form suitable for FormBuilder.

	[map {
		{
			page =&gt; htmllink($dest, $dest, $_,
					noimageinline =&gt; 1,
					linktext =&gt; pagetitle($_),
				)
		}
	} @{$list}]
}

sub renamepage_hook ($$$$) {
	my ($page, $src, $dest, $content)=@_;

	IkiWiki::run_hooks(renamepage =&gt; sub {
		$content=shift-&gt;(
			page =&gt; $page,
			oldpage =&gt; $src,
			newpage =&gt; $dest,
			content =&gt; $content,
		);
	});

	return $content;
}

sub rename_hook {
	my %params = @_;

	my @torename=@{$params{torename}};
	my %done=%{$params{done}};
	my $q=$params{cgi};
	my $session=$params{session};

	return () unless @torename;

	my @nextset;
	foreach my $torename (@torename) {
		unless (exists $done{$torename-&gt;{src}} &amp;&amp; $done{$torename-&gt;{src}}) {
			IkiWiki::run_hooks(rename =&gt; sub {
				push @nextset, shift-&gt;(
					torename =&gt; $torename,
					cgi =&gt; $q,
					session =&gt; $session,
				);
			});
			$done{$torename-&gt;{src}}=1;
		}
	}

	push @torename, rename_hook(
		torename =&gt; \@nextset,
		done =&gt; \%done,
		cgi =&gt; $q,
		session =&gt; $session,
	);

	# dedup
	my %seen;
	return grep { ! $seen{$_-&gt;{src}}++ } @torename;
}

sub do_rename ($$$) {
	my $rename=shift;
	my $q=shift;
	my $session=shift;

	# First, check if this rename is allowed.
	check_canrename($rename-&gt;{src},
		$rename-&gt;{srcfile},
		$rename-&gt;{dest},
		$rename-&gt;{destfile},
		$q, $session);

	# Ensure that the dest directory exists and is ok.
	IkiWiki::prep_writefile($rename-&gt;{destfile}, $config{srcdir});

	if ($config{rcs}) {
		IkiWiki::rcs_rename($rename-&gt;{srcfile}, $rename-&gt;{destfile});
	}
	else {
		if (! rename($config{srcdir}."/".$rename-&gt;{srcfile},
		             $config{srcdir}."/".$rename-&gt;{destfile})) {
			error("rename: $!");
		}
	}

}

sub fixlinks ($$$) {
	my $rename=shift;
	my $session=shift;

	my @fixedlinks;

	foreach my $page (keys %links) {
		my $needfix=0;
		foreach my $link (@{$links{$page}}) {
			my $bestlink=bestlink($page, $link);
			if ($bestlink eq $rename-&gt;{src}) {
				$needfix=1;
				last;
			}
		}
		if ($needfix) {
			my $file=$pagesources{$page};
			my $oldcontent=readfile($config{srcdir}."/".$file);
			my $content=renamepage_hook($page, $rename-&gt;{src}, $rename-&gt;{dest}, $oldcontent);
			if ($oldcontent ne $content) {
				my $token=IkiWiki::rcs_prepedit($file);
				eval { writefile($file, $config{srcdir}, $content) };
				next if $@;
				my $conflict=IkiWiki::rcs_commit(
					$file,
					sprintf(gettext("update for rename of %s to %s"), $rename-&gt;{srcfile}, $rename-&gt;{destfile}),
					$token,
					$session-&gt;param("name"),
					$session-&gt;remote_addr(),
				);
				push @fixedlinks, $page if ! defined $conflict;
			}
		}
	}

	return @fixedlinks;
}

1
</pre></body></html>