<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::highlight;

# This has been tested with highlight 2.16 and highlight 3.2+svn19.
# In particular version 3.2 won't work. It detects the different
# versions by the presence of the the highlight::DataDir class.

use warnings;
use strict;
use IkiWiki 3.00;
use Encode;

my $data_dir;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "highlight",  call =&gt; \&amp;getsetup);
	hook(type =&gt; "checkconfig", id =&gt; "highlight", call =&gt; \&amp;checkconfig);
	# this hook is used by the format plugin
	hook(type =&gt; "htmlizeformat", id =&gt; "highlight", 
		call =&gt; \&amp;htmlizeformat, last =&gt; 1);
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; 1, # format plugin
			section =&gt; "format",
		},
		tohighlight =&gt; {
			type =&gt; "string",
			example =&gt; ".c .h .cpp .pl .py Makefile:make",
			description =&gt; "types of source files to syntax highlight",
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
		filetypes_conf =&gt; {
			type =&gt; "string",
			example =&gt; "/etc/highlight/filetypes.conf",
			description =&gt; "location of highlight's filetypes.conf",
			safe =&gt; 0,
			rebuild =&gt; undef,
		},
		langdefdir =&gt; {
			type =&gt; "string",
			example =&gt; "/usr/share/highlight/langDefs",
			description =&gt; "location of highlight's langDefs directory",
			safe =&gt; 0,
			rebuild =&gt; undef,
		},
}

sub checkconfig () {
	eval q{use highlight};
	if (highlight::DataDir-&gt;can('new')) {
		$data_dir=new highlight::DataDir();
		$data_dir-&gt;searchDataDir("");
	} else {
		$data_dir=undef;
	}

	if (! exists $config{filetypes_conf}) {
	  if (! $data_dir ) {
		$config{filetypes_conf}= "/etc/highlight/filetypes.conf";
	      } elsif ( $data_dir -&gt; can('searchFile') ) {
		# 3.18 +
		$config{filetypes_conf}=
		  $data_dir -&gt; searchFile("filetypes.conf");
	      } else {
		# 3.9 +
		$config{filetypes_conf}=
		  $data_dir -&gt; getConfDir() . "/filetypes.conf";
	      }
	}
	# note that this is only used for old versions of highlight
	# where $data_dir will not be defined.
	if (! exists $config{langdefdir}) {
		$config{langdefdir}= "/usr/share/highlight/langDefs";

	}
	if (exists $config{tohighlight} &amp;&amp; read_filetypes()) {
		foreach my $file (split ' ', $config{tohighlight}) {
			my @opts = $file=~s/^\.// ?
				(keepextension =&gt; 1) :
				(noextension =&gt; 1);
			my $ext = $file=~s/:(.*)// ? $1 : $file;
		
			my $langfile=ext2langfile($ext);
			if (! defined $langfile) {
				error(sprintf(gettext(
					"tohighlight contains unknown file type '%s'"),
					$ext));
			}
	
			hook(
				type =&gt; "htmlize",
				id =&gt; $file,
				call =&gt; sub {
					my %params=@_;
				       	highlight($langfile, $file, $params{content});
				},
				longname =&gt; sprintf(gettext("Source code: %s"), $file),
				@opts,
			);
		}
	}
}

sub htmlizeformat {
	my $format=lc shift;
	my $langfile=ext2langfile($format);

	if (! defined $langfile) {
		return;
	}

	return Encode::decode_utf8(highlight($langfile, $format, shift));
}

my %ext2lang;
my $filetypes_read=0;
my %highlighters;

# Parse highlight's config file to get extension =&gt; language mappings.
sub read_filetypes () {
	my $f;
	if (!open($f, $config{filetypes_conf})) {
		warn($config{filetypes_conf}.": ".$!);
		return 0;
	};

	local $/=undef;
	my $config=&lt;$f&gt;;
	close $f;

	# highlight &gt;= 3.2 format (bind-style)
	while ($config=~m/Lang\s*=\s*\"([^"]+)\"[,\s]+Extensions\s*=\s*{([^}]+)}/sg) {
		my $lang=$1;
		foreach my $bit (split ',', $2) {
			$bit=~s/.*"(.*)".*/$1/s;
			$ext2lang{$bit}=$lang;
		}
	}

	# highlight &lt; 3.2 format
	if (! keys %ext2lang) {
		foreach (split("\n", $config)) {
			if (/^\$ext\((.*)\)=(.*)$/) {
				$ext2lang{$_}=$1 foreach $1, split ' ', $2;
			}
		}
	}

	return $filetypes_read=1;
}


sub searchlangdef {
  my $lang=shift;

  if ($data_dir) {
    return $data_dir-&gt;getLangPath($lang . ".lang");
  } else {
    return "$config{langdefdir}/$lang.lang";
  }

}
# Given a filename extension, determines the language definition to
# use to highlight it.
sub ext2langfile ($) {
	my $ext=shift;

	my $langfile=searchlangdef($ext);
	return $langfile if exists $highlighters{$langfile};

	read_filetypes() unless $filetypes_read;
	if (exists $ext2lang{$ext}) {
		return searchlangdef($ext2lang{$ext});
	}
	# If a language only has one common extension, it will not
	# be listed in filetypes, so check the langfile.
	elsif (-e $langfile) {
		return $langfile;
	}
	else {
		return undef;
	}
}

# Interface to the highlight C library.
sub highlight ($$) {
	my $langfile=shift;
	my $extorfile=shift;
	my $input=shift;

	eval q{use highlight};
	if ($@) {
		print STDERR gettext("warning: highlight perl module not available; falling back to pass through");
		return $input;
	}

	my $gen;
	if (! exists $highlighters{$langfile}) {
		no warnings 'once';
		$gen = highlight::CodeGenerator::getInstance($highlight::XHTML);
		use warnings;
		$gen-&gt;setFragmentCode(1); # generate html fragment
		$gen-&gt;setHTMLEnclosePreTag(1); # include stylish &lt;pre&gt;
		if ($data_dir){
			# new style, requires a real theme, but has no effect
			$gen-&gt;initTheme($data_dir-&gt;getThemePath("seashell.theme"));
		} else {
			# old style, anything works.
			$gen-&gt;initTheme("/dev/null");
		}
		$gen-&gt;loadLanguage($langfile); # must come after initTheme
		$gen-&gt;setEncoding("utf-8");
		$highlighters{$langfile}=$gen;
	}
	else {		
		$gen=$highlighters{$langfile};
	}

	return "&lt;div class=\"highlight-$extorfile\"&gt;".$gen-&gt;generateString($input)."&lt;/div&gt;";
}

1
</pre></body></html>