<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::link;

use warnings;
use strict;
use IkiWiki 3.00;

my $link_regexp;

my $email_regexp = qr/^.+@.+$/;
my $url_regexp = qr/^(?:[^:]+:\/\/|mailto:).*/i;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "link", call =&gt; \&amp;getsetup);
	hook(type =&gt; "checkconfig", id =&gt; "link", call =&gt; \&amp;checkconfig);
	hook(type =&gt; "linkify", id =&gt; "link", call =&gt; \&amp;linkify);
	hook(type =&gt; "scan", id =&gt; "link", call =&gt; \&amp;scan);
	hook(type =&gt; "renamepage", id =&gt; "link", call =&gt; \&amp;renamepage);
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; 1,
			section =&gt; "core",
		},
}

sub checkconfig () {
	if ($config{prefix_directives}) {
		$link_regexp = qr{
			\[\[(?=[^!])            # beginning of link
			(?:
				([^\]\|]+)      # 1: link text
				\|              # followed by '|'
			)?                      # optional
			
			([^\n\r\]#]+)           # 2: page to link to
			(?:
				\#              # '#', beginning of anchor
				([^\s\]]+)      # 3: anchor text
			)?                      # optional
			
			\]\]                    # end of link
		}x;
	}
	else {
		$link_regexp = qr{
			\[\[                    # beginning of link
			(?:
				([^\]\|\n\s]+)  # 1: link text
				\|              # followed by '|'
			)?                      # optional

			([^\s\]#]+)             # 2: page to link to
			(?:
				\#              # '#', beginning of anchor
				([^\s\]]+)      # 3: anchor text
			)?                      # optional

			\]\]                    # end of link
		}x;
	}
}

sub is_externallink ($$;$$) {
	my $page = shift;
	my $url = shift;
	my $anchor = shift;
	my $force = shift;
	
	if (defined $anchor) {
		$url.="#".$anchor;
	}

	if (! $force &amp;&amp; $url =~ /$email_regexp/) {
		# url looks like an email address, so we assume it
		# is supposed to be an external link if there is no
		# page with that name.
		return (! (bestlink($page, linkpage($url))))
	}

	return ($url =~ /$url_regexp/)
}

sub externallink ($$;$) {
	my $url = shift;
	my $anchor = shift;
	my $pagetitle = shift;

	if (defined $anchor) {
		$url.="#".$anchor;
	}

	# build pagetitle
	if (! $pagetitle) {
		$pagetitle = $url;
		# use only the email address as title for mailto: urls
		if ($pagetitle =~ /^mailto:.*/) {
			$pagetitle =~ s/^mailto:([^?]+).*/$1/;
		}
	}

	if ($url !~ /$url_regexp/) {
		# handle email addresses (without mailto:)
		$url = "mailto:" . $url;
	}

	return "&lt;a href=\"$url\"&gt;$pagetitle&lt;/a&gt;";
}

sub linkify (@) {
	my %params=@_;
	my $page=$params{page};
	my $destpage=$params{destpage};

	$params{content} =~ s{(\\?)$link_regexp}{
		defined $2
			? ( $1 
				? "[[$2|$3".(defined $4 ? "#$4" : "")."]]" 
				: is_externallink($page, $3, $4)
					? externallink($3, $4, $2)
					: htmllink($page, $destpage, linkpage($3),
						anchor =&gt; $4, linktext =&gt; pagetitle($2)))
			: ( $1 
				? "[[$3".(defined $4 ? "#$4" : "")."]]"
				: is_externallink($page, $3, $4)
					? externallink($3, $4)
					: htmllink($page, $destpage, linkpage($3),
						anchor =&gt; $4))
	}eg;
	
	return $params{content};
}

sub scan (@) {
	my %params=@_;
	my $page=$params{page};
	my $content=$params{content};

	while ($content =~ /(?&lt;!\\)$link_regexp/g) {
		if (! is_externallink($page, $2, $3, 1)) {
			add_link($page, linkpage($2));
		}
	}
}

sub renamepage (@) {
	my %params=@_;
	my $page=$params{page};
	my $old=$params{oldpage};
	my $new=$params{newpage};

	$params{content} =~ s{(?&lt;!\\)$link_regexp}{
		if (! is_externallink($page, $2, $3)) {
			my $linktext=$2;
			my $link=$linktext;
			if (bestlink($page, linkpage($linktext)) eq $old) {
				$link=pagetitle($new, 1);
				$link=~s/ /_/g;
				if ($linktext =~ m/.*\/*?[A-Z]/) {
					# preserve leading cap of last component
					my @bits=split("/", $link);
					$link=join("/", @bits[0..$#bits-1], ucfirst($bits[$#bits]));
				}
				if (index($linktext, "/") == 0) {
					# absolute link
					$link="/$link";
				}
			}
			defined $1
				? ( "[[$1|$link".($3 ? "#$3" : "")."]]" )
				: ( "[[$link".   ($3 ? "#$3" : "")."]]" )
		}
	}eg;

	return $params{content};
}

1
</pre></body></html>