<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::remove;

use warnings;
use strict;
use IkiWiki 2.00;

sub import { #{{{
	hook(type =&gt; "getsetup", id =&gt; "remove", call =&gt; \&amp;getsetup);
	hook(type =&gt; "formbuilder_setup", id =&gt; "remove", call =&gt; \&amp;formbuilder_setup);
	hook(type =&gt; "formbuilder", id =&gt; "remove", call =&gt; \&amp;formbuilder);
	hook(type =&gt; "sessioncgi", id =&gt; "remove", call =&gt; \&amp;sessioncgi);

} # }}}

sub getsetup () { #{{{
	return 
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; 0,
		},
} #}}}

sub check_canremove ($$$) { #{{{
	my $page=shift;
	my $q=shift;
	my $session=shift;

	# Must be a known source file.
	if (! exists $pagesources{$page}) {
		error(sprintf(gettext("%s does not exist"),
			htmllink("", "", $page, noimageinline =&gt; 1)));
	}

	# Must exist on disk, and be a regular file.
	my $file=$pagesources{$page};
	if (! -e "$config{srcdir}/$file") {
		error(sprintf(gettext("%s is not in the srcdir, so it cannot be deleted"), $file));
	}
	elsif (-l "$config{srcdir}/$file" &amp;&amp; ! -f _) {
		error(sprintf(gettext("%s is not a file"), $file));
	}
	
	# Must be editable.
	IkiWiki::check_canedit($page, $q, $session);

	# If a user can't upload an attachment, don't let them delete it.
	# This is sorta overkill, but better safe than sorry.
	if (! defined pagetype($pagesources{$page})) {
		if (IkiWiki::Plugin::attachment-&gt;can("check_canattach")) {
			IkiWiki::Plugin::attachment::check_canattach($session, $page, $file);
		}
		else {
			error("renaming of attachments is not allowed");
		}
	}
} #}}}

sub formbuilder_setup (@) { #{{{
	my %params=@_;
	my $form=$params{form};
	my $q=$params{cgi};

	if (defined $form-&gt;field("do") &amp;&amp; ($form-&gt;field("do") eq "edit" ||
	    $form-&gt;field("do") eq "create")) {
		# Removal button for the page, and also for attachments.
		push @{$params{buttons}}, "Remove" if $form-&gt;field("do") eq "edit";
		$form-&gt;tmpl_param("field-remove" =&gt; '&lt;input name="_submit" type="submit" value="Remove Attachments" /&gt;');
	}
} #}}}

sub confirmation_form ($$) { #{{{ 
	my $q=shift;
	my $session=shift;

	eval q{use CGI::FormBuilder};
	error($@) if $@;
	my $f = CGI::FormBuilder-&gt;new(
		name =&gt; "remove",
		header =&gt; 0,
		charset =&gt; "utf-8",
		method =&gt; 'POST',
		javascript =&gt; 0,
		params =&gt; $q,
		action =&gt; $config{cgiurl},
		stylesheet =&gt; IkiWiki::baseurl()."style.css",
		fields =&gt; [qw{do page}],
	);
	
	$f-&gt;field(name =&gt; "do", type =&gt; "hidden", value =&gt; "remove", force =&gt; 1);

	return $f, ["Remove", "Cancel"];
} #}}}

sub removal_confirm ($$@) { #{{{
	my $q=shift;
	my $session=shift;
	my $attachment=shift;
	my @pages=@_;

	foreach my $page (@pages) {
		check_canremove($page, $q, $session);
	}

   	# Save current form state to allow returning to it later
	# without losing any edits.
	# (But don't save what button was submitted, to avoid
	# looping back to here.)
	# Note: "_submit" is CGI::FormBuilder internals.
	$q-&gt;param(-name =&gt; "_submit", -value =&gt; "");
	$session-&gt;param(postremove =&gt; scalar $q-&gt;Vars);
	IkiWiki::cgi_savesession($session);
	
	my ($f, $buttons)=confirmation_form($q, $session);
	$f-&gt;title(sprintf(gettext("confirm removal of %s"),
		join(", ", map { pagetitle($_) } @pages)));
	$f-&gt;field(name =&gt; "page", type =&gt; "hidden", value =&gt; \@pages, force =&gt; 1);
	if (defined $attachment) {
		$f-&gt;field(name =&gt; "attachment", type =&gt; "hidden",
			value =&gt; $attachment, force =&gt; 1);
	}

	IkiWiki::showform($f, $buttons, $session, $q);
	exit 0;
} #}}}

sub postremove ($) { #{{{
	my $session=shift;

	# Load saved form state and return to edit form.
	my $postremove=CGI-&gt;new($session-&gt;param("postremove"));
	$session-&gt;clear("postremove");
	IkiWiki::cgi_savesession($session);
	IkiWiki::cgi($postremove, $session);
} #}}}

sub formbuilder (@) { #{{{
	my %params=@_;
	my $form=$params{form};

	if (defined $form-&gt;field("do") &amp;&amp; ($form-&gt;field("do") eq "edit" ||
	    $form-&gt;field("do") eq "create")) {
		my $q=$params{cgi};
		my $session=$params{session};

		if ($form-&gt;submitted eq "Remove" &amp;&amp; $form-&gt;field("do") eq "edit") {
			removal_confirm($q, $session, 0, $form-&gt;field("page"));
		}
		elsif ($form-&gt;submitted eq "Remove Attachments") {
			my @selected=$q-&gt;param("attachment_select");
			if (! @selected) {
				error(gettext("Please select the attachments to remove."));
			}
			removal_confirm($q, $session, 1, @selected);
		}
	}
} #}}}

sub sessioncgi ($$) { #{{{
        my $q=shift;

	if ($q-&gt;param("do") eq 'remove') {
        	my $session=shift;
		my ($form, $buttons)=confirmation_form($q, $session);
		IkiWiki::decode_form_utf8($form);

		if ($form-&gt;submitted eq 'Cancel') {
			postremove($session);
		}
		elsif ($form-&gt;submitted eq 'Remove' &amp;&amp; $form-&gt;validate) {
			my @pages=$q-&gt;param("page");
	
			# Validate removal by checking that the page exists,
			# and that the user is allowed to edit(/remove) it.
			my @files;
			foreach my $page (@pages) {
				check_canremove($page, $q, $session);
				
				# This untaint is safe because of the
				# checks performed above, which verify the
				# page is a normal file, etc.
				push @files, IkiWiki::possibly_foolish_untaint($pagesources{$page});
			}

			# Do removal, and update the wiki.
			require IkiWiki::Render;
			if ($config{rcs}) {
				IkiWiki::disable_commit_hook();
				foreach my $file (@files) {
					IkiWiki::rcs_remove($file);
				}
				IkiWiki::rcs_commit_staged(gettext("removed"),
					$session-&gt;param("name"), $ENV{REMOTE_ADDR});
				IkiWiki::enable_commit_hook();
				IkiWiki::rcs_update();
			}
			else {
				foreach my $file (@files) {
					IkiWiki::prune("$config{srcdir}/$file");
				}
			}
			IkiWiki::refresh();
			IkiWiki::saveindex();

			if ($q-&gt;param("attachment")) {
				# Attachments were deleted, so redirect
				# back to the edit form.
				postremove($session);
			}
			else {
				# The page is gone, so redirect to parent
				# of the page.
				my $parent=IkiWiki::dirname($pages[0]);
				if (! exists $pagesources{$parent}) {
					$parent="index";
				}
				IkiWiki::redirect($q, urlto($parent, '/', 1));
			}
		}
		else {
			IkiWiki::showform($form, $buttons, $session, $q);
		}

		exit 0;
	}
}

1
</pre></body></html>