<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Ikiwiki tag plugin.
package IkiWiki::Plugin::tag;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	hook(type =&gt; "getopt", id =&gt; "tag", call =&gt; \&amp;getopt);
	hook(type =&gt; "getsetup", id =&gt; "tag", call =&gt; \&amp;getsetup);
	hook(type =&gt; "preprocess", id =&gt; "tag", call =&gt; \&amp;preprocess_tag, scan =&gt; 1);
	hook(type =&gt; "preprocess", id =&gt; "taglink", call =&gt; \&amp;preprocess_taglink, scan =&gt; 1);
	hook(type =&gt; "pagetemplate", id =&gt; "tag", call =&gt; \&amp;pagetemplate);
}

sub getopt () {
	eval q{use Getopt::Long};
	error($@) if $@;
	Getopt::Long::Configure('pass_through');
	GetOptions("tagbase=s" =&gt; \$config{tagbase});
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; undef,
		},
		tagbase =&gt; {
			type =&gt; "string",
			example =&gt; "tag",
			description =&gt; "parent page tags are located under",
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
}

sub tagpage ($) {
	my $tag=shift;
			
	if ($tag !~ m{^\.?/} &amp;&amp;
	    defined $config{tagbase}) {
		$tag="/".$config{tagbase}."/".$tag;
		$tag=~y#/#/#s; # squash dups
	}

	return $tag;
}

sub taglink ($$$;@) {
	my $page=shift;
	my $destpage=shift;
	my $tag=shift;
	my %opts=@_;

	return htmllink($page, $destpage, tagpage($tag), %opts);
}

sub preprocess_tag (@) {
	if (! @_) {
		return "";
	}
	my %params=@_;
	my $page = $params{page};
	delete $params{page};
	delete $params{destpage};
	delete $params{preview};

	foreach my $tag (keys %params) {
		$tag=linkpage($tag);
		# hidden WikiLink
		add_link($page, tagpage($tag), 'tag');
	}
		
	return "";
}

sub preprocess_taglink (@) {
	if (! @_) {
		return "";
	}
	my %params=@_;
	return join(" ", map {
		if (/(.*)\|(.*)/) {
			my $tag=linkpage($2);
			add_link($params{page}, tagpage($tag), 'tag');
			return taglink($params{page}, $params{destpage}, $tag,
				linktext =&gt; pagetitle($1));
		}
		else {
			my $tag=linkpage($_);
			add_link($params{page}, tagpage($tag), 'tag');
			return taglink($params{page}, $params{destpage}, $tag);
		}
	}
	grep {
		$_ ne 'page' &amp;&amp; $_ ne 'destpage' &amp;&amp; $_ ne 'preview'
	} keys %params);
}

sub pagetemplate (@) {
	my %params=@_;
	my $page=$params{page};
	my $destpage=$params{destpage};
	my $template=$params{template};

	my $tags = $typedlinks{$page}{tag};

	$template-&gt;param(tags =&gt; [
		map { 
			link =&gt; taglink($page, $destpage, $_, rel =&gt; "tag")
		}, sort keys %$tags
	]) if defined $tags &amp;&amp; %$tags &amp;&amp; $template-&gt;query(name =&gt; "tags");

	if ($template-&gt;query(name =&gt; "categories")) {
		# It's an rss/atom template. Add any categories.
		if (defined $tags &amp;&amp; %$tags) {
			$template-&gt;param(categories =&gt; [map { category =&gt; $_ },
				sort keys %$tags]);
		}
	}
}

package IkiWiki::PageSpec;

sub match_tagged ($$;@) {
	return match_link($_[0], IkiWiki::Plugin::tag::tagpage($_[1]), linktype =&gt; 'tag');
}

1
</pre></body></html>