<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Structured template plugin.
package IkiWiki::Plugin::template;

use warnings;
use strict;
use IkiWiki 3.00;
use Encode;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "template", call =&gt; \&amp;getsetup);
	hook(type =&gt; "preprocess", id =&gt; "template", call =&gt; \&amp;preprocess,
		scan =&gt; 1);
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; undef,
			section =&gt; "widget",
		},
}

sub preprocess (@) {
	my %params=@_;

	# This needs to run even in scan mode, in order to process
	# links and other metadata included via the template.
	my $scan=! defined wantarray;

	if (! exists $params{id}) {
		error gettext("missing id parameter")
	}

	# The bare id is used, so a page templates/$id can be used as 
	# the template.
	my $template;
	eval {
		$template=template_depends($params{id}, $params{page},
			blind_cache =&gt; 1);
	};
	if ($@) {
		error gettext("failed to process template:")." $@";
	}
	if (! $template) {
		error sprintf(gettext("%s not found"),
			htmllink($params{page}, $params{destpage},
				"/templates/$params{id}"))
	}

	$params{basename}=IkiWiki::basename($params{page});

	foreach my $param (keys %params) {
		my $value=IkiWiki::preprocess($params{page}, $params{destpage},
		          IkiWiki::filter($params{page}, $params{destpage},
		          $params{$param}), $scan);
		if ($template-&gt;query(name =&gt; $param)) {
			my $htmlvalue=IkiWiki::htmlize($params{page}, $params{destpage},
					pagetype($pagesources{$params{page}}),
					$value);
			chomp $htmlvalue;
			$template-&gt;param($param =&gt; $htmlvalue);
		}
		if ($template-&gt;query(name =&gt; "raw_$param")) {
			chomp $value;
			$template-&gt;param("raw_$param" =&gt; $value);
		}
	}

	return IkiWiki::preprocess($params{page}, $params{destpage},
	       IkiWiki::filter($params{page}, $params{destpage},
	       $template-&gt;output), $scan);
}

1
</pre></body></html>