<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Blog aggregation plugin.
package IkiWiki::Plugin::aggregate;

use warnings;
use strict;
use IkiWiki;
use HTML::Entities;
use HTML::Parser;
use HTML::Tagset;
use URI;

my %feeds;
my %guids;

sub import { #{{{
	IkiWiki::hook(type =&gt; "getopt", id =&gt; "aggregate", 
		call =&gt; \&amp;getopt);
	IkiWiki::hook(type =&gt; "checkconfig", id =&gt; "aggregate",
		call =&gt; \&amp;checkconfig);
	IkiWiki::hook(type =&gt; "filter", id =&gt; "aggregate", 
		call =&gt; \&amp;filter);
	IkiWiki::hook(type =&gt; "preprocess", id =&gt; "aggregate",
		call =&gt; \&amp;preprocess);
        IkiWiki::hook(type =&gt; "delete", id =&gt; "aggregate",
                call =&gt; \&amp;delete);
	IkiWiki::hook(type =&gt; "savestate", id =&gt; "aggregate",
		call =&gt; \&amp;savestate);
} # }}}

sub getopt () { #{{{
        eval q{use Getopt::Long};
        Getopt::Long::Configure('pass_through');
        GetOptions("aggregate" =&gt; \$IkiWiki::config{aggregate});
} #}}}

sub checkconfig () { #{{{
	loadstate();
	if ($IkiWiki::config{aggregate}) {
		IkiWiki::loadindex();
		aggregate();
		savestate();
	}
} #}}}

sub filter (@) { #{{{
	my %params=@_;
	my $page=$params{page};

	# Mark all feeds originating on this page as removable;
	# preprocess will unmark those that still exist.
	remove_feeds($page);

	return $params{content};
} # }}}

sub preprocess (@) { #{{{
	my %params=@_;

	foreach my $required (qw{name url}) {
		if (! exists $params{$required}) {
			return "[[aggregate plugin missing $required parameter]]";
		}
	}

	my $feed={};
	my $name=$params{name};
	if (exists $feeds{$name}) {
		$feed=$feeds{$name};
	}
	else {
		$feeds{$name}=$feed;
	}
	$feed-&gt;{name}=$name;
	$feed-&gt;{sourcepage}=$params{page};
	$feed-&gt;{url}=$params{url};
	my $dir=exists $params{dir} ? $params{dir} : $params{page}."/".IkiWiki::titlepage($params{name});
	$dir=~s/^\/+//;
	($dir)=$dir=~/$IkiWiki::config{wiki_file_regexp}/;
	$feed-&gt;{dir}=$dir;
	$feed-&gt;{feedurl}=defined $params{feedurl} ? $params{feedurl} : "";
	$feed-&gt;{updateinterval}=defined $params{updateinterval} ? $params{updateinterval} * 60 : 15 * 60;
	$feed-&gt;{expireage}=defined $params{expireage} ? $params{expireage} : 0;
	$feed-&gt;{expirecount}=defined $params{expirecount} ? $params{expirecount} : 0;
	delete $feed-&gt;{remove};
	$feed-&gt;{lastupdate}=0 unless defined $feed-&gt;{lastupdate};
	$feed-&gt;{numposts}=0 unless defined $feed-&gt;{numposts};
	$feed-&gt;{newposts}=0 unless defined $feed-&gt;{newposts};
	$feed-&gt;{message}="new feed" unless defined $feed-&gt;{message};
	$feed-&gt;{tags}=[];
	while (@_) {
		my $key=shift;
		my $value=shift;
		if ($key eq 'tag') {
			push @{$feed-&gt;{tags}}, $value;
		}
	}

	return "&lt;a href=\"".$feed-&gt;{url}."\"&gt;".$feed-&gt;{name}."&lt;/a&gt;: ".
	       "&lt;i&gt;".$feed-&gt;{message}."&lt;/i&gt; (".$feed-&gt;{numposts}.
	       " stored posts; ".$feed-&gt;{newposts}." new)";
} # }}}

sub delete (@) { #{{{
	my @files=@_;

	# Remove feed data for removed pages.
	foreach my $file (@files) {
		my $page=IkiWiki::pagename($file);
		remove_feeds($page);
	}
} #}}}

sub loadstate () { #{{{
	if (-e "$IkiWiki::config{wikistatedir}/aggregate") {
		open (IN, "$IkiWiki::config{wikistatedir}/aggregate" ||
			die "$IkiWiki::config{wikistatedir}/aggregate: $!");
		while (&lt;IN&gt;) {
			$_=IkiWiki::possibly_foolish_untaint($_);
			chomp;
			my $data={};
			foreach my $i (split(/ /, $_)) {
				my ($field, $val)=split(/=/, $i, 2);
				if ($field eq "name" || $field eq "feed" ||
				    $field eq "guid" || $field eq "message") {
					$data-&gt;{$field}=decode_entities($val, " \t\n");
				}
				elsif ($field eq "tag") {
					push @{$data-&gt;{tags}}, $val;
				}
				else {
					$data-&gt;{$field}=$val;
				}
			}
			
			if (exists $data-&gt;{name}) {
				$feeds{$data-&gt;{name}}=$data;
			}
			elsif (exists $data-&gt;{guid}) {
				$guids{$data-&gt;{guid}}=$data;
			}
		}

		close IN;
	}
} #}}}

sub savestate () { #{{{
	eval q{use HTML::Entities};
	die $@ if $@;
	open (OUT, "&gt;$IkiWiki::config{wikistatedir}/aggregate" ||
		die "$IkiWiki::config{wikistatedir}/aggregate: $!");
	foreach my $data (values %feeds, values %guids) {
		if ($data-&gt;{remove}) {
			if ($data-&gt;{name}) {
				foreach my $guid (values %guids) {
					if ($guid-&gt;{feed} eq $data-&gt;{name}) {
						$guid-&gt;{remove}=1;
					}
				}
			}
			else {
				unlink pagefile($data-&gt;{page});
			}
			next;
		}

		my @line;
		foreach my $field (keys %$data) {
			if ($field eq "name" || $field eq "feed" ||
			    $field eq "guid" || $field eq "message") {
				push @line, "$field=".encode_entities($data-&gt;{$field}, " \t\n");
			}
			elsif ($field eq "tags") {
				push @line, "tag=$_" foreach @{$data-&gt;{tags}};
			}
			else {
				push @line, "$field=".$data-&gt;{$field};
			}
		}
		print OUT join(" ", @line)."\n";
	}
	close OUT;
} #}}}

sub aggregate () { #{{{
	eval q{use XML::Feed};
	die $@ if $@;
	eval q{use HTML::Entities};
	die $@ if $@;

	foreach my $feed (values %feeds) {
		next unless $IkiWiki::config{rebuild} || 
			time - $feed-&gt;{lastupdate} &gt;= $feed-&gt;{updateinterval};
		$feed-&gt;{lastupdate}=time;
		$feed-&gt;{newposts}=0;
		$IkiWiki::forcerebuild{$feed-&gt;{sourcepage}}=1;

		IkiWiki::debug("checking feed ".$feed-&gt;{name}." ...");

		if (! length $feed-&gt;{feedurl}) {
			my @urls=XML::Feed-&gt;find_feeds($feed-&gt;{url});
			if (! @urls) {
				$feed-&gt;{message}="could not find feed at ".$feed-&gt;{feedurl};
				IkiWiki::debug($feed-&gt;{message});
				next;
			}
			$feed-&gt;{feedurl}=pop @urls;
		}
		my $f=eval{XML::Feed-&gt;parse(URI-&gt;new($feed-&gt;{feedurl}))};
		if ($@) {
			$feed-&gt;{message}="feed crashed XML::Feed! $@";
			IkiWiki::debug($feed-&gt;{message});
			next;
		}
		if (! $f) {
			$feed-&gt;{message}=XML::Feed-&gt;errstr;
			IkiWiki::debug($feed-&gt;{message});
			next;
		}

		foreach my $entry ($f-&gt;entries) {
			add_page(
				feed =&gt; $feed,
				title =&gt; defined $entry-&gt;title ? decode_entities($entry-&gt;title) : "untitled",
				link =&gt; $entry-&gt;link,
				content =&gt; $entry-&gt;content-&gt;body,
				guid =&gt; defined $entry-&gt;id ? $entry-&gt;id : time."_".$feed-&gt;name,
				ctime =&gt; $entry-&gt;issued ? ($entry-&gt;issued-&gt;epoch || time) : time,
			);
		}

		$feed-&gt;{message}="processed ok";
	}

	# TODO: expiry
} #}}}

sub add_page (@) { #{{{
	my %params=@_;
	
	my $feed=$params{feed};
	my $guid={};
	my $mtime;
	if (exists $guids{$params{guid}}) {
		# updating an existing post
		$guid=$guids{$params{guid}};
	}
	else {
		# new post
		$guid-&gt;{guid}=$params{guid};
		$guids{$params{guid}}=$guid;
		$mtime=$params{ctime};
		$feed-&gt;{numposts}++;
		$feed-&gt;{newposts}++;

		# assign it an unused page
		my $page=IkiWiki::titlepage($params{title});
		# escape slashes and periods in title so it doesn't specify
		# directory name or trigger ".." disallowing code.
		$page=~s!([/.])!"__".ord($1)."__"!eg;
		$page=$feed-&gt;{dir}."/".$page;
		$page=lc($page);
		($page)=$page=~/$IkiWiki::config{wiki_file_regexp}/;
		if (! defined $page || ! length $page) {
			$page=$feed-&gt;{dir}."/item";
		}
		my $c="";
		while (exists $IkiWiki::pagesources{$page.$c} ||
		       -e pagefile($page.$c)) {
			$c++
		}
		$guid-&gt;{page}=$page;
		IkiWiki::debug("creating new page $page");
	}
	$guid-&gt;{feed}=$feed-&gt;{name};
	
	# To write or not to write? Need to avoid writing unchanged pages
	# to avoid unneccessary rebuilding. The mtime from rss cannot be
	# trusted; let's use a digest.
	eval q{use Digest::MD5 'md5_hex'};
	require Encode;
	my $digest=md5_hex(Encode::encode_utf8($params{content}));
	return unless ! exists $guid-&gt;{md5} || $guid-&gt;{md5} ne $digest || $IkiWiki::config{rebuild};
	$guid-&gt;{md5}=$digest;

	# Create the page.
	my $template=IkiWiki::template("aggregatepost.tmpl", blind_cache =&gt; 1);
	$template-&gt;param(title =&gt; $params{title})
		if defined $params{title} &amp;&amp; length($params{title});
	$template-&gt;param(content =&gt; htmlescape(htmlabs($params{content}, $feed-&gt;{feedurl})));
	$template-&gt;param(name =&gt; $feed-&gt;{name});
	$template-&gt;param(url =&gt; $feed-&gt;{url});
	$template-&gt;param(permalink =&gt; urlabs($params{link}, $feed-&gt;{feedurl}))
		if defined $params{link};
	if (ref $feed-&gt;{tags}) {
		$template-&gt;param(tags =&gt; [map { tag =&gt; $_ }, @{$feed-&gt;{tags}}]);
	}
	IkiWiki::writefile(IkiWiki::htmlpage($guid-&gt;{page}), $IkiWiki::config{srcdir},
		$template-&gt;output);

	# Set the mtime, this lets the build process get the right creation
	# time on record for the new page.
	utime $mtime, $mtime, pagefile($guid-&gt;{page}) if defined $mtime;
} #}}}

sub htmlescape ($) { #{{{
	# escape accidental wikilinks and preprocessor stuff
	my $html=shift;
	$html=~s/(?&lt;!\\)\[\[/\\\[\[/g;
	return $html;
} #}}}

sub urlabs ($$) { #{{{
	my $url=shift;
	my $urlbase=shift;

	URI-&gt;new_abs($url, $urlbase)-&gt;as_string;
} #}}}

sub htmlabs ($$) { #{{{
	# Convert links in html from relative to absolute.
	# Note that this is a heuristic, which is not specified by the rss
	# spec and may not be right for all feeds. Also, see Debian
	# bug #XXXX TODO: get bug.
	my $html=shift;
	my $urlbase=shift;

	my $ret="";
	my $p = HTML::Parser-&gt;new(api_version =&gt; 3);
	$p-&gt;handler(default =&gt; sub { $ret.=join("", @_) }, "text");
	$p-&gt;handler(start =&gt; sub {
		my ($tagname, $pos, $text) = @_;
		if (ref $HTML::Tagset::linkElements{$tagname}) {
			while (4 &lt;= @$pos) {
				# use attribute sets from right to left
				# to avoid invalidating the offsets
				# when replacing the values
				my($k_offset, $k_len, $v_offset, $v_len) =
					splice(@$pos, -4);
				my $attrname = lc(substr($text, $k_offset, $k_len));
				next unless grep { $_ eq $attrname } @{$HTML::Tagset::linkElements{$tagname}};
				next unless $v_offset; # 0 v_offset means no value
				my $v = substr($text, $v_offset, $v_len);
				$v =~ s/^([\'\"])(.*)\1$/$2/;
				my $new_v=urlabs($v, $urlbase);
				$new_v =~ s/\"/&amp;quot;/g; # since we quote with ""
				substr($text, $v_offset, $v_len) = qq("$new_v");
			}
		}
		$ret.=$text;
	}, "tagname, tokenpos, text");
	$p-&gt;parse($html);
	$p-&gt;eof;

	return $ret;
} #}}}

sub remove_feeds () { #{{{
	my $page=shift;

	my %removed;
	foreach my $id (keys %feeds) {
		if ($feeds{$id}-&gt;{sourcepage} eq $page) {
			$feeds{$id}-&gt;{remove}=1;
			$removed{$id}=1;
		}
	}
} #}}}

sub pagefile ($) { #{{{
	my $page=shift;

	return "$IkiWiki::config{srcdir}/".IkiWiki::htmlpage($page);
} #}}}

1
</pre></body></html>