<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Licensed under GPL v2 or greater
# (c) 2007 Patrick Winnertz &lt;patrick.winnertz@skolelinux.org&gt;

package IkiWiki::Plugin::teximg;
use warnings;
use strict;
use Digest::MD5 qw(md5_hex);
use File::Temp qw(tempdir);
use HTML::Entities;
use IkiWiki 2.00;

sub import { #{{{
	hook(type =&gt; "preprocess", id =&gt; "teximg", call =&gt; \&amp;preprocess);
} #}}}

sub preprocess (@) { #{{{
	my %params = @_;
	
	my $height = $params{height};
	if (! defined $height || ! length $height) {
		$height = 12;
	}
	else {
		$height =~ s#(\d+)#$1#;
	}
	
	my $code = $params{code};
	if (! defined $code &amp;&amp; ! length $code) {
		return "[[teximg ".gettext("missing tex code"). "]]";
	}

	if (check($code)) {
		return create($code, check_height($height), \%params);
	}
	else {
		return "[[teximg ".gettext("code includes disallowed latex commands"). "]]";
	}
} #}}}

sub check_height ($) { #{{{
	# Since latex doesn't support unlimited scaling this function
	# returns the closest supported size.
	my $height =shift;

	my @allowed=(8,9,10,11,12,14,17,20);

	my $ret;
	my $fit;
	foreach my $val (@allowed) {
		my $f = abs($val - $height);
		if (! defined($fit) || $f &lt; $fit ) {
			$ret=$val;
			$fit=$f;
		}
	}
	return $ret;
} #}}}

sub create ($$$) { #{{{
	# This function calls the image generating function and returns
	# the &lt;img .. /&gt; for the generated image.
	my $code = shift;
	my $height = shift;
	my $params = shift;

	if (! defined($height) and not length($height) ) {
		$height = 12;
	}

	my $digest = md5_hex($code, $height);

	my $teximgdir = "/teximg";
	my $imglink = "$teximgdir/$digest.png";
	my $imglog = "$teximgdir/$digest.log";
	will_render($params-&gt;{destpage}, $imglink);
	will_render($params-&gt;{destpage}, $imglog);

	my $imgurl;
	my $logurl;
	if (! $params-&gt;{preview}) {
		$imgurl = urlto($imglink, $params-&gt;{destpage});
		$logurl = urlto($imglog, $params-&gt;{destpage});
	}
	else {
		$imgurl="$config{url}/$teximgdir/$digest.png";
		$logurl="$config{url}/$teximgdir/$digest.log";
	}
	
	if (-e "$config{destdir}/$imglink" ||
	    gen_image($code, $height, $digest, $teximgdir)) {
		return qq{&lt;img src="$imgurl" alt="}
			.(exists $params-&gt;{alt} ? $params-&gt;{alt} : encode_entities($code))
			.qq{" class="teximg" /&gt;};
	}
	else {
		return qq{[[teximg &lt;a href="$logurl"&gt;}.gettext("failed to generate image from code")."&lt;/a&gt;]]";
	}
} #}}}

sub gen_image ($$$$) { #{{{
	# Actually creates the image.
	my $code = shift;
	my $height = shift;
	my $digest = shift;
	my $imagedir = shift;

	#TODO This should move into the setup file.
	my $tex = '\documentclass['.$height.'pt]{scrartcl}';
	$tex .= '\usepackage[version=3]{mhchem}';
	$tex .= '\usepackage{amsmath}';
	$tex .= '\usepackage{amsfonts}';
	$tex .= '\usepackage{amssymb}';
	$tex .= '\pagestyle{empty}';
	$tex .= '\begin{document}';
	$tex .= '$$'.$code.'$$';
	$tex .= '\end{document}';

	my $tmp = eval { create_tmp_dir($digest) };
	if (! $@ &amp;&amp;
	    writefile("$digest.tex", $tmp, $tex) &amp;&amp;
	    system("cd $tmp; latex --interaction=nonstopmode $tmp/$digest.tex &gt; /dev/null") == 0 &amp;&amp;
	    system("dvips -E $tmp/$digest.dvi -o $tmp/$digest.ps 2&gt; $tmp/$digest.log") == 0 &amp;&amp;
	    # ensure destination directory exists
	    writefile("$imagedir/$digest.png", $config{destdir}, "") &amp;&amp;
	    system("convert -density 120  -trim -transparent \"#FFFFFF\" $tmp/$digest.ps $config{destdir}/$imagedir/$digest.png &gt; $tmp/$digest.log") == 0) {
		return 1;
	}
	else {
		# store failure log
		my $log;
		{
			open(my $f, '&lt;', "$tmp/$digest.log");
			local $/=undef;
			$log = &lt;$f&gt;;
			close($f);
		}
		writefile("$digest.log", "$config{destdir}/$imagedir", $log);

		return 0;
	}
} #}}}

sub create_tmp_dir ($) { #{{{
	# Create a temp directory, it will be removed when ikiwiki exits.
	my $base = shift;

	my $template = $base.".XXXXXXXXXX";
	my $tmpdir = tempdir($template, TMPDIR =&gt; 1, CLEANUP =&gt; 1);
	return $tmpdir;
} #}}}

sub check ($) { #{{{
	# Check if the code is ok
	my $code = shift;

	my @badthings = (
		qr/\$\$/,
		qr/\\include/,
		qr/\\includegraphic/,
		qr/\\usepackage/,
		qr/\\newcommand/, 
		qr/\\renewcommand/,
		qr/\\def/,
		qr/\\input/,
		qr/\\open/,
		qr/\\loop/,
		qr/\\errorstopmode/,
		qr/\\scrollmode/,
		qr/\\batchmode/,
		qr/\\read/,
		qr/\\write/,
	);
	
	foreach my $thing (@badthings) {
		if ($code =~ m/$thing/ ) {
			return 0;
		}
	}
	return 1;
} #}}}

1
</pre></body></html>