<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::remove;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "remove", call =&gt; \&amp;getsetup);
	hook(type =&gt; "formbuilder_setup", id =&gt; "remove", call =&gt; \&amp;formbuilder_setup);
	hook(type =&gt; "formbuilder", id =&gt; "remove", call =&gt; \&amp;formbuilder);
	hook(type =&gt; "sessioncgi", id =&gt; "remove", call =&gt; \&amp;sessioncgi);

}

sub getsetup () {
	return 
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; 0,
			section =&gt; "web",
		},
}

sub allowed_dirs {
	return grep { defined $_ } (
		$config{srcdir},
		$IkiWiki::Plugin::transient::transientdir,
	);
}

sub check_canremove ($$$) {
	my $page=shift;
	my $q=shift;
	my $session=shift;

	# Must be a known source file.
	if (! exists $pagesources{$page}) {
		error(sprintf(gettext("%s does not exist"),
			htmllink("", "", $page, noimageinline =&gt; 1)));
	}

	# Must exist in either the srcdir or a suitable underlay (e.g.
	# transient underlay), and be a regular file.
	my $file=$pagesources{$page};
	my $dir;

	foreach my $srcdir (allowed_dirs()) {
		if (-e "$srcdir/$file") {
			$dir = $srcdir;
			last;
		}
	}

	if (! defined $dir) {
		error(sprintf(gettext("%s is not in the srcdir, so it cannot be deleted"), $file));
	}
	elsif (-l "$dir/$file" &amp;&amp; ! -f _) {
		error(sprintf(gettext("%s is not a file"), $file));
	}
	
	# If a user can't upload an attachment, don't let them delete it.
	# This is sorta overkill, but better safe than sorry.
	if (! defined pagetype($pagesources{$page})) {
		if (IkiWiki::Plugin::attachment-&gt;can("check_canattach")) {
			IkiWiki::Plugin::attachment::check_canattach($session, $page, "$dir/$file");
		}
		else {
			error("removal of attachments is not allowed");
		}
	}

	my $canremove;
	IkiWiki::run_hooks(canremove =&gt; sub {
		return if defined $canremove;
		my $ret=shift-&gt;(page =&gt; $page, cgi =&gt; $q, session =&gt; $session);
		if (defined $ret) {
			if ($ret eq "") {
				$canremove=1;
			}
			elsif (ref $ret eq 'CODE') {
				$ret-&gt;();
				$canremove=0;
			}
			elsif (defined $ret) {
				error($ret);
				$canremove=0;
			}
		}
	});
	return defined $canremove ? $canremove : 1;
}

sub formbuilder_setup (@) {
	my %params=@_;
	my $form=$params{form};
	my $q=$params{cgi};

	if (defined $form-&gt;field("do") &amp;&amp; ($form-&gt;field("do") eq "edit" ||
	    $form-&gt;field("do") eq "create")) {
		# Removal button for the page, and also for attachments.
		push @{$params{buttons}}, "Remove" if $form-&gt;field("do") eq "edit";
		$form-&gt;tmpl_param("field-remove" =&gt; '&lt;input name="_submit" type="submit" value="Remove Attachments" /&gt;');
	}
}

sub confirmation_form ($$) {
	my $q=shift;
	my $session=shift;

	eval q{use CGI::FormBuilder};
	error($@) if $@;
	my $f = CGI::FormBuilder-&gt;new(
		name =&gt; "remove",
		header =&gt; 0,
		charset =&gt; "utf-8",
		method =&gt; 'POST',
		javascript =&gt; 0,
		params =&gt; $q,
		action =&gt; IkiWiki::cgiurl(),
		stylesheet =&gt; 1,
		fields =&gt; [qw{do page}],
	);
	
	$f-&gt;field(name =&gt; "sid", type =&gt; "hidden", value =&gt; $session-&gt;id,
		force =&gt; 1);
	$f-&gt;field(name =&gt; "do", type =&gt; "hidden", value =&gt; "remove", force =&gt; 1);

	return $f, ["Remove", "Cancel"];
}

sub removal_confirm ($$@) {
	my $q=shift;
	my $session=shift;
	my $attachment=shift;
	my @pages=@_;
		
	# Special case for unsaved attachments.
	foreach my $page (@pages) {
		if ($attachment &amp;&amp; IkiWiki::Plugin::attachment-&gt;can("is_held_attachment")) {
			my $f=IkiWiki::Plugin::attachment::is_held_attachment($page);
			if (defined $f) {
				require IkiWiki::Render;
				IkiWiki::prune($f, "$config{wikistatedir}/attachments");
			}
		}
	}
	@pages=grep { exists $pagesources{$_} } @pages;
	return unless @pages;

	foreach my $page (@pages) {
		IkiWiki::check_canedit($page, $q, $session);
		check_canremove($page, $q, $session);
	}

	# Save current form state to allow returning to it later
	# without losing any edits.
	# (But don't save what button was submitted, to avoid
	# looping back to here.)
	# Note: "_submit" is CGI::FormBuilder internals.
	$q-&gt;param(-name =&gt; "_submit", -value =&gt; "");
	$session-&gt;param(postremove =&gt; scalar $q-&gt;Vars);
	IkiWiki::cgi_savesession($session);
	
	my ($f, $buttons)=confirmation_form($q, $session);
	$f-&gt;title(sprintf(gettext("confirm removal of %s"),
		join(", ", map { pagetitle($_) } @pages)));
	$f-&gt;field(name =&gt; "page", type =&gt; "hidden", value =&gt; \@pages, force =&gt; 1);
	if (defined $attachment) {
		$f-&gt;field(name =&gt; "attachment", type =&gt; "hidden",
			value =&gt; $attachment, force =&gt; 1);
	}

	IkiWiki::showform($f, $buttons, $session, $q);
	exit 0;
}

sub postremove ($) {
	my $session=shift;

	# Load saved form state and return to edit form.
	my $postremove=CGI-&gt;new($session-&gt;param("postremove"));
	$session-&gt;clear("postremove");
	IkiWiki::cgi_savesession($session);
	IkiWiki::cgi($postremove, $session);
}

sub formbuilder (@) {
	my %params=@_;
	my $form=$params{form};

	if (defined $form-&gt;field("do") &amp;&amp; ($form-&gt;field("do") eq "edit" ||
	    $form-&gt;field("do") eq "create")) {
		my $q=$params{cgi};
		my $session=$params{session};

		if ($form-&gt;submitted eq "Remove" &amp;&amp; $form-&gt;field("do") eq "edit") {
			removal_confirm($q, $session, 0, $form-&gt;field("page"));
		}
		elsif ($form-&gt;submitted eq "Remove Attachments") {
			my @selected=map { Encode::decode_utf8($_) } $q-&gt;param("attachment_select");
			if (! @selected) {
				error(gettext("Please select the attachments to remove."));
			}
			removal_confirm($q, $session, 1, @selected);
		}
	}
}

sub sessioncgi ($$) {
	my $q=shift;

	if ($q-&gt;param("do") eq 'remove') {
		my $session=shift;
		my ($form, $buttons)=confirmation_form($q, $session);
		IkiWiki::decode_form_utf8($form);

		if ($form-&gt;submitted eq 'Cancel') {
			postremove($session);
		}
		elsif ($form-&gt;submitted eq 'Remove' &amp;&amp; $form-&gt;validate) {
			IkiWiki::checksessionexpiry($q, $session, $q-&gt;param('sid'));

			my @pages=$form-&gt;field("page");
			
			# Validate removal by checking that the page exists,
			# and that the user is allowed to edit(/remove) it.
			my @files;
			foreach my $page (@pages) {
				IkiWiki::check_canedit($page, $q, $session);
				check_canremove($page, $q, $session);
				
				# This untaint is safe because of the
				# checks performed above, which verify the
				# page is a normal file, etc.
				push @files, IkiWiki::possibly_foolish_untaint($pagesources{$page});
			}

			# Do removal, and update the wiki.
			require IkiWiki::Render;
			if ($config{rcs}) {
				IkiWiki::disable_commit_hook();
			}
			my $rcs_removed = 1;

			foreach my $file (@files) {
				foreach my $srcdir (allowed_dirs()) {
					if (-e "$srcdir/$file") {
						if ($srcdir eq $config{srcdir} &amp;&amp; $config{rcs}) {
							IkiWiki::rcs_remove($file);
							$rcs_removed = 1;
						}
						else {
							IkiWiki::prune("$srcdir/$file", $srcdir);
						}
					}
				}
			}

			if ($config{rcs}) {
				if ($rcs_removed) {
					IkiWiki::rcs_commit_staged(
						message =&gt; gettext("removed"),
						session =&gt; $session,
					);
				}
				IkiWiki::enable_commit_hook();
				IkiWiki::rcs_update();
			}

			IkiWiki::refresh();
			IkiWiki::saveindex();

			if ($q-&gt;param("attachment")) {
				# Attachments were deleted, so redirect
				# back to the edit form.
				postremove($session);
			}
			else {
				# The page is gone, so redirect to parent
				# of the page.
				my $parent=IkiWiki::dirname($pages[0]);
				if (! exists $pagesources{$parent}) {
					$parent="index";
				}
				IkiWiki::redirect($q, urlto($parent));
			}
		}
		else {
			removal_confirm($q, $session, 0, $form-&gt;field("page"));
		}

		exit 0;
	}
}

1
</pre></body></html>