<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::svn;

use warnings;
use strict;
use IkiWiki;
use POSIX qw(setlocale LC_CTYPE);

sub import {
	hook(type =&gt; "checkconfig", id =&gt; "svn", call =&gt; \&amp;checkconfig);
	hook(type =&gt; "getsetup", id =&gt; "svn", call =&gt; \&amp;getsetup);
	hook(type =&gt; "rcs", id =&gt; "rcs_update", call =&gt; \&amp;rcs_update);
	hook(type =&gt; "rcs", id =&gt; "rcs_prepedit", call =&gt; \&amp;rcs_prepedit);
	hook(type =&gt; "rcs", id =&gt; "rcs_commit", call =&gt; \&amp;rcs_commit);
	hook(type =&gt; "rcs", id =&gt; "rcs_commit_staged", call =&gt; \&amp;rcs_commit_staged);
	hook(type =&gt; "rcs", id =&gt; "rcs_add", call =&gt; \&amp;rcs_add);
	hook(type =&gt; "rcs", id =&gt; "rcs_remove", call =&gt; \&amp;rcs_remove);
	hook(type =&gt; "rcs", id =&gt; "rcs_rename", call =&gt; \&amp;rcs_rename);
	hook(type =&gt; "rcs", id =&gt; "rcs_recentchanges", call =&gt; \&amp;rcs_recentchanges);
	hook(type =&gt; "rcs", id =&gt; "rcs_diff", call =&gt; \&amp;rcs_diff);
	hook(type =&gt; "rcs", id =&gt; "rcs_getctime", call =&gt; \&amp;rcs_getctime);
	hook(type =&gt; "rcs", id =&gt; "rcs_getmtime", call =&gt; \&amp;rcs_getmtime);
}

sub checkconfig () {
	if (! defined $config{svnpath}) {
		$config{svnpath}="trunk";
	}
	if (exists $config{svnpath}) {
		# code depends on the path not having extraneous slashes
		$config{svnpath}=~tr#/#/#s;
		$config{svnpath}=~s/\/$//;
		$config{svnpath}=~s/^\///;
	}
	if (defined $config{svn_wrapper} &amp;&amp; length $config{svn_wrapper}) {
		push @{$config{wrappers}}, {
			wrapper =&gt; $config{svn_wrapper},
			wrappermode =&gt; (defined $config{svn_wrappermode} ? $config{svn_wrappermode} : "04755"),
		};
	}
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 0, # rcs plugin
			rebuild =&gt; undef,
			section =&gt; "rcs",
		},
		svnrepo =&gt; {
			type =&gt; "string",
			example =&gt; "/svn/wiki",
			description =&gt; "subversion repository location",
			safe =&gt; 0, # path
			rebuild =&gt; 0,
		},
		svnpath =&gt; {
			type =&gt; "string",
			example =&gt; "trunk",
			description =&gt; "path inside repository where the wiki is located",
			safe =&gt; 0, # paranoia
			rebuild =&gt; 0,
		},
		svn_wrapper =&gt; {
			type =&gt; "string",
			example =&gt; "/svn/wikirepo/hooks/post-commit",
			description =&gt; "svn post-commit hook to generate",
			safe =&gt; 0, # file
			rebuild =&gt; 0,
		},
		svn_wrappermode =&gt; {
			type =&gt; "string",
			example =&gt; '04755',
			description =&gt; "mode for svn_wrapper (can safely be made suid)",
			safe =&gt; 0,
			rebuild =&gt; 0,
		},
		historyurl =&gt; {
			type =&gt; "string",
			example =&gt; "http://svn.example.org/trunk/[[file]]",
			description =&gt; "viewvc url to show file history ([[file]] substituted)",
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
		diffurl =&gt; {
			type =&gt; "string",
			example =&gt; "http://svn.example.org/trunk/[[file]]?root=wiki&amp;amp;r1=[[r1]]&amp;amp;r2=[[r2]]",
			description =&gt; "viewvc url to show a diff ([[file]], [[r1]], and [[r2]] substituted)",
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
}

# svn needs LC_CTYPE set to a UTF-8 locale, so try to find one. Any will do.
sub find_lc_ctype() {
	my $current = setlocale(LC_CTYPE());
	return $current if $current =~ m/UTF-?8$/i;

	# Make some obvious attempts to avoid calling `locale -a`
	foreach my $locale ("$current.UTF-8", "en_US.UTF-8", "en_GB.UTF-8") {
		return $locale if setlocale(LC_CTYPE(), $locale);
	}

	# Try to get all available locales and pick the first UTF-8 one found.
	if (my @locale = grep(/UTF-?8$/i, `locale -a`)) {
		chomp @locale;
		return $locale[0] if setlocale(LC_CTYPE(), $locale[0]);
	}

	# fallback to the current locale
	return $current;
}
$ENV{LC_CTYPE} = $ENV{LC_CTYPE} || find_lc_ctype();

sub svn_info ($$) {
	my $field=shift;
	my $file=shift;

	my $info=`LANG=C svn info $file`;
	my ($ret)=$info=~/^$field: (.*)$/m;
	return $ret;
}

sub rcs_update () {
	if (-d "$config{srcdir}/.svn") {
		if (system("svn", "update", "--quiet", $config{srcdir}) != 0) {
			warn("svn update failed\n");
		}
	}
}

sub rcs_prepedit ($) {
	# Prepares to edit a file under revision control. Returns a token
	# that must be passed into rcs_commit when the file is ready
	# for committing.
	# The file is relative to the srcdir.
	my $file=shift;
	
	if (-d "$config{srcdir}/.svn") {
		# For subversion, return the revision of the file when
		# editing begins.
		my $rev=svn_info("Revision", "$config{srcdir}/$file");
		return defined $rev ? $rev : "";
	}
}

sub commitmessage (@) {
	my %params=@_;

	if (defined $params{session}) {
		if (defined $params{session}-&gt;param("name")) {
			return "web commit by ".
				$params{session}-&gt;param("name").
				(length $params{message} ? ": $params{message}" : "");
		}
		elsif (defined $params{session}-&gt;remote_addr()) {
			return "web commit from ".
				$params{session}-&gt;remote_addr().
				(length $params{message} ? ": $params{message}" : "");
		}
	}
	return $params{message};
}

sub rcs_commit (@) {
	# Tries to commit the page; returns undef on _success_ and
	# a version of the page with the rcs's conflict markers on failure.
	# The file is relative to the srcdir.
	my %params=@_;

	if (-d "$config{srcdir}/.svn") {
		# Check to see if the page has been changed by someone
		# else since rcs_prepedit was called.
		my ($oldrev)=$params{token}=~/^([0-9]+)$/; # untaint
		my $rev=svn_info("Revision", "$config{srcdir}/$params{file}");
		if (defined $rev &amp;&amp; defined $oldrev &amp;&amp; $rev != $oldrev) {
			# Merge their changes into the file that we've
			# changed.
			if (system("svn", "merge", "--quiet", "-r$oldrev:$rev",
			           "$config{srcdir}/$params{file}", "$config{srcdir}/$params{file}") != 0) {
				warn("svn merge -r$oldrev:$rev failed\n");
			}
		}

		if (system("svn", "commit", "--quiet", 
		           "--encoding", "UTF-8", "-m",
		           IkiWiki::possibly_foolish_untaint(commitmessage(%params)),
			   $config{srcdir}) != 0) {
			my $conflict=readfile("$config{srcdir}/$params{file}");
			if (system("svn", "revert", "--quiet", "$config{srcdir}/$params{file}") != 0) {
				warn("svn revert failed\n");
			}
			return $conflict;
		}
	}
	return undef # success
}

sub rcs_commit_staged (@) {
	# Commits all staged changes. Changes can be staged using rcs_add,
	# rcs_remove, and rcs_rename.
	my %params=@_;
	
	if (system("svn", "commit", "--quiet",
	           "--encoding", "UTF-8", "-m",
	           IkiWiki::possibly_foolish_untaint(commitmessage(%params)),
		   $config{srcdir}) != 0) {
		warn("svn commit failed\n");
		return 1; # failure	
	}
	return undef # success
}

sub rcs_add ($) {
	# filename is relative to the root of the srcdir
	my $file=shift;

	if (-d "$config{srcdir}/.svn") {
		my $parent=IkiWiki::dirname($file);
		while (! -d "$config{srcdir}/$parent/.svn") {
			$file=$parent;
			$parent=IkiWiki::dirname($file);
		}
		
		if (system("svn", "add", "--quiet", "$config{srcdir}/$file") != 0) {
			warn("svn add failed\n");
		}
	}
}

sub rcs_remove ($) {
	# filename is relative to the root of the srcdir
	my $file=shift;

	if (-d "$config{srcdir}/.svn") {
		if (system("svn", "rm", "--force", "--quiet", "$config{srcdir}/$file") != 0) {
			warn("svn rm failed\n");
		}
	}
}

sub rcs_rename ($$) {
	# filenames relative to the root of the srcdir
	my ($src, $dest)=@_;
	
	if (-d "$config{srcdir}/.svn") {
		# Add parent directory for $dest
		my $parent=IkiWiki::dirname($dest);
		if (! -d "$config{srcdir}/$parent/.svn") {
			while (! -d "$config{srcdir}/$parent/.svn") {
				$parent=IkiWiki::dirname($dest);
			}
			if (system("svn", "add", "--quiet", "$config{srcdir}/$parent") != 0) {
				warn("svn add $parent failed\n");
			}
		}

		if (system("svn", "mv", "--force", "--quiet", 
		    "$config{srcdir}/$src", "$config{srcdir}/$dest") != 0) {
			warn("svn rename failed\n");
		}
	}
}

sub rcs_recentchanges ($) {
	my $num=shift;
	my @ret;
	
	return unless -d "$config{srcdir}/.svn";

	eval q{
		use Date::Parse;
		use XML::SAX;
		use XML::Simple;
	};
	error($@) if $@;

	# avoid using XML::SAX::PurePerl, it's buggy with UTF-8 data
	my @parsers = map { ${$_}{Name} } @{XML::SAX-&gt;parsers()};
	do {
		$XML::Simple::PREFERRED_PARSER = pop @parsers;
	} until $XML::Simple::PREFERRED_PARSER ne 'XML::SAX::PurePerl';

	# --limit is only supported on Subversion 1.2.0+
	my $svn_version=`svn --version -q`;
	my $svn_limit='';
	$svn_limit="--limit $num"
		if $svn_version =~ /\d\.(\d)\.\d/ &amp;&amp; $1 &gt;= 2;

	my $svn_url=svn_info("URL", $config{srcdir});
	my $xml = XMLin(scalar `svn $svn_limit --xml -v log '$svn_url'`,
		ForceArray =&gt; [ 'logentry', 'path' ],
		GroupTags =&gt; { paths =&gt; 'path' },
		KeyAttr =&gt; { path =&gt; 'content' },
	);
	foreach my $logentry (@{$xml-&gt;{logentry}}) {
		my (@pages, @message);

		my $rev = $logentry-&gt;{revision};
		my $user = $logentry-&gt;{author};

		my $when=str2time($logentry-&gt;{date}, 'UTC');

		foreach my $msgline (split(/\n/, $logentry-&gt;{msg})) {
			push @message, { line =&gt; $msgline };
		}

		my $committype="web";
		if (defined $message[0] &amp;&amp;
		    $message[0]-&gt;{line}=~/$config{web_commit_regexp}/) {
			$user=defined $2 ? "$2" : "$3";
			$message[0]-&gt;{line}=$4;
		}
		else {
			$committype="svn";
		}

		foreach my $file (keys %{$logentry-&gt;{paths}}) {
			if (length $config{svnpath}) {
				next unless $file=~/^\/\Q$config{svnpath}\E\/([^ ]+)(?:$|\s)/;
				$file=$1;
			}

			my $diffurl=defined $config{diffurl} ? $config{diffurl} : "";
			$diffurl=~s/\[\[file\]\]/$file/g;
			$diffurl=~s/\[\[r1\]\]/$rev - 1/eg;
			$diffurl=~s/\[\[r2\]\]/$rev/g;

			push @pages, {
				page =&gt; pagename($file),
				diffurl =&gt; $diffurl,
			} if length $file;
		}
		push @ret, {
			rev =&gt; $rev,
			user =&gt; $user,
			committype =&gt; $committype,
			when =&gt; $when,
			message =&gt; [@message],
			pages =&gt; [@pages],
		} if @pages;
		return @ret if @ret &gt;= $num;
	}

	return @ret;
}

sub rcs_diff ($) {
	my $rev=IkiWiki::possibly_foolish_untaint(int(shift));
	return `svnlook diff $config{svnrepo} -r$rev --no-diff-deleted`;
}

{

my ($lastfile, $lastmtime, $lastctime);

sub findtimes ($) {
	my $file=shift;

	if (defined $lastfile &amp;&amp; $lastfile eq $file) {
		return $lastmtime, $lastctime;
	}
	$lastfile=$file;

	my $svn_log_infoline=qr/^r\d+\s+\|\s+[^\s]+\s+\|\s+(\d+-\d+-\d+\s+\d+:\d+:\d+\s+[-+]?\d+).*/;
		
	my $child = open(SVNLOG, "-|");
	if (! $child) {
		exec("svn", "log", "$config{srcdir}/$file") || error("svn log failed to run");
	}

	my ($cdate, $mdate);
	while (&lt;SVNLOG&gt;) {
		if (/$svn_log_infoline/) {
			$cdate=$1;
			$mdate=$1 unless defined $mdate;
	    	}
	}
	close SVNLOG || error "svn log exited $?";

	if (! defined $cdate) {
		error "failed to parse svn log for $file";
	}
		
	eval q{use Date::Parse};
	error($@) if $@;
	
	$lastctime=str2time($cdate);
	$lastmtime=str2time($mdate);
	return $lastmtime, $lastctime;
}

}

sub rcs_getctime ($) {
	my $file=shift;

	return (findtimes($file))[1];
}

sub rcs_getmtime ($) {
	my $file=shift;

	return (findtimes($file))[0];
}

1
</pre></body></html>