<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::mercurial;

use warnings;
use strict;
use IkiWiki;
use Encode;
use URI::Escape q{uri_escape_utf8};
use open qw{:utf8 :std};

sub import {
	hook(type =&gt; "checkconfig", id =&gt; "mercurial", call =&gt; \&amp;checkconfig);
	hook(type =&gt; "getsetup", id =&gt; "mercurial", call =&gt; \&amp;getsetup);
	hook(type =&gt; "rcs", id =&gt; "rcs_update", call =&gt; \&amp;rcs_update);
	hook(type =&gt; "rcs", id =&gt; "rcs_prepedit", call =&gt; \&amp;rcs_prepedit);
	hook(type =&gt; "rcs", id =&gt; "rcs_commit", call =&gt; \&amp;rcs_commit);
	hook(type =&gt; "rcs", id =&gt; "rcs_commit_staged", call =&gt; \&amp;rcs_commit_staged);
	hook(type =&gt; "rcs", id =&gt; "rcs_add", call =&gt; \&amp;rcs_add);
	hook(type =&gt; "rcs", id =&gt; "rcs_remove", call =&gt; \&amp;rcs_remove);
	hook(type =&gt; "rcs", id =&gt; "rcs_rename", call =&gt; \&amp;rcs_rename);
	hook(type =&gt; "rcs", id =&gt; "rcs_recentchanges", call =&gt; \&amp;rcs_recentchanges);
	hook(type =&gt; "rcs", id =&gt; "rcs_diff", call =&gt; \&amp;rcs_diff);
	hook(type =&gt; "rcs", id =&gt; "rcs_getctime", call =&gt; \&amp;rcs_getctime);
	hook(type =&gt; "rcs", id =&gt; "rcs_getmtime", call =&gt; \&amp;rcs_getmtime);
}

sub checkconfig () {
	if (exists $config{mercurial_wrapper} &amp;&amp; length $config{mercurial_wrapper}) {
		push @{$config{wrappers}}, {
			wrapper =&gt; $config{mercurial_wrapper},
			wrappermode =&gt; (defined $config{mercurial_wrappermode} ? $config{mercurial_wrappermode} : "06755"),
		};
	}
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 0, # rcs plugin
			rebuild =&gt; undef,
			section =&gt; "rcs",
		},
		mercurial_wrapper =&gt; {
			type =&gt; "string",
			#example =&gt; # FIXME add example
			description =&gt; "mercurial post-commit hook to generate",
			safe =&gt; 0, # file
			rebuild =&gt; 0,
		},
		mercurial_wrappermode =&gt; {
			type =&gt; "string",
			example =&gt; '06755',
			description =&gt; "mode for mercurial_wrapper (can safely be made suid)",
			safe =&gt; 0,
			rebuild =&gt; 0,
		},
		historyurl =&gt; {
			type =&gt; "string",
			example =&gt; "http://example.com:8000/log/tip/[[file]]",
			description =&gt; "url to hg serve'd repository, to show file history ([[file]] substituted)",
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
		diffurl =&gt; {
			type =&gt; "string",
			example =&gt; "http://localhost:8000/?fd=[[r2]];file=[[file]]",
			description =&gt; "url to hg serve'd repository, to show diff ([[file]] and [[r2]] substituted)",
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
}

sub safe_hg (&amp;@) {
	# Start a child process safely without resorting to /bin/sh.
	# Returns command output (in list content) or success state
	# (in scalar context), or runs the specified data handler.

	my ($error_handler, $data_handler, @cmdline) = @_;

	my $pid = open my $OUT, "-|";

	error("Cannot fork: $!") if !defined $pid;

	if (!$pid) {
		# In child.
		# hg commands want to be in wc.
		chdir $config{srcdir}
		    or error("cannot chdir to $config{srcdir}: $!");

		exec @cmdline or error("Cannot exec '@cmdline': $!");
	}
	# In parent.

	my @lines;
	while (&lt;$OUT&gt;) {
		chomp;

		if (! defined $data_handler) {
			push @lines, $_;
		}
		else {
			last unless $data_handler-&gt;($_);
		}
	}

	close $OUT;

	$error_handler-&gt;("'@cmdline' failed: $!") if $? &amp;&amp; $error_handler;

	return wantarray ? @lines : ($? == 0);
}
# Convenient wrappers.
sub run_or_die ($@) { safe_hg(\&amp;error, undef, @_) }
sub run_or_cry ($@) { safe_hg(sub { warn @_ }, undef, @_) }
sub run_or_non ($@) { safe_hg(undef, undef, @_) }

sub mercurial_log ($) {
	my $out = shift;
	my @infos;

	while (&lt;$out&gt;) {
		my $line = $_;
		my ($key, $value);

		if (/^description:/) {
			$key = "description";
			$value = "";

			# slurp everything as the description text 
			# until the next changeset
			while (&lt;$out&gt;) {
				if (/^changeset: /) {
					$line = $_;
					last;
				}

				$value .= $_;
			}

			local $/ = "";
			chomp $value;
			$infos[$#infos]{$key} = $value;
		}

		chomp $line;
	        ($key, $value) = split /: +/, $line, 2;

		if ($key eq "changeset") {
			push @infos, {};

			# remove the revision index, which is strictly 
			# local to the repository
			$value =~ s/^\d+://;
		}

		$infos[$#infos]{$key} = $value;
	}
	close $out;

	return @infos;
}

sub rcs_update () {
	run_or_cry('hg', '-q', 'update');
}

sub rcs_prepedit ($) {
	return "";
}

sub rcs_commit (@) {
	my %params=@_;

	return rcs_commit_helper(@_);
}

sub rcs_commit_helper (@) {
	my %params=@_;

	my %env=%ENV;
	$ENV{HGENCODING} = 'utf-8';

	my $user="Anonymous";
	if (defined $params{session}) {
		if (defined $params{session}-&gt;param("name")) {
			$user = $params{session}-&gt;param("name");
		}
		elsif (defined $params{session}-&gt;remote_addr()) {
			$user = $params{session}-&gt;remote_addr();
		}

		my $nickname=$user;
		if (defined $params{session}-&gt;param("nickname")) {
			$nickname=encode_utf8($params{session}-&gt;param("nickname"));
			$nickname=~s/\s+/_/g;
			$nickname=~s/[^-_0-9[:alnum:]]+//g;
		}
		$ENV{HGUSER} = encode_utf8($user . ' &lt;' . $nickname . '@web&gt;');
	}

	if (! length $params{message}) {
		$params{message} = "no message given";
	}

	$params{message} = IkiWiki::possibly_foolish_untaint($params{message});

	my @opts;

	if (exists $params{file}) {
		push @opts, '--', $params{file};
	}
	# hg commit returns non-zero if nothing really changed.
	# So we should ignore its exit status (hence run_or_non).
	run_or_non('hg', 'commit', '-m', $params{message}, '-q', @opts);

	%ENV=%env;
	return undef; # success
}

sub rcs_commit_staged (@) {
	# Commits all staged changes. Changes can be staged using rcs_add,
	# rcs_remove, and rcs_rename.
	return rcs_commit_helper(@_);
}

sub rcs_add ($) {
	my ($file) = @_;

	run_or_cry('hg', 'add', $file);
}

sub rcs_remove ($) {
	# Remove file from archive.
	my ($file) = @_;

	run_or_cry('hg', 'remove', '-f', $file);
}

sub rcs_rename ($$) {
	my ($src, $dest) = @_;

	run_or_cry('hg', 'rename', '-f', $src, $dest);
}

sub rcs_recentchanges ($) {
	my ($num) = @_;

	my %env=%ENV;
	$ENV{HGENCODING} = 'utf-8';

	my @cmdline = ("hg", "-R", $config{srcdir}, "log", "-v", "-l", $num,
		"--style", "default");
	open (my $out, "@cmdline |");

	eval q{use Date::Parse};
	error($@) if $@;

	my @ret;
	foreach my $info (mercurial_log($out)) {
		my @pages = ();
		my @message = ();

		foreach my $msgline (split(/\n/, $info-&gt;{description})) {
			push @message, { line =&gt; $msgline };
		}

		foreach my $file (split / /,$info-&gt;{files}) {
			my $diffurl = defined $config{diffurl} ? $config{'diffurl'} : "";
			my $efile = uri_escape_utf8($file);
			$diffurl =~ s/\[\[file\]\]/$efile/go;
			$diffurl =~ s/\[\[r2\]\]/$info-&gt;{changeset}/go;

			push @pages, {
				page =&gt; pagename($file),
				diffurl =&gt; $diffurl,
			};
		}

		#"user &lt;email@domain.net&gt;": parse out "user".
		my $user = $info-&gt;{"user"};
		$user =~ s/\s*&lt;.*&gt;\s*$//;
		$user =~ s/^\s*//;

		#"user &lt;nickname@web&gt;": if "@web" hits, set $web_commit=true.
		my $web_commit = ($info-&gt;{'user'} =~ /\@web&gt;/);

		#"user &lt;nickname@web&gt;": if user is a URL (hits "://") and "@web"
		#was present, parse out nick.
		my $nickname;
		if ($user =~ /:\/\// &amp;&amp; $web_commit) {
			$nickname = $info-&gt;{'user'};
			$nickname =~ s/^[^&lt;]*&lt;([^\@]+)\@web&gt;\s*$/$1/;
		}

		push @ret, {
			rev        =&gt; $info-&gt;{"changeset"},
			user       =&gt; $user,
			nickname   =&gt; $nickname,
			committype =&gt; $web_commit ? "web" : "hg",
			when       =&gt; str2time($info-&gt;{"date"}),
			message    =&gt; [@message],
			pages      =&gt; [@pages],
		};
	}

	%ENV=%env;

	return @ret;
}

sub rcs_diff ($;$) {
	my $rev=shift;
	my $maxlines=shift;
	my @lines;
	my $addlines=sub {
		my $line=shift;
		return if defined $maxlines &amp;&amp; @lines == $maxlines;
		push @lines, $line."\n"
			if (@lines || $line=~/^diff --git/);
		return 1;
	};
	safe_hg(undef, $addlines, "hg", "diff", "-c", $rev, "-g");
	if (wantarray) {
		return @lines;
	}
	else {
		return join("", @lines);
	}
}

{
my %time_cache;

sub findtimes ($$) {
	my $file=shift;
	my $id=shift; # 0 = mtime ; 1 = ctime

	if (! keys %time_cache) {
		my $date;

		# It doesn't seem possible to specify the format wanted for the
		# changelog (same format as is generated in git.pm:findtimes(),
		# though the date differs slightly) without using a style
		# _file_. There is a "hg log" switch "--template" to directly
		# control simple output formatting, but in this case, the
		# {file} directive must be redefined, which can only be done
		# with "--style".
		#
		# If {file} is not redefined, all files are output on a single
		# line separated with a space. It is not possible to conclude
		# if the space is part of a filename or just a separator, and
		# thus impossible to use in this case.
		# 
		# Some output filters are available in hg, but they are not fit
		# for this cause (and would slow down the process
		# unnecessarily).
		
		eval q{use File::Temp};
		error $@ if $@;
		my ($tmpl_fh, $tmpl_filename) = File::Temp::tempfile(UNLINK =&gt; 1);
		
		print $tmpl_fh 'changeset = "{date}\\n{files}\\n"' . "\n";
		print $tmpl_fh 'file = "{file}\\n"' . "\n";
		
		foreach my $line (run_or_die('hg', 'log', '--style', $tmpl_filename)) {
			if (! defined $date &amp;&amp; $line =~ /^(\d+)/) {
				$date=$1;
			}
			elsif (! length $line) {
				$date=undef;
			}
			else {
				my $f=$line;

				if (! $time_cache{$f}) {
					$time_cache{$f}[0]=$date; # mtime
				}
				$time_cache{$f}[1]=$date; # ctime
			}
		}
	}

	return exists $time_cache{$file} ? $time_cache{$file}[$id] : 0;
}

}

sub rcs_getctime ($) {
	my $file = shift;

	return findtimes($file, 1);
}

sub rcs_getmtime ($) {
	my $file = shift;

	return findtimes($file, 0);
}

1
</pre></body></html>