<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::conditional;

use warnings;
use strict;
use IkiWiki 3.00;
use UNIVERSAL;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "conditional", call =&gt; \&amp;getsetup);
	hook(type =&gt; "preprocess", id =&gt; "if", call =&gt; \&amp;preprocess_if);
}

sub getsetup {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; undef,
			section =&gt; "widget",
		},
}

sub preprocess_if (@) {
	my %params=@_;

	foreach my $param (qw{test then}) {
		if (! exists $params{$param}) {
			error sprintf(gettext('%s parameter is required'), $param);
		}
	}

	my $result=0;
	if ((exists $params{all} &amp;&amp; ! IkiWiki::yesno($params{all})) ||
	    # An optimisation to avoid needless looping over every page
	    # for simple uses of some of the tests.
	    $params{test} =~ /^([\s\!()]*((enabled|sourcepage|destpage|included)\([^)]*\)|(and|or))[\s\!()]*)+$/) {
		add_depends($params{page}, "($params{test}) and $params{page}");
		$result=pagespec_match($params{page}, $params{test},
				location =&gt; $params{page},
				sourcepage =&gt; $params{page},
				destpage =&gt; $params{destpage});
	}
	else {
		$result=pagespec_match_list($params{page}, $params{test},
			# stop after first match
			num =&gt; 1,
			sourcepage =&gt; $params{page},
			destpage =&gt; $params{destpage},
		);
	}

	my $ret;
	if ($result) {
		$ret=$params{then};
	}
	elsif (exists $params{else}) {
		$ret=$params{else};
	}
	else {
		$ret="";
	}
	return IkiWiki::preprocess($params{page}, $params{destpage}, 
		IkiWiki::filter($params{page}, $params{destpage}, $ret));
}

package IkiWiki::PageSpec;

sub match_enabled ($$;@) {
	shift;
	my $plugin=shift;
	
	# test if the plugin is enabled
	if (UNIVERSAL::can("IkiWiki::Plugin::".$plugin, "import")) {
		return IkiWiki::SuccessReason-&gt;new("$plugin is enabled");
	}
	else {
		return IkiWiki::FailReason-&gt;new("$plugin is not enabled");
	}
}

sub match_sourcepage ($$;@) {
	shift;
	my $glob=shift;
	my %params=@_;
	
	$glob=derel($glob, $params{location});

	return IkiWiki::FailReason-&gt;new("cannot match sourcepage") unless exists $params{sourcepage};
	if (match_glob($params{sourcepage}, $glob, @_)) {
		return IkiWiki::SuccessReason-&gt;new("sourcepage matches $glob");
	}
	else {
		return IkiWiki::FailReason-&gt;new("sourcepage does not match $glob");
	}
}

sub match_destpage ($$;@) {
	shift;
	my $glob=shift;
	my %params=@_;
	
	$glob=derel($glob, $params{location});

	return IkiWiki::FailReason-&gt;new("cannot match destpage") unless exists $params{destpage};
	if (match_glob($params{destpage}, $glob, @_)) {
		return IkiWiki::SuccessReason-&gt;new("destpage matches $glob");
	}
	else {
		return IkiWiki::FailReason-&gt;new("destpage does not match $glob");
	}
}

sub match_included ($$;@) {
	shift;
	shift;
	my %params=@_;

	return IkiWiki::FailReason-&gt;new("cannot match included") unless exists $params{sourcepage} &amp;&amp; exists $params{destpage};
	if ($params{sourcepage} ne $params{destpage}) {
		return IkiWiki::SuccessReason-&gt;new("page $params{sourcepage} is included");
	}
	else {
		return IkiWiki::FailReason-&gt;new("page $params{sourcepage} is not included");
	}
}

1
</pre></body></html>