<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Provides a list of pages no other page links to.
package IkiWiki::Plugin::orphans;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "orphans", call =&gt; \&amp;getsetup);
	hook(type =&gt; "preprocess", id =&gt; "orphans", call =&gt; \&amp;preprocess);
}

sub getsetup () {
	return 
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; undef,
		},
}

sub preprocess (@) {
	my %params=@_;
	$params{pages}="*" unless defined $params{pages};
	
	# Needs to update whenever a page is added or removed, so
	# register a dependency.
	add_depends($params{page}, $params{pages});
	
	my @orphans;
	foreach my $page (pagespec_match_list(
			[ grep { ! IkiWiki::backlink_pages($_) &amp;&amp; $_ ne 'index' }
				keys %pagesources ],
			$params{pages}, location =&gt; $params{page})) {
		# If the page has a link to some other page, it's
		# indirectly linked to a page via that page's backlinks.
		next if grep { 
			length $_ &amp;&amp;
			($_ !~ /\/\Q$config{discussionpage}\E$/i || ! $config{discussion}) &amp;&amp;
			bestlink($page, $_) !~ /^(\Q$page\E|)$/ 
		} @{$links{$page}};
		push @orphans, $page;
	}
	
	return gettext("All pages have other pages linking to them.") unless @orphans;
	return "&lt;ul&gt;\n".
		join("\n",
			map {
				"&lt;li&gt;".
				htmllink($params{page}, $params{destpage}, $_,
					 noimageinline =&gt; 1).
				"&lt;/li&gt;"
			} sort @orphans).
		"&lt;/ul&gt;\n";
}

1
</pre></body></html>