<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Ikiwiki enhanced image handling plugin
# Christian Mock cm@tahina.priv.at 20061002
package IkiWiki::Plugin::img;

use warnings;
use strict;
use IkiWiki 3.00;

my %imgdefaults;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "img", call =&gt; \&amp;getsetup);
	hook(type =&gt; "preprocess", id =&gt; "img", call =&gt; \&amp;preprocess, scan =&gt; 1);
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; undef,
			section =&gt; "widget",
		},
}

sub preprocess (@) {
	my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
	my %params=@_;

	if (! defined $image) {
		error("bad image filename");
	}

	if (exists $imgdefaults{$params{page}}) {
		foreach my $key (keys %{$imgdefaults{$params{page}}}) {
			if (! exists $params{$key}) {
				$params{$key}=$imgdefaults{$params{page}}-&gt;{$key};
			}
		}
	}

	if (! exists $params{size} || ! length $params{size}) {
		$params{size}='full';
	}

	if ($image eq 'defaults') {
		$imgdefaults{$params{page}} = \%params;
		return '';
	}

	add_link($params{page}, $image);
	add_depends($params{page}, $image);

	# optimisation: detect scan mode, and avoid generating the image
	if (! defined wantarray) {
		return;
	}

	my $file = bestlink($params{page}, $image);
	my $srcfile = srcfile($file, 1);
	if (! length $file || ! defined $srcfile) {
		return htmllink($params{page}, $params{destpage}, $image);
	}

	my $dir = $params{page};
	my $base = IkiWiki::basename($file);
	my $issvg = $base=~s/\.svg$/.png/i;

	eval q{use Image::Magick};
	error gettext("Image::Magick is not installed") if $@;
	my $im = Image::Magick-&gt;new($issvg ? (magick =&gt; "png") : ());
	my $imglink;
	my $r = $im-&gt;Read($srcfile);
	error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
	
	my ($dwidth, $dheight);

	if ($params{size} ne 'full') {
		my ($w, $h) = ($params{size} =~ /^(\d*)x(\d*)$/);
		error sprintf(gettext('wrong size format "%s" (should be WxH)'), $params{size})
			unless (defined $w &amp;&amp; defined $h &amp;&amp;
			        (length $w || length $h));
		
		if ((length $w &amp;&amp; $w &gt; $im-&gt;Get("width")) ||
		    (length $h &amp;&amp; $h &gt; $im-&gt;Get("height"))) {
		    	# resizing larger
			$imglink = $file;

			# don't generate larger image, just set display size
			if (length $w &amp;&amp; length $h) {
				($dwidth, $dheight)=($w, $h);
			}
			# avoid division by zero on 0x0 image
			elsif ($im-&gt;Get("width") == 0 || $im-&gt;Get("height") == 0) {
				($dwidth, $dheight)=(0, 0);
			}
			# calculate unspecified size from the other one, preserving
			# aspect ratio
			elsif (length $w) {
				$dwidth=$w;
				$dheight=$w / $im-&gt;Get("width") * $im-&gt;Get("height");
			}
			elsif (length $h) {
				$dheight=$h;
				$dwidth=$h / $im-&gt;Get("height") * $im-&gt;Get("width");
			}
		}
		else {
			# resizing smaller
			my $outfile = "$config{destdir}/$dir/${w}x${h}-$base";
			$imglink = "$dir/${w}x${h}-$base";
		
			will_render($params{page}, $imglink);

			if (-e $outfile &amp;&amp; (-M $srcfile &gt;= -M $outfile)) {
				$im = Image::Magick-&gt;new;
				$r = $im-&gt;Read($outfile);
				error sprintf(gettext("failed to read %s: %s"), $outfile, $r) if $r;
			}
			else {
				($dwidth, $dheight)=($w, $h);
				$r = $im-&gt;Resize(geometry =&gt; "${w}x${h}");
				error sprintf(gettext("failed to resize: %s"), $r) if $r;

				# don't actually write resized file in preview mode;
				# rely on width and height settings
				if (! $params{preview}) {
					my @blob = $im-&gt;ImageToBlob();
					writefile($imglink, $config{destdir}, $blob[0], 1);
				}
				else {
					$imglink = $file;
				}
			}
			
			$dwidth = $im-&gt;Get("width") unless defined $dwidth;
			$dheight = $im-&gt;Get("height") unless defined $dheight;
		}
	}
	else {
		$imglink = $file;
		$dwidth = $im-&gt;Get("width");
		$dheight = $im-&gt;Get("height");
	}
	
	if (! defined($dwidth) || ! defined($dheight)) {
		error sprintf(gettext("failed to determine size of image %s"), $file)
	}

	my ($fileurl, $imgurl);
	if (! $params{preview}) {
		$fileurl=urlto($file, $params{destpage});
		$imgurl=urlto($imglink, $params{destpage});
	}
	else {
		$fileurl=urlto($file);
		$imgurl=urlto($imglink);
	}

	if (! exists $params{class}) {
		$params{class}="img";
	}

	my $attrs='';
	foreach my $attr (qw{alt title class id hspace vspace}) {
		if (exists $params{$attr}) {
			$attrs.=" $attr=\"$params{$attr}\"";
		}
	}
	
	my $imgtag='&lt;img src="'.$imgurl.
		'" width="'.$dwidth.
		'" height="'.$dheight.'"'.
		$attrs.
		(exists $params{align} &amp;&amp; ! exists $params{caption} ? ' align="'.$params{align}.'"' : '').
		' /&gt;';

	my $link;
	if (! defined $params{link}) {
		$link=$fileurl;
	}
	elsif ($params{link} =~ /^\w+:\/\//) {
		$link=$params{link};
	}

	if (defined $link) {
		$imgtag='&lt;a href="'.$link.'"&gt;'.$imgtag.'&lt;/a&gt;';
	}
	else {
		my $b = bestlink($params{page}, $params{link});
	
		if (length $b) {
			add_depends($params{page}, $b, deptype("presence"));
			$imgtag=htmllink($params{page}, $params{destpage},
				$params{link}, linktext =&gt; $imgtag,
				noimageinline =&gt; 1,
			);
		}
	}

	if (exists $params{caption}) {
		return '&lt;table class="img'.
			(exists $params{align} ? " align-$params{align}" : "").
			'"&gt;'.
			'&lt;caption&gt;'.$params{caption}.'&lt;/caption&gt;'.
			'&lt;tr&gt;&lt;td&gt;'.$imgtag.'&lt;/td&gt;&lt;/tr&gt;'.
			'&lt;/table&gt;';
	}
	else {
		return $imgtag;
	}
}

1
</pre></body></html>