<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# xapian-omega search engine plugin
package IkiWiki::Plugin::search;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "search", call =&gt; \&amp;getsetup);
	hook(type =&gt; "checkconfig", id =&gt; "search", call =&gt; \&amp;checkconfig);
	hook(type =&gt; "pagetemplate", id =&gt; "search", call =&gt; \&amp;pagetemplate);
	hook(type =&gt; "postscan", id =&gt; "search", call =&gt; \&amp;index);
	hook(type =&gt; "delete", id =&gt; "search", call =&gt; \&amp;delete);
	hook(type =&gt; "cgi", id =&gt; "search", call =&gt; \&amp;cgi);
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; 1,
			section =&gt; "web",
		},
		omega_cgi =&gt; {
			type =&gt; "string",
			example =&gt; "/usr/lib/cgi-bin/omega/omega",
			description =&gt; "path to the omega cgi program",
			safe =&gt; 0, # external program
			rebuild =&gt; 0,
		},
}

sub checkconfig () {
	foreach my $required (qw(url cgiurl)) {
		if (! length $config{$required}) {
			error(sprintf(gettext("Must specify %s when using the %s plugin"), $required, 'search'));
		}
	}
	
	if (! defined $config{omega_cgi}) {
		$config{omega_cgi}="/usr/lib/cgi-bin/omega/omega";
	}
}

my $form;
sub pagetemplate (@) {
	my %params=@_;
	my $page=$params{page};
	my $template=$params{template};

	# Add search box to page header.
	if ($template-&gt;query(name =&gt; "searchform")) {
		if (! defined $form) {
			my $searchform = template("searchform.tmpl", blind_cache =&gt; 1);
			$searchform-&gt;param(searchaction =&gt; $config{cgiurl});
			$form=$searchform-&gt;output;
		}

		$template-&gt;param(searchform =&gt; $form);
	}
}

my $scrubber;
my $stemmer;
sub index (@) {
	my %params=@_;

	setupfiles();

	# A unique pageterm is used to identify the document for a page.
	my $pageterm=pageterm($params{page});
	return $params{content} unless defined $pageterm;
	
	my $db=xapiandb();
	my $doc=Search::Xapian::Document-&gt;new();
	my $caption=pagetitle($params{page});
	my $title;
	if (exists $pagestate{$params{page}}{meta} &amp;&amp;
		exists $pagestate{$params{page}}{meta}{title}) {
		$title=$pagestate{$params{page}}{meta}{title};
	}
	else {
		$title=$caption;
	}

	# Remove html from text to be indexed.
	if (! defined $scrubber) {
		eval q{use HTML::Scrubber};
		if (! $@) {
			$scrubber=HTML::Scrubber-&gt;new(allow =&gt; []);
		}
	}
	my $toindex = defined $scrubber ? $scrubber-&gt;scrub($params{content}) : $params{content};
	
	# Take 512 characters for a sample, then extend it out
	# if it stopped in the middle of a word.
	my $size=512;
	my ($sample)=substr($toindex, 0, $size);
	if (length($sample) == $size) {
		my $max=length($toindex);
		my $next;
		while ($size &lt; $max &amp;&amp;
		       ($next=substr($toindex, $size++, 1)) !~ /\s/) {
			$sample.=$next;
		}
	}
	$sample=~s/\n/ /g;
	
	# data used by omega
	# Decode html entities in it, since omega re-encodes them.
	eval q{use HTML::Entities};
	error $@ if $@;
	$doc-&gt;set_data(
		"url=".urlto($params{page}, "")."\n".
		"sample=".decode_entities($sample)."\n".
		"caption=".decode_entities($caption)."\n".
		"modtime=$IkiWiki::pagemtime{$params{page}}\n".
		"size=".length($params{content})."\n"
	);

	# Index document and add terms for other metadata.
	my $tg = Search::Xapian::TermGenerator-&gt;new();
	if (! $stemmer) {
		my $langcode=$ENV{LANG} || "en";
		$langcode=~s/_.*//;

		# This whitelist is here to work around a xapian bug (#486138)
		my @whitelist=qw{da de en es fi fr hu it no pt ru ro sv tr};

		if (grep { $_ eq $langcode } @whitelist) {
			$stemmer=Search::Xapian::Stem-&gt;new($langcode);
		}
		else {
			$stemmer=Search::Xapian::Stem-&gt;new("english");
		}
	}
	$tg-&gt;set_stemmer($stemmer);
	$tg-&gt;set_document($doc);
	$tg-&gt;index_text($params{page}, 2);
	$tg-&gt;index_text($caption, 2);
	$tg-&gt;index_text($title, 2) if $title ne $caption;
	$tg-&gt;index_text($toindex);
	$tg-&gt;index_text(lc($title), 1, "S"); # for title:foo
	foreach my $link (@{$links{$params{page}}}) {
		$tg-&gt;index_text(lc($link), 1, "XLINK"); # for link:bar
	}

	$doc-&gt;add_term($pageterm);
	$db-&gt;replace_document_by_term($pageterm, $doc);
}

sub delete (@) {
	my $db=xapiandb();
	foreach my $page (@_) {
		my $pageterm=pageterm(pagename($page));
		$db-&gt;delete_document_by_term($pageterm) if defined $pageterm;
	}
}

sub cgi ($) {
	my $cgi=shift;

	if (defined $cgi-&gt;param('P')) {
		# only works for GET requests
		chdir("$config{wikistatedir}/xapian") || error("chdir: $!");
		$ENV{OMEGA_CONFIG_FILE}="./omega.conf";
		$ENV{CGIURL}=$config{cgiurl},
		IkiWiki::loadindex();
		$ENV{HELPLINK}=htmllink("", "", "ikiwiki/searching",
			noimageinline =&gt; 1, linktext =&gt; "Help");
		exec($config{omega_cgi}) || error("$config{omega_cgi} failed: $!");
	}
}

sub pageterm ($) {
	my $page=shift;

	# 240 is the number used by omindex to decide when to hash an
	# overlong term. This does not use a compatible hash method though.
	if (length $page &gt; 240) {
		eval q{use Digest::SHA1};
		if ($@) {
			debug("search: ".sprintf(gettext("need Digest::SHA1 to index %s"), $page)) if $@;
			return undef;
		}

		# Note no colon, therefore it's guaranteed to not overlap
		# with a page with the same name as the hash..
		return "U".lc(Digest::SHA1::sha1_hex($page));
	}
	else {
		return "U:".$page;
	}
}

my $db;
sub xapiandb () {
	if (! defined $db) {
		eval q{
			use Search::Xapian;
			use Search::Xapian::WritableDatabase;
		};
		error($@) if $@;
		$db=Search::Xapian::WritableDatabase-&gt;new($config{wikistatedir}."/xapian/default",
			Search::Xapian::DB_CREATE_OR_OPEN());
	}
	return $db;
}

{
my $setup=0;
sub setupfiles () {
	if (! $setup and (! -e $config{wikistatedir}."/xapian" || $config{rebuild})) {
		writefile("omega.conf", $config{wikistatedir}."/xapian",
			"database_dir .\n".
			"template_dir ./templates\n");
		
		# Avoid omega interpreting anything in the misctemplate
		# as an omegascript command.
		my $misctemplate=IkiWiki::misctemplate(gettext("search"), "\0");
		eval q{use HTML::Entities};
		error $@ if $@;
		$misctemplate=encode_entities($misctemplate, '\$');

		my $querytemplate=readfile(IkiWiki::template_file("searchquery.tmpl"));
		$misctemplate=~s/\0/$querytemplate/;

		writefile("query", $config{wikistatedir}."/xapian/templates",
			$misctemplate);
		$setup=1;
	}
}
}

1
</pre></body></html>