<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Markdown markup language
package IkiWiki::Plugin::mdwn;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	hook(type =&gt; "checkconfig", id =&gt; "mdwn", call =&gt; \&amp;checkconfig);
	hook(type =&gt; "getsetup", id =&gt; "mdwn", call =&gt; \&amp;getsetup);
	hook(type =&gt; "htmlize", id =&gt; "mdwn", call =&gt; \&amp;htmlize, longname =&gt; "Markdown");
	hook(type =&gt; "htmlize", id =&gt; "md", call =&gt; \&amp;htmlize, longname =&gt; "Markdown (popular file extension)", nocreate =&gt; 1);
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; 1, # format plugin
			section =&gt; "format",
		},
		multimarkdown =&gt; {
			type =&gt; "boolean",
			example =&gt; 0,
			description =&gt; "enable multimarkdown features?",
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
		nodiscount =&gt; {
			type =&gt; "boolean",
			example =&gt; 0,
			description =&gt; "disable use of markdown discount?",
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
		mdwn_footnotes =&gt; {
			type =&gt; "boolean",
			example =&gt; 1,
			description =&gt; "enable footnotes in Markdown (where supported)?",
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
		mdwn_alpha_lists =&gt; {
			type =&gt; "boolean",
			example =&gt; 0,
			description =&gt; "interpret line like 'A. First item' as ordered list when using Discount?",
			advanced =&gt; 1,
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
}

sub checkconfig () {
	$config{mdwn_footnotes} = 1 unless defined $config{mdwn_footnotes};
	$config{mdwn_alpha_lists} = 0 unless defined $config{mdwn_alpha_lists};
}

our $markdown_sub;
sub htmlize (@) {
	my %params=@_;
	my $content = $params{content};

	if (! defined $markdown_sub) {
		# Markdown is forked and splintered upstream and can be
		# available in a variety of forms. Support them all.
		no warnings 'once';
		$blosxom::version="is a proper perl module too much to ask?";
		use warnings 'all';

		if (exists $config{multimarkdown} &amp;&amp; $config{multimarkdown}) {
			eval q{use Text::MultiMarkdown};
			if ($@) {
				debug(gettext("multimarkdown is enabled, but Text::MultiMarkdown is not installed"));
			}
			else {
				$markdown_sub=sub {
					my %flags=( use_metadata =&gt; 0 );

					$flags{disable_footnotes}=not $config{mdwn_footnotes};

					Text::MultiMarkdown::markdown(shift, \%flags);
				}
			}
		}
		if (! defined $markdown_sub &amp;&amp;
		    (! exists $config{nodiscount} || ! $config{nodiscount})) {
			eval q{use Text::Markdown::Discount};
			if (! $@) {
				my $markdown = \&amp;Text::Markdown::Discount::markdown;
				my $always_flags = 0;

				# Disable Pandoc-style % Title, % Author, % Date
				# Use the meta plugin instead
				$always_flags |= Text::Markdown::Discount::MKD_NOHEADER();

				# Disable Unicodification of quote marks, em dashes...
				# Use the typography plugin instead
				$always_flags |= Text::Markdown::Discount::MKD_NOPANTS();

				# Workaround for discount's eliding of &lt;style&gt; blocks.
				# https://rt.cpan.org/Ticket/Display.html?id=74016
				if (Text::Markdown::Discount-&gt;can('MKD_NOSTYLE')) {
					$always_flags |= Text::Markdown::Discount::MKD_NOSTYLE();
				}
				elsif ($markdown-&gt;('&lt;style&gt;x&lt;/style&gt;', 0) !~ '&lt;style&gt;' &amp;&amp;
					$markdown-&gt;('&lt;style&gt;x&lt;/style&gt;', 0x00400000) =~ m{&lt;style&gt;x&lt;/style&gt;}) {
					$always_flags |= 0x00400000;
				}

				# Enable fenced code blocks in libmarkdown &gt;= 2.2.0
				# https://bugs.debian.org/888055
				if (Text::Markdown::Discount-&gt;can('MKD_FENCEDCODE')) {
					$always_flags |= Text::Markdown::Discount::MKD_FENCEDCODE();
				}
				elsif ($markdown-&gt;("~~~\nx\n~~~", 0) !~ m{&lt;pre\b} &amp;&amp;
					$markdown-&gt;("~~~\nx\n~~~", 0x02000000) =~ m{&lt;pre\b}) {
					$always_flags |= 0x02000000;
				}

				# PHP Markdown Extra-style term\n: definition -&gt; &lt;dl&gt;
				if (Text::Markdown::Discount-&gt;can('MKD_DLEXTRA')) {
					$always_flags |= Text::Markdown::Discount::MKD_DLEXTRA();
				}
				elsif ($markdown-&gt;("term\n: def\n", 0) !~ m{&lt;dl&gt;} &amp;&amp;
					$markdown-&gt;("term\n: def\n", 0x01000000) =~ m{&lt;dl&gt;}) {
					$always_flags |= 0x01000000;
				}

				# Allow dashes and underscores in tag names
				if (Text::Markdown::Discount-&gt;can('MKD_GITHUBTAGS')) {
					$always_flags |= Text::Markdown::Discount::MKD_GITHUBTAGS();
				}
				elsif ($markdown-&gt;('&lt;foo_bar&gt;', 0) !~ m{&lt;foo_bar} &amp;&amp;
					$markdown-&gt;('&lt;foo_bar&gt;', 0x08000000) =~ m{&lt;foo_bar\b}) {
					$always_flags |= 0x08000000;
				}

				$markdown_sub=sub {
					my $t=shift;

					# Workaround for discount binding bug
					# https://rt.cpan.org/Ticket/Display.html?id=73657
					return "" if $t=~/^\s*$/;

					my $flags=$always_flags;

					if ($config{mdwn_footnotes}) {
						$flags |= Text::Markdown::Discount::MKD_EXTRA_FOOTNOTE();
					}

					unless ($config{mdwn_alpha_lists}) {
						$flags |= Text::Markdown::Discount::MKD_NOALPHALIST();
					}

					return Text::Markdown::Discount::markdown($t, $flags);
				}
			}
		}
		if (! defined $markdown_sub) {
			eval q{use Text::Markdown};
			if (! $@) {
				if (Text::Markdown-&gt;can('markdown')) {
					$markdown_sub=\&amp;Text::Markdown::markdown;
				}
				else {
					$markdown_sub=\&amp;Text::Markdown::Markdown;
				}
			}
			else {
				eval q{use Markdown};
				if (! $@) {
					$markdown_sub=\&amp;Markdown::Markdown;
				}
				else {
					my $error = $@;
					do "/usr/bin/markdown" ||
						error(sprintf(gettext("failed to load Markdown.pm perl module (%s) or /usr/bin/markdown (%s)"), $error, $!));
					$markdown_sub=\&amp;Markdown::Markdown;
				}
			}
		}
		
		require Encode;
	}
	
	# Workaround for perl bug (#376329)
	$content=Encode::encode_utf8($content);
	eval {$content=&amp;$markdown_sub($content)};
	if ($@) {
		eval {$content=&amp;$markdown_sub($content)};
		print STDERR $@ if $@;
	}
	$content=Encode::decode_utf8($content);

	return $content;
}

1
</pre></body></html>