<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl

package IkiWiki;

use warnings;
use strict;
use Encode;
use URI::Escape q{uri_escape_utf8};
use POSIX ();
use Storable;
use open qw{:utf8 :std};

use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
	%pagestate %wikistate %renderedfiles %oldrenderedfiles
	%pagesources %delpagesources %destsources %depends %depends_simple
	@mass_depends %hooks %forcerebuild %loaded_plugins %typedlinks
	%oldtypedlinks %autofiles};

use Exporter q{import};
our @EXPORT = qw(hook debug error htmlpage template template_depends
	deptype add_depends pagespec_match pagespec_match_list bestlink
	htmllink readfile writefile pagetype srcfile pagename
	displaytime strftime_utf8 will_render gettext ngettext urlto targetpage
	add_underlay pagetitle titlepage linkpage newpagefile
	inject add_link add_autofile
	%config %links %pagestate %wikistate %renderedfiles
	%pagesources %destsources %typedlinks);
our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
our $installdir='/usr'; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE

# Page dependency types.
our $DEPEND_CONTENT=1;
our $DEPEND_PRESENCE=2;
our $DEPEND_LINKS=4;

# Optimisation.
use Memoize;
memoize("abs2rel");
memoize("sortspec_translate");
memoize("pagespec_translate");
memoize("template_file");

sub getsetup () {
	wikiname =&gt; {
		type =&gt; "string",
		default =&gt; "wiki",
		description =&gt; "name of the wiki",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	adminemail =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; 'me@example.com',
		description =&gt; "contact email for wiki",
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	adminuser =&gt; {
		type =&gt; "string",
		default =&gt; [],
		description =&gt; "users who are wiki admins",
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	banned_users =&gt; {
		type =&gt; "string",
		default =&gt; [],
		description =&gt; "users who are banned from the wiki",
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	srcdir =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; "$ENV{HOME}/wiki",
		description =&gt; "where the source of the wiki is located",
		safe =&gt; 0, # path
		rebuild =&gt; 1,
	},
	destdir =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; "/var/www/wiki",
		description =&gt; "where to build the wiki",
		safe =&gt; 0, # path
		rebuild =&gt; 1,
	},
	url =&gt; {
		type =&gt; "string",
		default =&gt; '',
		example =&gt; "http://example.com/wiki",
		description =&gt; "base url to the wiki",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	cgiurl =&gt; {
		type =&gt; "string",
		default =&gt; '',
		example =&gt; "http://example.com/wiki/ikiwiki.cgi",
		description =&gt; "url to the ikiwiki.cgi",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	cgi_wrapper =&gt; {
		type =&gt; "string",
		default =&gt; '',
		example =&gt; "/var/www/wiki/ikiwiki.cgi",
		description =&gt; "filename of cgi wrapper to generate",
		safe =&gt; 0, # file
		rebuild =&gt; 0,
	},
	cgi_wrappermode =&gt; {
		type =&gt; "string",
		default =&gt; '06755',
		description =&gt; "mode for cgi_wrapper (can safely be made suid)",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	rcs =&gt; {
		type =&gt; "string",
		default =&gt; '',
		description =&gt; "rcs backend to use",
		safe =&gt; 0, # don't allow overriding
		rebuild =&gt; 0,
	},
	default_plugins =&gt; {
		type =&gt; "internal",
		default =&gt; [qw{mdwn link inline meta htmlscrubber passwordauth
				openid signinedit lockedit conditional
				recentchanges parentlinks editpage}],
		description =&gt; "plugins to enable by default",
		safe =&gt; 0,
		rebuild =&gt; 1,
	},
	add_plugins =&gt; {
		type =&gt; "string",
		default =&gt; [],
		description =&gt; "plugins to add to the default configuration",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	disable_plugins =&gt; {
		type =&gt; "string",
		default =&gt; [],
		description =&gt; "plugins to disable",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	templatedir =&gt; {
		type =&gt; "string",
		default =&gt; "$installdir/share/ikiwiki/templates",
		description =&gt; "additional directory to search for template files",
		advanced =&gt; 1,
		safe =&gt; 0, # path
		rebuild =&gt; 1,
	},
	underlaydir =&gt; {
		type =&gt; "string",
		default =&gt; "$installdir/share/ikiwiki/basewiki",
		description =&gt; "base wiki source location",
		advanced =&gt; 1,
		safe =&gt; 0, # path
		rebuild =&gt; 0,
	},
	underlaydirbase =&gt; {
		type =&gt; "internal",
		default =&gt; "$installdir/share/ikiwiki",
		description =&gt; "parent directory containing additional underlays",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	wrappers =&gt; {
		type =&gt; "internal",
		default =&gt; [],
		description =&gt; "wrappers to generate",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	underlaydirs =&gt; {
		type =&gt; "internal",
		default =&gt; [],
		description =&gt; "additional underlays to use",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	verbose =&gt; {
		type =&gt; "boolean",
		example =&gt; 1,
		description =&gt; "display verbose messages?",
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	syslog =&gt; {
		type =&gt; "boolean",
		example =&gt; 1,
		description =&gt; "log to syslog?",
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	usedirs =&gt; {
		type =&gt; "boolean",
		default =&gt; 1,
		description =&gt; "create output files named page/index.html?",
		safe =&gt; 0, # changing requires manual transition
		rebuild =&gt; 1,
	},
	prefix_directives =&gt; {
		type =&gt; "boolean",
		default =&gt; 1,
		description =&gt; "use '!'-prefixed preprocessor directives?",
		safe =&gt; 0, # changing requires manual transition
		rebuild =&gt; 1,
	},
	indexpages =&gt; {
		type =&gt; "boolean",
		default =&gt; 0,
		description =&gt; "use page/index.mdwn source files",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	discussion =&gt; {
		type =&gt; "boolean",
		default =&gt; 1,
		description =&gt; "enable Discussion pages?",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	discussionpage =&gt; {
		type =&gt; "string",
		default =&gt; gettext("Discussion"),
		description =&gt; "name of Discussion pages",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	html5 =&gt; {
		type =&gt; "boolean",
		default =&gt; 0,
		description =&gt; "generate HTML5?",
		advanced =&gt; 0,
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	sslcookie =&gt; {
		type =&gt; "boolean",
		default =&gt; 0,
		description =&gt; "only send cookies over SSL connections?",
		advanced =&gt; 1,
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	default_pageext =&gt; {
		type =&gt; "string",
		default =&gt; "mdwn",
		description =&gt; "extension to use for new pages",
		safe =&gt; 0, # not sanitized
		rebuild =&gt; 0,
	},
	htmlext =&gt; {
		type =&gt; "string",
		default =&gt; "html",
		description =&gt; "extension to use for html files",
		safe =&gt; 0, # not sanitized
		rebuild =&gt; 1,
	},
	timeformat =&gt; {
		type =&gt; "string",
		default =&gt; '%c',
		description =&gt; "strftime format string to display date",
		advanced =&gt; 1,
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	locale =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; "en_US.UTF-8",
		description =&gt; "UTF-8 locale to use",
		advanced =&gt; 1,
		safe =&gt; 0,
		rebuild =&gt; 1,
	},
	userdir =&gt; {
		type =&gt; "string",
		default =&gt; "",
		example =&gt; "users",
		description =&gt; "put user pages below specified page",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	numbacklinks =&gt; {
		type =&gt; "integer",
		default =&gt; 10,
		description =&gt; "how many backlinks to show before hiding excess (0 to show all)",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	hardlink =&gt; {
		type =&gt; "boolean",
		default =&gt; 0,
		description =&gt; "attempt to hardlink source files? (optimisation for large files)",
		advanced =&gt; 1,
		safe =&gt; 0, # paranoia
		rebuild =&gt; 0,
	},
	umask =&gt; {
		type =&gt; "string",
		example =&gt; "public",
		description =&gt; "force ikiwiki to use a particular umask (keywords public, group or private, or a number)",
		advanced =&gt; 1,
		safe =&gt; 0, # paranoia
		rebuild =&gt; 0,
	},
	wrappergroup =&gt; {
		type =&gt; "string",
		example =&gt; "ikiwiki",
		description =&gt; "group for wrappers to run in",
		advanced =&gt; 1,
		safe =&gt; 0, # paranoia
		rebuild =&gt; 0,
	},
	libdir =&gt; {
		type =&gt; "string",
		default =&gt; "",
		example =&gt; "$ENV{HOME}/.ikiwiki/",
		description =&gt; "extra library and plugin directory",
		advanced =&gt; 1,
		safe =&gt; 0, # directory
		rebuild =&gt; 0,
	},
	ENV =&gt; {
		type =&gt; "string", 
		default =&gt; {},
		description =&gt; "environment variables",
		safe =&gt; 0, # paranoia
		rebuild =&gt; 0,
	},
	timezone =&gt; {
		type =&gt; "string", 
		default =&gt; "",
		example =&gt; "US/Eastern",
		description =&gt; "time zone name",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	include =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; '^\.htaccess$',
		description =&gt; "regexp of normally excluded files to include",
		advanced =&gt; 1,
		safe =&gt; 0, # regexp
		rebuild =&gt; 1,
	},
	exclude =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; '^(*\.private|Makefile)$',
		description =&gt; "regexp of files that should be skipped",
		advanced =&gt; 1,
		safe =&gt; 0, # regexp
		rebuild =&gt; 1,
	},
	wiki_file_prune_regexps =&gt; {
		type =&gt; "internal",
		default =&gt; [qr/(^|\/)\.\.(\/|$)/, qr/^\//, qr/^\./, qr/\/\./,
			qr/\.x?html?$/, qr/\.ikiwiki-new$/,
			qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
			qr/(^|\/)_MTN\//, qr/(^|\/)_darcs\//,
			qr/(^|\/)CVS\//, qr/\.dpkg-tmp$/],
		description =&gt; "regexps of source files to ignore",
		safe =&gt; 0,
		rebuild =&gt; 1,
	},
	wiki_file_chars =&gt; {
		type =&gt; "string",
		description =&gt; "specifies the characters that are allowed in source filenames",
		default =&gt; "-[:alnum:]+/.:_",
		safe =&gt; 0,
		rebuild =&gt; 1,
	},
	wiki_file_regexp =&gt; {
		type =&gt; "internal",
		description =&gt; "regexp of legal source files",
		safe =&gt; 0,
		rebuild =&gt; 1,
	},
	web_commit_regexp =&gt; {
		type =&gt; "internal",
		default =&gt; qr/^web commit (by (.*?(?=: |$))|from ([0-9a-fA-F:.]+[0-9a-fA-F])):?(.*)/,
		description =&gt; "regexp to parse web commits from logs",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	cgi =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "run as a cgi",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	cgi_disable_uploads =&gt; {
		type =&gt; "internal",
		default =&gt; 1,
		description =&gt; "whether CGI should accept file uploads",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	post_commit =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "run as a post-commit hook",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	rebuild =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "running in rebuild mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	setup =&gt; {
		type =&gt; "internal",
		default =&gt; undef,
		description =&gt; "running in setup mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	clean =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "running in clean mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	refresh =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "running in refresh mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	test_receive =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "running in receive test mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	wrapper_background_command =&gt; {
		type =&gt; "internal",
		default =&gt; '',
		description =&gt; "background shell command to run",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	gettime =&gt; {
		type =&gt; "internal",
		description =&gt; "running in gettime mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	w3mmode =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "running in w3mmode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	wikistatedir =&gt; {
		type =&gt; "internal",
		default =&gt; undef,
		description =&gt; "path to the .ikiwiki directory holding ikiwiki state",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	setupfile =&gt; {
		type =&gt; "internal",
		default =&gt; undef,
		description =&gt; "path to setup file",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	setuptype =&gt; {
		type =&gt; "internal",
		default =&gt; "Yaml",
		description =&gt; "perl class to use to dump setup file",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	allow_symlinks_before_srcdir =&gt; {
		type =&gt; "boolean",
		default =&gt; 0,
		description =&gt; "allow symlinks in the path leading to the srcdir (potentially insecure)",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
}

sub defaultconfig () {
	my %s=getsetup();
	my @ret;
	foreach my $key (keys %s) {
		push @ret, $key, $s{$key}-&gt;{default};
	}
	return @ret;
}

# URL to top of wiki as a path starting with /, valid from any wiki page or
# the CGI; if that's not possible, an absolute URL. Either way, it ends with /
my $local_url;
# URL to CGI script, similar to $local_url
my $local_cgiurl;

sub checkconfig () {
	# locale stuff; avoid LC_ALL since it overrides everything
	if (defined $ENV{LC_ALL}) {
		$ENV{LANG} = $ENV{LC_ALL};
		delete $ENV{LC_ALL};
	}
	if (defined $config{locale}) {
		if (POSIX::setlocale(&amp;POSIX::LC_ALL, $config{locale})) {
			$ENV{LANG}=$config{locale};
			define_gettext();
		}
	}
		
	if (! defined $config{wiki_file_regexp}) {
		$config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
	}

	if (ref $config{ENV} eq 'HASH') {
		foreach my $val (keys %{$config{ENV}}) {
			$ENV{$val}=$config{ENV}{$val};
		}
	}
	if (defined $config{timezone} &amp;&amp; length $config{timezone}) {
		$ENV{TZ}=$config{timezone};
	}
	else {
		$config{timezone}=$ENV{TZ};
	}

	if ($config{w3mmode}) {
		eval q{use Cwd q{abs_path}};
		error($@) if $@;
		$config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
		$config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
		$config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
			unless $config{cgiurl} =~ m!file:///!;
		$config{url}="file://".$config{destdir};
	}

	if ($config{cgi} &amp;&amp; ! length $config{url}) {
		error(gettext("Must specify url to wiki with --url when using --cgi"));
	}

	if (defined $config{url} &amp;&amp; length $config{url}) {
		eval q{use URI};
		my $baseurl = URI-&gt;new($config{url});

		$local_url = $baseurl-&gt;path . "/";
		$local_cgiurl = undef;

		if (length $config{cgiurl}) {
			my $cgiurl = URI-&gt;new($config{cgiurl});

			$local_cgiurl = $cgiurl-&gt;path;

			if ($cgiurl-&gt;scheme ne $baseurl-&gt;scheme or
				$cgiurl-&gt;authority ne $baseurl-&gt;authority) {
				# too far apart, fall back to absolute URLs
				$local_url = "$config{url}/";
				$local_cgiurl = $config{cgiurl};
			}
		}

		$local_url =~ s{//$}{/};
	}
	else {
		$local_cgiurl = $config{cgiurl};
	}

	$config{wikistatedir}="$config{srcdir}/.ikiwiki"
		unless exists $config{wikistatedir} &amp;&amp; defined $config{wikistatedir};

	if (defined $config{umask}) {
		my $u = possibly_foolish_untaint($config{umask});

		if ($u =~ m/^\d+$/) {
			umask($u);
		}
		elsif ($u eq 'private') {
			umask(077);
		}
		elsif ($u eq 'group') {
			umask(027);
		}
		elsif ($u eq 'public') {
			umask(022);
		}
		else {
			error(sprintf(gettext("unsupported umask setting %s"), $u));
		}
	}

	run_hooks(checkconfig =&gt; sub { shift-&gt;() });

	return 1;
}

sub listplugins () {
	my %ret;

	foreach my $dir (@INC, $config{libdir}) {
		next unless defined $dir &amp;&amp; length $dir;
		foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
			my ($plugin)=$file=~/.*\/(.*)\.pm$/;
			$ret{$plugin}=1;
		}
	}
	foreach my $dir ($config{libdir}, "$installdir/lib/ikiwiki") {
		next unless defined $dir &amp;&amp; length $dir;
		foreach my $file (glob("$dir/plugins/*")) {
			$ret{basename($file)}=1 if -x $file;
		}
	}

	return keys %ret;
}

sub loadplugins () {
	if (defined $config{libdir} &amp;&amp; length $config{libdir}) {
		unshift @INC, possibly_foolish_untaint($config{libdir});
	}

	foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
		loadplugin($plugin);
	}
	
	if ($config{rcs}) {
		if (exists $hooks{rcs}) {
			error(gettext("cannot use multiple rcs plugins"));
		}
		loadplugin($config{rcs});
	}
	if (! exists $hooks{rcs}) {
		loadplugin("norcs");
	}

	run_hooks(getopt =&gt; sub { shift-&gt;() });
	if (grep /^-/, @ARGV) {
		print STDERR "Unknown option (or missing parameter): $_\n"
			foreach grep /^-/, @ARGV;
		usage();
	}

	return 1;
}

sub loadplugin ($;$) {
	my $plugin=shift;
	my $force=shift;

	return if ! $force &amp;&amp; grep { $_ eq $plugin} @{$config{disable_plugins}};

	foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
	                 "$installdir/lib/ikiwiki") {
		if (defined $dir &amp;&amp; -x "$dir/plugins/$plugin") {
			eval { require IkiWiki::Plugin::external };
			if ($@) {
				my $reason=$@;
				error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
			}
			import IkiWiki::Plugin::external "$dir/plugins/$plugin";
			$loaded_plugins{$plugin}=1;
			return 1;
		}
	}

	my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
	eval qq{use $mod};
	if ($@) {
		error("Failed to load plugin $mod: $@");
	}
	$loaded_plugins{$plugin}=1;
	return 1;
}

sub error ($;$) {
	my $message=shift;
	my $cleaner=shift;
	log_message('err' =&gt; $message) if $config{syslog};
	if (defined $cleaner) {
		$cleaner-&gt;();
	}
	die $message."\n";
}

sub debug ($) {
	return unless $config{verbose};
	return log_message(debug =&gt; @_);
}

my $log_open=0;
sub log_message ($$) {
	my $type=shift;

	if ($config{syslog}) {
		require Sys::Syslog;
		if (! $log_open) {
			Sys::Syslog::setlogsock('unix');
			Sys::Syslog::openlog('ikiwiki', '', 'user');
			$log_open=1;
		}
		return eval {
			Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
		};
	}
	elsif (! $config{cgi}) {
		return print "@_\n";
	}
	else {
		return print STDERR "@_\n";
	}
}

sub possibly_foolish_untaint ($) {
	my $tainted=shift;
	my ($untainted)=$tainted=~/(.*)/s;
	return $untainted;
}

sub basename ($) {
	my $file=shift;

	$file=~s!.*/+!!;
	return $file;
}

sub dirname ($) {
	my $file=shift;

	$file=~s!/*[^/]+$!!;
	return $file;
}

sub isinternal ($) {
	my $page=shift;
	return exists $pagesources{$page} &amp;&amp;
		$pagesources{$page} =~ /\._([^.]+)$/;
}

sub pagetype ($) {
	my $file=shift;
	
	if ($file =~ /\.([^.]+)$/) {
		return $1 if exists $hooks{htmlize}{$1};
	}
	my $base=basename($file);
	if (exists $hooks{htmlize}{$base} &amp;&amp;
	    $hooks{htmlize}{$base}{noextension}) {
		return $base;
	}
	return;
}

my %pagename_cache;

sub pagename ($) {
	my $file=shift;

	if (exists $pagename_cache{$file}) {
		return $pagename_cache{$file};
	}

	my $type=pagetype($file);
	my $page=$file;
	$page=~s/\Q.$type\E*$//
		if defined $type &amp;&amp; !$hooks{htmlize}{$type}{keepextension}
			&amp;&amp; !$hooks{htmlize}{$type}{noextension};
	if ($config{indexpages} &amp;&amp; $page=~/(.*)\/index$/) {
		$page=$1;
	}

	$pagename_cache{$file} = $page;
	return $page;
}

sub newpagefile ($$) {
	my $page=shift;
	my $type=shift;

	if (! $config{indexpages} || $page eq 'index') {
		return $page.".".$type;
	}
	else {
		return $page."/index.".$type;
	}
}

sub targetpage ($$;$) {
	my $page=shift;
	my $ext=shift;
	my $filename=shift;
	
	if (defined $filename) {
		return $page."/".$filename.".".$ext;
	}
	elsif (! $config{usedirs} || $page eq 'index') {
		return $page.".".$ext;
	}
	else {
		return $page."/index.".$ext;
	}
}

sub htmlpage ($) {
	my $page=shift;
	
	return targetpage($page, $config{htmlext});
}

sub srcfile_stat {
	my $file=shift;
	my $nothrow=shift;

	return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
	foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
		return "$dir/$file", stat(_) if -e "$dir/$file";
	}
	error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
	return;
}

sub srcfile ($;$) {
	return (srcfile_stat(@_))[0];
}

sub add_literal_underlay ($) {
	my $dir=shift;

	if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
		unshift @{$config{underlaydirs}}, $dir;
	}
}

sub add_underlay ($) {
	my $dir = shift;

	if ($dir !~ /^\//) {
		$dir="$config{underlaydirbase}/$dir";
	}

	add_literal_underlay($dir);
	# why does it return 1? we just don't know
	return 1;
}

sub readfile ($;$$) {
	my $file=shift;
	my $binary=shift;
	my $wantfd=shift;

	if (-l $file) {
		error("cannot read a symlink ($file)");
	}
	
	local $/=undef;
	open (my $in, "&lt;", $file) || error("failed to read $file: $!");
	binmode($in) if ($binary);
	return \*$in if $wantfd;
	my $ret=&lt;$in&gt;;
	# check for invalid utf-8, and toss it back to avoid crashes
	if (! utf8::valid($ret)) {
		$ret=encode_utf8($ret);
	}
	close $in || error("failed to read $file: $!");
	return $ret;
}

sub prep_writefile ($$) {
	my $file=shift;
	my $destdir=shift;
	
	my $test=$file;
	while (length $test) {
		if (-l "$destdir/$test") {
			error("cannot write to a symlink ($test)");
		}
		if (-f _ &amp;&amp; $test ne $file) {
			# Remove conflicting file.
			foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
				foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
					if ($f eq $test) {
						unlink("$destdir/$test");
						last;
					}
				}
			}
		}
		$test=dirname($test);
	}

	my $dir=dirname("$destdir/$file");
	if (! -d $dir) {
		my $d="";
		foreach my $s (split(m!/+!, $dir)) {
			$d.="$s/";
			if (! -d $d) {
				mkdir($d) || error("failed to create directory $d: $!");
			}
		}
	}

	return 1;
}

sub writefile ($$$;$$) {
	my $file=shift; # can include subdirs
	my $destdir=shift; # directory to put file in
	my $content=shift;
	my $binary=shift;
	my $writer=shift;
	
	prep_writefile($file, $destdir);
	
	my $newfile="$destdir/$file.ikiwiki-new";
	if (-l $newfile) {
		error("cannot write to a symlink ($newfile)");
	}
	
	my $cleanup = sub { unlink($newfile) };
	open (my $out, '&gt;', $newfile) || error("failed to write $newfile: $!", $cleanup);
	binmode($out) if ($binary);
	if ($writer) {
		$writer-&gt;(\*$out, $cleanup);
	}
	else {
		print $out $content or error("failed writing to $newfile: $!", $cleanup);
	}
	close $out || error("failed saving $newfile: $!", $cleanup);
	rename($newfile, "$destdir/$file") || 
		error("failed renaming $newfile to $destdir/$file: $!", $cleanup);

	return 1;
}

my %cleared;
sub will_render ($$;$) {
	my $page=shift;
	my $dest=shift;
	my $clear=shift;

	# Important security check for independently created files.
	if (-e "$config{destdir}/$dest" &amp;&amp; ! $config{rebuild} &amp;&amp;
	    ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
		my $from_other_page=0;
	    	# Expensive, but rarely runs.
		foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
			if (grep {
				$_ eq $dest ||
				dirname($_) eq $dest
			    } @{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
				$from_other_page=1;
				last;
			}
		}

		error("$config{destdir}/$dest independently created, not overwriting with version from $page")
			unless $from_other_page;
	}

	# If $dest exists as a directory, remove conflicting files in it
	# rendered from other pages.
	if (-d _) {
		foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
			foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
				if (dirname($f) eq $dest) {
					unlink("$config{destdir}/$f");
					rmdir(dirname("$config{destdir}/$f"));
				}
			}
		}
	}

	if (! $clear || $cleared{$page}) {
		$renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
	}
	else {
		foreach my $old (@{$renderedfiles{$page}}) {
			delete $destsources{$old};
		}
		$renderedfiles{$page}=[$dest];
		$cleared{$page}=1;
	}
	$destsources{$dest}=$page;

	return 1;
}

sub bestlink ($$) {
	my $page=shift;
	my $link=shift;
	
	my $cwd=$page;
	if ($link=~s/^\/+//) {
		# absolute links
		$cwd="";
	}
	$link=~s/\/$//;

	do {
		my $l=$cwd;
		$l.="/" if length $l;
		$l.=$link;

		if (exists $pagesources{$l}) {
			return $l;
		}
		elsif (exists $pagecase{lc $l}) {
			return $pagecase{lc $l};
		}
	} while $cwd=~s{/?[^/]+$}{};

	if (length $config{userdir}) {
		my $l = "$config{userdir}/".lc($link);
		if (exists $pagesources{$l}) {
			return $l;
		}
		elsif (exists $pagecase{lc $l}) {
			return $pagecase{lc $l};
		}
	}

	#print STDERR "warning: page $page, broken link: $link\n";
	return "";
}

sub isinlinableimage ($) {
	my $file=shift;
	
	return $file =~ /\.(png|gif|jpg|jpeg|svg)$/i;
}

sub pagetitle ($;$) {
	my $page=shift;
	my $unescaped=shift;

	if ($unescaped) {
		$page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
	}
	else {
		$page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&amp;#$2;"/eg;
	}

	return $page;
}

sub titlepage ($) {
	my $title=shift;
	# support use w/o %config set
	my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
	$title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
	return $title;
}

sub linkpage ($) {
	my $link=shift;
	my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
	$link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
	return $link;
}

sub cgiurl (@) {
	my %params=@_;

	my $cgiurl=$local_cgiurl;

	if (exists $params{cgiurl}) {
		$cgiurl=$params{cgiurl};
		delete $params{cgiurl};
	}

	unless (%params) {
		return $cgiurl;
	}

	return $cgiurl."?".
		join("&amp;amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
}

sub cgiurl_abs (@) {
	eval q{use URI};
	URI-&gt;new_abs(cgiurl(@_), $config{cgiurl});
}

sub baseurl (;$) {
	my $page=shift;

	return $local_url if ! defined $page;
	
	$page=htmlpage($page);
	$page=~s/[^\/]+$//;
	$page=~s/[^\/]+\//..\//g;
	return $page;
}

sub urlabs ($$) {
	my $url=shift;
	my $urlbase=shift;

	return $url unless defined $urlbase &amp;&amp; length $urlbase;

	eval q{use URI};
	URI-&gt;new_abs($url, $urlbase)-&gt;as_string;
}

sub abs2rel ($$) {
	# Work around very innefficient behavior in File::Spec if abs2rel
	# is passed two relative paths. It's much faster if paths are
	# absolute! (Debian bug #376658; fixed in debian unstable now)
	my $path="/".shift;
	my $base="/".shift;

	require File::Spec;
	my $ret=File::Spec-&gt;abs2rel($path, $base);
	$ret=~s/^// if defined $ret;
	return $ret;
}

sub displaytime ($;$$) {
	# Plugins can override this function to mark up the time to
	# display.
	my $time=formattime($_[0], $_[1]);
	if ($config{html5}) {
		return '&lt;time datetime="'.date_3339($_[0]).'"'.
			($_[2] ? ' pubdate="pubdate"' : '').
			'&gt;'.$time.'&lt;/time&gt;';
	}
	else {
		return '&lt;span class="date"&gt;'.$time.'&lt;/span&gt;';
	}
}

sub formattime ($;$) {
	# Plugins can override this function to format the time.
	my $time=shift;
	my $format=shift;
	if (! defined $format) {
		$format=$config{timeformat};
	}

	return strftime_utf8($format, localtime($time));
}

my $strftime_encoding;
sub strftime_utf8 {
	# strftime doesn't know about encodings, so make sure
	# its output is properly treated as utf8.
	# Note that this does not handle utf-8 in the format string.
	($strftime_encoding) = POSIX::setlocale(&amp;POSIX::LC_TIME) =~ m#\.([^@]+)#
		unless defined $strftime_encoding;
	$strftime_encoding
		? Encode::decode($strftime_encoding, POSIX::strftime(@_))
		: POSIX::strftime(@_);
}

sub date_3339 ($) {
	my $time=shift;

	my $lc_time=POSIX::setlocale(&amp;POSIX::LC_TIME);
	POSIX::setlocale(&amp;POSIX::LC_TIME, "C");
	my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
	POSIX::setlocale(&amp;POSIX::LC_TIME, $lc_time);
	return $ret;
}

sub beautify_urlpath ($) {
	my $url=shift;

	# Ensure url is not an empty link, and if necessary,
	# add ./ to avoid colon confusion.
	if ($url !~ /^\// &amp;&amp; $url !~ /^\.\.?\//) {
		$url="./$url";
	}

	if ($config{usedirs}) {
		$url =~ s!/index.$config{htmlext}$!/!;
	}

	return $url;
}

sub urlto ($;$$) {
	my $to=shift;
	my $from=shift;
	my $absolute=shift;
	
	if (! length $to) {
		$to = 'index';
	}

	if (! $destsources{$to}) {
		$to=htmlpage($to);
	}

	if ($absolute) {
		return $config{url}.beautify_urlpath("/".$to);
	}

	if (! defined $from) {
		my $u = $local_url || '';
		$u =~ s{/$}{};
		return $u.beautify_urlpath("/".$to);
	}

	my $link = abs2rel($to, dirname(htmlpage($from)));

	return beautify_urlpath($link);
}

sub isselflink ($$) {
	# Plugins can override this function to support special types
	# of selflinks.
	my $page=shift;
	my $link=shift;

	return $page eq $link;
}

sub htmllink ($$$;@) {
	my $lpage=shift; # the page doing the linking
	my $page=shift; # the page that will contain the link (different for inline)
	my $link=shift;
	my %opts=@_;

	$link=~s/\/$//;

	my $bestlink;
	if (! $opts{forcesubpage}) {
		$bestlink=bestlink($lpage, $link);
	}
	else {
		$bestlink="$lpage/".lc($link);
	}

	my $linktext;
	if (defined $opts{linktext}) {
		$linktext=$opts{linktext};
	}
	else {
		$linktext=pagetitle(basename($link));
	}
	
	return "&lt;span class=\"selflink\"&gt;$linktext&lt;/span&gt;"
		if length $bestlink &amp;&amp; isselflink($page, $bestlink) &amp;&amp;
		   ! defined $opts{anchor};
	
	if (! $destsources{$bestlink}) {
		$bestlink=htmlpage($bestlink);

		if (! $destsources{$bestlink}) {
			my $cgilink = "";
			if (length $config{cgiurl}) {
				$cgilink = "&lt;a href=\"".
					cgiurl(
						do =&gt; "create",
						page =&gt; $link,
						from =&gt; $lpage
					)."\" rel=\"nofollow\"&gt;?&lt;/a&gt;";
			}
			return "&lt;span class=\"createlink\"&gt;$cgilink$linktext&lt;/span&gt;"
		}
	}
	
	$bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
	$bestlink=beautify_urlpath($bestlink);
	
	if (! $opts{noimageinline} &amp;&amp; isinlinableimage($bestlink)) {
		return "&lt;img src=\"$bestlink\" alt=\"$linktext\" /&gt;";
	}

	if (defined $opts{anchor}) {
		$bestlink.="#".$opts{anchor};
	}

	my @attrs;
	foreach my $attr (qw{rel class title}) {
		if (defined $opts{$attr}) {
			push @attrs, " $attr=\"$opts{$attr}\"";
		}
	}

	return "&lt;a href=\"$bestlink\"@attrs&gt;$linktext&lt;/a&gt;";
}

sub userpage ($) {
	my $user=shift;
	return length $config{userdir} ? "$config{userdir}/$user" : $user;
}

sub openiduser ($) {
	my $user=shift;

	if (defined $user &amp;&amp; $user =~ m!^https?://! &amp;&amp;
	    eval q{use Net::OpenID::VerifiedIdentity; 1} &amp;&amp; !$@) {
		my $display;

		if (Net::OpenID::VerifiedIdentity-&gt;can("DisplayOfURL")) {
			$display = Net::OpenID::VerifiedIdentity::DisplayOfURL($user);
		}
		else {
			# backcompat with old version
			my $oid=Net::OpenID::VerifiedIdentity-&gt;new(identity =&gt; $user);
			$display=$oid-&gt;display;
		}

		# Convert "user.somehost.com" to "user [somehost.com]"
		# (also "user.somehost.co.uk")
		if ($display !~ /\[/) {
			$display=~s/^([-a-zA-Z0-9]+?)\.([-.a-zA-Z0-9]+\.[a-z]+)$/$1 [$2]/;
		}
		# Convert "http://somehost.com/user" to "user [somehost.com]".
		# (also "https://somehost.com/user/")
		if ($display !~ /\[/) {
			$display=~s/^https?:\/\/(.+)\/([^\/#?]+)\/?(?:[#?].*)?$/$2 [$1]/;
		}
		$display=~s!^https?://!!; # make sure this is removed
		eval q{use CGI 'escapeHTML'};
		error($@) if $@;
		return escapeHTML($display);
	}
	return;
}

sub htmlize ($$$$) {
	my $page=shift;
	my $destpage=shift;
	my $type=shift;
	my $content=shift;
	
	my $oneline = $content !~ /\n/;
	
	if (exists $hooks{htmlize}{$type}) {
		$content=$hooks{htmlize}{$type}{call}-&gt;(
			page =&gt; $page,
			content =&gt; $content,
		);
	}
	else {
		error("htmlization of $type not supported");
	}

	run_hooks(sanitize =&gt; sub {
		$content=shift-&gt;(
			page =&gt; $page,
			destpage =&gt; $destpage,
			content =&gt; $content,
		);
	});
	
	if ($oneline) {
		# hack to get rid of enclosing junk added by markdown
		# and other htmlizers/sanitizers
		$content=~s/^&lt;p&gt;//i;
		$content=~s/&lt;\/p&gt;\n*$//i;
	}

	return $content;
}

sub linkify ($$$) {
	my $page=shift;
	my $destpage=shift;
	my $content=shift;

	run_hooks(linkify =&gt; sub {
		$content=shift-&gt;(
			page =&gt; $page,
			destpage =&gt; $destpage,
			content =&gt; $content,
		);
	});
	
	return $content;
}

our %preprocessing;
our $preprocess_preview=0;
sub preprocess ($$$;$$) {
	my $page=shift; # the page the data comes from
	my $destpage=shift; # the page the data will appear in (different for inline)
	my $content=shift;
	my $scan=shift;
	my $preview=shift;

	# Using local because it needs to be set within any nested calls
	# of this function.
	local $preprocess_preview=$preview if defined $preview;

	my $handle=sub {
		my $escape=shift;
		my $prefix=shift;
		my $command=shift;
		my $params=shift;
		$params="" if ! defined $params;

		if (length $escape) {
			return "[[$prefix$command $params]]";
		}
		elsif (exists $hooks{preprocess}{$command}) {
			return "" if $scan &amp;&amp; ! $hooks{preprocess}{$command}{scan};
			# Note: preserve order of params, some plugins may
			# consider it significant.
			my @params;
			while ($params =~ m{
				(?:([-\w]+)=)?		# 1: named parameter key?
				(?:
					"""(.*?)"""	# 2: triple-quoted value
				|
					"([^"]*?)"	# 3: single-quoted value
				|
					'''(.*?)'''     # 4: triple-single-quote
				|
					&lt;&lt;([a-zA-Z]+)\n # 5: heredoc start
					(.*?)\n\5	# 6: heredoc value
				|
					(\S+)		# 7: unquoted value
				)
				(?:\s+|$)		# delimiter to next param
			}msgx) {
				my $key=$1;
				my $val;
				if (defined $2) {
					$val=$2;
					$val=~s/\r\n/\n/mg;
					$val=~s/^\n+//g;
					$val=~s/\n+$//g;
				}
				elsif (defined $3) {
					$val=$3;
				}
				elsif (defined $4) {
					$val=$4;
				}
				elsif (defined $7) {
					$val=$7;
				}
				elsif (defined $6) {
					$val=$6;
				}

				if (defined $key) {
					push @params, $key, $val;
				}
				else {
					push @params, $val, '';
				}
			}
			if ($preprocessing{$page}++ &gt; 3) {
				# Avoid loops of preprocessed pages preprocessing
				# other pages that preprocess them, etc.
				return "[[!$command &lt;span class=\"error\"&gt;".
					sprintf(gettext("preprocessing loop detected on %s at depth %i"),
						$page, $preprocessing{$page}).
					"&lt;/span&gt;]]";
			}
			my $ret;
			if (! $scan) {
				$ret=eval {
					$hooks{preprocess}{$command}{call}-&gt;(
						@params,
						page =&gt; $page,
						destpage =&gt; $destpage,
						preview =&gt; $preprocess_preview,
					);
				};
				if ($@) {
					my $error=$@;
					chomp $error;
				 	$ret="[[!$command &lt;span class=\"error\"&gt;".
						gettext("Error").": $error"."&lt;/span&gt;]]";
				}
			}
			else {
				# use void context during scan pass
				eval {
					$hooks{preprocess}{$command}{call}-&gt;(
						@params,
						page =&gt; $page,
						destpage =&gt; $destpage,
						preview =&gt; $preprocess_preview,
					);
				};
				$ret="";
			}
			$preprocessing{$page}--;
			return $ret;
		}
		else {
			return "[[$prefix$command $params]]";
		}
	};
	
	my $regex;
	if ($config{prefix_directives}) {
		$regex = qr{
			(\\?)		# 1: escape?
			\[\[(!)		# directive open; 2: prefix
			([-\w]+)	# 3: command
			(		# 4: the parameters..
				\s+	# Must have space if parameters present
				(?:
					(?:[-\w]+=)?		# named parameter key?
					(?:
						""".*?"""	# triple-quoted value
						|
						"[^"]*?"	# single-quoted value
						|
						'''.*?'''	# triple-single-quote
						|
						&lt;&lt;([a-zA-Z]+)\n # 5: heredoc start
						(?:.*?)\n\5	# heredoc value
						|
						[^"\s\]]+	# unquoted value
					)
					\s*			# whitespace or end
								# of directive
				)
			*)?		# 0 or more parameters
			\]\]		# directive closed
		}sx;
	}
	else {
		$regex = qr{
			(\\?)		# 1: escape?
			\[\[(!?)	# directive open; 2: optional prefix
			([-\w]+)	# 3: command
			\s+
			(		# 4: the parameters..
				(?:
					(?:[-\w]+=)?		# named parameter key?
					(?:
						""".*?"""	# triple-quoted value
						|
						"[^"]*?"	# single-quoted value
						|
						'''.*?'''       # triple-single-quote
						|
						&lt;&lt;([a-zA-Z]+)\n # 5: heredoc start
						(?:.*?)\n\5	# heredoc value
						|
						[^"\s\]]+	# unquoted value
					)
					\s*			# whitespace or end
								# of directive
				)
			*)		# 0 or more parameters
			\]\]		# directive closed
		}sx;
	}

	$content =~ s{$regex}{$handle-&gt;($1, $2, $3, $4)}eg;
	return $content;
}

sub filter ($$$) {
	my $page=shift;
	my $destpage=shift;
	my $content=shift;

	run_hooks(filter =&gt; sub {
		$content=shift-&gt;(page =&gt; $page, destpage =&gt; $destpage, 
			content =&gt; $content);
	});

	return $content;
}

sub check_canedit ($$$;$) {
	my $page=shift;
	my $q=shift;
	my $session=shift;
	my $nonfatal=shift;
	
	my $canedit;
	run_hooks(canedit =&gt; sub {
		return if defined $canedit;
		my $ret=shift-&gt;($page, $q, $session);
		if (defined $ret) {
			if ($ret eq "") {
				$canedit=1;
			}
			elsif (ref $ret eq 'CODE') {
				$ret-&gt;() unless $nonfatal;
				$canedit=0;
			}
			elsif (defined $ret) {
				error($ret) unless $nonfatal;
				$canedit=0;
			}
		}
	});
	return defined $canedit ? $canedit : 1;
}

sub check_content (@) {
	my %params=@_;
	
	return 1 if ! exists $hooks{checkcontent}; # optimisation

	if (exists $pagesources{$params{page}}) {
		my @diff;
		my %old=map { $_ =&gt; 1 }
		        split("\n", readfile(srcfile($pagesources{$params{page}})));
		foreach my $line (split("\n", $params{content})) {
			push @diff, $line if ! exists $old{$line};
		}
		$params{diff}=join("\n", @diff);
	}

	my $ok;
	run_hooks(checkcontent =&gt; sub {
		return if defined $ok;
		my $ret=shift-&gt;(%params);
		if (defined $ret) {
			if ($ret eq "") {
				$ok=1;
			}
			elsif (ref $ret eq 'CODE') {
				$ret-&gt;() unless $params{nonfatal};
				$ok=0;
			}
			elsif (defined $ret) {
				error($ret) unless $params{nonfatal};
				$ok=0;
			}
		}

	});
	return defined $ok ? $ok : 1;
}

sub check_canchange (@) {
	my %params = @_;
	my $cgi = $params{cgi};
	my $session = $params{session};
	my @changes = @{$params{changes}};

	my %newfiles;
	foreach my $change (@changes) {
		# This untaint is safe because we check file_pruned and
		# wiki_file_regexp.
		my ($file)=$change-&gt;{file}=~/$config{wiki_file_regexp}/;
		$file=possibly_foolish_untaint($file);
		if (! defined $file || ! length $file ||
		    file_pruned($file)) {
			error(gettext("bad file name %s"), $file);
		}

		my $type=pagetype($file);
		my $page=pagename($file) if defined $type;

		if ($change-&gt;{action} eq 'add') {
			$newfiles{$file}=1;
		}

		if ($change-&gt;{action} eq 'change' ||
		    $change-&gt;{action} eq 'add') {
			if (defined $page) {
				check_canedit($page, $cgi, $session);
				next;
			}
			else {
				if (IkiWiki::Plugin::attachment-&gt;can("check_canattach")) {
					IkiWiki::Plugin::attachment::check_canattach($session, $file, $change-&gt;{path});
					check_canedit($file, $cgi, $session);
					next;
				}
			}
		}
		elsif ($change-&gt;{action} eq 'remove') {
			# check_canremove tests to see if the file is present
			# on disk. This will fail when a single commit adds a
			# file and then removes it again. Avoid the problem
			# by not testing the removal in such pairs of changes.
			# (The add is still tested, just to make sure that
			# no data is added to the repo that a web edit
			# could not add.)
			next if $newfiles{$file};

			if (IkiWiki::Plugin::remove-&gt;can("check_canremove")) {
				IkiWiki::Plugin::remove::check_canremove(defined $page ? $page : $file, $cgi, $session);
				check_canedit(defined $page ? $page : $file, $cgi, $session);
				next;
			}
		}
		else {
			error "unknown action ".$change-&gt;{action};
		}

		error sprintf(gettext("you are not allowed to change %s"), $file);
	}
}


my $wikilock;

sub lockwiki () {
	# Take an exclusive lock on the wiki to prevent multiple concurrent
	# run issues. The lock will be dropped on program exit.
	if (! -d $config{wikistatedir}) {
		mkdir($config{wikistatedir});
	}
	open($wikilock, '&gt;', "$config{wikistatedir}/lockfile") ||
		error ("cannot write to $config{wikistatedir}/lockfile: $!");
	if (! flock($wikilock, 2)) { # LOCK_EX
		error("failed to get lock");
	}
	return 1;
}

sub unlockwiki () {
	POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
	return close($wikilock) if $wikilock;
	return;
}

my $commitlock;

sub commit_hook_enabled () {
	open($commitlock, '+&gt;', "$config{wikistatedir}/commitlock") ||
		error("cannot write to $config{wikistatedir}/commitlock: $!");
	if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
		close($commitlock) || error("failed closing commitlock: $!");
		return 0;
	}
	close($commitlock) || error("failed closing commitlock: $!");
	return 1;
}

sub disable_commit_hook () {
	open($commitlock, '&gt;', "$config{wikistatedir}/commitlock") ||
		error("cannot write to $config{wikistatedir}/commitlock: $!");
	if (! flock($commitlock, 2)) { # LOCK_EX
		error("failed to get commit lock");
	}
	return 1;
}

sub enable_commit_hook () {
	return close($commitlock) if $commitlock;
	return;
}

sub loadindex () {
	%oldrenderedfiles=%pagectime=();
	if (! $config{rebuild}) {
		%pagesources=%pagemtime=%oldlinks=%links=%depends=
		%destsources=%renderedfiles=%pagecase=%pagestate=
		%depends_simple=%typedlinks=%oldtypedlinks=();
	}
	my $in;
	if (! open ($in, "&lt;", "$config{wikistatedir}/indexdb")) {
		if (-e "$config{wikistatedir}/index") {
			system("ikiwiki-transition", "indexdb", $config{srcdir});
			open ($in, "&lt;", "$config{wikistatedir}/indexdb") || return;
		}
		else {
			$config{gettime}=1; # first build
			return;
		}
	}

	my $index=Storable::fd_retrieve($in);
	if (! defined $index) {
		return 0;
	}

	my $pages;
	if (exists $index-&gt;{version} &amp;&amp; ! ref $index-&gt;{version}) {
		$pages=$index-&gt;{page};
		%wikistate=%{$index-&gt;{state}};
		# Handle plugins that got disabled by loading a new setup.
		if (exists $config{setupfile}) {
			require IkiWiki::Setup;
			IkiWiki::Setup::disabled_plugins(
				grep { ! $loaded_plugins{$_} } keys %wikistate);
		}
	}
	else {
		$pages=$index;
		%wikistate=();
	}

	foreach my $src (keys %$pages) {
		my $d=$pages-&gt;{$src};
		my $page=pagename($src);
		$pagectime{$page}=$d-&gt;{ctime};
		$pagesources{$page}=$src;
		if (! $config{rebuild}) {
			$pagemtime{$page}=$d-&gt;{mtime};
			$renderedfiles{$page}=$d-&gt;{dest};
			if (exists $d-&gt;{links} &amp;&amp; ref $d-&gt;{links}) {
				$links{$page}=$d-&gt;{links};
				$oldlinks{$page}=[@{$d-&gt;{links}}];
			}
			if (ref $d-&gt;{depends_simple} eq 'ARRAY') {
				# old format
				$depends_simple{$page}={
					map { $_ =&gt; 1 } @{$d-&gt;{depends_simple}}
				};
			}
			elsif (exists $d-&gt;{depends_simple}) {
				$depends_simple{$page}=$d-&gt;{depends_simple};
			}
			if (exists $d-&gt;{dependslist}) {
				# old format
				$depends{$page}={
					map { $_ =&gt; $DEPEND_CONTENT }
						@{$d-&gt;{dependslist}}
				};
			}
			elsif (exists $d-&gt;{depends} &amp;&amp; ! ref $d-&gt;{depends}) {
				# old format
				$depends{$page}={$d-&gt;{depends} =&gt; $DEPEND_CONTENT };
			}
			elsif (exists $d-&gt;{depends}) {
				$depends{$page}=$d-&gt;{depends};
			}
			if (exists $d-&gt;{state}) {
				$pagestate{$page}=$d-&gt;{state};
			}
			if (exists $d-&gt;{typedlinks}) {
				$typedlinks{$page}=$d-&gt;{typedlinks};

				while (my ($type, $links) = each %{$typedlinks{$page}}) {
					next unless %$links;
					$oldtypedlinks{$page}{$type} = {%$links};
				}
			}
		}
		$oldrenderedfiles{$page}=[@{$d-&gt;{dest}}];
	}
	foreach my $page (keys %pagesources) {
		$pagecase{lc $page}=$page;
	}
	foreach my $page (keys %renderedfiles) {
		$destsources{$_}=$page foreach @{$renderedfiles{$page}};
	}
	return close($in);
}

sub saveindex () {
	run_hooks(savestate =&gt; sub { shift-&gt;() });

	my @plugins=keys %loaded_plugins;

	if (! -d $config{wikistatedir}) {
		mkdir($config{wikistatedir});
	}
	my $newfile="$config{wikistatedir}/indexdb.new";
	my $cleanup = sub { unlink($newfile) };
	open (my $out, '&gt;', $newfile) || error("cannot write to $newfile: $!", $cleanup);

	my %index;
	foreach my $page (keys %pagemtime) {
		next unless $pagemtime{$page};
		my $src=$pagesources{$page};

		$index{page}{$src}={
			ctime =&gt; $pagectime{$page},
			mtime =&gt; $pagemtime{$page},
			dest =&gt; $renderedfiles{$page},
			links =&gt; $links{$page},
		};

		if (exists $depends{$page}) {
			$index{page}{$src}{depends} = $depends{$page};
		}

		if (exists $depends_simple{$page}) {
			$index{page}{$src}{depends_simple} = $depends_simple{$page};
		}

		if (exists $typedlinks{$page} &amp;&amp; %{$typedlinks{$page}}) {
			$index{page}{$src}{typedlinks} = $typedlinks{$page};
		}

		if (exists $pagestate{$page}) {
			foreach my $id (@plugins) {
				foreach my $key (keys %{$pagestate{$page}{$id}}) {
					$index{page}{$src}{state}{$id}{$key}=$pagestate{$page}{$id}{$key};
				}
			}
		}
	}

	$index{state}={};
	foreach my $id (@plugins) {
		$index{state}{$id}={}; # used to detect disabled plugins
		foreach my $key (keys %{$wikistate{$id}}) {
			$index{state}{$id}{$key}=$wikistate{$id}{$key};
		}
	}
	
	$index{version}="3";
	my $ret=Storable::nstore_fd(\%index, $out);
	return if ! defined $ret || ! $ret;
	close $out || error("failed saving to $newfile: $!", $cleanup);
	rename($newfile, "$config{wikistatedir}/indexdb") ||
		error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
	
	return 1;
}

sub template_file ($) {
	my $name=shift;
	
	my $tpage=($name =~ s/^\///) ? $name : "templates/$name";
	my $template;
	if ($name !~ /\.tmpl$/ &amp;&amp; exists $pagesources{$tpage}) {
		$template=srcfile($pagesources{$tpage}, 1);
		$name.=".tmpl";
	}
	else {
		$template=srcfile($tpage, 1);
	}

	if (defined $template) {
		return $template, $tpage, 1 if wantarray;
		return $template;
	}
	else {
		$name=~s:/::; # avoid path traversal
		foreach my $dir ($config{templatedir},
		                 "$installdir/share/ikiwiki/templates") {
			if (-e "$dir/$name") {
				$template="$dir/$name";
				last;
			}
		}
		if (defined $template) {	
			return $template, $tpage if wantarray;
			return $template;
		}
	}

	return;
}

sub template_depends ($$;@) {
	my $name=shift;
	my $page=shift;
	
	my ($filename, $tpage, $untrusted)=template_file($name);
	if (! defined $filename) {
		error(sprintf(gettext("template %s not found"), $name))
	}

	if (defined $page &amp;&amp; defined $tpage) {
		add_depends($page, $tpage);
	}
	
	my @opts=(
		filter =&gt; sub {
			my $text_ref = shift;
			${$text_ref} = decode_utf8(${$text_ref});
		},
		loop_context_vars =&gt; 1,
		die_on_bad_params =&gt; 0,
		parent_global_vars =&gt; 1,
		filename =&gt; $filename,
		@_,
		($untrusted ? (no_includes =&gt; 1) : ()),
	);
	return @opts if wantarray;

	require HTML::Template;
	return HTML::Template-&gt;new(@opts);
}

sub template ($;@) {
	template_depends(shift, undef, @_);
}

sub templateactions ($$) {
	my $template=shift;
	my $page=shift;

	my $have_actions=0;
	my @actions;
	run_hooks(pageactions =&gt; sub {
		push @actions, map { { action =&gt; $_ } } 
			grep { defined } shift-&gt;(page =&gt; $page);
	});
	$template-&gt;param(actions =&gt; \@actions);

	if ($config{cgiurl} &amp;&amp; exists $hooks{auth}) {
		$template-&gt;param(prefsurl =&gt; cgiurl(do =&gt; "prefs"));
		$have_actions=1;
	}

	if ($have_actions || @actions) {
		$template-&gt;param(have_actions =&gt; 1);
	}
}

sub hook (@) {
	my %param=@_;
	
	if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
		error 'hook requires type, call, and id parameters';
	}

	return if $param{no_override} &amp;&amp; exists $hooks{$param{type}}{$param{id}};
	
	$hooks{$param{type}}{$param{id}}=\%param;
	return 1;
}

sub run_hooks ($$) {
	# Calls the given sub for each hook of the given type,
	# passing it the hook function to call.
	my $type=shift;
	my $sub=shift;

	if (exists $hooks{$type}) {
		my (@first, @middle, @last);
		foreach my $id (keys %{$hooks{$type}}) {
			if ($hooks{$type}{$id}{first}) {
				push @first, $id;
			}
			elsif ($hooks{$type}{$id}{last}) {
				push @last, $id;
			}
			else {
				push @middle, $id;
			}
		}
		foreach my $id (@first, @middle, @last) {
			$sub-&gt;($hooks{$type}{$id}{call});
		}
	}

	return 1;
}

sub rcs_update () {
	$hooks{rcs}{rcs_update}{call}-&gt;(@_);
}

sub rcs_prepedit ($) {
	$hooks{rcs}{rcs_prepedit}{call}-&gt;(@_);
}

sub rcs_commit (@) {
	$hooks{rcs}{rcs_commit}{call}-&gt;(@_);
}

sub rcs_commit_staged (@) {
	$hooks{rcs}{rcs_commit_staged}{call}-&gt;(@_);
}

sub rcs_add ($) {
	$hooks{rcs}{rcs_add}{call}-&gt;(@_);
}

sub rcs_remove ($) {
	$hooks{rcs}{rcs_remove}{call}-&gt;(@_);
}

sub rcs_rename ($$) {
	$hooks{rcs}{rcs_rename}{call}-&gt;(@_);
}

sub rcs_recentchanges ($) {
	$hooks{rcs}{rcs_recentchanges}{call}-&gt;(@_);
}

sub rcs_diff ($;$) {
	$hooks{rcs}{rcs_diff}{call}-&gt;(@_);
}

sub rcs_getctime ($) {
	$hooks{rcs}{rcs_getctime}{call}-&gt;(@_);
}

sub rcs_getmtime ($) {
	$hooks{rcs}{rcs_getmtime}{call}-&gt;(@_);
}

sub rcs_receive () {
	$hooks{rcs}{rcs_receive}{call}-&gt;();
}

sub add_depends ($$;$) {
	my $page=shift;
	my $pagespec=shift;
	my $deptype=shift || $DEPEND_CONTENT;

	# Is the pagespec a simple page name?
	if ($pagespec =~ /$config{wiki_file_regexp}/ &amp;&amp;
	    $pagespec !~ /[\s*?()!]/) {
		$depends_simple{$page}{lc $pagespec} |= $deptype;
		return 1;
	}

	# Add explicit dependencies for influences.
	my $sub=pagespec_translate($pagespec);
	return unless defined $sub;
	foreach my $p (keys %pagesources) {
		my $r=$sub-&gt;($p, location =&gt; $page);
		my $i=$r-&gt;influences;
		my $static=$r-&gt;influences_static;
		foreach my $k (keys %$i) {
			next unless $r || $static || $k eq $page;
			$depends_simple{$page}{lc $k} |= $i-&gt;{$k};
		}
		last if $static;
	}

	$depends{$page}{$pagespec} |= $deptype;
	return 1;
}

sub deptype (@) {
	my $deptype=0;
	foreach my $type (@_) {
		if ($type eq 'presence') {
			$deptype |= $DEPEND_PRESENCE;
		}
		elsif ($type eq 'links') { 
			$deptype |= $DEPEND_LINKS;
		}
		elsif ($type eq 'content') {
			$deptype |= $DEPEND_CONTENT;
		}
	}
	return $deptype;
}

my $file_prune_regexp;
sub file_pruned ($) {
	my $file=shift;

	if (defined $config{include} &amp;&amp; length $config{include}) {
		return 0 if $file =~ m/$config{include}/;
	}

	if (! defined $file_prune_regexp) {
		$file_prune_regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
		$file_prune_regexp=qr/$file_prune_regexp/;
	}
	return $file =~ m/$file_prune_regexp/;
}

sub define_gettext () {
	# If translation is needed, redefine the gettext function to do it.
	# Otherwise, it becomes a quick no-op.
	my $gettext_obj;
	my $getobj;
	if ((exists $ENV{LANG} &amp;&amp; length $ENV{LANG}) ||
	    (exists $ENV{LC_ALL} &amp;&amp; length $ENV{LC_ALL}) ||
	    (exists $ENV{LC_MESSAGES} &amp;&amp; length $ENV{LC_MESSAGES})) {
	    	$getobj=sub {
			$gettext_obj=eval q{
				use Locale::gettext q{textdomain};
				Locale::gettext-&gt;domain('ikiwiki')
			};
		};
	}

	no warnings 'redefine';
	*gettext=sub {
		$getobj-&gt;() if $getobj;
		if ($gettext_obj) {
			$gettext_obj-&gt;get(shift);
		}
		else {
			return shift;
		}
	};
	*ngettext=sub {
		$getobj-&gt;() if $getobj;
		if ($gettext_obj) {
			$gettext_obj-&gt;nget(@_);
		}
		else {
			return ($_[2] == 1 ? $_[0] : $_[1])
		}
	};
}

sub gettext {
	define_gettext();
	gettext(@_);
}

sub ngettext {
	define_gettext();
	ngettext(@_);
}

sub yesno ($) {
	my $val=shift;

	return (defined $val &amp;&amp; (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
}

sub inject {
	# Injects a new function into the symbol table to replace an
	# exported function.
	my %params=@_;

	# This is deep ugly perl foo, beware.
	no strict;
	no warnings;
	if (! defined $params{parent}) {
		$params{parent}='::';
		$params{old}=\&amp;{$params{name}};
		$params{name}=~s/.*:://;
	}
	my $parent=$params{parent};
	foreach my $ns (grep /^\w+::/, keys %{$parent}) {
		$ns = $params{parent} . $ns;
		inject(%params, parent =&gt; $ns) unless $ns eq '::main::';
		*{$ns . $params{name}} = $params{call}
			if exists ${$ns}{$params{name}} &amp;&amp;
			   \&amp;{${$ns}{$params{name}}} == $params{old};
	}
	use strict;
	use warnings;
}

sub add_link ($$;$) {
	my $page=shift;
	my $link=shift;
	my $type=shift;

	push @{$links{$page}}, $link
		unless grep { $_ eq $link } @{$links{$page}};

	if (defined $type) {
		$typedlinks{$page}{$type}{$link} = 1;
	}
}

sub add_autofile ($$$) {
	my $file=shift;
	my $plugin=shift;
	my $generator=shift;
	
	$autofiles{$file}{plugin}=$plugin;
	$autofiles{$file}{generator}=$generator;
}

sub sortspec_translate ($$) {
	my $spec = shift;
	my $reverse = shift;

	my $code = "";
	my @data;
	while ($spec =~ m{
		\s*
		(-?)		# group 1: perhaps negated
		\s*
		(		# group 2: a word
			\w+\([^\)]*\)	# command(params)
			|
			[^\s]+		# or anything else
		)
		\s*
	}gx) {
		my $negated = $1;
		my $word = $2;
		my $params = undef;

		if ($word =~ m/^(\w+)\((.*)\)$/) {
			# command with parameters
			$params = $2;
			$word = $1;
		}
		elsif ($word !~ m/^\w+$/) {
			error(sprintf(gettext("invalid sort type %s"), $word));
		}

		if (length $code) {
			$code .= " || ";
		}

		if ($negated) {
			$code .= "-";
		}

		if (exists $IkiWiki::SortSpec::{"cmp_$word"}) {
			if (defined $params) {
				push @data, $params;
				$code .= "IkiWiki::SortSpec::cmp_$word(\$data[$#data])";
			}
			else {
				$code .= "IkiWiki::SortSpec::cmp_$word(undef)";
			}
		}
		else {
			error(sprintf(gettext("unknown sort type %s"), $word));
		}
	}

	if (! length $code) {
		# undefined sorting method... sort arbitrarily
		return sub { 0 };
	}

	if ($reverse) {
		$code="-($code)";
	}

	no warnings;
	return eval 'sub { '.$code.' }';
}

sub pagespec_translate ($) {
	my $spec=shift;

	# Convert spec to perl code.
	my $code="";
	my @data;
	while ($spec=~m{
		\s*		# ignore whitespace
		(		# 1: match a single word
			\!		# !
		|
			\(		# (
		|
			\)		# )
		|
			\w+\([^\)]*\)	# command(params)
		|
			[^\s()]+	# any other text
		)
		\s*		# ignore whitespace
	}gx) {
		my $word=$1;
		if (lc $word eq 'and') {
			$code.=' &amp;';
		}
		elsif (lc $word eq 'or') {
			$code.=' |';
		}
		elsif ($word eq "(" || $word eq ")" || $word eq "!") {
			$code.=' '.$word;
		}
		elsif ($word =~ /^(\w+)\((.*)\)$/) {
			if (exists $IkiWiki::PageSpec::{"match_$1"}) {
				push @data, $2;
				$code.="IkiWiki::PageSpec::match_$1(\$page, \$data[$#data], \@_)";
			}
			else {
				push @data, qq{unknown function in pagespec "$word"};
				$code.="IkiWiki::ErrorReason-&gt;new(\$data[$#data])";
			}
		}
		else {
			push @data, $word;
			$code.=" IkiWiki::PageSpec::match_glob(\$page, \$data[$#data], \@_)";
		}
	}

	if (! length $code) {
		$code="IkiWiki::FailReason-&gt;new('empty pagespec')";
	}

	no warnings;
	return eval 'sub { my $page=shift; '.$code.' }';
}

sub pagespec_match ($$;@) {
	my $page=shift;
	my $spec=shift;
	my @params=@_;

	# Backwards compatability with old calling convention.
	if (@params == 1) {
		unshift @params, 'location';
	}

	my $sub=pagespec_translate($spec);
	return IkiWiki::ErrorReason-&gt;new("syntax error in pagespec \"$spec\"")
		if ! defined $sub;
	return $sub-&gt;($page, @params);
}

sub pagespec_match_list ($$;@) {
	my $page=shift;
	my $pagespec=shift;
	my %params=@_;

	# Backwards compatability with old calling convention.
	if (ref $page) {
		print STDERR "warning: a plugin (".caller().") is using pagespec_match_list in an obsolete way, and needs to be updated\n";
		$params{list}=$page;
		$page=$params{location}; # ugh!
	}

	my $sub=pagespec_translate($pagespec);
	error "syntax error in pagespec \"$pagespec\""
		if ! defined $sub;
	my $sort=sortspec_translate($params{sort}, $params{reverse})
		if defined $params{sort};

	my @candidates;
	if (exists $params{list}) {
		@candidates=exists $params{filter}
			? grep { ! $params{filter}-&gt;($_) } @{$params{list}}
			: @{$params{list}};
	}
	else {
		@candidates=exists $params{filter}
			? grep { ! $params{filter}-&gt;($_) } keys %pagesources
			: keys %pagesources;
	}
	
	# clear params, remainder is passed to pagespec
	$depends{$page}{$pagespec} |= ($params{deptype} || $DEPEND_CONTENT);
	my $num=$params{num};
	delete @params{qw{num deptype reverse sort filter list}};
	
	# when only the top matches will be returned, it's efficient to
	# sort before matching to pagespec,
	if (defined $num &amp;&amp; defined $sort) {
		@candidates=IkiWiki::SortSpec::sort_pages(
			$sort, @candidates);
	}
	
	my @matches;
	my $firstfail;
	my $count=0;
	my $accum=IkiWiki::SuccessReason-&gt;new();
	foreach my $p (@candidates) {
		my $r=$sub-&gt;($p, %params, location =&gt; $page);
		error(sprintf(gettext("cannot match pages: %s"), $r))
			if $r-&gt;isa("IkiWiki::ErrorReason");
		unless ($r || $r-&gt;influences_static) {
			$r-&gt;remove_influence($p);
		}
		$accum |= $r;
		if ($r) {
			push @matches, $p;
			last if defined $num &amp;&amp; ++$count == $num;
		}
	}

	# Add simple dependencies for accumulated influences.
	my $i=$accum-&gt;influences;
	foreach my $k (keys %$i) {
		$depends_simple{$page}{lc $k} |= $i-&gt;{$k};
	}

	# when all matches will be returned, it's efficient to
	# sort after matching
	if (! defined $num &amp;&amp; defined $sort) {
		return IkiWiki::SortSpec::sort_pages(
			$sort, @matches);
	}
	else {
		return @matches;
	}
}

sub pagespec_valid ($) {
	my $spec=shift;

	return defined pagespec_translate($spec);
}

sub glob2re ($) {
	my $re=quotemeta(shift);
	$re=~s/\\\*/.*/g;
	$re=~s/\\\?/./g;
	return qr/^$re$/i;
}

package IkiWiki::FailReason;

use overload (
	'""'	=&gt; sub { $_[0][0] },
	'0+'	=&gt; sub { 0 },
	'!'	=&gt; sub { bless $_[0], 'IkiWiki::SuccessReason'},
	'&amp;'	=&gt; sub { $_[0]-&gt;merge_influences($_[1], 1); $_[0] },
	'|'	=&gt; sub { $_[1]-&gt;merge_influences($_[0]); $_[1] },
	fallback =&gt; 1,
);

our @ISA = 'IkiWiki::SuccessReason';

package IkiWiki::SuccessReason;

use overload (
	'""'	=&gt; sub { $_[0][0] },
	'0+'	=&gt; sub { 1 },
	'!'	=&gt; sub { bless $_[0], 'IkiWiki::FailReason'},
	'&amp;'	=&gt; sub { $_[1]-&gt;merge_influences($_[0], 1); $_[1] },
	'|'	=&gt; sub { $_[0]-&gt;merge_influences($_[1]); $_[0] },
	fallback =&gt; 1,
);

sub new {
	my $class = shift;
	my $value = shift;
	return bless [$value, {@_}], $class;
}

sub influences {
	my $this=shift;
	$this-&gt;[1]={@_} if @_;
	my %i=%{$this-&gt;[1]};
	delete $i{""};
	return \%i;
}

sub influences_static {
	return ! $_[0][1]-&gt;{""};
}

sub merge_influences {
	my $this=shift;
	my $other=shift;
	my $anded=shift;

	if (! $anded || (($this || %{$this-&gt;[1]}) &amp;&amp;
	                 ($other || %{$other-&gt;[1]}))) {
		foreach my $influence (keys %{$other-&gt;[1]}) {
			$this-&gt;[1]{$influence} |= $other-&gt;[1]{$influence};
		}
	}
	else {
		# influence blocker
		$this-&gt;[1]={};
	}
}

sub remove_influence {
	my $this=shift;
	my $torm=shift;

	delete $this-&gt;[1]{$torm};
}

package IkiWiki::ErrorReason;

our @ISA = 'IkiWiki::FailReason';

package IkiWiki::PageSpec;

sub derel ($$) {
	my $path=shift;
	my $from=shift;

	if ($path =~ m!^\.(/|$)!) {
		if ($1) {
			$from=~s#/?[^/]+$## if defined $from;
			$path=~s#^\./##;
			$path="$from/$path" if defined $from &amp;&amp; length $from;
		}
		else {
			$path = $from;
			$path = "" unless defined $path;
		}
	}

	return $path;
}

my %glob_cache;

sub match_glob ($$;@) {
	my $page=shift;
	my $glob=shift;
	my %params=@_;
	
	$glob=derel($glob, $params{location});

	# Instead of converting the glob to a regex every time,
	# cache the compiled regex to save time.
	my $re=$glob_cache{$glob};
	unless (defined $re) {
		$glob_cache{$glob} = $re = IkiWiki::glob2re($glob);
	}
	if ($page =~ $re) {
		if (! IkiWiki::isinternal($page) || $params{internal}) {
			return IkiWiki::SuccessReason-&gt;new("$glob matches $page");
		}
		else {
			return IkiWiki::FailReason-&gt;new("$glob matches $page, but the page is an internal page");
		}
	}
	else {
		return IkiWiki::FailReason-&gt;new("$glob does not match $page");
	}
}

sub match_internal ($$;@) {
	return match_glob(shift, shift, @_, internal =&gt; 1)
}

sub match_page ($$;@) {
	my $page=shift;
	my $match=match_glob($page, shift, @_);
	if ($match) {
		my $source=exists $IkiWiki::pagesources{$page} ?
			$IkiWiki::pagesources{$page} :
			$IkiWiki::delpagesources{$page};
		my $type=defined $source ? IkiWiki::pagetype($source) : undef;
		if (! defined $type) {	
			return IkiWiki::FailReason-&gt;new("$page is not a page");
		}
	}
	return $match;
}

sub match_link ($$;@) {
	my $page=shift;
	my $link=lc(shift);
	my %params=@_;

	$link=derel($link, $params{location});
	my $from=exists $params{location} ? $params{location} : '';
	my $linktype=$params{linktype};
	my $qualifier='';
	if (defined $linktype) {
		$qualifier=" with type $linktype";
	}

	my $links = $IkiWiki::links{$page};
	return IkiWiki::FailReason-&gt;new("$page has no links", $page =&gt; $IkiWiki::DEPEND_LINKS, "" =&gt; 1)
		unless $links &amp;&amp; @{$links};
	my $bestlink = IkiWiki::bestlink($from, $link);
	foreach my $p (@{$links}) {
		next unless (! defined $linktype || exists $IkiWiki::typedlinks{$page}{$linktype}{$p});

		if (length $bestlink) {
			if ($bestlink eq IkiWiki::bestlink($page, $p)) {
				return IkiWiki::SuccessReason-&gt;new("$page links to $link$qualifier", $page =&gt; $IkiWiki::DEPEND_LINKS, "" =&gt; 1)
			}
		}
		else {
			if (match_glob($p, $link, %params)) {
				return IkiWiki::SuccessReason-&gt;new("$page links to page $p$qualifier, matching $link", $page =&gt; $IkiWiki::DEPEND_LINKS, "" =&gt; 1)
			}
			my ($p_rel)=$p=~/^\/?(.*)/;
			$link=~s/^\///;
			if (match_glob($p_rel, $link, %params)) {
				return IkiWiki::SuccessReason-&gt;new("$page links to page $p_rel$qualifier, matching $link", $page =&gt; $IkiWiki::DEPEND_LINKS, "" =&gt; 1)
			}
		}
	}
	return IkiWiki::FailReason-&gt;new("$page does not link to $link$qualifier", $page =&gt; $IkiWiki::DEPEND_LINKS, "" =&gt; 1);
}

sub match_backlink ($$;@) {
	my $page=shift;
	my $testpage=shift;
	my %params=@_;
	if ($testpage eq '.') {
		$testpage = $params{'location'}
	}
	my $ret=match_link($testpage, $page, @_);
	$ret-&gt;influences($testpage =&gt; $IkiWiki::DEPEND_LINKS);
	return $ret;
}

sub match_created_before ($$;@) {
	my $page=shift;
	my $testpage=shift;
	my %params=@_;
	
	$testpage=derel($testpage, $params{location});

	if (exists $IkiWiki::pagectime{$testpage}) {
		if ($IkiWiki::pagectime{$page} &lt; $IkiWiki::pagectime{$testpage}) {
			return IkiWiki::SuccessReason-&gt;new("$page created before $testpage", $testpage =&gt; $IkiWiki::DEPEND_PRESENCE);
		}
		else {
			return IkiWiki::FailReason-&gt;new("$page not created before $testpage", $testpage =&gt; $IkiWiki::DEPEND_PRESENCE);
		}
	}
	else {
		return IkiWiki::ErrorReason-&gt;new("$testpage does not exist", $testpage =&gt; $IkiWiki::DEPEND_PRESENCE);
	}
}

sub match_created_after ($$;@) {
	my $page=shift;
	my $testpage=shift;
	my %params=@_;
	
	$testpage=derel($testpage, $params{location});

	if (exists $IkiWiki::pagectime{$testpage}) {
		if ($IkiWiki::pagectime{$page} &gt; $IkiWiki::pagectime{$testpage}) {
			return IkiWiki::SuccessReason-&gt;new("$page created after $testpage", $testpage =&gt; $IkiWiki::DEPEND_PRESENCE);
		}
		else {
			return IkiWiki::FailReason-&gt;new("$page not created after $testpage", $testpage =&gt; $IkiWiki::DEPEND_PRESENCE);
		}
	}
	else {
		return IkiWiki::ErrorReason-&gt;new("$testpage does not exist", $testpage =&gt; $IkiWiki::DEPEND_PRESENCE);
	}
}

sub match_creation_day ($$;@) {
	my $page=shift;
	my $d=shift;
	if ($d !~ /^\d+$/) {
		return IkiWiki::ErrorReason-&gt;new("invalid day $d");
	}
	if ((localtime($IkiWiki::pagectime{$page}))[3] == $d) {
		return IkiWiki::SuccessReason-&gt;new('creation_day matched');
	}
	else {
		return IkiWiki::FailReason-&gt;new('creation_day did not match');
	}
}

sub match_creation_month ($$;@) {
	my $page=shift;
	my $m=shift;
	if ($m !~ /^\d+$/) {
		return IkiWiki::ErrorReason-&gt;new("invalid month $m");
	}
	if ((localtime($IkiWiki::pagectime{$page}))[4] + 1 == $m) {
		return IkiWiki::SuccessReason-&gt;new('creation_month matched');
	}
	else {
		return IkiWiki::FailReason-&gt;new('creation_month did not match');
	}
}

sub match_creation_year ($$;@) {
	my $page=shift;
	my $y=shift;
	if ($y !~ /^\d+$/) {
		return IkiWiki::ErrorReason-&gt;new("invalid year $y");
	}
	if ((localtime($IkiWiki::pagectime{$page}))[5] + 1900 == $y) {
		return IkiWiki::SuccessReason-&gt;new('creation_year matched');
	}
	else {
		return IkiWiki::FailReason-&gt;new('creation_year did not match');
	}
}

sub match_user ($$;@) {
	shift;
	my $user=shift;
	my %params=@_;
	
	my $regexp=IkiWiki::glob2re($user);
	
	if (! exists $params{user}) {
		return IkiWiki::ErrorReason-&gt;new("no user specified");
	}

	if (defined $params{user} &amp;&amp; $params{user}=~$regexp) {
		return IkiWiki::SuccessReason-&gt;new("user is $user");
	}
	elsif (! defined $params{user}) {
		return IkiWiki::FailReason-&gt;new("not logged in");
	}
	else {
		return IkiWiki::FailReason-&gt;new("user is $params{user}, not $user");
	}
}

sub match_admin ($$;@) {
	shift;
	shift;
	my %params=@_;
	
	if (! exists $params{user}) {
		return IkiWiki::ErrorReason-&gt;new("no user specified");
	}

	if (defined $params{user} &amp;&amp; IkiWiki::is_admin($params{user})) {
		return IkiWiki::SuccessReason-&gt;new("user is an admin");
	}
	elsif (! defined $params{user}) {
		return IkiWiki::FailReason-&gt;new("not logged in");
	}
	else {
		return IkiWiki::FailReason-&gt;new("user is not an admin");
	}
}

sub match_ip ($$;@) {
	shift;
	my $ip=shift;
	my %params=@_;
	
	if (! exists $params{ip}) {
		return IkiWiki::ErrorReason-&gt;new("no IP specified");
	}

	if (defined $params{ip} &amp;&amp; lc $params{ip} eq lc $ip) {
		return IkiWiki::SuccessReason-&gt;new("IP is $ip");
	}
	else {
		return IkiWiki::FailReason-&gt;new("IP is $params{ip}, not $ip");
	}
}

package IkiWiki::SortSpec;

# This is in the SortSpec namespace so that the $a and $b that sort() uses
# are easily available in this namespace, for cmp functions to use them.
sub sort_pages {
	my $f=shift;
	sort $f @_
}

sub cmp_title {
	IkiWiki::pagetitle(IkiWiki::basename($a))
	cmp
	IkiWiki::pagetitle(IkiWiki::basename($b))
}

sub cmp_path { IkiWiki::pagetitle($a) cmp IkiWiki::pagetitle($b) }
sub cmp_mtime { $IkiWiki::pagemtime{$b} &lt;=&gt; $IkiWiki::pagemtime{$a} }
sub cmp_age { $IkiWiki::pagectime{$b} &lt;=&gt; $IkiWiki::pagectime{$a} }

1
</pre></body></html>