<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl

package IkiWiki;

use warnings;
use strict;
use Encode;
use HTML::Entities;
use URI::Escape q{uri_escape_utf8};
use POSIX;
use Storable;
use open qw{:utf8 :std};

use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
	    %pagestate %wikistate %renderedfiles %oldrenderedfiles
	    %pagesources %destsources %depends %hooks %forcerebuild
	    $gettext_obj %loaded_plugins};

use Exporter q{import};
our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
                 bestlink htmllink readfile writefile pagetype srcfile pagename
                 displaytime will_render gettext urlto targetpage
		 add_underlay pagetitle titlepage linkpage newpagefile
		 inject
                 %config %links %pagestate %wikistate %renderedfiles
                 %pagesources %destsources);
our $VERSION = 2.00; # plugin interface version, next is ikiwiki version
our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE

# Optimisation.
use Memoize;
memoize("abs2rel");
memoize("pagespec_translate");
memoize("file_pruned");

sub getsetup () { #{{{
	wikiname =&gt; {
		type =&gt; "string",
		default =&gt; "wiki",
		description =&gt; "name of the wiki",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	adminemail =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; 'me@example.com',
		description =&gt; "contact email for wiki",
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	adminuser =&gt; {
		type =&gt; "string",
		default =&gt; [],
		description =&gt; "users who are wiki admins",
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	banned_users =&gt; {
		type =&gt; "string",
		default =&gt; [],
		description =&gt; "users who are banned from the wiki",
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	srcdir =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; "$ENV{HOME}/wiki",
		description =&gt; "where the source of the wiki is located",
		safe =&gt; 0, # path
		rebuild =&gt; 1,
	},
	destdir =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; "/var/www/wiki",
		description =&gt; "where to build the wiki",
		safe =&gt; 0, # path
		rebuild =&gt; 1,
	},
	url =&gt; {
		type =&gt; "string",
		default =&gt; '',
		example =&gt; "http://example.com/wiki",
		description =&gt; "base url to the wiki",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	cgiurl =&gt; {
		type =&gt; "string",
		default =&gt; '',
		example =&gt; "http://example.com/wiki/ikiwiki.cgi",
		description =&gt; "url to the ikiwiki.cgi",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	cgi_wrapper =&gt; {
		type =&gt; "string",
		default =&gt; '',
		example =&gt; "/var/www/wiki/ikiwiki.cgi",
		description =&gt; "cgi wrapper to generate",
		safe =&gt; 0, # file
		rebuild =&gt; 0,
	},
	cgi_wrappermode =&gt; {
		type =&gt; "string",
		default =&gt; '06755',
		description =&gt; "mode for cgi_wrapper (can safely be made suid)",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	rcs =&gt; {
		type =&gt; "string",
		default =&gt; '',
		description =&gt; "rcs backend to use",
		safe =&gt; 0, # don't allow overriding
		rebuild =&gt; 0,
	},
	default_plugins =&gt; {
		type =&gt; "internal",
		default =&gt; [qw{mdwn link inline meta htmlscrubber passwordauth
				openid signinedit lockedit conditional
				recentchanges parentlinks editpage}],
		description =&gt; "plugins to enable by default",
		safe =&gt; 0,
		rebuild =&gt; 1,
	},
	add_plugins =&gt; {
		type =&gt; "string",
		default =&gt; [],
		description =&gt; "plugins to add to the default configuration",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	disable_plugins =&gt; {
		type =&gt; "string",
		default =&gt; [],
		description =&gt; "plugins to disable",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	templatedir =&gt; {
		type =&gt; "string",
		default =&gt; "$installdir/share/ikiwiki/templates",
		description =&gt; "location of template files",
		advanced =&gt; 1,
		safe =&gt; 0, # path
		rebuild =&gt; 1,
	},
	underlaydir =&gt; {
		type =&gt; "string",
		default =&gt; "$installdir/share/ikiwiki/basewiki",
		description =&gt; "base wiki source location",
		advanced =&gt; 1,
		safe =&gt; 0, # path
		rebuild =&gt; 0,
	},
	wrappers =&gt; {
		type =&gt; "internal",
		default =&gt; [],
		description =&gt; "wrappers to generate",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	underlaydirs =&gt; {
		type =&gt; "internal",
		default =&gt; [],
		description =&gt; "additional underlays to use",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	verbose =&gt; {
		type =&gt; "boolean",
		example =&gt; 1,
		description =&gt; "display verbose messages when building?",
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	syslog =&gt; {
		type =&gt; "boolean",
		example =&gt; 1,
		description =&gt; "log to syslog?",
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	usedirs =&gt; {
		type =&gt; "boolean",
		default =&gt; 1,
		description =&gt; "create output files named page/index.html?",
		safe =&gt; 0, # changing requires manual transition
		rebuild =&gt; 1,
	},
	prefix_directives =&gt; {
		type =&gt; "boolean",
		default =&gt; 0,
		description =&gt; "use '!'-prefixed preprocessor directives?",
		safe =&gt; 0, # changing requires manual transition
		rebuild =&gt; 1,
	},
	indexpages =&gt; {
		type =&gt; "boolean",
		default =&gt; 0,
		description =&gt; "use page/index.mdwn source files",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	discussion =&gt; {
		type =&gt; "boolean",
		default =&gt; 1,
		description =&gt; "enable Discussion pages?",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	sslcookie =&gt; {
		type =&gt; "boolean",
		default =&gt; 0,
		description =&gt; "only send cookies over SSL connections?",
		advanced =&gt; 1,
		safe =&gt; 1,
		rebuild =&gt; 0,
	},
	default_pageext =&gt; {
		type =&gt; "string",
		default =&gt; "mdwn",
		description =&gt; "extension to use for new pages",
		safe =&gt; 0, # not sanitized
		rebuild =&gt; 0,
	},
	htmlext =&gt; {
		type =&gt; "string",
		default =&gt; "html",
		description =&gt; "extension to use for html files",
		safe =&gt; 0, # not sanitized
		rebuild =&gt; 1,
	},
	timeformat =&gt; {
		type =&gt; "string",
		default =&gt; '%c',
		description =&gt; "strftime format string to display date",
		advanced =&gt; 1,
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	locale =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; "en_US.UTF-8",
		description =&gt; "UTF-8 locale to use",
		advanced =&gt; 1,
		safe =&gt; 0,
		rebuild =&gt; 1,
	},
	userdir =&gt; {
		type =&gt; "string",
		default =&gt; "",
		example =&gt; "users",
		description =&gt; "put user pages below specified page",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	numbacklinks =&gt; {
		type =&gt; "integer",
		default =&gt; 10,
		description =&gt; "how many backlinks to show before hiding excess (0 to show all)",
		safe =&gt; 1,
		rebuild =&gt; 1,
	},
	hardlink =&gt; {
		type =&gt; "boolean",
		default =&gt; 0,
		description =&gt; "attempt to hardlink source files? (optimisation for large files)",
		advanced =&gt; 1,
		safe =&gt; 0, # paranoia
		rebuild =&gt; 0,
	},
	umask =&gt; {
		type =&gt; "integer",
		description =&gt; "",
		example =&gt; "022",
		description =&gt; "force ikiwiki to use a particular umask",
		advanced =&gt; 1,
		safe =&gt; 0, # paranoia
		rebuild =&gt; 0,
	},
	libdir =&gt; {
		type =&gt; "string",
		default =&gt; "",
		example =&gt; "$ENV{HOME}/.ikiwiki/",
		description =&gt; "extra library and plugin directory",
		advanced =&gt; 1,
		safe =&gt; 0, # directory
		rebuild =&gt; 0,
	},
	ENV =&gt; {
		type =&gt; "string", 
		default =&gt; {},
		description =&gt; "environment variables",
		safe =&gt; 0, # paranoia
		rebuild =&gt; 0,
	},
	exclude =&gt; {
		type =&gt; "string",
		default =&gt; undef,
		example =&gt; '\.wav$',
		description =&gt; "regexp of source files to ignore",
		advanced =&gt; 1,
		safe =&gt; 0, # regexp
		rebuild =&gt; 1,
	},
	wiki_file_prune_regexps =&gt; {
		type =&gt; "internal",
		default =&gt; [qr/(^|\/)\.\.(\/|$)/, qr/^\./, qr/\/\./,
			qr/\.x?html?$/, qr/\.ikiwiki-new$/,
			qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
			qr/(^|\/)_MTN\//,
			qr/\.dpkg-tmp$/],
		description =&gt; "regexps of source files to ignore",
		safe =&gt; 0,
		rebuild =&gt; 1,
	},
	wiki_file_chars =&gt; {
		type =&gt; "string",
		description =&gt; "specifies the characters that are allowed in source filenames",
		default =&gt; "-[:alnum:]+/.:_",
		safe =&gt; 0,
		rebuild =&gt; 1,
	},
	wiki_file_regexp =&gt; {
		type =&gt; "internal",
		description =&gt; "regexp of legal source files",
		safe =&gt; 0,
		rebuild =&gt; 1,
	},
	web_commit_regexp =&gt; {
		type =&gt; "internal",
		default =&gt; qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
		description =&gt; "regexp to parse web commits from logs",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	cgi =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "run as a cgi",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	cgi_disable_uploads =&gt; {
		type =&gt; "internal",
		default =&gt; 1,
		description =&gt; "whether CGI should accept file uploads",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	post_commit =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "run as a post-commit hook",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	rebuild =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "running in rebuild mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	setup =&gt; {
		type =&gt; "internal",
		default =&gt; undef,
		description =&gt; "running in setup mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	refresh =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "running in refresh mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	test_receive =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "running in receive test mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	getctime =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "running in getctime mode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	w3mmode =&gt; {
		type =&gt; "internal",
		default =&gt; 0,
		description =&gt; "running in w3mmode",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	wikistatedir =&gt; {
		type =&gt; "internal",
		default =&gt; undef,
		description =&gt; "path to the .ikiwiki directory holding ikiwiki state",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	setupfile =&gt; {
		type =&gt; "internal",
		default =&gt; undef,
		description =&gt; "path to setup file",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
	allow_symlinks_before_srcdir =&gt; {
		type =&gt; "boolean",
		default =&gt; 0,
		description =&gt; "allow symlinks in the path leading to the srcdir (potentially insecure)",
		safe =&gt; 0,
		rebuild =&gt; 0,
	},
} #}}}

sub defaultconfig () { #{{{
	my %s=getsetup();
	my @ret;
	foreach my $key (keys %s) {
		push @ret, $key, $s{$key}-&gt;{default};
	}
	use Data::Dumper;
	return @ret;
} #}}}

sub checkconfig () { #{{{
	# locale stuff; avoid LC_ALL since it overrides everything
	if (defined $ENV{LC_ALL}) {
		$ENV{LANG} = $ENV{LC_ALL};
		delete $ENV{LC_ALL};
	}
	if (defined $config{locale}) {
		if (POSIX::setlocale(&amp;POSIX::LC_ALL, $config{locale})) {
			$ENV{LANG}=$config{locale};
			$gettext_obj=undef;
		}
	}
		
	if (! defined $config{wiki_file_regexp}) {
		$config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
	}

	if (ref $config{ENV} eq 'HASH') {
		foreach my $val (keys %{$config{ENV}}) {
			$ENV{$val}=$config{ENV}{$val};
		}
	}

	if ($config{w3mmode}) {
		eval q{use Cwd q{abs_path}};
		error($@) if $@;
		$config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
		$config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
		$config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
			unless $config{cgiurl} =~ m!file:///!;
		$config{url}="file://".$config{destdir};
	}

	if ($config{cgi} &amp;&amp; ! length $config{url}) {
		error(gettext("Must specify url to wiki with --url when using --cgi"));
	}
	
	$config{wikistatedir}="$config{srcdir}/.ikiwiki"
		unless exists $config{wikistatedir} &amp;&amp; defined $config{wikistatedir};

	if (defined $config{umask}) {
		umask(possibly_foolish_untaint($config{umask}));
	}

	run_hooks(checkconfig =&gt; sub { shift-&gt;() });

	return 1;
} #}}}

sub listplugins () { #{{{
	my %ret;

	foreach my $dir (@INC, $config{libdir}) {
		next unless defined $dir &amp;&amp; length $dir;
		foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
			my ($plugin)=$file=~/.*\/(.*)\.pm$/;
			$ret{$plugin}=1;
		}
	}
	foreach my $dir ($config{libdir}, "$installdir/lib/ikiwiki") {
		next unless defined $dir &amp;&amp; length $dir;
		foreach my $file (glob("$dir/plugins/*")) {
			$ret{basename($file)}=1 if -x $file;
		}
	}

	return keys %ret;
} #}}}

sub loadplugins () { #{{{
	if (defined $config{libdir} &amp;&amp; length $config{libdir}) {
		unshift @INC, possibly_foolish_untaint($config{libdir});
	}

	foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
		loadplugin($plugin);
	}
	
	if ($config{rcs}) {
		if (exists $IkiWiki::hooks{rcs}) {
			error(gettext("cannot use multiple rcs plugins"));
		}
		loadplugin($config{rcs});
	}
	if (! exists $IkiWiki::hooks{rcs}) {
		loadplugin("norcs");
	}

	run_hooks(getopt =&gt; sub { shift-&gt;() });
	if (grep /^-/, @ARGV) {
		print STDERR "Unknown option: $_\n"
			foreach grep /^-/, @ARGV;
		usage();
	}

	return 1;
} #}}}

sub loadplugin ($) { #{{{
	my $plugin=shift;

	return if grep { $_ eq $plugin} @{$config{disable_plugins}};

	foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
	                 "$installdir/lib/ikiwiki") {
		if (defined $dir &amp;&amp; -x "$dir/plugins/$plugin") {
			eval { require IkiWiki::Plugin::external };
			if ($@) {
				my $reason=$@;
				error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
			}
			import IkiWiki::Plugin::external "$dir/plugins/$plugin";
			$loaded_plugins{$plugin}=1;
			return 1;
		}
	}

	my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
	eval qq{use $mod};
	if ($@) {
		error("Failed to load plugin $mod: $@");
	}
	$loaded_plugins{$plugin}=1;
	return 1;
} #}}}

sub error ($;$) { #{{{
	my $message=shift;
	my $cleaner=shift;
	log_message('err' =&gt; $message) if $config{syslog};
	if (defined $cleaner) {
		$cleaner-&gt;();
	}
	die $message."\n";
} #}}}

sub debug ($) { #{{{
	return unless $config{verbose};
	return log_message(debug =&gt; @_);
} #}}}

my $log_open=0;
sub log_message ($$) { #{{{
	my $type=shift;

	if ($config{syslog}) {
		require Sys::Syslog;
		if (! $log_open) {
			Sys::Syslog::setlogsock('unix');
			Sys::Syslog::openlog('ikiwiki', '', 'user');
			$log_open=1;
		}
		return eval {
			Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
		};
	}
	elsif (! $config{cgi}) {
		return print "@_\n";
	}
	else {
		return print STDERR "@_\n";
	}
} #}}}

sub possibly_foolish_untaint ($) { #{{{
	my $tainted=shift;
	my ($untainted)=$tainted=~/(.*)/s;
	return $untainted;
} #}}}

sub basename ($) { #{{{
	my $file=shift;

	$file=~s!.*/+!!;
	return $file;
} #}}}

sub dirname ($) { #{{{
	my $file=shift;

	$file=~s!/*[^/]+$!!;
	return $file;
} #}}}

sub pagetype ($) { #{{{
	my $page=shift;
	
	if ($page =~ /\.([^.]+)$/) {
		return $1 if exists $hooks{htmlize}{$1};
	}
	return;
} #}}}

sub isinternal ($) { #{{{
	my $page=shift;
	return exists $pagesources{$page} &amp;&amp;
		$pagesources{$page} =~ /\._([^.]+)$/;
} #}}}

sub pagename ($) { #{{{
	my $file=shift;

	my $type=pagetype($file);
	my $page=$file;
	$page=~s/\Q.$type\E*$// if defined $type &amp;&amp; !$hooks{htmlize}{$type}{keepextension};
	if ($config{indexpages} &amp;&amp; $page=~/(.*)\/index$/) {
		$page=$1;
	}
	return $page;
} #}}}

sub newpagefile ($$) { #{{{
	my $page=shift;
	my $type=shift;

	if (! $config{indexpages} || $page eq 'index') {
		return $page.".".$type;
	}
	else {
		return $page."/index.".$type;
	}
} #}}}

sub targetpage ($$) { #{{{
	my $page=shift;
	my $ext=shift;
	
	if (! $config{usedirs} || $page eq 'index') {
		return $page.".".$ext;
	}
	else {
		return $page."/index.".$ext;
	}
} #}}}

sub htmlpage ($) { #{{{
	my $page=shift;
	
	return targetpage($page, $config{htmlext});
} #}}}

sub srcfile_stat { #{{{
	my $file=shift;
	my $nothrow=shift;

	return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
	foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
		return "$dir/$file", stat(_) if -e "$dir/$file";
	}
	error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
	return;
} #}}}

sub srcfile ($;$) { #{{{
	return (srcfile_stat(@_))[0];
} #}}}

sub add_underlay ($) { #{{{
	my $dir=shift;

	if ($dir !~ /^\//) {
		$dir="$config{underlaydir}/../$dir";
	}

	if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
		unshift @{$config{underlaydirs}}, $dir;
	}

	return 1;
} #}}}

sub readfile ($;$$) { #{{{
	my $file=shift;
	my $binary=shift;
	my $wantfd=shift;

	if (-l $file) {
		error("cannot read a symlink ($file)");
	}
	
	local $/=undef;
	open (my $in, "&lt;", $file) || error("failed to read $file: $!");
	binmode($in) if ($binary);
	return \*$in if $wantfd;
	my $ret=&lt;$in&gt;;
	close $in || error("failed to read $file: $!");
	return $ret;
} #}}}

sub prep_writefile ($$) { #{{{
	my $file=shift;
	my $destdir=shift;
	
	my $test=$file;
	while (length $test) {
		if (-l "$destdir/$test") {
			error("cannot write to a symlink ($test)");
		}
		$test=dirname($test);
	}

	my $dir=dirname("$destdir/$file");
	if (! -d $dir) {
		my $d="";
		foreach my $s (split(m!/+!, $dir)) {
			$d.="$s/";
			if (! -d $d) {
				mkdir($d) || error("failed to create directory $d: $!");
			}
		}
	}

	return 1;
} #}}}

sub writefile ($$$;$$) { #{{{
	my $file=shift; # can include subdirs
	my $destdir=shift; # directory to put file in
	my $content=shift;
	my $binary=shift;
	my $writer=shift;
	
	prep_writefile($file, $destdir);
	
	my $newfile="$destdir/$file.ikiwiki-new";
	if (-l $newfile) {
		error("cannot write to a symlink ($newfile)");
	}
	
	my $cleanup = sub { unlink($newfile) };
	open (my $out, '&gt;', $newfile) || error("failed to write $newfile: $!", $cleanup);
	binmode($out) if ($binary);
	if ($writer) {
		$writer-&gt;(\*$out, $cleanup);
	}
	else {
		print $out $content or error("failed writing to $newfile: $!", $cleanup);
	}
	close $out || error("failed saving $newfile: $!", $cleanup);
	rename($newfile, "$destdir/$file") || 
		error("failed renaming $newfile to $destdir/$file: $!", $cleanup);

	return 1;
} #}}}

my %cleared;
sub will_render ($$;$) { #{{{
	my $page=shift;
	my $dest=shift;
	my $clear=shift;

	# Important security check.
	if (-e "$config{destdir}/$dest" &amp;&amp; ! $config{rebuild} &amp;&amp;
	    ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
		error("$config{destdir}/$dest independently created, not overwriting with version from $page");
	}

	if (! $clear || $cleared{$page}) {
		$renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
	}
	else {
		foreach my $old (@{$renderedfiles{$page}}) {
			delete $destsources{$old};
		}
		$renderedfiles{$page}=[$dest];
		$cleared{$page}=1;
	}
	$destsources{$dest}=$page;

	return 1;
} #}}}

sub bestlink ($$) { #{{{
	my $page=shift;
	my $link=shift;
	
	my $cwd=$page;
	if ($link=~s/^\/+//) {
		# absolute links
		$cwd="";
	}
	$link=~s/\/$//;

	do {
		my $l=$cwd;
		$l.="/" if length $l;
		$l.=$link;

		if (exists $links{$l}) {
			return $l;
		}
		elsif (exists $pagecase{lc $l}) {
			return $pagecase{lc $l};
		}
	} while $cwd=~s{/?[^/]+$}{};

	if (length $config{userdir}) {
		my $l = "$config{userdir}/".lc($link);
		if (exists $links{$l}) {
			return $l;
		}
		elsif (exists $pagecase{lc $l}) {
			return $pagecase{lc $l};
		}
	}

	#print STDERR "warning: page $page, broken link: $link\n";
	return "";
} #}}}

sub isinlinableimage ($) { #{{{
	my $file=shift;
	
	return $file =~ /\.(png|gif|jpg|jpeg)$/i;
} #}}}

sub pagetitle ($;$) { #{{{
	my $page=shift;
	my $unescaped=shift;

	if ($unescaped) {
		$page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
	}
	else {
		$page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&amp;#$2;"/eg;
	}

	return $page;
} #}}}

sub titlepage ($) { #{{{
	my $title=shift;
	# support use w/o %config set
	my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
	$title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
	return $title;
} #}}}

sub linkpage ($) { #{{{
	my $link=shift;
	my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
	$link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
	return $link;
} #}}}

sub cgiurl (@) { #{{{
	my %params=@_;

	return $config{cgiurl}."?".
		join("&amp;amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
} #}}}

sub baseurl (;$) { #{{{
	my $page=shift;

	return "$config{url}/" if ! defined $page;
	
	$page=htmlpage($page);
	$page=~s/[^\/]+$//;
	$page=~s/[^\/]+\//..\//g;
	return $page;
} #}}}

sub abs2rel ($$) { #{{{
	# Work around very innefficient behavior in File::Spec if abs2rel
	# is passed two relative paths. It's much faster if paths are
	# absolute! (Debian bug #376658; fixed in debian unstable now)
	my $path="/".shift;
	my $base="/".shift;

	require File::Spec;
	my $ret=File::Spec-&gt;abs2rel($path, $base);
	$ret=~s/^// if defined $ret;
	return $ret;
} #}}}

sub displaytime ($;$) { #{{{
	# Plugins can override this function to mark up the time to
	# display.
	return '&lt;span class="date"&gt;'.formattime(@_).'&lt;/span&gt;';
} #}}}

sub formattime ($;$) { #{{{
	# Plugins can override this function to format the time.
	my $time=shift;
	my $format=shift;
	if (! defined $format) {
		$format=$config{timeformat};
	}

	# strftime doesn't know about encodings, so make sure
	# its output is properly treated as utf8
	return decode_utf8(POSIX::strftime($format, localtime($time)));
} #}}}

sub beautify_urlpath ($) { #{{{
	my $url=shift;

	if ($config{usedirs}) {
		$url =~ s!/index.$config{htmlext}$!/!;
	}

	# Ensure url is not an empty link, and
	# if it's relative, make that explicit to avoid colon confusion.
	if ($url !~ /^\//) {
		$url="./$url";
	}

	return $url;
} #}}}

sub urlto ($$;$) { #{{{
	my $to=shift;
	my $from=shift;
	my $absolute=shift;
	
	if (! length $to) {
		return beautify_urlpath(baseurl($from)."index.$config{htmlext}");
	}

	if (! $destsources{$to}) {
		$to=htmlpage($to);
	}

	if ($absolute) {
		return $config{url}.beautify_urlpath("/".$to);
	}

	my $link = abs2rel($to, dirname(htmlpage($from)));

	return beautify_urlpath($link);
} #}}}

sub htmllink ($$$;@) { #{{{
	my $lpage=shift; # the page doing the linking
	my $page=shift; # the page that will contain the link (different for inline)
	my $link=shift;
	my %opts=@_;

	$link=~s/\/$//;

	my $bestlink;
	if (! $opts{forcesubpage}) {
		$bestlink=bestlink($lpage, $link);
	}
	else {
		$bestlink="$lpage/".lc($link);
	}

	my $linktext;
	if (defined $opts{linktext}) {
		$linktext=$opts{linktext};
	}
	else {
		$linktext=pagetitle(basename($link));
	}
	
	return "&lt;span class=\"selflink\"&gt;$linktext&lt;/span&gt;"
		if length $bestlink &amp;&amp; $page eq $bestlink &amp;&amp;
		   ! defined $opts{anchor};
	
	if (! $destsources{$bestlink}) {
		$bestlink=htmlpage($bestlink);

		if (! $destsources{$bestlink}) {
			return $linktext unless length $config{cgiurl};
			return "&lt;span class=\"createlink\"&gt;&lt;a href=\"".
				cgiurl(
					do =&gt; "create",
					page =&gt; lc($link),
					from =&gt; $lpage
				).
				"\" rel=\"nofollow\"&gt;?&lt;/a&gt;$linktext&lt;/span&gt;"
		}
	}
	
	$bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
	$bestlink=beautify_urlpath($bestlink);
	
	if (! $opts{noimageinline} &amp;&amp; isinlinableimage($bestlink)) {
		return "&lt;img src=\"$bestlink\" alt=\"$linktext\" /&gt;";
	}

	if (defined $opts{anchor}) {
		$bestlink.="#".$opts{anchor};
	}

	my @attrs;
	if (defined $opts{rel}) {
		push @attrs, ' rel="'.$opts{rel}.'"';
	}
	if (defined $opts{class}) {
		push @attrs, ' class="'.$opts{class}.'"';
	}

	return "&lt;a href=\"$bestlink\"@attrs&gt;$linktext&lt;/a&gt;";
} #}}}

sub userlink ($) { #{{{
	my $user=shift;

	my $oiduser=eval { openiduser($user) };
	if (defined $oiduser) {
		return "&lt;a href=\"$user\"&gt;$oiduser&lt;/a&gt;";
	}
	else {
		eval q{use CGI 'escapeHTML'};
		error($@) if $@;

		return htmllink("", "", escapeHTML(
			length $config{userdir} ? $config{userdir}."/".$user : $user
		), noimageinline =&gt; 1);
	}
} #}}}

sub htmlize ($$$$) { #{{{
	my $page=shift;
	my $destpage=shift;
	my $type=shift;
	my $content=shift;
	
	my $oneline = $content !~ /\n/;

	if (exists $hooks{htmlize}{$type}) {
		$content=$hooks{htmlize}{$type}{call}-&gt;(
			page =&gt; $page,
			content =&gt; $content,
		);
	}
	else {
		error("htmlization of $type not supported");
	}

	run_hooks(sanitize =&gt; sub {
		$content=shift-&gt;(
			page =&gt; $page,
			destpage =&gt; $destpage,
			content =&gt; $content,
		);
	});
	
	if ($oneline) {
		# hack to get rid of enclosing junk added by markdown
		# and other htmlizers
		$content=~s/^&lt;p&gt;//i;
		$content=~s/&lt;\/p&gt;$//i;
		chomp $content;
	}

	return $content;
} #}}}

sub linkify ($$$) { #{{{
	my $page=shift;
	my $destpage=shift;
	my $content=shift;

	run_hooks(linkify =&gt; sub {
		$content=shift-&gt;(
			page =&gt; $page,
			destpage =&gt; $destpage,
			content =&gt; $content,
		);
	});
	
	return $content;
} #}}}

our %preprocessing;
our $preprocess_preview=0;
sub preprocess ($$$;$$) { #{{{
	my $page=shift; # the page the data comes from
	my $destpage=shift; # the page the data will appear in (different for inline)
	my $content=shift;
	my $scan=shift;
	my $preview=shift;

	# Using local because it needs to be set within any nested calls
	# of this function.
	local $preprocess_preview=$preview if defined $preview;

	my $handle=sub {
		my $escape=shift;
		my $prefix=shift;
		my $command=shift;
		my $params=shift;
		$params="" if ! defined $params;

		if (length $escape) {
			return "[[$prefix$command $params]]";
		}
		elsif (exists $hooks{preprocess}{$command}) {
			return "" if $scan &amp;&amp; ! $hooks{preprocess}{$command}{scan};
			# Note: preserve order of params, some plugins may
			# consider it significant.
			my @params;
			while ($params =~ m{
				(?:([-\w]+)=)?		# 1: named parameter key?
				(?:
					"""(.*?)"""	# 2: triple-quoted value
				|
					"([^"]+)"	# 3: single-quoted value
				|
					(\S+)		# 4: unquoted value
				)
				(?:\s+|$)		# delimiter to next param
			}sgx) {
				my $key=$1;
				my $val;
				if (defined $2) {
					$val=$2;
					$val=~s/\r\n/\n/mg;
					$val=~s/^\n+//g;
					$val=~s/\n+$//g;
				}
				elsif (defined $3) {
					$val=$3;
				}
				elsif (defined $4) {
					$val=$4;
				}

				if (defined $key) {
					push @params, $key, $val;
				}
				else {
					push @params, $val, '';
				}
			}
			if ($preprocessing{$page}++ &gt; 3) {
				# Avoid loops of preprocessed pages preprocessing
				# other pages that preprocess them, etc.
				return "[[!$command &lt;span class=\"error\"&gt;".
					sprintf(gettext("preprocessing loop detected on %s at depth %i"),
						$page, $preprocessing{$page}).
					"&lt;/span&gt;]]";
			}
			my $ret;
			if (! $scan) {
				$ret=eval {
					$hooks{preprocess}{$command}{call}-&gt;(
						@params,
						page =&gt; $page,
						destpage =&gt; $destpage,
						preview =&gt; $preprocess_preview,
					);
				};
				if ($@) {
					chomp $@;
				 	$ret="[[!$command &lt;span class=\"error\"&gt;".
						gettext("Error").": $@"."&lt;/span&gt;]]";
				}
			}
			else {
				# use void context during scan pass
				eval {
					$hooks{preprocess}{$command}{call}-&gt;(
						@params,
						page =&gt; $page,
						destpage =&gt; $destpage,
						preview =&gt; $preprocess_preview,
					);
				};
				$ret="";
			}
			$preprocessing{$page}--;
			return $ret;
		}
		else {
			return "[[$prefix$command $params]]";
		}
	};
	
	my $regex;
	if ($config{prefix_directives}) {
		$regex = qr{
			(\\?)		# 1: escape?
			\[\[(!)		# directive open; 2: prefix
			([-\w]+)	# 3: command
			(		# 4: the parameters..
				\s+	# Must have space if parameters present
				(?:
					(?:[-\w]+=)?		# named parameter key?
					(?:
						""".*?"""	# triple-quoted value
						|
						"[^"]+"		# single-quoted value
						|
						[^\s\]]+	# unquoted value
					)
					\s*			# whitespace or end
								# of directive
				)
			*)?		# 0 or more parameters
			\]\]		# directive closed
		}sx;
	}
	else {
		$regex = qr{
			(\\?)		# 1: escape?
			\[\[(!?)	# directive open; 2: optional prefix
			([-\w]+)	# 3: command
			\s+
			(		# 4: the parameters..
				(?:
					(?:[-\w]+=)?		# named parameter key?
					(?:
						""".*?"""	# triple-quoted value
						|
						"[^"]+"		# single-quoted value
						|
						[^\s\]]+	# unquoted value
					)
					\s*			# whitespace or end
								# of directive
				)
			*)		# 0 or more parameters
			\]\]		# directive closed
		}sx;
	}

	$content =~ s{$regex}{$handle-&gt;($1, $2, $3, $4)}eg;
	return $content;
} #}}}

sub filter ($$$) { #{{{
	my $page=shift;
	my $destpage=shift;
	my $content=shift;

	run_hooks(filter =&gt; sub {
		$content=shift-&gt;(page =&gt; $page, destpage =&gt; $destpage, 
			content =&gt; $content);
	});

	return $content;
} #}}}

sub indexlink () { #{{{
	return "&lt;a href=\"$config{url}\"&gt;$config{wikiname}&lt;/a&gt;";
} #}}}

my $wikilock;

sub lockwiki (;$) { #{{{
	my $wait=@_ ? shift : 1;
	# Take an exclusive lock on the wiki to prevent multiple concurrent
	# run issues. The lock will be dropped on program exit.
	if (! -d $config{wikistatedir}) {
		mkdir($config{wikistatedir});
	}
	open($wikilock, '&gt;', "$config{wikistatedir}/lockfile") ||
		error ("cannot write to $config{wikistatedir}/lockfile: $!");
	if (! flock($wikilock, 2 | 4)) { # LOCK_EX | LOCK_NB
		if ($wait) {
			debug("wiki seems to be locked, waiting for lock");
			my $wait=600; # arbitrary, but don't hang forever to 
			              # prevent process pileup
			for (1..$wait) {
				return if flock($wikilock, 2 | 4);
				sleep 1;
			}
			error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
		}
		else {
			return 0;
		}
	}
	return 1;
} #}}}

sub unlockwiki () { #{{{
	return close($wikilock) if $wikilock;
	return;
} #}}}

my $commitlock;

sub commit_hook_enabled () { #{{{
	open($commitlock, '+&gt;', "$config{wikistatedir}/commitlock") ||
		error("cannot write to $config{wikistatedir}/commitlock: $!");
	if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
		close($commitlock) || error("failed closing commitlock: $!");
		return 0;
	}
	close($commitlock) || error("failed closing commitlock: $!");
	return 1;
} #}}}

sub disable_commit_hook () { #{{{
	open($commitlock, '&gt;', "$config{wikistatedir}/commitlock") ||
		error("cannot write to $config{wikistatedir}/commitlock: $!");
	if (! flock($commitlock, 2)) { # LOCK_EX
		error("failed to get commit lock");
	}
	return 1;
} #}}}

sub enable_commit_hook () { #{{{
	return close($commitlock) if $commitlock;
	return;
} #}}}

sub loadindex () { #{{{
	%oldrenderedfiles=%pagectime=();
	if (! $config{rebuild}) {
		%pagesources=%pagemtime=%oldlinks=%links=%depends=
		%destsources=%renderedfiles=%pagecase=%pagestate=();
	}
	my $in;
	if (! open ($in, "&lt;", "$config{wikistatedir}/indexdb")) {
		if (-e "$config{wikistatedir}/index") {
			system("ikiwiki-transition", "indexdb", $config{srcdir});
			open ($in, "&lt;", "$config{wikistatedir}/indexdb") || return;
		}
		else {
			return;
		}
	}

	my $index=Storable::fd_retrieve($in);
	if (! defined $index) {
		return 0;
	}

	my $pages;
	if (exists $index-&gt;{version} &amp;&amp; ! ref $index-&gt;{version}) {
		$pages=$index-&gt;{page};
		%wikistate=%{$index-&gt;{state}};
	}
	else {
		$pages=$index;
		%wikistate=();
	}

	foreach my $src (keys %$pages) {
		my $d=$pages-&gt;{$src};
		my $page=pagename($src);
		$pagectime{$page}=$d-&gt;{ctime};
		if (! $config{rebuild}) {
			$pagesources{$page}=$src;
			$pagemtime{$page}=$d-&gt;{mtime};
			$renderedfiles{$page}=$d-&gt;{dest};
			if (exists $d-&gt;{links} &amp;&amp; ref $d-&gt;{links}) {
				$links{$page}=$d-&gt;{links};
				$oldlinks{$page}=[@{$d-&gt;{links}}];
			}
			if (exists $d-&gt;{depends}) {
				$depends{$page}=$d-&gt;{depends};
			}
			if (exists $d-&gt;{state}) {
				$pagestate{$page}=$d-&gt;{state};
			}
		}
		$oldrenderedfiles{$page}=[@{$d-&gt;{dest}}];
	}
	foreach my $page (keys %pagesources) {
		$pagecase{lc $page}=$page;
	}
	foreach my $page (keys %renderedfiles) {
		$destsources{$_}=$page foreach @{$renderedfiles{$page}};
	}
	return close($in);
} #}}}

sub saveindex () { #{{{
	run_hooks(savestate =&gt; sub { shift-&gt;() });

	my %hookids;
	foreach my $type (keys %hooks) {
		$hookids{$_}=1 foreach keys %{$hooks{$type}};
	}
	my @hookids=keys %hookids;

	if (! -d $config{wikistatedir}) {
		mkdir($config{wikistatedir});
	}
	my $newfile="$config{wikistatedir}/indexdb.new";
	my $cleanup = sub { unlink($newfile) };
	open (my $out, '&gt;', $newfile) || error("cannot write to $newfile: $!", $cleanup);

	my %index;
	foreach my $page (keys %pagemtime) {
		next unless $pagemtime{$page};
		my $src=$pagesources{$page};

		$index{page}{$src}={
			ctime =&gt; $pagectime{$page},
			mtime =&gt; $pagemtime{$page},
			dest =&gt; $renderedfiles{$page},
			links =&gt; $links{$page},
		};

		if (exists $depends{$page}) {
			$index{page}{$src}{depends} = $depends{$page};
		}

		if (exists $pagestate{$page}) {
			foreach my $id (@hookids) {
				foreach my $key (keys %{$pagestate{$page}{$id}}) {
					$index{page}{$src}{state}{$id}{$key}=$pagestate{$page}{$id}{$key};
				}
			}
		}
	}

	$index{state}={};
	foreach my $id (@hookids) {
		foreach my $key (keys %{$wikistate{$id}}) {
			$index{state}{$id}{$key}=$wikistate{$id}{$key};
		}
	}
	
	$index{version}="3";
	my $ret=Storable::nstore_fd(\%index, $out);
	return if ! defined $ret || ! $ret;
	close $out || error("failed saving to $newfile: $!", $cleanup);
	rename($newfile, "$config{wikistatedir}/indexdb") ||
		error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
	
	return 1;
} #}}}

sub template_file ($) { #{{{
	my $template=shift;

	foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
		return "$dir/$template" if -e "$dir/$template";
	}
	return;
} #}}}

sub template_params (@) { #{{{
	my $filename=template_file(shift);

	if (! defined $filename) {
		return if wantarray;
		return "";
	}

	my @ret=(
		filter =&gt; sub {
			my $text_ref = shift;
			${$text_ref} = decode_utf8(${$text_ref});
		},
		filename =&gt; $filename,
		loop_context_vars =&gt; 1,
		die_on_bad_params =&gt; 0,
		@_
	);
	return wantarray ? @ret : {@ret};
} #}}}

sub template ($;@) { #{{{
	require HTML::Template;
	return HTML::Template-&gt;new(template_params(@_));
} #}}}

sub misctemplate ($$;@) { #{{{
	my $title=shift;
	my $pagebody=shift;
	
	my $template=template("misc.tmpl");
	$template-&gt;param(
		title =&gt; $title,
		indexlink =&gt; indexlink(),
		wikiname =&gt; $config{wikiname},
		pagebody =&gt; $pagebody,
		baseurl =&gt; baseurl(),
		@_,
	);
	run_hooks(pagetemplate =&gt; sub {
		shift-&gt;(page =&gt; "", destpage =&gt; "", template =&gt; $template);
	});
	return $template-&gt;output;
}#}}}

sub hook (@) { # {{{
	my %param=@_;
	
	if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
		error 'hook requires type, call, and id parameters';
	}

	return if $param{no_override} &amp;&amp; exists $hooks{$param{type}}{$param{id}};
	
	$hooks{$param{type}}{$param{id}}=\%param;
	return 1;
} # }}}

sub run_hooks ($$) { # {{{
	# Calls the given sub for each hook of the given type,
	# passing it the hook function to call.
	my $type=shift;
	my $sub=shift;

	if (exists $hooks{$type}) {
		my @deferred;
		foreach my $id (keys %{$hooks{$type}}) {
			if ($hooks{$type}{$id}{last}) {
				push @deferred, $id;
				next;
			}
			$sub-&gt;($hooks{$type}{$id}{call});
		}
		foreach my $id (@deferred) {
			$sub-&gt;($hooks{$type}{$id}{call});
		}
	}

	return 1;
} #}}}

sub rcs_update () { #{{{
	$hooks{rcs}{rcs_update}{call}-&gt;(@_);
} #}}}

sub rcs_prepedit ($) { #{{{
	$hooks{rcs}{rcs_prepedit}{call}-&gt;(@_);
} #}}}

sub rcs_commit ($$$;$$) { #{{{
	$hooks{rcs}{rcs_commit}{call}-&gt;(@_);
} #}}}

sub rcs_commit_staged ($$$) { #{{{
	$hooks{rcs}{rcs_commit_staged}{call}-&gt;(@_);
} #}}}

sub rcs_add ($) { #{{{
	$hooks{rcs}{rcs_add}{call}-&gt;(@_);
} #}}}

sub rcs_remove ($) { #{{{
	$hooks{rcs}{rcs_remove}{call}-&gt;(@_);
} #}}}

sub rcs_rename ($$) { #{{{
	$hooks{rcs}{rcs_rename}{call}-&gt;(@_);
} #}}}

sub rcs_recentchanges ($) { #{{{
	$hooks{rcs}{rcs_recentchanges}{call}-&gt;(@_);
} #}}}

sub rcs_diff ($) { #{{{
	$hooks{rcs}{rcs_diff}{call}-&gt;(@_);
} #}}}

sub rcs_getctime ($) { #{{{
	$hooks{rcs}{rcs_getctime}{call}-&gt;(@_);
} #}}}

sub rcs_receive () { #{{{
	$hooks{rcs}{rcs_receive}{call}-&gt;();
} #}}}

sub globlist_to_pagespec ($) { #{{{
	my @globlist=split(' ', shift);

	my (@spec, @skip);
	foreach my $glob (@globlist) {
		if ($glob=~/^!(.*)/) {
			push @skip, $glob;
		}
		else {
			push @spec, $glob;
		}
	}

	my $spec=join(' or ', @spec);
	if (@skip) {
		my $skip=join(' and ', @skip);
		if (length $spec) {
			$spec="$skip and ($spec)";
		}
		else {
			$spec=$skip;
		}
	}
	return $spec;
} #}}}

sub is_globlist ($) { #{{{
	my $s=shift;
	return ( $s =~ /[^\s]+\s+([^\s]+)/ &amp;&amp; $1 ne "and" &amp;&amp; $1 ne "or" );
} #}}}

sub safequote ($) { #{{{
	my $s=shift;
	$s=~s/[{}]//g;
	return "q{$s}";
} #}}}

sub add_depends ($$) { #{{{
	my $page=shift;
	my $pagespec=shift;
	
	return unless pagespec_valid($pagespec);

	if (! exists $depends{$page}) {
		$depends{$page}=$pagespec;
	}
	else {
		$depends{$page}=pagespec_merge($depends{$page}, $pagespec);
	}

	return 1;
} # }}}

sub file_pruned ($$) { #{{{
	require File::Spec;
	my $file=File::Spec-&gt;canonpath(shift);
	my $base=File::Spec-&gt;canonpath(shift);
	$file =~ s#^\Q$base\E/+##;

	my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
	return $file =~ m/$regexp/ &amp;&amp; $file ne $base;
} #}}}

sub gettext { #{{{
	# Only use gettext in the rare cases it's needed.
	if ((exists $ENV{LANG} &amp;&amp; length $ENV{LANG}) ||
	    (exists $ENV{LC_ALL} &amp;&amp; length $ENV{LC_ALL}) ||
	    (exists $ENV{LC_MESSAGES} &amp;&amp; length $ENV{LC_MESSAGES})) {
		if (! $gettext_obj) {
			$gettext_obj=eval q{
				use Locale::gettext q{textdomain};
				Locale::gettext-&gt;domain('ikiwiki')
			};
			if ($@) {
				print STDERR "$@";
				$gettext_obj=undef;
				return shift;
			}
		}
		return $gettext_obj-&gt;get(shift);
	}
	else {
		return shift;
	}
} #}}}

sub yesno ($) { #{{{
	my $val=shift;

	return (defined $val &amp;&amp; lc($val) eq gettext("yes"));
} #}}}

sub inject { #{{{
	# Injects a new function into the symbol table to replace an
	# exported function.
	my %params=@_;

	# This is deep ugly perl foo, beware.
	no strict;
	no warnings;
	if (! defined $params{parent}) {
		$params{parent}='::';
		$params{old}=\&amp;{$params{name}};
		$params{name}=~s/.*:://;
	}
	my $parent=$params{parent};
	foreach my $ns (grep /^\w+::/, keys %{$parent}) {
		$ns = $params{parent} . $ns;
		inject(%params, parent =&gt; $ns) unless $ns eq '::main::';
		*{$ns . $params{name}} = $params{call}
			if exists ${$ns}{$params{name}} &amp;&amp;
			   \&amp;{${$ns}{$params{name}}} == $params{old};
	}
	use strict;
	use warnings;
} #}}}

sub pagespec_merge ($$) { #{{{
	my $a=shift;
	my $b=shift;

	return $a if $a eq $b;

        # Support for old-style GlobLists.
        if (is_globlist($a)) {
                $a=globlist_to_pagespec($a);
        }
        if (is_globlist($b)) {
                $b=globlist_to_pagespec($b);
        }

	return "($a) or ($b)";
} #}}}

sub pagespec_translate ($) { #{{{
	my $spec=shift;

	# Support for old-style GlobLists.
	if (is_globlist($spec)) {
		$spec=globlist_to_pagespec($spec);
	}

	# Convert spec to perl code.
	my $code="";
	while ($spec=~m{
		\s*		# ignore whitespace
		(		# 1: match a single word
			\!		# !
		|
			\(		# (
		|
			\)		# )
		|
			\w+\([^\)]*\)	# command(params)
		|
			[^\s()]+	# any other text
		)
		\s*		# ignore whitespace
	}igx) {
		my $word=$1;
		if (lc $word eq 'and') {
			$code.=' &amp;&amp;';
		}
		elsif (lc $word eq 'or') {
			$code.=' ||';
		}
		elsif ($word eq "(" || $word eq ")" || $word eq "!") {
			$code.=' '.$word;
		}
		elsif ($word =~ /^(\w+)\((.*)\)$/) {
			if (exists $IkiWiki::PageSpec::{"match_$1"}) {
				$code.="IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).", \@_)";
			}
			else {
				$code.=' 0';
			}
		}
		else {
			$code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \@_)";
		}
	}

	if (! length $code) {
		$code=0;
	}

	no warnings;
	return eval 'sub { my $page=shift; '.$code.' }';
} #}}}

sub pagespec_match ($$;@) { #{{{
	my $page=shift;
	my $spec=shift;
	my @params=@_;

	# Backwards compatability with old calling convention.
	if (@params == 1) {
		unshift @params, 'location';
	}

	my $sub=pagespec_translate($spec);
	return IkiWiki::FailReason-&gt;new("syntax error in pagespec \"$spec\"") if $@;
	return $sub-&gt;($page, @params);
} #}}}

sub pagespec_valid ($) { #{{{
	my $spec=shift;

	my $sub=pagespec_translate($spec);
	return ! $@;
} #}}}

sub glob2re ($) { #{{{
	my $re=quotemeta(shift);
	$re=~s/\\\*/.*/g;
	$re=~s/\\\?/./g;
	return $re;
} #}}}

package IkiWiki::FailReason;

use overload ( #{{{
	'""'	=&gt; sub { ${$_[0]} },
	'0+'	=&gt; sub { 0 },
	'!'	=&gt; sub { bless $_[0], 'IkiWiki::SuccessReason'},
	fallback =&gt; 1,
); #}}}

sub new { #{{{
	my $class = shift;
	my $value = shift;
	return bless \$value, $class;
} #}}}

package IkiWiki::SuccessReason;

use overload ( #{{{
	'""'	=&gt; sub { ${$_[0]} },
	'0+'	=&gt; sub { 1 },
	'!'	=&gt; sub { bless $_[0], 'IkiWiki::FailReason'},
	fallback =&gt; 1,
); #}}}

sub new { #{{{
	my $class = shift;
	my $value = shift;
	return bless \$value, $class;
}; #}}}

package IkiWiki::PageSpec;

sub match_glob ($$;@) { #{{{
	my $page=shift;
	my $glob=shift;
	my %params=@_;
	
	my $from=exists $params{location} ? $params{location} : '';
	
	# relative matching
	if ($glob =~ m!^\./!) {
		$from=~s#/?[^/]+$##;
		$glob=~s#^\./##;
		$glob="$from/$glob" if length $from;
	}

	my $regexp=IkiWiki::glob2re($glob);
	if ($page=~/^$regexp$/i) {
		if (! IkiWiki::isinternal($page) || $params{internal}) {
			return IkiWiki::SuccessReason-&gt;new("$glob matches $page");
		}
		else {
			return IkiWiki::FailReason-&gt;new("$glob matches $page, but the page is an internal page");
		}
	}
	else {
		return IkiWiki::FailReason-&gt;new("$glob does not match $page");
	}
} #}}}

sub match_internal ($$;@) { #{{{
	return match_glob($_[0], $_[1], @_, internal =&gt; 1)
} #}}}

sub match_link ($$;@) { #{{{
	my $page=shift;
	my $link=lc(shift);
	my %params=@_;

	my $from=exists $params{location} ? $params{location} : '';

	# relative matching
	if ($link =~ m!^\.! &amp;&amp; defined $from) {
		$from=~s#/?[^/]+$##;
		$link=~s#^\./##;
		$link="$from/$link" if length $from;
	}

	my $links = $IkiWiki::links{$page};
	return IkiWiki::FailReason-&gt;new("$page has no links") unless $links &amp;&amp; @{$links};
	my $bestlink = IkiWiki::bestlink($from, $link);
	foreach my $p (@{$links}) {
		if (length $bestlink) {
			return IkiWiki::SuccessReason-&gt;new("$page links to $link")
				if $bestlink eq IkiWiki::bestlink($page, $p);
		}
		else {
			return IkiWiki::SuccessReason-&gt;new("$page links to page $p matching $link")
				if match_glob($p, $link, %params);
			$p=~s/^\///;
			$link=~s/^\///;
			return IkiWiki::SuccessReason-&gt;new("$page links to page $p matching $link")
				if match_glob($p, $link, %params);
		}
	}
	return IkiWiki::FailReason-&gt;new("$page does not link to $link");
} #}}}

sub match_backlink ($$;@) { #{{{
	return match_link($_[1], $_[0], @_);
} #}}}

sub match_created_before ($$;@) { #{{{
	my $page=shift;
	my $testpage=shift;

	if (exists $IkiWiki::pagectime{$testpage}) {
		if ($IkiWiki::pagectime{$page} &lt; $IkiWiki::pagectime{$testpage}) {
			return IkiWiki::SuccessReason-&gt;new("$page created before $testpage");
		}
		else {
			return IkiWiki::FailReason-&gt;new("$page not created before $testpage");
		}
	}
	else {
		return IkiWiki::FailReason-&gt;new("$testpage has no ctime");
	}
} #}}}

sub match_created_after ($$;@) { #{{{
	my $page=shift;
	my $testpage=shift;

	if (exists $IkiWiki::pagectime{$testpage}) {
		if ($IkiWiki::pagectime{$page} &gt; $IkiWiki::pagectime{$testpage}) {
			return IkiWiki::SuccessReason-&gt;new("$page created after $testpage");
		}
		else {
			return IkiWiki::FailReason-&gt;new("$page not created after $testpage");
		}
	}
	else {
		return IkiWiki::FailReason-&gt;new("$testpage has no ctime");
	}
} #}}}

sub match_creation_day ($$;@) { #{{{
	if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
		return IkiWiki::SuccessReason-&gt;new('creation_day matched');
	}
	else {
		return IkiWiki::FailReason-&gt;new('creation_day did not match');
	}
} #}}}

sub match_creation_month ($$;@) { #{{{
	if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
		return IkiWiki::SuccessReason-&gt;new('creation_month matched');
	}
	else {
		return IkiWiki::FailReason-&gt;new('creation_month did not match');
	}
} #}}}

sub match_creation_year ($$;@) { #{{{
	if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
		return IkiWiki::SuccessReason-&gt;new('creation_year matched');
	}
	else {
		return IkiWiki::FailReason-&gt;new('creation_year did not match');
	}
} #}}}

sub match_user ($$;@) { #{{{
	shift;
	my $user=shift;
	my %params=@_;
	
	if (! exists $params{user}) {
		return IkiWiki::FailReason-&gt;new("no user specified");
	}

	if (defined $params{user} &amp;&amp; lc $params{user} eq lc $user) {
		return IkiWiki::SuccessReason-&gt;new("user is $user");
	}
	elsif (! defined $params{user}) {
		return IkiWiki::FailReason-&gt;new("not logged in");
	}
	else {
		return IkiWiki::FailReason-&gt;new("user is $params{user}, not $user");
	}
} #}}}

sub match_admin ($$;@) { #{{{
	shift;
	shift;
	my %params=@_;
	
	if (! exists $params{user}) {
		return IkiWiki::FailReason-&gt;new("no user specified");
	}

	if (defined $params{user} &amp;&amp; IkiWiki::is_admin($params{user})) {
		return IkiWiki::SuccessReason-&gt;new("user is an admin");
	}
	elsif (! defined $params{user}) {
		return IkiWiki::FailReason-&gt;new("not logged in");
	}
	else {
		return IkiWiki::FailReason-&gt;new("user is not an admin");
	}
} #}}}

sub match_ip ($$;@) { #{{{
	shift;
	my $ip=shift;
	my %params=@_;
	
	if (! exists $params{ip}) {
		return IkiWiki::FailReason-&gt;new("no IP specified");
	}

	if (defined $params{ip} &amp;&amp; lc $params{ip} eq lc $ip) {
		return IkiWiki::SuccessReason-&gt;new("IP is $ip");
	}
	else {
		return IkiWiki::FailReason-&gt;new("IP is $params{ip}, not $ip");
	}
} #}}}

1
</pre></body></html>