<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Receive;

use warnings;
use strict;
use IkiWiki;

sub getuser () {
	my $user=(getpwuid(exists $ENV{CALLER_UID} ? $ENV{CALLER_UID} : $&lt;))[0];
	if (! defined $user) {
		error("cannot determine username for $&lt;");
	}
	return $user;
}

sub trusted () {
	my $user=getuser();
	return ! ref $config{untrusted_committers} ||
		! grep { $_ eq $user } @{$config{untrusted_committers}};
}

sub genwrapper () {
	# Test for commits from untrusted committers in the wrapper, to
	# avoid starting ikiwiki proper at all for trusted commits.

	my $ret=&lt;&lt;"EOF";
	{
		int u=getuid();
EOF
	$ret.="\t\tif ( ".
		join("&amp;&amp;", map {
			my $uid=getpwnam($_);
			if (! defined $uid) {
				error(sprintf(gettext("cannot determine id of untrusted committer %s"), $_));
			}
			"u != $uid";
		} @{$config{untrusted_committers}}).
		") exit(0);\n";

	
	$ret.=&lt;&lt;"EOF";
		asprintf(&amp;s, "CALLER_UID=%i", u);
		newenviron[i++]=s;
	}
EOF
	return $ret;
}

sub test () {
	exit 0 if trusted();

	IkiWiki::lockwiki();
	IkiWiki::loadindex();

	# Dummy up a cgi environment to use when calling check_canedit
	# and friends.
	eval q{use CGI};
	error($@) if $@;
	my $cgi=CGI-&gt;new;

	# And dummy up a session object.
	require IkiWiki::CGI;
	my $session=IkiWiki::cgi_getsession($cgi);
	$session-&gt;param("name", getuser());
	# Make sure whatever user was authed is in the
	# userinfo db.
	require IkiWiki::UserInfo;
	if (! IkiWiki::userinfo_get($session-&gt;param("name"), "regdate")) {
		IkiWiki::userinfo_setall($session-&gt;param("name"), {
			email =&gt; "",
			password =&gt; "",
			regdate =&gt; time,
		}) || error("failed adding user");
	}

	check_canchange(
		cgi =&gt; $cgi,
		session =&gt; $session,
		changes =&gt; [IkiWiki::rcs_receive()]
	);
	exit 0;
}

1
</pre></body></html>