<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl

use warnings;
use strict;
use Storable;
use IkiWiki;

package IkiWiki;

sub userinfo_retrieve () { #{{{
	my $userinfo=eval{ Storable::lock_retrieve("$config{wikistatedir}/userdb") };
	return $userinfo;
} #}}}

sub userinfo_store ($) { #{{{
	my $userinfo=shift;
	
	my $newfile="$config{wikistatedir}/userdb.new";
	my $oldmask=umask(077);
	my $ret=Storable::lock_nstore($userinfo, $newfile);
	umask($oldmask);
	if (defined $ret &amp;&amp; $ret) {
		if (! rename($newfile, "$config{wikistatedir}/userdb")) {
			unlink($newfile);
			$ret=undef;
		}
	}
	return $ret;
} #}}}

sub userinfo_get ($$) { #{{{
	my $user=shift;
	my $field=shift;

	my $userinfo=userinfo_retrieve();
	if (! defined $userinfo ||
	    ! exists $userinfo-&gt;{$user} || ! ref $userinfo-&gt;{$user} ||
            ! exists $userinfo-&gt;{$user}-&gt;{$field}) {
		return "";
	}
	return $userinfo-&gt;{$user}-&gt;{$field};
} #}}}

sub userinfo_set ($$$) { #{{{
	my $user=shift;
	my $field=shift;
	my $value=shift;
	
	my $userinfo=userinfo_retrieve();
	if (! defined $userinfo ||
	    ! exists $userinfo-&gt;{$user} || ! ref $userinfo-&gt;{$user}) {
		return "";
	}
	
	$userinfo-&gt;{$user}-&gt;{$field}=$value;
	return userinfo_store($userinfo);
} #}}}

sub userinfo_setall ($$) { #{{{
	my $user=shift;
	my $info=shift;
	
	my $userinfo=userinfo_retrieve();
	if (! defined $userinfo) {
		$userinfo={};
	}
	$userinfo-&gt;{$user}=$info;
	return userinfo_store($userinfo);
} #}}}

sub is_admin ($) { #{{{
	my $user_name=shift;

	return grep { $_ eq $user_name } @{$config{adminuser}};
} #}}}

sub get_banned_users () { #{{{
	my @ret;
	my $userinfo=userinfo_retrieve();
	foreach my $user (keys %{$userinfo}) {
		push @ret, $user if $userinfo-&gt;{$user}-&gt;{banned};
	}
	return @ret;
} #}}}

sub set_banned_users (@) { #{{{
	my %banned=map { $_ =&gt; 1 } @_;
	my $userinfo=userinfo_retrieve();
	foreach my $user (keys %{$userinfo}) {
		$userinfo-&gt;{$user}-&gt;{banned} = $banned{$user};
	}
	return userinfo_store($userinfo);
} #}}}

1
</pre></body></html>