<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl

use warnings;
use strict;
use IkiWiki;
use IkiWiki::UserInfo;
use open qw{:utf8 :std};
use Encode;

package IkiWiki;

sub printheader ($) { #{{{
	my $session=shift;
	
	if ($config{sslcookie}) {
		print $session-&gt;header(-charset =&gt; 'utf-8',
			-cookie =&gt; $session-&gt;cookie(-secure =&gt; 1));
	} else {
		print $session-&gt;header(-charset =&gt; 'utf-8');
	}

} #}}}

sub redirect ($$) { #{{{
	my $q=shift;
	my $url=shift;
	if (! $config{w3mmode}) {
		print $q-&gt;redirect($url);
	}
	else {
		print "Content-type: text/plain\n";
		print "W3m-control: GOTO $url\n\n";
	}
} #}}}

sub page_locked ($$;$) { #{{{
	my $page=shift;
	my $session=shift;
	my $nonfatal=shift;
	
	my $user=$session-&gt;param("name");
	return if defined $user &amp;&amp; is_admin($user);

	foreach my $admin (@{$config{adminuser}}) {
		my $locked_pages=userinfo_get($admin, "locked_pages");
		if (pagespec_match($page, userinfo_get($admin, "locked_pages"))) {
			return 1 if $nonfatal;

			#translators: The first parameter is a page name,
			#translators: second is the user who locked it.
			error(sprintf(gettext("%s is locked by %s and cannot be edited"),
				htmllink("", "", $page, 1),
				userlink($admin)));
		}
	}

	return 0;
} #}}}

sub decode_form_utf8 ($) { #{{{
	my $form = shift;
	foreach my $f ($form-&gt;field) {
		next if Encode::is_utf8(scalar $form-&gt;field($f));
		$form-&gt;field(name  =&gt; $f,
			     value =&gt; decode_utf8($form-&gt;field($f)),
			     force =&gt; 1,
			    );
	}
} #}}}

sub cgi_recentchanges ($) { #{{{
	my $q=shift;
	
	# Optimisation: building recentchanges means calculating lots of
	# links. Memoizing htmllink speeds it up a lot (can't be memoized
	# during page builds as the return values may change, but they
	# won't here.)
	eval q{use Memoize};
	error($@) if $@;
	memoize("htmllink");

	eval q{use Time::Duration};
	error($@) if $@;

	my $changelog=[rcs_recentchanges(100)];
	foreach my $change (@$changelog) {
		$change-&gt;{when} = concise(ago($change-&gt;{when}));

		$change-&gt;{user} = userlink($change-&gt;{user});

		my $is_excess = exists $change-&gt;{pages}[10]; # limit pages to first 10
		delete @{$change-&gt;{pages}}[10 .. @{$change-&gt;{pages}}] if $is_excess;
		$change-&gt;{pages} = [
			map {
				$_-&gt;{link} = htmllink("", "", $_-&gt;{page}, 1);
				$_;
			} @{$change-&gt;{pages}}
		];
		push @{$change-&gt;{pages}}, { link =&gt; '...' } if $is_excess;
	}

	my $template=template("recentchanges.tmpl"); 
	$template-&gt;param(
		title =&gt; "RecentChanges",
		indexlink =&gt; indexlink(),
		wikiname =&gt; $config{wikiname},
		changelog =&gt; $changelog,
		baseurl =&gt; baseurl(),
	);
	run_hooks(pagetemplate =&gt; sub {
		shift-&gt;(page =&gt; "", destpage =&gt; "", template =&gt; $template);
	});
	print $q-&gt;header(-charset =&gt; 'utf-8'), $template-&gt;output;
} #}}}

sub cgi_signin ($$) { #{{{
	my $q=shift;
	my $session=shift;

	eval q{use CGI::FormBuilder};
	error($@) if $@;
	my $form = CGI::FormBuilder-&gt;new(
		title =&gt; "signin",
		header =&gt; 1,
		charset =&gt; "utf-8",
		method =&gt; 'POST',
		required =&gt; 'NONE',
		javascript =&gt; 0,
		params =&gt; $q,
		action =&gt; $config{cgiurl},
		header =&gt; 0,
		template =&gt; (-e "$config{templatedir}/signin.tmpl" ?
			     {template_params("signin.tmpl")} : ""),
		stylesheet =&gt; baseurl()."style.css",
	);
	my $buttons=["Login"];
	
	$form-&gt;field(name =&gt; "do", type =&gt; "hidden");
	
	if ($q-&gt;param("do") ne "signin" &amp;&amp; !$form-&gt;submitted) {
		$form-&gt;text(gettext("You need to log in first."));
	}
	
	run_hooks(formbuilder_setup =&gt; sub {
		shift-&gt;(form =&gt; $form, cgi =&gt; $q, session =&gt; $session);
	});
	
	decode_form_utf8($form);

	if (exists $hooks{formbuilder}) {
		run_hooks(formbuilder =&gt; sub {
			shift-&gt;(form =&gt; $form, cgi =&gt; $q, session =&gt; $session,
				buttons =&gt; $buttons);
		});
	}
	else {
		if ($form-&gt;submitted) {
			$form-&gt;validate;
		}
		printheader($session);
		print misctemplate($form-&gt;title, $form-&gt;render(submit =&gt; $buttons));
	}
} #}}}

sub cgi_postsignin ($$) { #{{{
	my $q=shift;
	my $session=shift;

	# Continue with whatever was being done before the signin process.
	if (defined $q-&gt;param("do") &amp;&amp; $q-&gt;param("do") ne "signin" &amp;&amp;
	    defined $session-&gt;param("postsignin")) {
		my $postsignin=CGI-&gt;new($session-&gt;param("postsignin"));
		$session-&gt;clear("postsignin");
		cgi($postsignin, $session);
		cgi_savesession($session);
		exit;
	}
	else {
		redirect($q, $config{url});
	}
} #}}}

sub cgi_prefs ($$) { #{{{
	my $q=shift;
	my $session=shift;

	eval q{use CGI::FormBuilder};
	error($@) if $@;
	my $form = CGI::FormBuilder-&gt;new(
		title =&gt; "preferences",
		header =&gt; 0,
		charset =&gt; "utf-8",
		method =&gt; 'POST',
		validate =&gt; {
			email =&gt; 'EMAIL',
		},
		required =&gt; 'NONE',
		javascript =&gt; 0,
		params =&gt; $q,
		action =&gt; $config{cgiurl},
		template =&gt; (-e "$config{templatedir}/prefs.tmpl" ?
			     {template_params("prefs.tmpl")} : ""),
		stylesheet =&gt; baseurl()."style.css",
	);
	my $buttons=["Save Preferences", "Logout", "Cancel"];

	run_hooks(formbuilder_setup =&gt; sub {
		shift-&gt;(form =&gt; $form, cgi =&gt; $q, session =&gt; $session);
	});
	
	$form-&gt;field(name =&gt; "do", type =&gt; "hidden");
	$form-&gt;field(name =&gt; "email", size =&gt; 50);
	$form-&gt;field(name =&gt; "subscriptions", size =&gt; 50,
		comment =&gt; "(".htmllink("", "", "PageSpec", 1).")");
	$form-&gt;field(name =&gt; "locked_pages", size =&gt; 50,
		comment =&gt; "(".htmllink("", "", "PageSpec", 1).")");
	$form-&gt;field(name =&gt; "banned_users", size =&gt; 50);
	
	my $user_name=$session-&gt;param("name");
	if (! is_admin($user_name)) {
		$form-&gt;field(name =&gt; "locked_pages", type =&gt; "hidden");
		$form-&gt;field(name =&gt; "banned_users", type =&gt; "hidden");
	}

	if (! $form-&gt;submitted) {
		$form-&gt;field(name =&gt; "email", force =&gt; 1,
			value =&gt; userinfo_get($user_name, "email"));
		$form-&gt;field(name =&gt; "subscriptions", force =&gt; 1,
			value =&gt; userinfo_get($user_name, "subscriptions"));
		$form-&gt;field(name =&gt; "locked_pages", force =&gt; 1,
			value =&gt; userinfo_get($user_name, "locked_pages"));
		if (is_admin($user_name)) {
			$form-&gt;field(name =&gt; "banned_users", force =&gt; 1,
				value =&gt; join(" ", get_banned_users()));
		}
	}
	
	decode_form_utf8($form);
	
	if ($form-&gt;submitted eq 'Logout') {
		$session-&gt;delete();
		redirect($q, $config{url});
		return;
	}
	elsif ($form-&gt;submitted eq 'Cancel') {
		redirect($q, $config{url});
		return;
	}
	elsif ($form-&gt;submitted eq 'Save Preferences' &amp;&amp; $form-&gt;validate) {
		foreach my $field (qw(email subscriptions locked_pages)) {
			if (defined $form-&gt;field($field) &amp;&amp; length $form-&gt;field($field)) {
				userinfo_set($user_name, $field, $form-&gt;field($field)) || error("failed to set $field");
			}
		}
		if (is_admin($user_name)) {
			set_banned_users(grep { ! is_admin($_) }
					split(' ', $form-&gt;field("banned_users")));
		}
		$form-&gt;text(gettext("Preferences saved."));
	}
	
	if (exists $hooks{formbuilder}) {
		run_hooks(formbuilder =&gt; sub {
			shift-&gt;(form =&gt; $form, cgi =&gt; $q, session =&gt; $session,
				buttons =&gt; $buttons);
		});
	}
	else {
		printheader($session);
		print misctemplate($form-&gt;title, $form-&gt;render(submit =&gt; $buttons));
	}
} #}}}

sub cgi_editpage ($$) { #{{{
	my $q=shift;
	my $session=shift;

	my @fields=qw(do rcsinfo subpage from page type editcontent comments);
	my @buttons=("Save Page", "Preview", "Cancel");
	
	eval q{use CGI::FormBuilder};
	error($@) if $@;
	my $form = CGI::FormBuilder-&gt;new(
		fields =&gt; \@fields,
		header =&gt; 1,
		charset =&gt; "utf-8",
		method =&gt; 'POST',
		validate =&gt; {
			editcontent =&gt; '/.+/',
		},
		required =&gt; [qw{editcontent}],
		javascript =&gt; 0,
		params =&gt; $q,
		action =&gt; $config{cgiurl},
		table =&gt; 0,
		template =&gt; (-e "$config{templatedir}/editpage.tmpl" ?
				{template_params("editpage.tmpl")} : ""),
	);
	
	run_hooks(formbuilder_setup =&gt; sub {
		shift-&gt;(form =&gt; $form, cgi =&gt; $q, session =&gt; $session);
	});
	
	decode_form_utf8($form);
	
	# This untaint is safe because titlepage removes any problematic
	# characters.
	my ($page)=$form-&gt;field('page');
	$page=titlepage(possibly_foolish_untaint($page));
	if (! defined $page || ! length $page || file_pruned($page, $config{srcdir}) || $page=~/^\//) {
		error("bad page name");
	}
	
	my $from;
	if (defined $form-&gt;field('from')) {
		($from)=$form-&gt;field('from')=~/$config{wiki_file_regexp}/;
	}
	
	my $file;
	my $type;
	if (exists $pagesources{$page}) {
		$file=$pagesources{$page};
		$type=pagetype($file);
	}
	else {
		$type=$form-&gt;param('type');
		if (defined $type &amp;&amp; length $type &amp;&amp; $hooks{htmlize}{$type}) {
			$type=possibly_foolish_untaint($type);
		}
		elsif (defined $from) {
			# favor the type of linking page
			$type=pagetype($pagesources{$from});
		}
		$type=$config{default_pageext} unless defined $type;
		$file=$page.".".$type;
	}

	my $newfile=0;
	if (! -e "$config{srcdir}/$file") {
		$newfile=1;
	}

	$form-&gt;field(name =&gt; "do", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "from", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "rcsinfo", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "subpage", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "page", value =&gt; $page, force =&gt; 1);
	$form-&gt;field(name =&gt; "type", value =&gt; $type, force =&gt; 1);
	$form-&gt;field(name =&gt; "comments", type =&gt; "text", size =&gt; 80);
	$form-&gt;field(name =&gt; "editcontent", type =&gt; "textarea", rows =&gt; 20,
		cols =&gt; 80);
	$form-&gt;tmpl_param("can_commit", $config{rcs});
	$form-&gt;tmpl_param("indexlink", indexlink());
	$form-&gt;tmpl_param("helponformattinglink",
		htmllink("", "", "HelpOnFormatting", 1));
	$form-&gt;tmpl_param("baseurl", baseurl());
	if (! $form-&gt;submitted) {
		$form-&gt;field(name =&gt; "rcsinfo", value =&gt; rcs_prepedit($file),
			force =&gt; 1);
	}
	
	if ($form-&gt;submitted eq "Cancel") {
		if ($newfile &amp;&amp; defined $from) {
			redirect($q, "$config{url}/".htmlpage($from));
		}
		elsif ($newfile) {
			redirect($q, $config{url});
		}
		else {
			redirect($q, "$config{url}/".htmlpage($page));
		}
		return;
	}
	elsif ($form-&gt;submitted eq "Preview") {
		my $content=$form-&gt;field('editcontent');
		my $comments=$form-&gt;field('comments');
		$form-&gt;field(name =&gt; "editcontent",
				value =&gt; $content, force =&gt; 1);
		$form-&gt;field(name =&gt; "comments",
				value =&gt; $comments, force =&gt; 1);
		$config{rss}=$config{atom}=0; # avoid preview writing a feed!
		$form-&gt;tmpl_param("page_preview",
			htmlize($page, $type,
			linkify($page, "",
			preprocess($page, $page,
			filter($page, $content)))));
	}
	else {
		$form-&gt;tmpl_param("page_preview", "");
	}
	$form-&gt;tmpl_param("page_conflict", "");
	
	if (! $form-&gt;submitted || $form-&gt;submitted eq "Preview" || 
	    ! $form-&gt;validate) {
		if ($form-&gt;field("do") eq "create") {
			my @page_locs;
			my $best_loc;
			if (! defined $from || ! length $from ||
			    $from ne $form-&gt;field('from') ||
			    file_pruned($from, $config{srcdir}) ||
			    $from=~/^\// ||
			    $form-&gt;submitted eq "Preview") {
				@page_locs=$best_loc=$page;
			}
			else {
				my $dir=$from."/";
				$dir=~s![^/]+/+$!!;
				
				if ((defined $form-&gt;field('subpage') &amp;&amp; length $form-&gt;field('subpage')) ||
				    $page eq gettext('discussion')) {
					$best_loc="$from/$page";
				}
				else {
					$best_loc=$dir.$page;
				}
				
				push @page_locs, $dir.$page;
				push @page_locs, "$from/$page";
				while (length $dir) {
					$dir=~s![^/]+/+$!!;
					push @page_locs, $dir.$page;
				}
			}
			push @page_locs, "$config{userdir}/$page"
				if length $config{userdir};

			@page_locs = grep {
				! exists $pagecase{lc $_} &amp;&amp;
				! page_locked($_, $session, 1)
			} @page_locs;
			
			if (! @page_locs) {
				# hmm, someone else made the page in the
				# meantime?
				redirect($q, "$config{url}/".htmlpage($page));
				return;
			}
			
			my @page_types;
			if (exists $hooks{htmlize}) {
				@page_types=keys %{$hooks{htmlize}};
			}
			
			$form-&gt;tmpl_param("page_select", 1);
			$form-&gt;field(name =&gt; "page", type =&gt; 'select',
				options =&gt; \@page_locs, value =&gt; $best_loc);
			$form-&gt;field(name =&gt; "type", type =&gt; 'select',
				options =&gt; \@page_types);
			$form-&gt;title(sprintf(gettext("creating %s"), pagetitle($page)));
		}
		elsif ($form-&gt;field("do") eq "edit") {
			page_locked($page, $session);
			if (! defined $form-&gt;field('editcontent') || 
			    ! length $form-&gt;field('editcontent')) {
				my $content="";
				if (exists $pagesources{$page}) {
					$content=readfile(srcfile($pagesources{$page}));
					$content=~s/\n/\r\n/g;
				}
				$form-&gt;field(name =&gt; "editcontent", value =&gt; $content,
					force =&gt; 1);
			}
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), pagetitle($page)));
		}
		
		print $form-&gt;render(submit =&gt; \@buttons);
	}
	else {
		# save page
		page_locked($page, $session);
		
		my $content=$form-&gt;field('editcontent');

		$content=~s/\r\n/\n/g;
		$content=~s/\r/\n/g;
		writefile($file, $config{srcdir}, $content);
		
		if ($config{rcs}) {
			my $message="";
			if (defined $form-&gt;field('comments') &amp;&amp;
			    length $form-&gt;field('comments')) {
				$message=$form-&gt;field('comments');
			}
			
			if ($newfile) {
				rcs_add($file);
			}
			# prevent deadlock with post-commit hook
			unlockwiki();
			# presumably the commit will trigger an update
			# of the wiki
			my $conflict=rcs_commit($file, $message,
				$form-&gt;field("rcsinfo"),
				$session-&gt;param("name"), $ENV{REMOTE_ADDR});
		
			if (defined $conflict) {
				$form-&gt;field(name =&gt; "rcsinfo", value =&gt; rcs_prepedit($file),
					force =&gt; 1);
				$form-&gt;tmpl_param("page_conflict", 1);
				$form-&gt;field("editcontent", value =&gt; $conflict, force =&gt; 1);
				$form-&gt;field(name =&gt; "comments", value =&gt; $form-&gt;field('comments'), force =&gt; 1);
				$form-&gt;field("do", "edit)");
				$form-&gt;tmpl_param("page_select", 0);
				$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
				$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
				$form-&gt;title(sprintf(gettext("editing %s"), $page));
				print $form-&gt;render(submit =&gt; \@buttons);
				return;
			}
		}
		else {
			require IkiWiki::Render;
			refresh();
			saveindex();
		}
		
		# The trailing question mark tries to avoid broken
		# caches and get the most recent version of the page.
		redirect($q, "$config{url}/".htmlpage($page)."?updated");
	}
} #}}}

sub cgi_getsession ($) { #{{{
	my $q=shift;

	eval q{use CGI::Session};
	CGI::Session-&gt;name("ikiwiki_session_".encode_utf8($config{wikiname}));
	
	my $oldmask=umask(077);
	my $session = CGI::Session-&gt;new("driver:DB_File", $q,
		{ FileName =&gt; "$config{wikistatedir}/sessions.db" });
	umask($oldmask);

	return $session;
} #}}}

sub cgi_savesession ($) { #{{{
	my $session=shift;

	# Force session flush with safe umask.
	my $oldmask=umask(077);
	$session-&gt;flush;
	umask($oldmask);
}

sub cgi (;$$) { #{{{
	my $q=shift;
	my $session=shift;

	if (! $q) {
		eval q{use CGI};
		error($@) if $@;
	
		$q=CGI-&gt;new;
	
		run_hooks(cgi =&gt; sub { shift-&gt;($q) });
	}

	my $do=$q-&gt;param('do');
	if (! defined $do || ! length $do) {
		my $error = $q-&gt;cgi_error;
		if ($error) {
			error("Request not processed: $error");
		}
		else {
			error("\"do\" parameter missing");
		}
	}
	
	# Things that do not need a session.
	if ($do eq 'recentchanges') {
		cgi_recentchanges($q);
		return;
	}
	elsif ($do eq 'hyperestraier') {
		cgi_hyperestraier();
	}

	# Need to lock the wiki before getting a session.
	lockwiki();
	
	if (! $session) {
		$session=cgi_getsession($q);
	}
	
	# Auth hooks can sign a user in.
	if ($do ne 'signin' &amp;&amp; ! defined $session-&gt;param("name")) {
		run_hooks(auth =&gt; sub {
			shift-&gt;($q, $session)
		});
		if (defined $session-&gt;param("name")) {
			# Make sure whatever user was authed is in the
			# userinfo db.
			if (! userinfo_get($session-&gt;param("name"), "regdate")) {
				userinfo_setall($session-&gt;param("name"), {
					email =&gt; "",
					password =&gt; "",
					regdate =&gt; time,
				});
			}
		}
	}

	# Everything below this point needs the user to be signed in.
	if (((! $config{anonok} || $do eq 'prefs') &amp;&amp;
	     (! defined $session-&gt;param("name") ||
	     ! userinfo_get($session-&gt;param("name"), "regdate")))
            || $do eq 'signin') {
	    	if ($do ne 'signin' &amp;&amp; ! defined $session-&gt;param("postsignin")) {
			$session-&gt;param(postsignin =&gt; $ENV{QUERY_STRING});
		}
		cgi_signin($q, $session);
		cgi_savesession($session);
		return;
	}
	elsif (defined $session-&gt;param("postsignin")) {
		cgi_postsignin($q, $session);
	}

	if (defined $session-&gt;param("name") &amp;&amp; userinfo_get($session-&gt;param("name"), "banned")) {
		print $q-&gt;header(-status =&gt; "403 Forbidden");
		$session-&gt;delete();
		print gettext("You are banned.");
		cgi_savesession($session);
		exit;
	}
	
	if ($do eq 'create' || $do eq 'edit') {
		cgi_editpage($q, $session);
	}
	elsif ($do eq 'prefs') {
		cgi_prefs($q, $session);
	}
	elsif ($do eq 'blog') {
		my $page=titlepage(decode_utf8($q-&gt;param('title')));
		$page=~s/(\/)/"__".ord($1)."__"/eg; # escape slashes too
		# if the page already exists, munge it to be unique
		my $from=$q-&gt;param('from');
		my $add="";
		while (exists $pagecase{lc "$from/$page$add"}) {
			$add=1 unless length $add;
			$add++;
		}
		$q-&gt;param('page', $page.$add);
		# now run same as create
		$q-&gt;param('do', 'create');
		cgi_editpage($q, $session);
	}
	else {
		error("unknown do parameter");
	}
} #}}}

sub userlink ($) { #{{{
	my $user=shift;

	eval q{use CGI 'escapeHTML'};
	error($@) if $@;
	if ($user =~ m!^https?://! &amp;&amp;
	    eval q{use Net::OpenID::VerifiedIdentity; 1} &amp;&amp; !$@) {
		# Munge user-urls, as used by eg, OpenID.
		my $oid=Net::OpenID::VerifiedIdentity-&gt;new(identity =&gt; $user);
		my $display=$oid-&gt;display;
		# Convert "user.somehost.com" to "user [somehost.com]".
		if ($display !~ /\[/) {
			$display=~s/^(.*?)\.([^.]+\.[a-z]+)$/$1 [$2]/;
		}
		# Convert "http://somehost.com/user" to "user [somehost.com]".
		if ($display !~ /\[/) {
			$display=~s/^https?:\/\/(.+)\/([^\/]+)$/$2 [$1]/;
		}
		$display=~s!^https?://!!; # make sure this is removed
		return "&lt;a href=\"$user\"&gt;".escapeHTML($display)."&lt;/a&gt;";
	}
	else {
		return htmllink("", "", escapeHTML(
			length $config{userdir} ? $config{userdir}."/".$user : $user
		), 1);
	}
} #}}}

1
</pre></body></html>