<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::postsparkline;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	IkiWiki::loadplugin('sparkline');
	hook(type =&gt; "getsetup", id =&gt; "postsparkline", call =&gt; \&amp;getsetup);
	hook(type =&gt; "preprocess", id =&gt; "postsparkline", call =&gt; \&amp;preprocess);
}

sub getsetup () {
	return 
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; undef,
		},
}

sub preprocess (@) {
	my %params=@_;

	if (! exists $params{max}) {
		$params{max}=100;
	}

	if (! exists $params{pages}) {
		return "";
	}

	if (! exists $params{time} || $params{time} ne 'mtime') {
		$params{timehash} = \%IkiWiki::pagectime;
	}
	else {
		$params{timehash} = \%IkiWiki::pagemtime;
	}

	if (! exists $params{formula}) {
		error gettext("missing formula")
	}
	my $formula=$params{formula};
	$formula=~s/[^a-zA-Z0-9]*//g;
	$formula=IkiWiki::possibly_foolish_untaint($formula);
	if (! length $formula ||
	    ! IkiWiki::Plugin::postsparkline::formula-&gt;can($formula)) {
		error gettext("unknown formula");
	}

	add_depends($params{page}, $params{pages});

	my @list=pagespec_match_list(
		[ grep { $_ ne $params{page} } keys %pagesources],
		$params{pages}, location =&gt; $params{page});
	
	@list = sort { $params{timehash}-&gt;{$b} &lt;=&gt; $params{timehash}-&gt;{$a} } @list;

	my @data=eval qq{IkiWiki::Plugin::postsparkline::formula::$formula(\\\%params, \@list)};
	if ($@) {
		error $@;
	}

	if (! @data) {
		# generate an empty graph
		push @data, 0 foreach 1..($params{max} / 2);
	}

	my $color=exists $params{color} ? "($params{color})" : "";

	delete $params{pages};
	delete $params{formula};
	delete $params{ftime};
	delete $params{color};
	return IkiWiki::Plugin::sparkline::preprocess(%params, 
		map { $_.$color =&gt; "" } reverse @data);
}

sub perfoo ($@) {
	my $sub=shift;
	my $params=shift;
	
	my $max=$params-&gt;{max};
	my ($first, $prev, $cur);
	my $count=0;
	my @data;
	foreach (@_) {
		$cur=$sub-&gt;($params-&gt;{timehash}-&gt;{$_});
		if (defined $prev) {
			if ($prev != $cur) {
				push @data, "$prev,$count";
				$count=0;
				last if --$max &lt;= 0;

				for ($cur+1 .. $prev-1) {
					push @data, "$_,0";
					last if --$max == 0;
				}
			}
		}
		else {
			$first=$cur;
		}
		$count++;
		$prev=$cur;
	}

	return @data;
}

package IkiWiki::Plugin::postsparkline::formula;

sub peryear (@) {
	return IkiWiki::Plugin::postsparkline::perfoo(sub {
		return (localtime $_[0])[5];
	}, @_);
}

sub permonth (@) {
	return IkiWiki::Plugin::postsparkline::perfoo(sub {
		my ($month, $year)=(localtime $_[0])[4,5];
		return $year*12+$month;
	}, @_);
}

sub perday (@) {
	return IkiWiki::Plugin::postsparkline::perfoo(sub {
		my ($year, $yday)=(localtime $_[0])[5,7];
		return $year*365+$yday;
	}, @_);
}

sub interval ($@) {
	my $params=shift;

	my $max=$params-&gt;{max};
	my @data;
	for (my $i=1; $i &lt; @_; $i++) {
		push @data, $params-&gt;{timehash}-&gt;{$_[$i-1]} - $params-&gt;{timehash}-&gt;{$_[$i]};
		last if --$max &lt;= 0;
	}
	return @data;
}

1
</pre></body></html>