<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Copyright Â© 2006-2008 Joey Hess &lt;joey@ikiwiki.info&gt;
# Copyright Â© 2008 Simon McVittie &lt;http://smcv.pseudorandom.co.uk/&gt;
# Licensed under the GNU GPL, version 2, or any later version published by the
# Free Software Foundation
package IkiWiki::Plugin::comments;

use warnings;
use strict;
use IkiWiki 3.00;
use Encode;
use POSIX qw(strftime);

use constant PREVIEW =&gt; "Preview";
use constant POST_COMMENT =&gt; "Post comment";
use constant CANCEL =&gt; "Cancel";

my $postcomment;
my %commentstate;

sub import {
	hook(type =&gt; "checkconfig", id =&gt; 'comments',  call =&gt; \&amp;checkconfig);
	hook(type =&gt; "getsetup", id =&gt; 'comments',  call =&gt; \&amp;getsetup);
	hook(type =&gt; "preprocess", id =&gt; '_comment', call =&gt; \&amp;preprocess);
	hook(type =&gt; "sessioncgi", id =&gt; 'comment', call =&gt; \&amp;sessioncgi);
	hook(type =&gt; "htmlize", id =&gt; "_comment", call =&gt; \&amp;htmlize);
	hook(type =&gt; "pagetemplate", id =&gt; "comments", call =&gt; \&amp;pagetemplate);
	hook(type =&gt; "formbuilder_setup", id =&gt; "comments", call =&gt; \&amp;formbuilder_setup);
	# Load goto to fix up user page links for logged-in commenters
	IkiWiki::loadplugin("goto");
	IkiWiki::loadplugin("inline");
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
		comments_pagespec =&gt; {
			type =&gt; 'pagespec',
			example =&gt; 'blog/* and !*/Discussion',
			description =&gt; 'PageSpec of pages where comments are allowed',
			link =&gt; 'ikiwiki/PageSpec',
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
		comments_closed_pagespec =&gt; {
			type =&gt; 'pagespec',
			example =&gt; 'blog/controversial or blog/flamewar',
			description =&gt; 'PageSpec of pages where posting new comments is not allowed',
			link =&gt; 'ikiwiki/PageSpec',
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
		comments_pagename =&gt; {
			type =&gt; 'string',
			default =&gt; 'comment_',
			description =&gt; 'Base name for comments, e.g. "comment_" for pages like "sandbox/comment_12"',
			safe =&gt; 0, # manual page moving required
			rebuild =&gt; undef,
		},
		comments_allowdirectives =&gt; {
			type =&gt; 'boolean',
			example =&gt; 0,
			description =&gt; 'Interpret directives in comments?',
			safe =&gt; 1,
			rebuild =&gt; 0,
		},
		comments_allowauthor =&gt; {
			type =&gt; 'boolean',
			example =&gt; 0,
			description =&gt; 'Allow anonymous commenters to set an author name?',
			safe =&gt; 1,
			rebuild =&gt; 0,
		},
		comments_commit =&gt; {
			type =&gt; 'boolean',
			example =&gt; 1,
			description =&gt; 'commit comments to the VCS',
			# old uncommitted comments are likely to cause
			# confusion if this is changed
			safe =&gt; 0,
			rebuild =&gt; 0,
		},
}

sub checkconfig () {
	$config{comments_commit} = 1
		unless defined $config{comments_commit};
	$config{comments_pagespec} = ''
		unless defined $config{comments_pagespec};
	$config{comments_closed_pagespec} = ''
		unless defined $config{comments_closed_pagespec};
	$config{comments_pagename} = 'comment_'
		unless defined $config{comments_pagename};
}

sub htmlize {
	my %params = @_;
	return $params{content};
}

# FIXME: copied verbatim from meta
sub safeurl ($) {
	my $url=shift;
	if (exists $IkiWiki::Plugin::htmlscrubber::{safe_url_regexp} &amp;&amp;
	    defined $IkiWiki::Plugin::htmlscrubber::safe_url_regexp) {
		return $url=~/$IkiWiki::Plugin::htmlscrubber::safe_url_regexp/;
	}
	else {
		return 1;
	}
}

sub preprocess {
	my %params = @_;
	my $page = $params{page};

	my $format = $params{format};
	if (defined $format &amp;&amp; ! exists $IkiWiki::hooks{htmlize}{$format}) {
		error(sprintf(gettext("unsupported page format %s"), $format));
	}

	my $content = $params{content};
	if (! defined $content) {
		error(gettext("comment must have content"));
	}
	$content =~ s/\\"/"/g;

	$content = IkiWiki::filter($page, $params{destpage}, $content);

	if ($config{comments_allowdirectives}) {
		$content = IkiWiki::preprocess($page, $params{destpage},
			$content);
	}

	# no need to bother with htmlize if it's just HTML
	$content = IkiWiki::htmlize($page, $params{destpage}, $format, $content)
		if defined $format;

	IkiWiki::run_hooks(sanitize =&gt; sub {
		$content = shift-&gt;(
			page =&gt; $page,
			destpage =&gt; $params{destpage},
			content =&gt; $content,
		);
	});

	# set metadata, possibly overriding [[!meta]] directives from the
	# comment itself

	my $commentuser;
	my $commentip;
	my $commentauthor;
	my $commentauthorurl;
	my $commentopenid;
	if (defined $params{username}) {
		$commentuser = $params{username};

		my $oiduser = eval { IkiWiki::openiduser($commentuser) };

		if (defined $oiduser) {
			# looks like an OpenID
			$commentauthorurl = $commentuser;
			$commentauthor = $oiduser;
			$commentopenid = $commentuser;
		}
		else {
			$commentauthorurl = IkiWiki::cgiurl(
				do =&gt; 'goto',
				page =&gt; (length $config{userdir}
					? "$config{userdir}/$commentuser"
					: "$commentuser"));

			$commentauthor = $commentuser;
		}
	}
	else {
		if (defined $params{ip}) {
			$commentip = $params{ip};
		}
		$commentauthor = gettext("Anonymous");
	}

	$commentstate{$page}{commentuser} = $commentuser;
	$commentstate{$page}{commentopenid} = $commentopenid;
	$commentstate{$page}{commentip} = $commentip;
	$commentstate{$page}{commentauthor} = $commentauthor;
	$commentstate{$page}{commentauthorurl} = $commentauthorurl;
	if (! defined $pagestate{$page}{meta}{author}) {
		$pagestate{$page}{meta}{author} = $commentauthor;
	}
	if (! defined $pagestate{$page}{meta}{authorurl}) {
		$pagestate{$page}{meta}{authorurl} = $commentauthorurl;
	}

	if ($config{comments_allowauthor}) {
		if (defined $params{claimedauthor}) {
			$pagestate{$page}{meta}{author} = $params{claimedauthor};
		}

		if (defined $params{url}) {
			my $url=$params{url};

			eval q{use URI::Heuristic}; 
		  	if (! $@) {
				$url=URI::Heuristic::uf_uristr($url);
			}

			if (safeurl($url)) {
				$pagestate{$page}{meta}{authorurl} = $url;
			}
		}
	}
	else {
		$pagestate{$page}{meta}{author} = $commentauthor;
		$pagestate{$page}{meta}{authorurl} = $commentauthorurl;
	}

	if (defined $params{subject}) {
		$pagestate{$page}{meta}{title} = $params{subject};
	}

	if ($params{page} =~ m/\/(\Q$config{comments_pagename}\E\d+)$/) {
		$pagestate{$page}{meta}{permalink} = urlto(IkiWiki::dirname($params{page}), undef, 1).
			"#".page_to_id($params{page});
	}

	eval q{use Date::Parse};
	if (! $@) {
		my $time = str2time($params{date});
		$IkiWiki::pagectime{$page} = $time if defined $time;
	}

	return $content;
}

sub sessioncgi ($$) {
	my $cgi=shift;
	my $session=shift;

	my $do = $cgi-&gt;param('do');
	if ($do eq 'comment') {
		editcomment($cgi, $session);
	}
	elsif ($do eq 'commentmoderation') {
		commentmoderation($cgi, $session);
	}
}

# Mostly cargo-culted from IkiWiki::plugin::editpage
sub editcomment ($$) {
	my $cgi=shift;
	my $session=shift;

	IkiWiki::decode_cgi_utf8($cgi);

	eval q{use CGI::FormBuilder};
	error($@) if $@;

	my @buttons = (POST_COMMENT, PREVIEW, CANCEL);
	my $form = CGI::FormBuilder-&gt;new(
		fields =&gt; [qw{do sid page subject editcontent type author url}],
		charset =&gt; 'utf-8',
		method =&gt; 'POST',
		required =&gt; [qw{editcontent}],
		javascript =&gt; 0,
		params =&gt; $cgi,
		action =&gt; $config{cgiurl},
		header =&gt; 0,
		table =&gt; 0,
		template =&gt; scalar IkiWiki::template_params('editcomment.tmpl'),
	);

	IkiWiki::decode_form_utf8($form);
	IkiWiki::run_hooks(formbuilder_setup =&gt; sub {
			shift-&gt;(title =&gt; "comment", form =&gt; $form, cgi =&gt; $cgi,
				session =&gt; $session, buttons =&gt; \@buttons);
		});
	IkiWiki::decode_form_utf8($form);

	my $type = $form-&gt;param('type');
	if (defined $type &amp;&amp; length $type &amp;&amp; $IkiWiki::hooks{htmlize}{$type}) {
		$type = IkiWiki::possibly_foolish_untaint($type);
	}
	else {
		$type = $config{default_pageext};
	}
	my @page_types;
	if (exists $IkiWiki::hooks{htmlize}) {
		@page_types = grep { ! /^_/ } keys %{$IkiWiki::hooks{htmlize}};
	}

	$form-&gt;field(name =&gt; 'do', type =&gt; 'hidden');
	$form-&gt;field(name =&gt; 'sid', type =&gt; 'hidden', value =&gt; $session-&gt;id,
		force =&gt; 1);
	$form-&gt;field(name =&gt; 'page', type =&gt; 'hidden');
	$form-&gt;field(name =&gt; 'subject', type =&gt; 'text', size =&gt; 72);
	$form-&gt;field(name =&gt; 'editcontent', type =&gt; 'textarea', rows =&gt; 10);
	$form-&gt;field(name =&gt; "type", value =&gt; $type, force =&gt; 1,
		type =&gt; 'select', options =&gt; \@page_types);

	$form-&gt;tmpl_param(username =&gt; $session-&gt;param('name'));

	if ($config{comments_allowauthor} and
	    ! defined $session-&gt;param('name')) {
		$form-&gt;tmpl_param(allowauthor =&gt; 1);
		$form-&gt;field(name =&gt; 'author', type =&gt; 'text', size =&gt; '40');
		$form-&gt;field(name =&gt; 'url', type =&gt; 'text', size =&gt; '40');
	}
	else {
		$form-&gt;tmpl_param(allowauthor =&gt; 0);
		$form-&gt;field(name =&gt; 'author', type =&gt; 'hidden', value =&gt; '',
			force =&gt; 1);
		$form-&gt;field(name =&gt; 'url', type =&gt; 'hidden', value =&gt; '',
			force =&gt; 1);
	}

	if (! defined $session-&gt;param('name')) {
		# Make signinurl work and return here.
		$form-&gt;tmpl_param(signinurl =&gt; IkiWiki::cgiurl(do =&gt; 'signin'));
		$session-&gt;param(postsignin =&gt; $ENV{QUERY_STRING});
		IkiWiki::cgi_savesession($session);
	}

	# The untaint is OK (as in editpage) because we're about to pass
	# it to file_pruned anyway
	my $page = $form-&gt;field('page');
	$page = IkiWiki::possibly_foolish_untaint($page);
	if (! defined $page || ! length $page ||
		IkiWiki::file_pruned($page, $config{srcdir})) {
		error(gettext("bad page name"));
	}

	my $baseurl = urlto($page, undef, 1);

	$form-&gt;title(sprintf(gettext("commenting on %s"),
			IkiWiki::pagetitle($page)));

	$form-&gt;tmpl_param('helponformattinglink',
		htmllink($page, $page, 'ikiwiki/formatting',
			noimageinline =&gt; 1,
			linktext =&gt; 'FormattingHelp'),
			allowdirectives =&gt; $config{allow_directives});

	if ($form-&gt;submitted eq CANCEL) {
		# bounce back to the page they wanted to comment on, and exit.
		# CANCEL need not be considered in future
		IkiWiki::redirect($cgi, urlto($page, undef, 1));
		exit;
	}

	if (not exists $pagesources{$page}) {
		error(sprintf(gettext(
			"page '%s' doesn't exist, so you can't comment"),
			$page));
	}

	if (pagespec_match($page, $config{comments_closed_pagespec},
		location =&gt; $page)) {
		error(sprintf(gettext(
			"comments on page '%s' are closed"),
			$page));
	}

	# Set a flag to indicate that we're posting a comment,
	# so that postcomment() can tell it should match.
	$postcomment=1;
	IkiWiki::check_canedit($page, $cgi, $session);
	$postcomment=0;

	my $location=unique_comment_location($page, $config{srcdir});

	my $content = "[[!_comment format=$type\n";

	# FIXME: handling of double quotes probably wrong?
	if (defined $session-&gt;param('name')) {
		my $username = $session-&gt;param('name');
		$username =~ s/"/&amp;quot;/g;
		$content .= " username=\"$username\"\n";
	}
	elsif (defined $ENV{REMOTE_ADDR}) {
		my $ip = $ENV{REMOTE_ADDR};
		if ($ip =~ m/^([.0-9]+)$/) {
			$content .= " ip=\"$1\"\n";
		}
	}

	if ($config{comments_allowauthor}) {
		my $author = $form-&gt;field('author');
		if (defined $author &amp;&amp; length $author) {
			$author =~ s/"/&amp;quot;/g;
			$content .= " claimedauthor=\"$author\"\n";
		}
		my $url = $form-&gt;field('url');
		if (defined $url &amp;&amp; length $url) {
			$url =~ s/"/&amp;quot;/g;
			$content .= " url=\"$url\"\n";
		}
	}

	my $subject = $form-&gt;field('subject');
	if (defined $subject &amp;&amp; length $subject) {
		$subject =~ s/"/&amp;quot;/g;
		$content .= " subject=\"$subject\"\n";
	}

	$content .= " date=\"" . decode_utf8(strftime('%Y-%m-%dT%H:%M:%SZ', gmtime)) . "\"\n";

	my $editcontent = $form-&gt;field('editcontent') || '';
	$editcontent =~ s/\r\n/\n/g;
	$editcontent =~ s/\r/\n/g;
	$editcontent =~ s/"/\\"/g;
	$content .= " content=\"\"\"\n$editcontent\n\"\"\"]]\n";

	# This is essentially a simplified version of editpage:
	# - the user does not control the page that's created, only the parent
	# - it's always a create operation, never an edit
	# - this means that conflicts should never happen
	# - this means that if they do, rocks fall and everyone dies

	if ($form-&gt;submitted eq PREVIEW) {
		my $preview=previewcomment($content, $location, $page, time);
		IkiWiki::run_hooks(format =&gt; sub {
			$preview = shift-&gt;(page =&gt; $page,
				content =&gt; $preview);
		});
		$form-&gt;tmpl_param(page_preview =&gt; $preview);
	}
	else {
		$form-&gt;tmpl_param(page_preview =&gt; "");
	}

	if ($form-&gt;submitted eq POST_COMMENT &amp;&amp; $form-&gt;validate) {
		IkiWiki::checksessionexpiry($cgi, $session);
		
		$postcomment=1;
		my $ok=IkiWiki::check_content(content =&gt; $form-&gt;field('editcontent'),
			subject =&gt; $form-&gt;field('subject'),
			$config{comments_allowauthor} ? (
				author =&gt; $form-&gt;field('author'),
				url =&gt; $form-&gt;field('url'),
			) : (),
			page =&gt; $location,
			cgi =&gt; $cgi,
			session =&gt; $session,
			nonfatal =&gt; 1,
		);
		$postcomment=0;

		if (! $ok) {
			my $penddir=$config{wikistatedir}."/comments_pending";
			$location=unique_comment_location($page, $penddir);
			writefile("$location._comment", $penddir, $content);
			IkiWiki::printheader($session);
			print IkiWiki::misctemplate(gettext(gettext("comment stored for moderation")),
				"&lt;p&gt;".
				gettext("Your comment will be posted after moderator review").
				"&lt;/p&gt;");
			exit;
		}

		# FIXME: could probably do some sort of graceful retry
		# on error? Would require significant unwinding though
		my $file = "$location._comment";
		writefile($file, $config{srcdir}, $content);

		my $conflict;

		if ($config{rcs} and $config{comments_commit}) {
			my $message = gettext("Added a comment");
			if (defined $form-&gt;field('subject') &amp;&amp;
				length $form-&gt;field('subject')) {
				$message = sprintf(
					gettext("Added a comment: %s"),
					$form-&gt;field('subject'));
			}

			IkiWiki::rcs_add($file);
			IkiWiki::disable_commit_hook();
			$conflict = IkiWiki::rcs_commit_staged($message,
				$session-&gt;param('name'), $ENV{REMOTE_ADDR});
			IkiWiki::enable_commit_hook();
			IkiWiki::rcs_update();
		}

		# Now we need a refresh
		require IkiWiki::Render;
		IkiWiki::refresh();
		IkiWiki::saveindex();

		# this should never happen, unless a committer deliberately
		# breaks it or something
		error($conflict) if defined $conflict;

		# Jump to the new comment on the page.
		# The trailing question mark tries to avoid broken
		# caches and get the most recent version of the page.
		IkiWiki::redirect($cgi, urlto($page, undef, 1).
			"?updated#".page_to_id($location));

	}
	else {
		IkiWiki::showform ($form, \@buttons, $session, $cgi,
			forcebaseurl =&gt; $baseurl);
	}

	exit;
}

sub commentmoderation ($$) {
	my $cgi=shift;
	my $session=shift;

	IkiWiki::needsignin($cgi, $session);
	if (! IkiWiki::is_admin($session-&gt;param("name"))) {
		error(gettext("you are not logged in as an admin"));
	}

	IkiWiki::decode_cgi_utf8($cgi);
	
	if (defined $cgi-&gt;param('sid')) {
		IkiWiki::checksessionexpiry($cgi, $session);

		my $rejectalldefer=$cgi-&gt;param('rejectalldefer');

		my %vars=$cgi-&gt;Vars;
		my $added=0;
		foreach my $id (keys %vars) {
			if ($id =~ /(.*)\Q._comment\E$/) {
				my $action=$cgi-&gt;param($id);
				next if $action eq 'Defer' &amp;&amp; ! $rejectalldefer;

				# Make sure that the id is of a legal
				# pending comment before untainting.
				my ($f)= $id =~ /$config{wiki_file_regexp}/;
				if (! defined $f || ! length $f ||
				    IkiWiki::file_pruned($f, $config{srcdir})) {
					error("illegal file");
				}

				my $page=IkiWiki::possibly_foolish_untaint(IkiWiki::dirname($1));
				my $file="$config{wikistatedir}/comments_pending/".
					IkiWiki::possibly_foolish_untaint($id);

				if ($action eq 'Accept') {
					my $content=eval { readfile($file) };
					next if $@; # file vanished since form was displayed
					my $dest=unique_comment_location($page, $config{srcdir})."._comment";
					writefile($dest, $config{srcdir}, $content);
					if ($config{rcs} and $config{comments_commit}) {
						IkiWiki::rcs_add($dest);
					}
					$added++;
				}

				# This removes empty subdirs, so the
				# .ikiwiki/comments_pending dir will
				# go away when all are moderated.
				require IkiWiki::Render;
				IkiWiki::prune($file);
			}
		}

		if ($added) {
			my $conflict;
			if ($config{rcs} and $config{comments_commit}) {
				my $message = gettext("Comment moderation");
				IkiWiki::disable_commit_hook();
				$conflict=IkiWiki::rcs_commit_staged($message,
					$session-&gt;param('name'), $ENV{REMOTE_ADDR});
				IkiWiki::enable_commit_hook();
				IkiWiki::rcs_update();
			}
		
			# Now we need a refresh
			require IkiWiki::Render;
			IkiWiki::refresh();
			IkiWiki::saveindex();
		
			error($conflict) if defined $conflict;
		}
	}

	my @comments=map {
		my ($id, $ctime)=@{$_};
		my $file="$config{wikistatedir}/comments_pending/$id";
		my $content=readfile($file);
		my $preview=previewcomment($content, $id,
			IkiWiki::dirname($_), $ctime);
		{
			id =&gt; $id,
			view =&gt; $preview,
		} 
	} sort { $b-&gt;[1] &lt;=&gt; $a-&gt;[1] } comments_pending();

	my $template=template("commentmoderation.tmpl");
	$template-&gt;param(
		sid =&gt; $session-&gt;id,
		comments =&gt; \@comments,
	);
	IkiWiki::printheader($session);
	my $out=$template-&gt;output;
	IkiWiki::run_hooks(format =&gt; sub {
		$out = shift-&gt;(page =&gt; "", content =&gt; $out);
	});
	print IkiWiki::misctemplate(gettext("comment moderation"), $out);
	exit;
}

sub formbuilder_setup (@) {
	my %params=@_;

	my $form=$params{form};
	if ($form-&gt;title eq "preferences" &amp;&amp;
	    IkiWiki::is_admin($params{session}-&gt;param("name"))) {
		push @{$params{buttons}}, "Comment Moderation";
		if ($form-&gt;submitted &amp;&amp; $form-&gt;submitted eq "Comment Moderation") {
			commentmoderation($params{cgi}, $params{session});
		}
	}
}

sub comments_pending () {
	my $dir="$config{wikistatedir}/comments_pending/";
	return unless -d $dir;

	my @ret;
	eval q{use File::Find};
	error($@) if $@;
	find({
		no_chdir =&gt; 1,
		wanted =&gt; sub {
			$_=decode_utf8($_);
			if (IkiWiki::file_pruned($_, $dir)) {
				$File::Find::prune=1;
			}
			elsif (! -l $_ &amp;&amp; ! -d _) {
				$File::Find::prune=0;
				my ($f)=/$config{wiki_file_regexp}/; # untaint
				if (defined $f &amp;&amp; $f =~ /\Q._comment\E$/) {
					my $ctime=(stat($f))[10];
					$f=~s/^\Q$dir\E\/?//;
                                        push @ret, [$f, $ctime];
				}
			}
		}
	}, $dir);

	return @ret;
}

sub previewcomment ($$$) {
	my $content=shift;
	my $location=shift;
	my $page=shift;
	my $time=shift;

	my $preview = IkiWiki::htmlize($location, $page, '_comment',
			IkiWiki::linkify($location, $page,
			IkiWiki::preprocess($location, $page,
			IkiWiki::filter($location, $page, $content), 0, 1)));

	my $template = template("comment.tmpl");
	$template-&gt;param(content =&gt; $preview);
	$template-&gt;param(ctime =&gt; displaytime($time));

	IkiWiki::run_hooks(pagetemplate =&gt; sub {
		shift-&gt;(page =&gt; $location,
			destpage =&gt; $page,
			template =&gt; $template);
	});

	$template-&gt;param(have_actions =&gt; 0);

	return $template-&gt;output;
}

sub commentsshown ($) {
	my $page=shift;

	return ! pagespec_match($page, "internal(*/$config{comments_pagename}*)",
	                        location =&gt; $page) &amp;&amp;
	       pagespec_match($page, $config{comments_pagespec},
	                      location =&gt; $page);
}

sub commentsopen ($) {
	my $page = shift;

	return length $config{cgiurl} &gt; 0 &amp;&amp;
	       (! length $config{comments_closed_pagespec} ||
	        ! pagespec_match($page, $config{comments_closed_pagespec},
	                         location =&gt; $page));
}

sub pagetemplate (@) {
	my %params = @_;

	my $page = $params{page};
	my $template = $params{template};
	my $shown = ($template-&gt;query(name =&gt; 'commentslink') ||
	             $template-&gt;query(name =&gt; 'commentsurl') ||
	             $template-&gt;query(name =&gt; 'atomcommentsurl') ||
	             $template-&gt;query(name =&gt; 'comments')) &amp;&amp;
	            commentsshown($page);

	if ($template-&gt;query(name =&gt; 'comments')) {
		my $comments = undef;
		if ($shown) {
			$comments = IkiWiki::preprocess_inline(
				pages =&gt; "internal($page/$config{comments_pagename}*)",
				template =&gt; 'comment',
				show =&gt; 0,
				reverse =&gt; 'yes',
				page =&gt; $page,
				destpage =&gt; $params{destpage},
				feedfile =&gt; 'comments',
				emptyfeeds =&gt; 'no',
			);
		}

		if (defined $comments &amp;&amp; length $comments) {
			$template-&gt;param(comments =&gt; $comments);
		}

		if ($shown &amp;&amp; commentsopen($page)) {
			my $addcommenturl = IkiWiki::cgiurl(do =&gt; 'comment',
				page =&gt; $page);
			$template-&gt;param(addcommenturl =&gt; $addcommenturl);
		}
	}

	if ($template-&gt;query(name =&gt; 'commentsurl')) {
		if ($shown) {
			$template-&gt;param(commentsurl =&gt;
				urlto($page, undef, 1).'#comments');
		}
	}

	if ($template-&gt;query(name =&gt; 'atomcommentsurl') &amp;&amp; $config{usedirs}) {
		if ($shown) {
			# This will 404 until there are some comments, but I
			# think that's probably OK...
			$template-&gt;param(atomcommentsurl =&gt;
				urlto($page, undef, 1).'comments.atom');
		}
	}

	if ($template-&gt;query(name =&gt; 'commentslink')) {
		# XXX Would be nice to say how many comments there are in
		# the link. But, to update the number, blog pages
		# would have to update whenever comments of any inlines
		# page are added, which is not currently done.
		if ($shown) {
			$template-&gt;param(commentslink =&gt;
				htmllink($page, $params{destpage}, $page,
					linktext =&gt; gettext("Comments"),
					anchor =&gt; "comments",
					noimageinline =&gt; 1));
		}
	}

	# everything below this point is only relevant to the comments
	# themselves
	if (!exists $commentstate{$page}) {
		return;
	}
	
	if ($template-&gt;query(name =&gt; 'commentid')) {
		$template-&gt;param(commentid =&gt; page_to_id($page));
	}

	if ($template-&gt;query(name =&gt; 'commentuser')) {
		$template-&gt;param(commentuser =&gt;
			$commentstate{$page}{commentuser});
	}

	if ($template-&gt;query(name =&gt; 'commentopenid')) {
		$template-&gt;param(commentopenid =&gt;
			$commentstate{$page}{commentopenid});
	}

	if ($template-&gt;query(name =&gt; 'commentip')) {
		$template-&gt;param(commentip =&gt;
			$commentstate{$page}{commentip});
	}

	if ($template-&gt;query(name =&gt; 'commentauthor')) {
		$template-&gt;param(commentauthor =&gt;
			$commentstate{$page}{commentauthor});
	}

	if ($template-&gt;query(name =&gt; 'commentauthorurl')) {
		$template-&gt;param(commentauthorurl =&gt;
			$commentstate{$page}{commentauthorurl});
	}

	if ($template-&gt;query(name =&gt; 'removeurl') &amp;&amp;
	    IkiWiki::Plugin::remove-&gt;can("check_canremove") &amp;&amp;
	    length $config{cgiurl}) {
		$template-&gt;param(removeurl =&gt; IkiWiki::cgiurl(do =&gt; 'remove',
			page =&gt; $page));
		$template-&gt;param(have_actions =&gt; 1);
	}
}

sub unique_comment_location ($) {
	my $page=shift;
	my $dir=shift;

	my $location;
	my $i = 0;
	do {
		$i++;
		$location = "$page/$config{comments_pagename}$i";
	} while (-e "$dir/$location._comment");

	return $location;
}

sub page_to_id ($) {
	# Converts a comment page name into a unique, legal html id
	# addtibute value, that can be used as an anchor to link to the
	# comment.
	my $page=shift;

	eval q{use Digest::MD5 'md5_hex'};
	error($@) if $@;

	return "comment-".md5_hex($page);
}
	
package IkiWiki::PageSpec;

sub match_postcomment ($$;@) {
	my $page = shift;
	my $glob = shift;

	if (! $postcomment) {
		return IkiWiki::FailReason-&gt;new("not posting a comment");
	}
	return match_glob($page, $glob);
}

1
</pre></body></html>