<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::cutpaste;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "cutpaste", call =&gt; \&amp;getsetup);
	hook(type =&gt; "needsbuild", id =&gt; "cutpaste", call =&gt; \&amp;needsbuild);
	hook(type =&gt; "preprocess", id =&gt; "cut", call =&gt; \&amp;preprocess_cut, scan =&gt; 1);
	hook(type =&gt; "preprocess", id =&gt; "copy", call =&gt; \&amp;preprocess_copy, scan =&gt; 1);
	hook(type =&gt; "preprocess", id =&gt; "paste", call =&gt; \&amp;preprocess_paste);
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; undef,
			section =&gt; "widget",
		},
}

sub needsbuild (@) {
	my $needsbuild=shift;
	foreach my $page (keys %pagestate) {
		if (exists $pagestate{$page}{cutpaste}) {
			if (exists $pagesources{$page} &amp;&amp;
			    grep { $_ eq $pagesources{$page} } @$needsbuild) {
				# remove state, will be re-added if
				# the cut/copy directive is still present
				# on rebuild.
				delete $pagestate{$page}{cutpaste};
			}
		}
	}
	return $needsbuild;
}

sub preprocess_cut (@) {
	my %params=@_;

	foreach my $param (qw{id text}) {
		if (! exists $params{$param}) {
			error sprintf(gettext('%s parameter is required'), $param);
		}
	}

	$pagestate{$params{page}}{cutpaste}{$params{id}} = $params{text};

	return "" if defined wantarray;
}

sub preprocess_copy (@) {
	my %params=@_;

	foreach my $param (qw{id text}) {
		if (! exists $params{$param}) {
			error sprintf(gettext('%s parameter is required'), $param);
		}
	}

	$pagestate{$params{page}}{cutpaste}{$params{id}} = $params{text};

	return IkiWiki::preprocess($params{page}, $params{destpage}, $params{text})
		if defined wantarray;
}

sub preprocess_paste (@) {
	my %params=@_;

	foreach my $param (qw{id}) {
		if (! exists $params{$param}) {
			error sprintf(gettext('%s parameter is required'), $param);
		}
	}

	if (! exists $pagestate{$params{page}}{cutpaste}) {
		error gettext('no text was copied in this page');
	}
	if (! exists $pagestate{$params{page}}{cutpaste}{$params{id}}) {
		error sprintf(gettext('no text was copied in this page with id %s'), $params{id});
	}

	return IkiWiki::preprocess($params{page}, $params{destpage},
		$pagestate{$params{page}}{cutpaste}{$params{id}});
}

1;
</pre></body></html>