<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Ikiwiki enhanced image handling plugin
# Christian Mock cm@tahina.priv.at 20061002
package IkiWiki::Plugin::img;

use warnings;
use strict;
use IkiWiki;
use Image::Magick;

my %imgdefaults;

sub import { #{{{
	hook(type =&gt; "preprocess", id =&gt; "img", call =&gt; \&amp;preprocess);
} #}}}

sub preprocess (@) { #{{{
	my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
	my %params=@_;

	if (! exists $imgdefaults{$params{page}}) {
		$imgdefaults{$params{page}} = {};
	}
	my $size = $params{size} || $imgdefaults{$params{page}}-&gt;{size} || 'full';
	my $alt = $params{alt} || $imgdefaults{$params{page}}-&gt;{alt} || '';

	if ($image eq 'defaults') {
		$imgdefaults{$params{page}} = {
			size =&gt; $size,
			alt =&gt; $alt,
		};
		return '';
	}

	add_depends($params{page}, $image);
	my $file = bestlink($params{page}, $image) || return "[[img $image not found]]";

	my $dir = IkiWiki::dirname($file);
	my $base = IkiWiki::basename($file);
	my $im = Image::Magick-&gt;new;
	my $imglink;
	my $r;

	if ($size ne 'full') {
		my ($w, $h) = ($size =~ /^(\d+)x(\d+)$/);
		return "[[img bad size \"$size\"]]" unless (defined $w &amp;&amp; defined $h);

		my $outfile = "$config{destdir}/$dir/${w}x${h}-$base";
		$imglink = "$dir/${w}x${h}-$base";
		will_render($params{page}, $imglink);

		if (-e $outfile &amp;&amp; (-M srcfile($file) &gt;= -M $outfile)) {
			$r = $im-&gt;Read($outfile);
			return "[[img failed to read $outfile: $r]]" if $r;
		}
		else {
			$r = $im-&gt;Read(srcfile($file));
			return "[[img failed to read $file: $r]]" if $r;

			$r = $im-&gt;Resize(geometry =&gt; "${w}x${h}");
			return "[[img failed to resize: $r]]" if $r;

			my @blob = $im-&gt;ImageToBlob();
			writefile($imglink, $config{destdir}, $blob[0], 1);
		}
	}
	else {
		$r = $im-&gt;Read(srcfile($file));
		return "[[img failed to read $file: $r]]" if $r;
		$imglink = $file;
	}

	add_depends($imglink, $params{page});

	return '&lt;a href="'.
		IkiWiki::abs2rel($file, IkiWiki::dirname($params{destpage})).
		'"&gt;&lt;img src="'.
		IkiWiki::abs2rel($imglink, IkiWiki::dirname($params{destpage})).
		'" alt="'.$alt.'" width="'.$im-&gt;Get("width").
		'" height="'.$im-&gt;Get("height").'" /&gt;&lt;/a&gt;';
} #}}}

1;
</pre></body></html>