<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Ikiwiki parentlinks plugin.
package IkiWiki::Plugin::parentlinks;

use warnings;
use strict;
use IkiWiki 2.00;

sub import { #{{{
	hook(type =&gt; "pagetemplate", id =&gt; "parentlinks", call =&gt; \&amp;pagetemplate);
} # }}}

sub parentlinks ($) { #{{{
	my $page=shift;

	my @ret;
	my $path="";
	my $title=$config{wikiname};
	my $i=0;
	my $depth=0;
	my $height=0;

	my @pagepath=(split("/", $page));
	my $pagedepth=@pagepath;
	foreach my $dir (@pagepath) {
		next if $dir eq 'index';
		$depth=$i;
		$height=($pagedepth - $depth);
		push @ret, {
			url =&gt; urlto($path, $page),
			page =&gt; $title,
			depth =&gt; $depth,
			height =&gt; $height,
			"depth_$depth" =&gt; 1,
			"height_$height" =&gt; 1,
		};
		$path.="/".$dir;
		$title=IkiWiki::pagetitle($dir);
		$i++;
	}
	return @ret;
} #}}}

sub pagetemplate (@) { #{{{
	my %params=@_;
        my $page=$params{page};
        my $template=$params{template};

	if ($template-&gt;query(name =&gt; "parentlinks")) {
		$template-&gt;param(parentlinks =&gt; [parentlinks($page)]);
	}
} # }}}

1
</pre></body></html>