<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# CamelCase links
package IkiWiki::Plugin::camelcase;

use warnings;
use strict;
use IkiWiki 3.00;

# This regexp is based on the one in Text::WikiFormat.
my $link_regexp=qr{
	(?&lt;![^A-Za-z0-9\s])	# try to avoid expanding non-links with a
				# zero width negative lookbehind for
				# characters that suggest it's not a link
	\b			# word boundry
	(
		(?:
			[A-Z]		# Uppercase start
			[a-z0-9]	# followed by lowercase
			\w*		# and rest of word
		)
		{2,}			# repeated twice
	)
}x;

sub import {
	hook(type =&gt; "getsetup", id =&gt; "camelcase", call =&gt; \&amp;getsetup);
	hook(type =&gt; "linkify", id =&gt; "camelcase", call =&gt; \&amp;linkify);
	hook(type =&gt; "scan", id =&gt; "camelcase", call =&gt; \&amp;scan);
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; undef,
		},
		camelcase_ignore =&gt; {
			type =&gt; "string",
			example =&gt; [],
			description =&gt; "list of words to not turn into links",
			safe =&gt; 1,
			rebuild =&gt; undef, # might change links
		},
}

sub linkify (@) {
	my %params=@_;
	my $page=$params{page};
	my $destpage=$params{destpage};

	$params{content}=~s{$link_regexp}{
		ignored($1) ? $1 : htmllink($page, $destpage, linkpage($1))
	}eg;

	return $params{content};
}

sub scan (@) {
        my %params=@_;
        my $page=$params{page};
        my $content=$params{content};

	while ($content =~ /$link_regexp/g) {
		add_link($page, linkpage($1)) unless ignored($1)
	}
}

sub ignored ($) {
	my $word=lc shift;
	grep { $word eq lc $_ } @{$config{'camelcase_ignore'}}
}

1
</pre></body></html>