<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::editpage;

use warnings;
use strict;
use IkiWiki;
use open qw{:utf8 :std};

sub import {
	hook(type =&gt; "getsetup", id =&gt; "editpage", call =&gt; \&amp;getsetup);
	hook(type =&gt; "refresh", id =&gt; "editpage", call =&gt; \&amp;refresh);
        hook(type =&gt; "sessioncgi", id =&gt; "editpage", call =&gt; \&amp;IkiWiki::cgi_editpage);
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; 1,
			section =&gt; "core",
		},
}

sub refresh () {
	if (exists $wikistate{editpage} &amp;&amp; exists $wikistate{editpage}{previews}) {
		# Expire old preview files after one hour.
		my $expire=time - (60 * 60);

		my @previews;
		foreach my $file (@{$wikistate{editpage}{previews}}) {
			my $mtime=(stat("$config{destdir}/$file"))[9];
			if (defined $mtime &amp;&amp; $mtime &lt;= $expire) {
				# Avoid deleting a preview that was later saved.
				my $delete=1;
				foreach my $page (keys %renderedfiles) {
					if (grep { $_ eq $file } @{$renderedfiles{$page}}) {
						$delete=0;
					}
				}
				if ($delete) {
					debug(sprintf(gettext("removing old preview %s"), $file));
					IkiWiki::prune("$config{destdir}/$file", $config{destdir});
				}
			}
			elsif (defined $mtime) {
				push @previews, $file;
			}
		}
		$wikistate{editpage}{previews}=\@previews;
	}
}

# Back to ikiwiki namespace for the rest, this code is very much
# internal to ikiwiki even though it's separated into a plugin,
# and other plugins use the function below.
package IkiWiki;

sub cgi_editpage ($$) {
	my $q=shift;
	my $session=shift;
	
        my $do=$q-&gt;param('do');
	return unless $do eq 'create' || $do eq 'edit';

	decode_cgi_utf8($q);

	my @fields=qw(do rcsinfo subpage from page type editcontent
		editmessage subscribe);
	my @buttons=("Save Page", "Preview", "Cancel");
	eval q{use CGI::FormBuilder};
	error($@) if $@;
	my $form = CGI::FormBuilder-&gt;new(
		fields =&gt; \@fields,
		charset =&gt; "utf-8",
		method =&gt; 'POST',
		required =&gt; [qw{editcontent}],
		javascript =&gt; 0,
		params =&gt; $q,
		action =&gt; IkiWiki::cgiurl(),
		header =&gt; 0,
		table =&gt; 0,
		template =&gt; { template("editpage.tmpl") },
	);
	
	decode_form_utf8($form);
	run_hooks(formbuilder_setup =&gt; sub {
		shift-&gt;(form =&gt; $form, cgi =&gt; $q, session =&gt; $session,
			buttons =&gt; \@buttons);
	});
	decode_form_utf8($form);
	
	# This untaint is safe because we check file_pruned and
	# wiki_file_regexp.
	my ($page)=$form-&gt;field('page')=~/$config{wiki_file_regexp}/;
	if (! defined $page) {
		error(gettext("bad page name"));
	}
	$page=possibly_foolish_untaint($page);
	my $absolute=($page =~ s#^/+##); # absolute name used to force location
	if (! defined $page || ! length $page ||
	    file_pruned($page)) {
		error(gettext("bad page name"));
	}

	my $baseurl = urlto($page);

	my $from;
	if (defined $form-&gt;field('from')) {
		($from)=$form-&gt;field('from')=~/$config{wiki_file_regexp}/;
	}
	
	my $file;
	my $type;
	if (exists $pagesources{$page} &amp;&amp; $form-&gt;field("do") ne "create") {
		$file=$pagesources{$page};
		$type=pagetype($file);
		if (! defined $type || $type=~/^_/) {
			error(sprintf(gettext("%s is not an editable page"), $page));
		}
		if (! $form-&gt;submitted) {
			$form-&gt;field(name =&gt; "rcsinfo",
				value =&gt; rcs_prepedit($file), force =&gt; 1);
		}
		$form-&gt;field(name =&gt; "editcontent", validate =&gt; '/.*/');
	}
	else {
		$type=$form-&gt;param('type');
		if (defined $type &amp;&amp; length $type &amp;&amp; $hooks{htmlize}{$type}) {
			$type=possibly_foolish_untaint($type);
		}
		elsif (defined $from &amp;&amp; exists $pagesources{$from}) {
			# favor the type of linking page
			$type=pagetype($pagesources{$from});
		}
		$type=$config{default_pageext}
			if ! defined $type || $type=~/^_/; # not internal type
		$file=newpagefile($page, $type);
		if (! $form-&gt;submitted) {
			$form-&gt;field(name =&gt; "rcsinfo", value =&gt; "", force =&gt; 1);
		}
		$form-&gt;field(name =&gt; "editcontent", validate =&gt; '/.+/');
	}

	$form-&gt;field(name =&gt; "do", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "sid", type =&gt; "hidden", value =&gt; $session-&gt;id,
		force =&gt; 1);
	$form-&gt;field(name =&gt; "from", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "rcsinfo", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "subpage", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "page", value =&gt; $page, force =&gt; 1);
	$form-&gt;field(name =&gt; "type", value =&gt; $type, force =&gt; 1);
	$form-&gt;field(name =&gt; "editmessage", type =&gt; "text", size =&gt; 80);
	$form-&gt;field(name =&gt; "editcontent", type =&gt; "textarea", rows =&gt; 20,
		cols =&gt; 80);
	$form-&gt;tmpl_param("can_commit", $config{rcs});
	$form-&gt;tmpl_param("helponformattinglink",
		htmllink($page, $page, "ikiwiki/formatting",
			noimageinline =&gt; 1,
			linktext =&gt; "FormattingHelp"));
	
	my $cansubscribe=IkiWiki::Plugin::notifyemail-&gt;can("subscribe")
		&amp;&amp; IkiWiki::Plugin::comments-&gt;can("import")
		&amp;&amp; defined $session-&gt;param('name');
	if ($cansubscribe) {
		$form-&gt;field(name =&gt; "subscribe", type =&gt; "checkbox",
			options =&gt; [gettext("email comments to me")]);
	}
	else {
		$form-&gt;field(name =&gt; "subscribe", type =&gt; 'hidden');
	}
	
	my $previewing=0;
	if ($form-&gt;submitted eq "Cancel") {
		if ($form-&gt;field("do") eq "create" &amp;&amp; defined $from) {
			redirect($q, urlto($from));
		}
		elsif ($form-&gt;field("do") eq "create") {
			redirect($q, baseurl(undef));
		}
		else {
			redirect($q, $baseurl);
		}
		exit;
	}
	elsif ($form-&gt;submitted eq "Preview") {
		$previewing=1;

		my $new=not exists $pagesources{$page};
		# temporarily record its type
		$pagesources{$page}=$page.".".$type if $new;
		my %wasrendered=map { $_ =&gt; 1 } @{$renderedfiles{$page}};

		my $content=$form-&gt;field('editcontent');

		run_hooks(editcontent =&gt; sub {
			$content=shift-&gt;(
				content =&gt; $content,
				page =&gt; $page,
				cgi =&gt; $q,
				session =&gt; $session,
			);
		});
		my $preview=htmlize($page, $page, $type,
			linkify($page, $page,
			preprocess($page, $page,
			filter($page, $page, $content), 0, 1)));
		run_hooks(format =&gt; sub {
			$preview=shift-&gt;(
				page =&gt; $page,
				content =&gt; $preview,
			);
		});
		$form-&gt;tmpl_param("page_preview", $preview);
		
		# Previewing may have created files on disk.
		# Keep a list of these to be deleted later.
		my %previews = map { $_ =&gt; 1 } @{$wikistate{editpage}{previews}};
		foreach my $f (@{$renderedfiles{$page}}) {
			$previews{$f}=1 unless $wasrendered{$f};
		}

		# Throw out any other state changes made during previewing,
		# and save the previews list.
		loadindex();
		@{$wikistate{editpage}{previews}} = keys %previews;
		saveindex();
	}
	elsif ($form-&gt;submitted eq "Save Page") {
		$form-&gt;tmpl_param("page_preview", "");
	}
	
	if ($form-&gt;submitted ne "Save Page" || ! $form-&gt;validate) {
		if ($form-&gt;field("do") eq "create") {
			my @page_locs;
			my $best_loc;
			if (! defined $from || ! length $from ||
			    $from ne $form-&gt;field('from') ||
			    file_pruned($from) ||
			    $absolute ||
			    $form-&gt;submitted) {
				@page_locs=$best_loc=$page;
				unshift @page_locs, lc($page)
					if ! $form-&gt;submitted &amp;&amp; lc($page) ne $page;
			}
			elsif (lc $page eq lc $config{discussionpage}) {
				@page_locs=$best_loc="$from/".lc($page);
			}
			else {
				my $dir=$from."/";
				$dir=~s![^/]+/+$!!;
				
				if ((defined $form-&gt;field('subpage') &amp;&amp;
				     length $form-&gt;field('subpage'))) {
					$best_loc="$from/$page";
				}
				else {
					$best_loc=$dir.$page;
				}
				
				my $mixedcase=lc($page) ne $page;

				push @page_locs, $dir.lc($page) if $mixedcase;
				push @page_locs, $dir.$page;
				push @page_locs, $from."/".lc($page) if $mixedcase;
				push @page_locs, $from."/".$page;
				while (length $dir) {
					$dir=~s![^/]+/+$!!;
					push @page_locs, $dir.lc($page) if $mixedcase;
					push @page_locs, $dir.$page;
				}

				my $userpage=IkiWiki::userpage($page);
				push @page_locs, $userpage
					if ! grep { $_ eq $userpage } @page_locs;
			}

			@page_locs = grep {
				! exists $pagecase{lc $_}
			} @page_locs;
			if (! @page_locs) {
				# hmm, someone else made the page in the
				# meantime?
				if ($previewing) {
					# let them go ahead with the edit
					# and resolve the conflict at save
					# time
					@page_locs=$page;
				}
				else {
					redirect($q, $baseurl);
					exit;
				}
			}

			my @editable_locs = grep {
				check_canedit($_, $q, $session, 1)
			} @page_locs;
			if (! @editable_locs) {
				# now let it throw an error, or prompt for
				# login
				map { check_canedit($_, $q, $session) }
					($best_loc, @page_locs);
			}
			
			my @page_types;
			if (exists $hooks{htmlize}) {
				foreach my $key (grep { !/^_/ } keys %{$hooks{htmlize}}) {
					push @page_types, [$key, $hooks{htmlize}{$key}{longname} || $key];
				}
			}
			@page_types=sort @page_types;
			
			$form-&gt;tmpl_param("page_select", 1);
			$form-&gt;field(name =&gt; "page", type =&gt; 'select',
				options =&gt; [ map { [ $_, pagetitle($_, 1) ] } @editable_locs ],
				value =&gt; $best_loc);
			$form-&gt;field(name =&gt; "type", type =&gt; 'select',
				options =&gt; \@page_types);
			$form-&gt;title(sprintf(gettext("creating %s"), pagetitle(basename($page))));
			
		}
		elsif ($form-&gt;field("do") eq "edit") {
			check_canedit($page, $q, $session);
			if (! defined $form-&gt;field('editcontent') || 
			    ! length $form-&gt;field('editcontent')) {
				my $content="";
				if (exists $pagesources{$page}) {
					$content=readfile(srcfile($pagesources{$page}));
					$content=~s/\n/\r\n/g;
				}
				$form-&gt;field(name =&gt; "editcontent", value =&gt; $content,
					force =&gt; 1);
			}
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), pagetitle(basename($page))));
		}
		
		showform($form, \@buttons, $session, $q, page =&gt; $page);
	}
	else {
		# save page
		check_canedit($page, $q, $session);
		checksessionexpiry($q, $session, $q-&gt;param('sid'));

		my $exists=-e "$config{srcdir}/$file";

		if ($form-&gt;field("do") ne "create" &amp;&amp; ! $exists &amp;&amp;
		    ! defined srcfile($file, 1)) {
			$form-&gt;tmpl_param("message", template("editpagegone.tmpl")-&gt;output);
			$form-&gt;field(name =&gt; "do", value =&gt; "create", force =&gt; 1);
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), $page));
			showform($form, \@buttons, $session, $q,
				page =&gt; $page);
			exit;
		}
		elsif ($form-&gt;field("do") eq "create" &amp;&amp; $exists) {
			$form-&gt;tmpl_param("message", template("editcreationconflict.tmpl")-&gt;output);
			$form-&gt;field(name =&gt; "do", value =&gt; "edit", force =&gt; 1);
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), $page));
			$form-&gt;field("editcontent", 
				value =&gt; readfile("$config{srcdir}/$file").
				         "\n\n\n".$form-&gt;field("editcontent"),
				force =&gt; 1);
			showform($form, \@buttons, $session, $q,
				page =&gt; $page);
			exit;
		}
			
		my $message="";
		if (defined $form-&gt;field('editmessage') &amp;&amp;
		    length $form-&gt;field('editmessage')) {
			$message=$form-&gt;field('editmessage');
		}
		
		my $content=$form-&gt;field('editcontent');
		check_content(content =&gt; $content, page =&gt; $page,
			cgi =&gt; $q, session =&gt; $session,
			subject =&gt; $message);
		run_hooks(editcontent =&gt; sub {
			$content=shift-&gt;(
				content =&gt; $content,
				page =&gt; $page,
				cgi =&gt; $q,
				session =&gt; $session,
			);
		});
		$content=~s/\r\n/\n/g;
		$content=~s/\r/\n/g;
		$content.="\n" if $content !~ /\n$/;

		$config{cgi}=0; # avoid cgi error message
		eval { writefile($file, $config{srcdir}, $content) };
		$config{cgi}=1;
		if ($@) {
			# save $@ in case a called function clobbers it
			my $error = $@;
			$form-&gt;field(name =&gt; "rcsinfo", value =&gt; rcs_prepedit($file),
				force =&gt; 1);
			my $mtemplate=template("editfailedsave.tmpl");
			$mtemplate-&gt;param(error_message =&gt; $error);
			$form-&gt;tmpl_param("message", $mtemplate-&gt;output);
			$form-&gt;field("editcontent", value =&gt; $content, force =&gt; 1);
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), $page));
			showform($form, \@buttons, $session, $q,
				page =&gt; $page);
			exit;
		}
		
		my $conflict;
		if ($config{rcs}) {
			if (! $exists) {
				rcs_add($file);
			}

			# Prevent deadlock with post-commit hook by
			# signaling to it that it should not try to
			# do anything.
			disable_commit_hook();
			$conflict=rcs_commit(
				file =&gt; $file,
				message =&gt; $message,
				token =&gt; $form-&gt;field("rcsinfo"),
				session =&gt; $session,
			);
			enable_commit_hook();
			rcs_update();
		}
		
		# Refresh even if there was a conflict, since other changes
		# may have been committed while the post-commit hook was
		# disabled.
		require IkiWiki::Render;
		refresh();
		saveindex();

		if (defined $conflict) {
			$form-&gt;field(name =&gt; "rcsinfo", value =&gt; rcs_prepedit($file),
				force =&gt; 1);
			$form-&gt;tmpl_param("message", template("editconflict.tmpl")-&gt;output);
			$form-&gt;field("editcontent", value =&gt; $conflict, force =&gt; 1);
			$form-&gt;field("do", "edit", force =&gt; 1);
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), $page));
			showform($form, \@buttons, $session, $q,
				page =&gt; $page);
		}
		else {
			# The trailing question mark tries to avoid broken
			# caches and get the most recent version of the page.
			redirect($q, $baseurl."?updated");
		}

		if ($cansubscribe &amp;&amp; length $form-&gt;field("subscribe")) {
			my $subspec="comment($page)";
			IkiWiki::Plugin::notifyemail::subscribe(
				$session-&gt;param('name'), $subspec);
		}
	}

	exit;
}

1
</pre></body></html>