<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Page inlining and blogging.
package IkiWiki::Plugin::inline;

use warnings;
use strict;
use IkiWiki;

sub import { #{{{
	IkiWiki::hook(type =&gt; "preprocess", id =&gt; "inline", 
		call =&gt; \&amp;IkiWiki::preprocess_inline);
} # }}}

# Back to ikiwiki namespace for the rest, this code is very much
# internal to ikiwiki even though it's separated into a plugin.
package IkiWiki;
	
sub preprocess_inline (@) { #{{{
	my %params=@_;

	if (! exists $params{pages}) {
		return "";
	}
	if (! exists $params{archive}) {
		$params{archive}="no";
	}
	if (! exists $params{show} &amp;&amp; $params{archive} eq "no") {
		$params{show}=10;
	}
	add_depends($params{page}, $params{pages});

	my $ret="";
	
	if (exists $params{rootpage}) {
		# Add a blog post form, with a rss link button.
		my $formtemplate=HTML::Template-&gt;new(blind_cache =&gt; 1,
			filename =&gt; "$config{templatedir}/blogpost.tmpl");
		$formtemplate-&gt;param(cgiurl =&gt; $config{cgiurl});
		$formtemplate-&gt;param(rootpage =&gt; $params{rootpage});
		if ($config{rss}) {
			$formtemplate-&gt;param(rssurl =&gt; rsspage(basename($params{page})));
		}
		$ret.=$formtemplate-&gt;output;
	}
	elsif ($config{rss}) {
		# Add a rss link button.
		my $linktemplate=HTML::Template-&gt;new(blind_cache =&gt; 1,
			filename =&gt; "$config{templatedir}/rsslink.tmpl");
		$linktemplate-&gt;param(rssurl =&gt; rsspage(basename($params{page})));
		$ret.=$linktemplate-&gt;output;
	}
	
	my $template=HTML::Template-&gt;new(blind_cache =&gt; 1,
		filename =&gt; (($params{archive} eq "no") 
				? "$config{templatedir}/inlinepage.tmpl"
				: "$config{templatedir}/inlinepagetitle.tmpl"));
	
	my @pages;
	foreach my $page (blog_list($params{pages}, $params{show})) {
		next if $page eq $params{page};
		push @pages, $page;
		$template-&gt;param(pagelink =&gt; htmllink($params{page}, $params{page}, $page));
		$template-&gt;param(content =&gt; get_inline_content($params{page}, $page))
			if $params{archive} eq "no";
		$template-&gt;param(ctime =&gt; displaytime($pagectime{$page}));
		$ret.=$template-&gt;output;
	}
	
	# TODO: should really add this to renderedfiles and call
	# check_overwrite, but currently renderedfiles
	# only supports listing one file per page.
	if ($config{rss}) {
		writefile(rsspage($params{page}), $config{destdir},
			genrss($params{page}, @pages));
	}
	
	return $ret;
} #}}}

sub blog_list ($$) { #{{{
	my $globlist=shift;
	my $maxitems=shift;

	my @list;
	foreach my $page (keys %pagesources) {
		if (globlist_match($page, $globlist)) {
			push @list, $page;
		}
	}

	@list=sort { $pagectime{$b} &lt;=&gt; $pagectime{$a} } @list;
	return @list if ! $maxitems || @list &lt;= $maxitems;
	return @list[0..$maxitems - 1];
} #}}}

sub get_inline_content ($$) { #{{{
	my $parentpage=shift;
	my $page=shift;
	
	my $file=$pagesources{$page};
	my $type=pagetype($file);
	if ($type ne 'unknown') {
		return htmlize($type, preprocess($page, linkify($page, $parentpage, readfile(srcfile($file))), 1));
	}
	else {
		return "";
	}
} #}}}

sub date_822 ($) { #{{{
	my $time=shift;

	eval q{use POSIX};
	return POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
} #}}}

sub absolute_urls ($$) { #{{{
	# sucky sub because rss sucks
	my $content=shift;
	my $url=shift;

	$url=~s/[^\/]+$//;
	
	$content=~s/&lt;a\s+href="(?!http:\/\/)([^"]+)"/&lt;a href="$url$1"/ig;
	$content=~s/&lt;img\s+src="(?!http:\/\/)([^"]+)"/&lt;img src="$url$1"/ig;
	return $content;
} #}}}

sub rsspage ($) { #{{{
	my $page=shift;

	return $page.".rss";
} #}}}

sub genrss ($@) { #{{{
	my $page=shift;
	my @pages=@_;
	
	my $url="$config{url}/".htmlpage($page);
	
	my $template=HTML::Template-&gt;new(blind_cache =&gt; 1,
		filename =&gt; "$config{templatedir}/rsspage.tmpl");
	
	my @items;
	foreach my $p (@pages) {
		push @items, {
			itemtitle =&gt; pagetitle(basename($p)),
			itemurl =&gt; "$config{url}/$renderedfiles{$p}",
			itempubdate =&gt; date_822($pagectime{$p}),
			itemcontent =&gt; absolute_urls(get_inline_content($page, $p), $url),
		} if exists $renderedfiles{$p};
	}

	$template-&gt;param(
		title =&gt; $config{wikiname},
		pageurl =&gt; $url,
		items =&gt; \@items,
	);
	
	return $template-&gt;output;
} #}}}

1
</pre></body></html>