<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl

use warnings;
use strict;
use IkiWiki;
use IkiWiki::UserInfo;
use open qw{:utf8 :std};
use Encode;

package IkiWiki;

sub printheader ($) { #{{{
	my $session=shift;
	
	if ($config{sslcookie}) {
		print $session-&gt;header(-charset =&gt; 'utf-8',
			-cookie =&gt; $session-&gt;cookie(-secure =&gt; 1));
	} else {
		print $session-&gt;header(-charset =&gt; 'utf-8');
	}

} #}}}

sub showform ($$$$) { #{{{
	my $form=shift;
	my $buttons=shift;
	my $session=shift;
	my $cgi=shift;

	if (exists $hooks{formbuilder}) {
		run_hooks(formbuilder =&gt; sub {
			shift-&gt;(form =&gt; $form, cgi =&gt; $cgi, session =&gt; $session,
				buttons =&gt; $buttons);
		});
	}

	printheader($session);
	print misctemplate($form-&gt;title, $form-&gt;render(submit =&gt; $buttons));
}

sub redirect ($$) { #{{{
	my $q=shift;
	my $url=shift;
	if (! $config{w3mmode}) {
		print $q-&gt;redirect($url);
	}
	else {
		print "Content-type: text/plain\n";
		print "W3m-control: GOTO $url\n\n";
	}
} #}}}

sub check_canedit ($$$;$) { #{{{
	my $page=shift;
	my $q=shift;
	my $session=shift;
	my $nonfatal=shift;
	
	my $canedit;
	run_hooks(canedit =&gt; sub {
		return if defined $canedit;
		my $ret=shift-&gt;($page, $q, $session);
		if (defined $ret) {
			if ($ret eq "") {
				$canedit=1;
			}
			elsif (ref $ret eq 'CODE') {
				$ret-&gt;() unless $nonfatal;
				$canedit=0;
			}
			elsif (defined $ret) {
				error($ret) unless $nonfatal;
				$canedit=0;
			}
		}
	});
	return $canedit;
} #}}}

sub decode_cgi_utf8 ($) { #{{{
	my $cgi = shift;
	foreach my $f ($cgi-&gt;param) {
		$cgi-&gt;param($f, map { decode_utf8 $_ } $cgi-&gt;param($f));
	}
} #}}}

# Check if the user is signed in. If not, redirect to the signin form and
# save their place to return to later.
sub needsignin ($$) { #{{{
	my $q=shift;
	my $session=shift;

	if (! defined $session-&gt;param("name") ||
	    ! userinfo_get($session-&gt;param("name"), "regdate")) {
		$session-&gt;param(postsignin =&gt; $ENV{QUERY_STRING});
		cgi_signin($q, $session);
		cgi_savesession($session);
		exit;
	}
} #}}}	

sub cgi_signin ($$) { #{{{
	my $q=shift;
	my $session=shift;

	decode_cgi_utf8($q);
	eval q{use CGI::FormBuilder};
	error($@) if $@;
	my $form = CGI::FormBuilder-&gt;new(
		title =&gt; "signin",
		name =&gt; "signin",
		charset =&gt; "utf-8",
		method =&gt; 'POST',
		required =&gt; 'NONE',
		javascript =&gt; 0,
		params =&gt; $q,
		action =&gt; $config{cgiurl},
		header =&gt; 0,
		template =&gt; {type =&gt; 'div'},
		stylesheet =&gt; baseurl()."style.css",
	);
	my $buttons=["Login"];
	
	if ($q-&gt;param("do") ne "signin" &amp;&amp; !$form-&gt;submitted) {
		$form-&gt;text(gettext("You need to log in first."));
	}
	$form-&gt;field(name =&gt; "do", type =&gt; "hidden", value =&gt; "signin",
		force =&gt; 1);
	
	run_hooks(formbuilder_setup =&gt; sub {
		shift-&gt;(form =&gt; $form, cgi =&gt; $q, session =&gt; $session,
		        buttons =&gt; $buttons);
	});

	if ($form-&gt;submitted) {
		$form-&gt;validate;
	}

	showform($form, $buttons, $session, $q);
} #}}}

sub cgi_postsignin ($$) { #{{{
	my $q=shift;
	my $session=shift;
	
	# Continue with whatever was being done before the signin process.
	if (defined $session-&gt;param("postsignin")) {
		my $postsignin=CGI-&gt;new($session-&gt;param("postsignin"));
		$session-&gt;clear("postsignin");
		cgi($postsignin, $session);
		cgi_savesession($session);
		exit;
	}
	else {
		error(gettext("login failed, perhaps you need to turn on cookies?"));
	}
} #}}}

sub cgi_prefs ($$) { #{{{
	my $q=shift;
	my $session=shift;

	needsignin($q, $session);

	decode_cgi_utf8($q);
	eval q{use CGI::FormBuilder};
	error($@) if $@;
	my $form = CGI::FormBuilder-&gt;new(
		title =&gt; "preferences",
		name =&gt; "preferences",
		header =&gt; 0,
		charset =&gt; "utf-8",
		method =&gt; 'POST',
		validate =&gt; {
			email =&gt; 'EMAIL',
		},
		required =&gt; 'NONE',
		javascript =&gt; 0,
		params =&gt; $q,
		action =&gt; $config{cgiurl},
		template =&gt; {type =&gt; 'div'},
		stylesheet =&gt; baseurl()."style.css",
		fieldsets =&gt; [
			[login =&gt; gettext("Login")],
			[preferences =&gt; gettext("Preferences")],
			[admin =&gt; gettext("Admin")]
		],
	);
	my $buttons=["Save Preferences", "Logout", "Cancel"];

	run_hooks(formbuilder_setup =&gt; sub {
		shift-&gt;(form =&gt; $form, cgi =&gt; $q, session =&gt; $session,
		        buttons =&gt; $buttons);
	});
	
	$form-&gt;field(name =&gt; "do", type =&gt; "hidden");
	$form-&gt;field(name =&gt; "email", size =&gt; 50, fieldset =&gt; "preferences");
	$form-&gt;field(name =&gt; "banned_users", size =&gt; 50,
		fieldset =&gt; "admin");
	
	my $user_name=$session-&gt;param("name");
	if (! is_admin($user_name)) {
		$form-&gt;field(name =&gt; "banned_users", type =&gt; "hidden");
	}

	if (! $form-&gt;submitted) {
		$form-&gt;field(name =&gt; "email", force =&gt; 1,
			value =&gt; userinfo_get($user_name, "email"));
		if (is_admin($user_name)) {
			$form-&gt;field(name =&gt; "banned_users", force =&gt; 1,
				value =&gt; join(" ", get_banned_users()));
		}
	}
	
	if ($form-&gt;submitted eq 'Logout') {
		$session-&gt;delete();
		redirect($q, $config{url});
		return;
	}
	elsif ($form-&gt;submitted eq 'Cancel') {
		redirect($q, $config{url});
		return;
	}
	elsif ($form-&gt;submitted eq 'Save Preferences' &amp;&amp; $form-&gt;validate) {
		if (defined $form-&gt;field('email')) {
			userinfo_set($user_name, 'email', $form-&gt;field('email')) ||
				error("failed to set email");
		}
		if (is_admin($user_name)) {
			set_banned_users(grep { ! is_admin($_) }
					split(' ',
						$form-&gt;field("banned_users"))) ||
				error("failed saving changes");
		}
		$form-&gt;text(gettext("Preferences saved."));
	}
	
	showform($form, $buttons, $session, $q);
} #}}}

sub cgi_editpage ($$) { #{{{
	my $q=shift;
	my $session=shift;

	my @fields=qw(do rcsinfo subpage from page type editcontent comments);
	my @buttons=("Save Page", "Preview", "Cancel");
	
	decode_cgi_utf8($q);
	eval q{use CGI::FormBuilder};
	error($@) if $@;
	my $form = CGI::FormBuilder-&gt;new(
		title =&gt; "editpage",
		fields =&gt; \@fields,
		charset =&gt; "utf-8",
		method =&gt; 'POST',
		required =&gt; [qw{editcontent}],
		javascript =&gt; 0,
		params =&gt; $q,
		action =&gt; $config{cgiurl},
		header =&gt; 0,
		table =&gt; 0,
		template =&gt; scalar template_params("editpage.tmpl"),
		wikiname =&gt; $config{wikiname},
	);
	
	run_hooks(formbuilder_setup =&gt; sub {
		shift-&gt;(form =&gt; $form, cgi =&gt; $q, session =&gt; $session,
			buttons =&gt; \@buttons);
	});
	
	# This untaint is safe because titlepage removes any problematic
	# characters.
	my ($page)=$form-&gt;field('page');
	$page=titlepage(possibly_foolish_untaint($page));
	if (! defined $page || ! length $page ||
	    file_pruned($page, $config{srcdir}) || $page=~/^\//) {
		error("bad page name");
	}
	
	my $from;
	if (defined $form-&gt;field('from')) {
		($from)=$form-&gt;field('from')=~/$config{wiki_file_regexp}/;
	}
	
	my $file;
	my $type;
	if (exists $pagesources{$page} &amp;&amp; $form-&gt;field("do") ne "create") {
		$file=$pagesources{$page};
		$type=pagetype($file);
		if (! defined $type || $type=~/^_/) {
			error(sprintf(gettext("%s is not an editable page"), $page));
		}
		if (! $form-&gt;submitted) {
			$form-&gt;field(name =&gt; "rcsinfo",
				value =&gt; rcs_prepedit($file), force =&gt; 1);
		}
		$form-&gt;field(name =&gt; "editcontent", validate =&gt; '/.*/');
	}
	else {
		$type=$form-&gt;param('type');
		if (defined $type &amp;&amp; length $type &amp;&amp; $hooks{htmlize}{$type}) {
			$type=possibly_foolish_untaint($type);
		}
		elsif (defined $from &amp;&amp; exists $pagesources{$from}) {
			# favor the type of linking page
			$type=pagetype($pagesources{$from});
		}
		$type=$config{default_pageext} unless defined $type;
		$file=$page.".".$type;
		if (! $form-&gt;submitted) {
			$form-&gt;field(name =&gt; "rcsinfo", value =&gt; "", force =&gt; 1);
		}
		$form-&gt;field(name =&gt; "editcontent", validate =&gt; '/.+/');
	}

	$form-&gt;field(name =&gt; "do", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "from", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "rcsinfo", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "subpage", type =&gt; 'hidden');
	$form-&gt;field(name =&gt; "page", value =&gt; pagetitle($page, 1), force =&gt; 1);
	$form-&gt;field(name =&gt; "type", value =&gt; $type, force =&gt; 1);
	$form-&gt;field(name =&gt; "comments", type =&gt; "text", size =&gt; 80);
	$form-&gt;field(name =&gt; "editcontent", type =&gt; "textarea", rows =&gt; 20,
		cols =&gt; 80);
	$form-&gt;tmpl_param("can_commit", $config{rcs});
	$form-&gt;tmpl_param("indexlink", indexlink());
	$form-&gt;tmpl_param("helponformattinglink",
		htmllink("", "", "ikiwiki/formatting",
			noimageinline =&gt; 1,
			linktext =&gt; "FormattingHelp"));
	$form-&gt;tmpl_param("baseurl", baseurl());
	
	if ($form-&gt;submitted eq "Cancel") {
		if ($form-&gt;field("do") eq "create" &amp;&amp; defined $from) {
			redirect($q, "$config{url}/".htmlpage($from));
		}
		elsif ($form-&gt;field("do") eq "create") {
			redirect($q, $config{url});
		}
		else {
			redirect($q, "$config{url}/".htmlpage($page));
		}
		return;
	}
	elsif ($form-&gt;submitted eq "Preview") {
		my $content=$form-&gt;field('editcontent');
		run_hooks(editcontent =&gt; sub {
			$content=shift-&gt;(
				content =&gt; $content,
				page =&gt; $page,
				cgi =&gt; $q,
				session =&gt; $session,
			);
		});
		$form-&gt;tmpl_param("page_preview",
			htmlize($page, $type,
			linkify($page, "/",
			preprocess($page, "/",
			filter($page, "/", $content), 0, 1))));
		# previewing may have created files on disk
		saveindex();
	}
	elsif ($form-&gt;submitted eq "Save Page") {
		$form-&gt;tmpl_param("page_preview", "");
	}
	$form-&gt;tmpl_param("page_conflict", "");
	
	if ($form-&gt;submitted ne "Save Page" || ! $form-&gt;validate) {
		if ($form-&gt;field("do") eq "create") {
			my @page_locs;
			my $best_loc;
			if (! defined $from || ! length $from ||
			    $from ne $form-&gt;field('from') ||
			    file_pruned($from, $config{srcdir}) ||
			    $from=~/^\// ||
			    $form-&gt;submitted eq "Preview") {
				@page_locs=$best_loc=$page;
			}
			else {
				my $dir=$from."/";
				$dir=~s![^/]+/+$!!;
				
				if ((defined $form-&gt;field('subpage') &amp;&amp; length $form-&gt;field('subpage')) ||
				    $page eq gettext('discussion')) {
					$best_loc="$from/$page";
				}
				else {
					$best_loc=$dir.$page;
				}
				
				push @page_locs, $dir.$page;
				push @page_locs, "$from/$page";
				while (length $dir) {
					$dir=~s![^/]+/+$!!;
					push @page_locs, $dir.$page;
				}
			
				push @page_locs, "$config{userdir}/$page"
					if length $config{userdir};
			}

			@page_locs = grep {
				! exists $pagecase{lc $_}
			} @page_locs;
			if (! @page_locs) {
				# hmm, someone else made the page in the
				# meantime?
				if ($form-&gt;submitted eq "Preview") {
					# let them go ahead with the edit
					# and resolve the conflict at save
					# time
					@page_locs=$page;
				}
				else {
					redirect($q, "$config{url}/".htmlpage($page));
					return;
				}
			}

			my @editable_locs = grep {
				check_canedit($_, $q, $session, 1)
			} @page_locs;
			if (! @editable_locs) {
				# let it throw an error this time
				map { check_canedit($_, $q, $session) } @page_locs;
			}
			
			my @page_types;
			if (exists $hooks{htmlize}) {
				@page_types=grep { !/^_/ }
					keys %{$hooks{htmlize}};
			}
			
			$form-&gt;tmpl_param("page_select", 1);
			$form-&gt;field(name =&gt; "page", type =&gt; 'select',
				options =&gt; [ map { pagetitle($_, 1) } @editable_locs ],
				value =&gt; pagetitle($best_loc, 1));
			$form-&gt;field(name =&gt; "type", type =&gt; 'select',
				options =&gt; \@page_types);
			$form-&gt;title(sprintf(gettext("creating %s"), pagetitle($page)));
			
		}
		elsif ($form-&gt;field("do") eq "edit") {
			check_canedit($page, $q, $session);
			if (! defined $form-&gt;field('editcontent') || 
			    ! length $form-&gt;field('editcontent')) {
				my $content="";
				if (exists $pagesources{$page}) {
					$content=readfile(srcfile($pagesources{$page}));
					$content=~s/\n/\r\n/g;
				}
				$form-&gt;field(name =&gt; "editcontent", value =&gt; $content,
					force =&gt; 1);
			}
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), pagetitle($page)));
		}
		
		showform($form, \@buttons, $session, $q);
	}
	else {
		# save page
		check_canedit($page, $q, $session);

		my $exists=-e "$config{srcdir}/$file";

		if ($form-&gt;field("do") ne "create" &amp;&amp; ! $exists &amp;&amp;
		    ! eval { srcfile($file) }) {
			$form-&gt;tmpl_param("page_gone", 1);
			$form-&gt;field(name =&gt; "do", value =&gt; "create", force =&gt; 1);
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), $page));
			showform($form, \@buttons, $session, $q);
			return;
		}
		elsif ($form-&gt;field("do") eq "create" &amp;&amp; $exists) {
			$form-&gt;tmpl_param("creation_conflict", 1);
			$form-&gt;field(name =&gt; "do", value =&gt; "edit", force =&gt; 1);
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), $page));
			$form-&gt;field("editcontent", 
				value =&gt; readfile("$config{srcdir}/$file").
				         "\n\n\n".$form-&gt;field("editcontent"),
				force =&gt; 1);
			showform($form, \@buttons, $session, $q);
			return;
		}
		
		my $content=$form-&gt;field('editcontent');
		run_hooks(editcontent =&gt; sub {
			$content=shift-&gt;(
				content =&gt; $content,
				page =&gt; $page,
				cgi =&gt; $q,
				session =&gt; $session,
			);
		});
		$content=~s/\r\n/\n/g;
		$content=~s/\r/\n/g;
		$content.="\n" if $content !~ /\n$/;

		$config{cgi}=0; # avoid cgi error message
		eval { writefile($file, $config{srcdir}, $content) };
		$config{cgi}=1;
		if ($@) {
			$form-&gt;field(name =&gt; "rcsinfo", value =&gt; rcs_prepedit($file),
				force =&gt; 1);
			$form-&gt;tmpl_param("failed_save", 1);
			$form-&gt;tmpl_param("error_message", $@);
			$form-&gt;field("editcontent", value =&gt; $content, force =&gt; 1);
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), $page));
			showform($form, \@buttons, $session, $q);
			return;
		}
		
		my $conflict;
		if ($config{rcs}) {
			my $message="";
			if (defined $form-&gt;field('comments') &amp;&amp;
			    length $form-&gt;field('comments')) {
				$message=$form-&gt;field('comments');
			}
			
			if (! $exists) {
				rcs_add($file);
			}

			# Prevent deadlock with post-commit hook by
			# signaling to it that it should not try to
			# do anything.
			disable_commit_hook();
			$conflict=rcs_commit($file, $message,
				$form-&gt;field("rcsinfo"),
				$session-&gt;param("name"), $ENV{REMOTE_ADDR});
			enable_commit_hook();
			rcs_update();
		}
		
		# Refresh even if there was a conflict, since other changes
		# may have been committed while the post-commit hook was
		# disabled.
		require IkiWiki::Render;
		refresh();
		saveindex();

		if (defined $conflict) {
			$form-&gt;field(name =&gt; "rcsinfo", value =&gt; rcs_prepedit($file),
				force =&gt; 1);
			$form-&gt;tmpl_param("page_conflict", 1);
			$form-&gt;field("editcontent", value =&gt; $conflict, force =&gt; 1);
			$form-&gt;field("do", "edit", force =&gt; 1);
			$form-&gt;tmpl_param("page_select", 0);
			$form-&gt;field(name =&gt; "page", type =&gt; 'hidden');
			$form-&gt;field(name =&gt; "type", type =&gt; 'hidden');
			$form-&gt;title(sprintf(gettext("editing %s"), $page));
			showform($form, \@buttons, $session, $q);
			return;
		}
		else {
			# The trailing question mark tries to avoid broken
			# caches and get the most recent version of the page.
			redirect($q, "$config{url}/".htmlpage($page)."?updated");
		}
	}
} #}}}

sub cgi_getsession ($) { #{{{
	my $q=shift;

	eval q{use CGI::Session};
	CGI::Session-&gt;name("ikiwiki_session_".encode_utf8($config{wikiname}));
	
	my $oldmask=umask(077);
	my $session = CGI::Session-&gt;new("driver:DB_File", $q,
		{ FileName =&gt; "$config{wikistatedir}/sessions.db" });
	umask($oldmask);

	return $session;
} #}}}

sub cgi_savesession ($) { #{{{
	my $session=shift;

	# Force session flush with safe umask.
	my $oldmask=umask(077);
	$session-&gt;flush;
	umask($oldmask);
} #}}}

sub cgi (;$$) { #{{{
	my $q=shift;
	my $session=shift;

	if (! $q) {
		eval q{use CGI};
		error($@) if $@;
	
		$q=CGI-&gt;new;
	
		run_hooks(cgi =&gt; sub { shift-&gt;($q) });
	}

	my $do=$q-&gt;param('do');
	if (! defined $do || ! length $do) {
		my $error = $q-&gt;cgi_error;
		if ($error) {
			error("Request not processed: $error");
		}
		else {
			error("\"do\" parameter missing");
		}
	}
	
	# Need to lock the wiki before getting a session.
	lockwiki();
	loadindex();
	
	if (! $session) {
		$session=cgi_getsession($q);
	}
	
	# Auth hooks can sign a user in.
	if ($do ne 'signin' &amp;&amp; ! defined $session-&gt;param("name")) {
		run_hooks(auth =&gt; sub {
			shift-&gt;($q, $session)
		});
		if (defined $session-&gt;param("name")) {
			# Make sure whatever user was authed is in the
			# userinfo db.
			if (! userinfo_get($session-&gt;param("name"), "regdate")) {
				userinfo_setall($session-&gt;param("name"), {
					email =&gt; "",
					password =&gt; "",
					regdate =&gt; time,
				}) || error("failed adding user");
			}
		}
	}
	
	if (defined $session-&gt;param("name") &amp;&amp;
	    userinfo_get($session-&gt;param("name"), "banned")) {
		print $q-&gt;header(-status =&gt; "403 Forbidden");
		$session-&gt;delete();
		print gettext("You are banned.");
		cgi_savesession($session);
	}

	run_hooks(sessioncgi =&gt; sub { shift-&gt;($q, $session) });

	if ($do eq 'signin') {
		cgi_signin($q, $session);
		cgi_savesession($session);
	}
	elsif ($do eq 'prefs') {
		cgi_prefs($q, $session);
	}
	elsif ($do eq 'create' || $do eq 'edit') {
		cgi_editpage($q, $session);
	}
	elsif (defined $session-&gt;param("postsignin") || $do eq 'postsignin') {
		cgi_postsignin($q, $session);
	}
	else {
		error("unknown do parameter");
	}
} #}}}

1
</pre></body></html>