<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# Ikiwiki tag plugin.
package IkiWiki::Plugin::tag;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	hook(type =&gt; "checkconfig", id =&gt; "tag", call =&gt; \&amp;checkconfig);
	hook(type =&gt; "getopt", id =&gt; "tag", call =&gt; \&amp;getopt);
	hook(type =&gt; "getsetup", id =&gt; "tag", call =&gt; \&amp;getsetup);
	hook(type =&gt; "preprocess", id =&gt; "tag", call =&gt; \&amp;preprocess_tag, scan =&gt; 1);
	hook(type =&gt; "preprocess", id =&gt; "taglink", call =&gt; \&amp;preprocess_taglink, scan =&gt; 1);
	hook(type =&gt; "pagetemplate", id =&gt; "tag", call =&gt; \&amp;pagetemplate);

	IkiWiki::loadplugin("transient");
}

sub getopt () {
	eval q{use Getopt::Long};
	error($@) if $@;
	Getopt::Long::Configure('pass_through');
	GetOptions("tagbase=s" =&gt; \$config{tagbase});
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; undef,
		},
		tagbase =&gt; {
			type =&gt; "string",
			example =&gt; "tag",
			description =&gt; "parent page tags are located under",
			safe =&gt; 1,
			rebuild =&gt; 1,
		},
		tag_autocreate =&gt; {
			type =&gt; "boolean",
			example =&gt; 1,
			description =&gt; "autocreate new tag pages?",
			safe =&gt; 1,
			rebuild =&gt; undef,
		},
		tag_autocreate_commit =&gt; {
			type =&gt; "boolean",
			example =&gt; 1,
			default =&gt; 1,
			description =&gt; "commit autocreated tag pages",
			safe =&gt; 1,
			rebuild =&gt; 0,
		},
}

sub checkconfig () {
	if (! defined $config{tag_autocreate_commit}) {
		$config{tag_autocreate_commit} = 1;
	}
}

sub taglink ($) {
	my $tag=shift;
	
	if ($tag !~ m{^/} &amp;&amp;
	    defined $config{tagbase}) {
		$tag="/".$config{tagbase}."/".$tag;
		$tag=~y#/#/#s; # squash dups
	}

	return $tag;
}

# Returns a tag name from a tag link
sub tagname ($) {
	my $tag=shift;
	if (defined $config{tagbase}) {
		$tag =~ s!^/\Q$config{tagbase}\E/!!;
	} else {
		$tag =~ s!^\.?/!!;
	}
	return pagetitle($tag, 1);
}

sub htmllink_tag ($$$;@) {
	my $page=shift;
	my $destpage=shift;
	my $tag=shift;
	my %opts=@_;

	return htmllink($page, $destpage, taglink($tag), %opts);
}

sub gentag ($) {
	my $tag=shift;

	if ($config{tag_autocreate} ||
	    ($config{tagbase} &amp;&amp; ! defined $config{tag_autocreate})) {
		my $tagpage=taglink($tag);
		if ($tagpage=~/^\.\/(.*)/) {
			$tagpage=$1;
		}
		else {
			$tagpage=~s/^\///;
		}
		if (exists $IkiWiki::pagecase{lc $tagpage}) {
			$tagpage=$IkiWiki::pagecase{lc $tagpage}
		}

		my $tagfile = newpagefile($tagpage, $config{default_pageext});

		add_autofile($tagfile, "tag", sub {
			my $message=sprintf(gettext("creating tag page %s"), $tagpage);
			debug($message);

			my $template=template("autotag.tmpl");
			$template-&gt;param(tagname =&gt; tagname($tag));
			$template-&gt;param(tag =&gt; $tag);

			my $dir = $config{srcdir};
			if (! $config{tag_autocreate_commit}) {
				no warnings 'once';
				$dir = $IkiWiki::Plugin::transient::transientdir;
			}

			writefile($tagfile, $dir, $template-&gt;output);
			if ($config{rcs} &amp;&amp; $config{tag_autocreate_commit}) {
				IkiWiki::disable_commit_hook();
				IkiWiki::rcs_add($tagfile);
				IkiWiki::rcs_commit_staged(message =&gt; $message);
				IkiWiki::enable_commit_hook();
			}
		});
	}
}

sub preprocess_tag (@) {
	if (! @_) {
		return "";
	}
	my %params=@_;
	my $page = $params{page};
	delete $params{page};
	delete $params{destpage};
	delete $params{preview};

	foreach my $tag (keys %params) {
		$tag=linkpage($tag);
		
		# hidden WikiLink
		add_link($page, taglink($tag), 'tag');
		
		gentag($tag);
	}
		
	return "";
}

sub preprocess_taglink (@) {
	if (! @_) {
		return "";
	}
	my %params=@_;
	return join(" ", map {
		if (/(.*)\|(.*)/) {
			my $tag=linkpage($2);
			add_link($params{page}, taglink($tag), 'tag');
			gentag($tag);
			return htmllink_tag($params{page}, $params{destpage}, $tag,
				linktext =&gt; pagetitle($1));
		}
		else {
			my $tag=linkpage($_);
			add_link($params{page}, taglink($tag), 'tag');
			gentag($tag);
			return htmllink_tag($params{page}, $params{destpage}, $tag);
		}
	}
	grep {
		$_ ne 'page' &amp;&amp; $_ ne 'destpage' &amp;&amp; $_ ne 'preview'
	} keys %params);
}

sub pagetemplate (@) {
	my %params=@_;
	my $page=$params{page};
	my $destpage=$params{destpage};
	my $template=$params{template};

	my $tags = $typedlinks{$page}{tag};

	$template-&gt;param(tags =&gt; [
		map { 
			link =&gt; htmllink_tag($page, $destpage, $_,
					rel =&gt; "tag", linktext =&gt; tagname($_))
		}, sort keys %$tags
	]) if defined $tags &amp;&amp; %$tags &amp;&amp; $template-&gt;query(name =&gt; "tags");

	if ($template-&gt;query(name =&gt; "categories")) {
		# It's an rss/atom template. Add any categories.
		if (defined $tags &amp;&amp; %$tags) {
			eval q{use HTML::Entities};
			$template-&gt;param(categories =&gt;
				[map { category =&gt; HTML::Entities::encode_entities_numeric(tagname($_)) },
					sort keys %$tags]);
		}
	}
}

package IkiWiki::PageSpec;

sub match_tagged ($$;@) {
	my $page=shift;
	my $glob=IkiWiki::Plugin::tag::taglink(shift);
	return match_link($page, $glob, linktype =&gt; 'tag', @_);
}

1
</pre></body></html>