<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
# hyperestraier search engine plugin
package IkiWiki::Plugin::search;

use warnings;
use strict;
use IkiWiki;

sub import { #{{{
	hook(type =&gt; "getopt", id =&gt; "hyperestraier",
		call =&gt; \&amp;getopt);
	hook(type =&gt; "checkconfig", id =&gt; "hyperestraier",
		call =&gt; \&amp;checkconfig);
	hook(type =&gt; "pagetemplate", id =&gt; "hyperestraier",
		call =&gt; \&amp;pagetemplate);
	hook(type =&gt; "delete", id =&gt; "hyperestraier",
		call =&gt; \&amp;delete);
	hook(type =&gt; "change", id =&gt; "hyperestraier",
		call =&gt; \&amp;change);
	hook(type =&gt; "cgi", id =&gt; "hyperestraier",
		call =&gt; \&amp;cgi);
} # }}}

sub getopt () { #{{{
        eval q{use Getopt::Long};
	error($@) if $@;
        Getopt::Long::Configure('pass_through');
        GetOptions("estseek=s" =&gt; \$config{estseek});
} #}}}

sub checkconfig () { #{{{
	foreach my $required (qw(url cgiurl)) {
		if (! length $config{$required}) {
			error("Must specify $required when using the search plugin\n");
		}
	}
} #}}}

my $form;
sub pagetemplate (@) { #{{{
	my %params=@_;
	my $page=$params{page};
	my $template=$params{template};

	# Add search box to page header.
	if ($template-&gt;query(name =&gt; "searchform")) {
		if (! defined $form) {
			my $searchform = template("searchform.tmpl", blind_cache =&gt; 1);
			$searchform-&gt;param(searchaction =&gt; $config{cgiurl});
			$form=$searchform-&gt;output;
		}

		$template-&gt;param(searchform =&gt; $form);
	}
} #}}}

sub delete (@) { #{{{
	debug("cleaning hyperestraier search index");
	estcmd("purge -cl");
	estcfg();
} #}}}

sub change (@) { #{{{
	debug("updating hyperestraier search index");
	estcmd("gather -cm -bc -cl -sd",
		map {
			Encode::encode_utf8($config{destdir}."/".$_)
				foreach @{$renderedfiles{pagename($_)}};
		} @_
	);
	estcfg();
} #}}}

sub cgi ($) { #{{{
	my $cgi=shift;

	if (defined $cgi-&gt;param('phrase')) {
		# only works for GET requests
		chdir("$config{wikistatedir}/hyperestraier") || error("chdir: $!");
		exec("./".IkiWiki::basename($config{cgiurl})) || error("estseek.cgi failed");
	}
} #}}}

my $configured=0;
sub estcfg () { #{{{
	return if $configured;
	$configured=1;
	
	my $estdir="$config{wikistatedir}/hyperestraier";
	my $cgi=IkiWiki::basename($config{cgiurl});
	$cgi=~s/\..*$//;
	open(TEMPLATE, "&gt;:utf8", "$estdir/$cgi.tmpl") ||
		error("write $estdir/$cgi.tmpl: $!");
	print TEMPLATE IkiWiki::misctemplate("search", 
		"&lt;!--ESTFORM--&gt;\n\n&lt;!--ESTRESULT--&gt;\n\n&lt;!--ESTINFO--&gt;\n\n",
		baseurl =&gt; IkiWiki::dirname($config{cgiurl})."/");
	close TEMPLATE;
	open(TEMPLATE, "&gt;$estdir/$cgi.conf") ||
		error("write $estdir/$cgi.conf: $!");
	my $template=template("estseek.conf");
	eval q{use Cwd 'abs_path'};
	$template-&gt;param(
		index =&gt; $estdir,
		tmplfile =&gt; "$estdir/$cgi.tmpl",
		destdir =&gt; abs_path($config{destdir}),
		url =&gt; $config{url},
	);
	print TEMPLATE $template-&gt;output;
	close TEMPLATE;
	$cgi="$estdir/".IkiWiki::basename($config{cgiurl});
	unlink($cgi);
	my $estseek = defined $config{estseek} ? $config{estseek} : '/usr/lib/estraier/estseek.cgi';
	symlink($estseek, $cgi) ||
		error("symlink $estseek $cgi: $!");
} # }}}

sub estcmd ($;@) { #{{{
	my @params=split(' ', shift);
	push @params, "-cl", "$config{wikistatedir}/hyperestraier";
	if (@_) {
		push @params, "-";
	}
	
	my $pid=open(CHILD, "|-");
	if ($pid) {
		# parent
		foreach (@_) {
			print CHILD "$_\n";
		}
		close(CHILD) || error("estcmd @params exited nonzero: $?");
	}
	else {
		# child
		open(STDOUT, "/dev/null"); # shut it up (closing won't work)
		exec("estcmd", @params) || error("can't run estcmd");
	}
} #}}}

1
</pre></body></html>