<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#!/usr/bin/perl
package IkiWiki::Plugin::attachment;

use warnings;
use strict;
use IkiWiki 3.00;

sub import {
	add_underlay("attachment");
	add_underlay("javascript");
	add_underlay("jquery");
	hook(type =&gt; "getsetup", id =&gt; "attachment", call =&gt; \&amp;getsetup);
	hook(type =&gt; "checkconfig", id =&gt; "attachment", call =&gt; \&amp;checkconfig);
	hook(type =&gt; "formbuilder_setup", id =&gt; "attachment", call =&gt; \&amp;formbuilder_setup);
	hook(type =&gt; "formbuilder", id =&gt; "attachment", call =&gt; \&amp;formbuilder, last =&gt; 1);
	IkiWiki::loadplugin("filecheck");
}

sub getsetup () {
	return
		plugin =&gt; {
			safe =&gt; 1,
			rebuild =&gt; 0,
			section =&gt; "web",
		},
		allowed_attachments =&gt; {
			type =&gt; "pagespec",
			example =&gt; "virusfree() and mimetype(image/*) and maxsize(50kb)",
			description =&gt; "enhanced PageSpec specifying what attachments are allowed",
			link =&gt; "ikiwiki/PageSpec/attachment",
			safe =&gt; 1,
			rebuild =&gt; 0,
		},
		virus_checker =&gt; {
			type =&gt; "string",
			example =&gt; "clamdscan -",
			description =&gt; "virus checker program (reads STDIN, returns nonzero if virus found)",
			safe =&gt; 0, # executed
			rebuild =&gt; 0,
		},
}

sub check_canattach ($$;$) {
	my $session=shift;
	my $dest=shift; # where it's going to be put, under the srcdir
	my $file=shift; # the path to the attachment currently

	# Don't allow an attachment to be uploaded with the same name as an
	# existing page.
	if (exists $IkiWiki::pagesources{$dest} &amp;&amp;
	    $IkiWiki::pagesources{$dest} ne $dest) {
		error(sprintf(gettext("there is already a page named %s"), $dest));
	}

	# Use a special pagespec to test that the attachment is valid.
	my $allowed=1;
	if (defined $config{allowed_attachments} &amp;&amp;
	    length $config{allowed_attachments}) {
		$allowed=pagespec_match($dest,
			$config{allowed_attachments},
			file =&gt; $file,
			user =&gt; $session-&gt;param("name"),
			ip =&gt; $session-&gt;remote_addr(),
		);
	}

	if (! $allowed) {
		error(gettext("prohibited by allowed_attachments")." ($allowed)");
	}
	else {
		return 1;
	}
}

sub checkconfig () {
	$config{cgi_disable_uploads}=0;
}

sub formbuilder_setup (@) {
	my %params=@_;
	my $form=$params{form};
	my $q=$params{cgi};

	if (defined $form-&gt;field("do") &amp;&amp; ($form-&gt;field("do") eq "edit" ||
	    $form-&gt;field("do") eq "create")) {
		# Add attachment field, set type to multipart.
		$form-&gt;enctype(&amp;CGI::MULTIPART);
		$form-&gt;field(name =&gt; 'attachment', type =&gt; 'file');
		# These buttons are not put in the usual place, so
		# are not added to the normal formbuilder button list.
		$form-&gt;tmpl_param("field-upload" =&gt; '&lt;input name="_submit" type="submit" value="Upload Attachment" /&gt;');
		$form-&gt;tmpl_param("field-link" =&gt; '&lt;input name="_submit" type="submit" value="Insert Links" /&gt;');

		# Add all the javascript used by the attachments interface.
		require IkiWiki::Plugin::toggle;
		my $js=IkiWiki::Plugin::toggle::include_javascript($params{page});
		$js.='&lt;link rel="stylesheet" href="'.urlto("ikiwiki/jquery-ui.min.css", $params{page}).'" id="theme"&gt;'."\n";
		my @jsfiles=qw{jquery.min jquery-ui.min
			jquery.tmpl.min jquery.iframe-transport
			jquery.fileupload jquery.fileupload-ui
		};
		foreach my $file (@jsfiles) {
			$js.='&lt;script src="'.urlto("ikiwiki/$file.js", $params{page}).
			     '" type="text/javascript" charset="utf-8"&gt;&lt;/script&gt;'."\n";
		}
		$form-&gt;tmpl_param("javascript" =&gt; $js);

		# Start with the attachments interface toggled invisible,
		# but if it was used, keep it open.
		if ($form-&gt;submitted ne "Upload Attachment" &amp;&amp;
		    (! defined $q-&gt;param("attachment_select") ||
		    ! length $q-&gt;param("attachment_select"))) {
			$form-&gt;tmpl_param("attachments-class" =&gt; "toggleable");
		}
		else {
			$form-&gt;tmpl_param("attachments-class" =&gt; "toggleable-open");
		}
		
		# Save attachments in holding area before previewing and
		# saving.
		if ($form-&gt;submitted eq "Preview" ||
		    $form-&gt;submitted eq "Save Page") {
			attachments_save($form, $params{session});
		}
	}
}

sub formbuilder (@) {
	my %params=@_;
	my $form=$params{form};
	my $q=$params{cgi};

	return if ! defined $form-&gt;field("do") || ($form-&gt;field("do") ne "edit" &amp;&amp; $form-&gt;field("do") ne "create") ;

	my $filename=Encode::decode_utf8($q-&gt;param('attachment'));
	if (defined $filename &amp;&amp; length $filename) {
		attachment_store($filename, $form, $q, $params{session});
	}

	if ($form-&gt;submitted eq "Save Page") {
		attachments_save($form, $params{session});
	}

	if ($form-&gt;submitted eq "Insert Links") {
		my $page=quotemeta(Encode::decode_utf8($q-&gt;param("page")));
		my $add="";
		foreach my $f ($q-&gt;param("attachment_select")) {
			$f=Encode::decode_utf8($f);
			$f=~s/^$page\///;
			if (IkiWiki::isinlinableimage($f) &amp;&amp;
			    UNIVERSAL::can("IkiWiki::Plugin::img", "import")) {
				$add.='[[!img '.$f.' align="right" size="" alt=""]]';
			}
			else {
				$add.="[[$f]]";
			}
			$add.="\n";
		}
		$form-&gt;field(name =&gt; 'editcontent',
			value =&gt; $form-&gt;field('editcontent')."\n\n".$add,
			force =&gt; 1) if length $add;
	}
	
	# Generate the attachment list only after having added any new
	# attachments.
	$form-&gt;tmpl_param("attachment_list" =&gt; [attachment_list($form-&gt;field('page'))]);
}

sub attachment_holding_location {
	my $page=attachment_location(shift);

	my $dir=$config{wikistatedir}."/attachments/".
		IkiWiki::possibly_foolish_untaint(linkpage($page));
	$dir=~s/\/$//;
	return $dir;
}

sub is_held_attachment {
	my $attachment=shift;

	my $f=attachment_holding_location($attachment);
	if (-f $f) {
		return $f
	}
	else {
		return undef;
	}
}

# Stores the attachment in a holding area, not yet in the wiki proper.
sub attachment_store {
	my $filename=shift;
	my $form=shift;
	my $q=shift;
	my $session=shift;
	
	# This is an (apparently undocumented) way to get the name
	# of the temp file that CGI writes the upload to.
	my $tempfile=$q-&gt;tmpFileName($filename);
	if (! defined $tempfile || ! length $tempfile) {
		# perl 5.8 needs an alternative, awful method
		if ($q =~ /HASH/ &amp;&amp; exists $q-&gt;{'.tmpfiles'}) {
			foreach my $key (keys(%{$q-&gt;{'.tmpfiles'}})) {
				$tempfile=$q-&gt;tmpFileName(\$key);
				last if defined $tempfile &amp;&amp; length $tempfile;
			}
		}
		if (! defined $tempfile || ! length $tempfile) {
			error("CGI::tmpFileName failed to return the uploaded file name");
		}
	}

	$filename=IkiWiki::basename($filename);
	$filename=~s/.*\\+(.+)/$1/; # hello, windows
	$filename=IkiWiki::possibly_foolish_untaint(linkpage($filename));
	my $dest=attachment_holding_location($form-&gt;field('page'));
	
	# Check that the user is allowed to edit the attachment.
	my $final_filename=
		linkpage(IkiWiki::possibly_foolish_untaint(
			attachment_location($form-&gt;field('page')))).
		$filename;
	eval {
		if (IkiWiki::file_pruned($final_filename)) {
			error(gettext("bad attachment filename"));
		}
		IkiWiki::check_canedit($final_filename, $q, $session);
		# And that the attachment itself is acceptable.
		check_canattach($session, $final_filename, $tempfile);
	};
	if ($@) {
		json_response($q, $form, $dest."/".$filename, $@);
		error $@;
	}

	# Move the attachment into holding directory.
	# Try to use a fast rename; fall back to copying.
	IkiWiki::prep_writefile($filename, $dest);
	unlink($dest."/".$filename);
	if (rename($tempfile, $dest."/".$filename)) {
		# The temp file has tight permissions; loosen up.
		chmod(0666 &amp; ~umask, $dest."/".$filename);
	}
	else {
		my $fh=$q-&gt;upload('attachment');
		if (! defined $fh || ! ref $fh) {
			# needed by old CGI versions
			$fh=$q-&gt;param('attachment');
			if (! defined $fh || ! ref $fh) {
				# even that doesn't always work,
				# fall back to opening the tempfile
				$fh=undef;
				open($fh, "&lt;", $tempfile) || error("failed to open \"$tempfile\": $!");
			}
		}
		binmode($fh);
		require IkiWiki::Render; 
		writefile($filename, $dest, undef, 1, sub {
			IkiWiki::fast_file_copy($tempfile, $filename, $fh, @_);
		});
	}

	json_response($q, $form, $dest."/".$filename, stored_msg());
}

# Save all stored attachments for a page.
sub attachments_save {
	my $form=shift;
	my $session=shift;

	# Move attachments out of holding directory.
	my @attachments;
	my $dir=attachment_holding_location($form-&gt;field('page'));
	foreach my $filename (glob("$dir/*")) {
		$filename=Encode::decode_utf8($filename);
		next unless -f $filename;
		my $destdir=$config{srcdir}."/".
			linkpage(IkiWiki::possibly_foolish_untaint(
				attachment_location($form-&gt;field('page'))));
		my $destfile=IkiWiki::basename($filename);
		my $dest=$destdir.$destfile;
		unlink($dest);
		IkiWiki::prep_writefile($destfile, $destdir);
		rename($filename, $dest);
		push @attachments, $dest;
	}
	return unless @attachments;
	require IkiWiki::Render;
	IkiWiki::prune($dir);

	# Check the attachments in and trigger a wiki refresh.
	if ($config{rcs}) {
		IkiWiki::rcs_add($_) foreach @attachments;
		IkiWiki::disable_commit_hook();
		IkiWiki::rcs_commit_staged(
			message =&gt; gettext("attachment upload"),
			session =&gt; $session,
		);
		IkiWiki::enable_commit_hook();
		IkiWiki::rcs_update();
	}
	IkiWiki::refresh();
	IkiWiki::saveindex();
}

sub attachment_location ($) {
	my $page=shift;
	
	# Put the attachment in a subdir of the page it's attached
	# to, unless that page is the "index" page.
	return "" if $page eq 'index';
	$page.="/" if length $page;
	
	return $page;
}

sub attachment_list ($) {
	my $page=shift;
	my $loc=attachment_location($page);

	my $std=sub {
		my $file=shift;
		my $mtime=shift;
		my $date=shift;
		my $size=shift;

		name =&gt; $file,
		size =&gt; IkiWiki::Plugin::filecheck::humansize($size),
		mtime =&gt; $date,
		mtime_raw =&gt; $mtime,
	};

	# attachments already in the wiki
	my %attachments;
	foreach my $f (values %pagesources) {
		if (! defined pagetype($f) &amp;&amp;
		    $f=~m/^\Q$loc\E[^\/]+$/) {
			$attachments{$f}={
				$std-&gt;($f, $IkiWiki::pagemtime{$f}, displaytime($IkiWiki::pagemtime{$f}), (stat($f))[7]),
				link =&gt; htmllink($page, $page, $f, noimageinline =&gt; 1),
			};
		}
	}
	
	# attachments in holding directory
	my $dir=attachment_holding_location($page);
	my $heldmsg=gettext("this attachment is not yet saved");
	foreach my $file (glob("$dir/*")) {
		$file=Encode::decode_utf8($file);
		next unless -f $file;
		my $base=IkiWiki::basename($file);
		my $f=$loc.$base;
		$attachments{$f}={
			$std-&gt;($f, (stat($file))[9]*2, stored_msg(), (stat(_))[7]),
			link =&gt; $base,
		}
	}

	# Sort newer attachments to the end of the list.
	return sort { $a-&gt;{mtime_raw} &lt;=&gt; $b-&gt;{mtime_raw} || $a-&gt;{link} cmp $b-&gt;{link} }
		values %attachments;
}

sub stored_msg {
	gettext("just uploaded");
}

sub json_response ($$$$) {
	my $q=shift;
	my $form=shift;
	my $filename=shift;
	my $stored_msg=shift;

	if (! defined $form-&gt;submitted ||
	    $form-&gt;submitted ne "Upload Attachment") {
		eval q{use JSON};
		error $@ if $@;
		print "Content-type: text/html\n\n";
		my $size=-s $filename;
		print to_json([
			{
				name =&gt; IkiWiki::basename($filename),
				size =&gt; $size,
				humansize =&gt; IkiWiki::Plugin::filecheck::humansize($size),
				stored_msg =&gt; $stored_msg,
				
			}
		]);
		exit 0;
	}
}

1
</pre></body></html>