IkiWiki/Plugin/attachment.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::attachment;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         add_underlay("javascript");
  10         hook(type => "getsetup", id => "attachment", call => \&getsetup);
  11         hook(type => "checkconfig", id => "attachment", call => \&checkconfig);
  12         hook(type => "formbuilder_setup", id => "attachment", call => \&formbuilder_setup);
  13         hook(type => "formbuilder", id => "attachment", call => \&formbuilder, last => 1);
  14         IkiWiki::loadplugin("filecheck");
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => 0,
  22                         section => "web",
  23                 },
  24                 allowed_attachments => {
  25                         type => "pagespec",
  26                         example => "virusfree() and mimetype(image/*) and maxsize(50kb)",
  27                         description => "enhanced PageSpec specifying what attachments are allowed",
  28                         link => "ikiwiki/PageSpec/attachment",
  29                         safe => 1,
  30                         rebuild => 0,
  31                 },
  32                 virus_checker => {
  33                         type => "string",
  34                         example => "clamdscan -",
  35                         description => "virus checker program (reads STDIN, returns nonzero if virus found)",
  36                         safe => 0, # executed
  37                         rebuild => 0,
  38                 },
  39 }
  40
  41 sub check_canattach ($$;$) {
  42         my $session=shift;
  43         my $dest=shift; # where it's going to be put, under the srcdir
  44         my $file=shift; # the path to the attachment currently
  45
  46         # Don't allow an attachment to be uploaded with the same name as an
  47         # existing page.
  48         if (exists $IkiWiki::pagesources{$dest} &&
  49             $IkiWiki::pagesources{$dest} ne $dest) {
  50                 error(sprintf(gettext("there is already a page named %s"), $dest));
  51         }
  52
  53         # Use a special pagespec to test that the attachment is valid.
  54         my $allowed=1;
  55         if (defined $config{allowed_attachments} &&
  56             length $config{allowed_attachments}) {
  57                 $allowed=pagespec_match($dest,
  58                         $config{allowed_attachments},
  59                         file => $file,
  60                         user => $session->param("name"),
  61                         ip => $session->remote_addr(),
  62                 );
  63         }
  64
  65         if (! $allowed) {
  66                 error(gettext("prohibited by allowed_attachments")." ($allowed)");
  67         }
  68         else {
  69                 return 1;
  70         }
  71 }
  72
  73 sub checkconfig () {
  74         $config{cgi_disable_uploads}=0;
  75 }
  76
  77 sub formbuilder_setup (@) {
  78         my %params=@_;
  79         my $form=$params{form};
  80         my $q=$params{cgi};
  81
  82         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
  83             $form->field("do") eq "create")) {
  84                 # Add attachment field, set type to multipart.
  85                 $form->enctype(&CGI::MULTIPART);
  86                 $form->field(name => 'attachment', type => 'file');
  87                 # These buttons are not put in the usual place, so
  88                 # are not added to the normal formbuilder button list.
  89                 $form->tmpl_param("field-upload" => '<input name="_submit" type="submit" value="Upload Attachment" />');
  90                 $form->tmpl_param("field-link" => '<input name="_submit" type="submit" value="Insert Links" />');
  91
  92                 # Add the toggle javascript; the attachments interface uses
  93                 # it to toggle visibility.
  94                 require IkiWiki::Plugin::toggle;
  95                 $form->tmpl_param("javascript" => IkiWiki::Plugin::toggle::include_javascript($params{page}));
  96                 # Start with the attachments interface toggled invisible,
  97                 # but if it was used, keep it open.
  98                 if ($form->submitted ne "Upload Attachment" &&
  99                     (! defined $q->param("attachment_select") ||
 100                     ! length $q->param("attachment_select"))) {
 101                         $form->tmpl_param("attachments-class" => "toggleable");
 102                 }
 103                 else {
 104                         $form->tmpl_param("attachments-class" => "toggleable-open");
 105                 }
 106
 107                 # Save attachments in holding area before previewing so
 108                 # they can be seen in the preview.
 109                 if ($form->submitted eq "Preview") {
 110                         attachments_save($form, $params{session});
 111                 }
 112         }
 113 }
 114
 115 sub formbuilder (@) {
 116         my %params=@_;
 117         my $form=$params{form};
 118         my $q=$params{cgi};
 119
 120         return if ! defined $form->field("do") || ($form->field("do") ne "edit" && $form->field("do") ne "create") ;
 121
 122         my $filename=Encode::decode_utf8($q->param('attachment'));
 123         if (defined $filename && length $filename &&
 124             ($form->submitted eq "Upload Attachment" || $form->submitted eq "Save Page")) {
 125                 attachment_store($filename, $form, $q, $params{session});
 126         }
 127         if ($form->submitted eq "Save Page") {
 128                 attachments_save($form, $params{session});
 129         }
 130
 131         if ($form->submitted eq "Insert Links") {
 132                 my $page=quotemeta(Encode::decode_utf8($q->param("page")));
 133                 my $add="";
 134                 foreach my $f ($q->param("attachment_select")) {
 135                         $f=Encode::decode_utf8($f);
 136                         $f=~s/^$page\///;
 137                         if (IkiWiki::isinlinableimage($f) &&
 138                             UNIVERSAL::can("IkiWiki::Plugin::img", "import")) {
 139                                 $add.='[[!img '.$f.' align="right" size="" alt=""]]';
 140                         }
 141                         else {
 142                                 $add.="[[$f]]";
 143                         }
 144                         $add.="\n";
 145                 }
 146                 $form->field(name => 'editcontent',
 147                         value => $form->field('editcontent')."\n\n".$add,
 148                         force => 1) if length $add;
 149         }
 150
 151         # Generate the attachment list only after having added any new
 152         # attachments.
 153         $form->tmpl_param("attachment_list" => [attachment_list($form->field('page'))]);
 154 }
 155
 156 sub attachment_holding_dir {
 157         my $page=attachment_location(shift);
 158
 159         return $config{wikistatedir}."/attachments/".
 160                 IkiWiki::possibly_foolish_untaint(linkpage($page));
 161 }
 162
 163 sub remove_held_attachment {
 164         my $attachment=shift;
 165
 166         my $f=attachment_holding_dir($attachment);
 167         $f=~s/\/$//;
 168         if (-f $f) {
 169                 require IkiWiki::Render;
 170                 IkiWiki::prune($f);
 171                 return 1;
 172         }
 173         else {
 174                 return 0;
 175         }
 176 }
 177
 178 # Stores the attachment in a holding area, not yet in the wiki proper.
 179 sub attachment_store {
 180         my $filename=shift;
 181         my $form=shift;
 182         my $q=shift;
 183         my $session=shift;
 184
 185         # This is an (apparently undocumented) way to get the name
 186         # of the temp file that CGI writes the upload to.
 187         my $tempfile=$q->tmpFileName($filename);
 188         if (! defined $tempfile || ! length $tempfile) {
 189                 # perl 5.8 needs an alternative, awful method
 190                 if ($q =~ /HASH/ && exists $q->{'.tmpfiles'}) {
 191                         foreach my $key (keys(%{$q->{'.tmpfiles'}})) {
 192                                 $tempfile=$q->tmpFileName(\$key);
 193                                 last if defined $tempfile && length $tempfile;
 194                         }
 195                 }
 196                 if (! defined $tempfile || ! length $tempfile) {
 197                         error("CGI::tmpFileName failed to return the uploaded file name");
 198                 }
 199         }
 200
 201         $filename=IkiWiki::basename($filename);
 202         $filename=~s/.*\\+(.+)/$1/; # hello, windows
 203         $filename=IkiWiki::possibly_foolish_untaint(linkpage($filename));
 204
 205         # Check that the user is allowed to edit the attachment.
 206         my $final_filename=
 207                 linkpage(IkiWiki::possibly_foolish_untaint(
 208                         attachment_location($form->field('page')))).
 209                 $filename;
 210         if (IkiWiki::file_pruned($final_filename)) {
 211                 error(gettext("bad attachment filename"));
 212         }
 213         IkiWiki::check_canedit($final_filename, $q, $session);
 214         # And that the attachment itself is acceptable.
 215         check_canattach($session, $final_filename, $tempfile);
 216
 217         # Move the attachment into holding directory.
 218         # Try to use a fast rename; fall back to copying.
 219         my $dest=attachment_holding_dir($form->field('page'));
 220         IkiWiki::prep_writefile($filename, $dest);
 221         unlink($dest."/".$filename);
 222         if (rename($tempfile, $dest."/".$filename)) {
 223                 # The temp file has tight permissions; loosen up.
 224                 chmod(0666 & ~umask, $dest."/".$filename);
 225         }
 226         else {
 227                 my $fh=$q->upload('attachment');
 228                 if (! defined $fh || ! ref $fh) {
 229                         # needed by old CGI versions
 230                         $fh=$q->param('attachment');
 231                         if (! defined $fh || ! ref $fh) {
 232                                 # even that doesn't always work,
 233                                 # fall back to opening the tempfile
 234                                 $fh=undef;
 235                                 open($fh, "<", $tempfile) || error("failed to open \"$tempfile\": $!");
 236                         }
 237                 }
 238                 binmode($fh);
 239                 require IkiWiki::Render;
 240                 writefile($filename, $dest, undef, 1, sub {
 241                         IkiWiki::fast_file_copy($tempfile, $filename, $fh, @_);
 242                 });
 243         }
 244 }
 245
 246 # Save all stored attachments for a page.
 247 sub attachments_save {
 248         my $form=shift;
 249         my $session=shift;
 250
 251         # Move attachments out of holding directory.
 252         my @attachments;
 253         my $dir=attachment_holding_dir($form->field('page'));
 254         foreach my $filename (glob("$dir/*")) {
 255                 next unless -f $filename;
 256                 my $dest=$config{srcdir}."/".
 257                         linkpage(IkiWiki::possibly_foolish_untaint(
 258                                 attachment_location($form->field('page')))).
 259                         IkiWiki::basename($filename);
 260                 unlink($dest);
 261                 rename($filename, $dest);
 262                 push @attachments, $dest;
 263         }
 264         return unless @attachments;
 265         require IkiWiki::Render;
 266         IkiWiki::prune($dir);
 267
 268         # Check the attachments in and trigger a wiki refresh.
 269         if ($config{rcs}) {
 270                 IkiWiki::rcs_add($_) foreach @attachments;
 271                 IkiWiki::disable_commit_hook();
 272                 IkiWiki::rcs_commit_staged(
 273                         message => gettext("attachment upload"),
 274                         session => $session,
 275                 );
 276                 IkiWiki::enable_commit_hook();
 277                 IkiWiki::rcs_update();
 278         }
 279         IkiWiki::refresh();
 280         IkiWiki::saveindex();
 281 }
 282
 283 sub attachment_location ($) {
 284         my $page=shift;
 285
 286         # Put the attachment in a subdir of the page it's attached
 287         # to, unless that page is an "index" page.
 288         $page=~s/(^|\/)index//;
 289         $page.="/" if length $page;
 290
 291         return $page;
 292 }
 293
 294 sub attachment_list ($) {
 295         my $page=shift;
 296         my $loc=attachment_location($page);
 297
 298         my $std=sub {
 299                 my $file=shift;
 300                 my $mtime=shift;
 301                 my $size=shift;
 302
 303                 "field-select" => '<input type="checkbox" name="attachment_select" value="'.$file.'" />',
 304                 size => IkiWiki::Plugin::filecheck::humansize($size),
 305                 mtime => displaytime($mtime),
 306                 mtime_raw => $mtime,
 307         };
 308
 309         # attachments already in the wiki
 310         my %attachments;
 311         foreach my $f (values %pagesources) {
 312                 if (! defined pagetype($f) &&
 313                     $f=~m/^\Q$loc\E[^\/]+$/) {
 314                         $attachments{$f}={
 315                                 $std->($f, $IkiWiki::pagemtime{$f}, (stat($f))[7]),
 316                                 link => htmllink($page, $page, $f, noimageinline => 1),
 317                         };
 318                 }
 319         }
 320
 321         # attachments in holding directory
 322         my $dir=attachment_holding_dir($page);
 323         my $heldmsg=gettext("this attachment is not yet saved");
 324         foreach my $file (glob("$dir/*")) {
 325                 next unless -f $file;
 326                 my $mtime=(stat(_))[9];
 327                 my $base=IkiWiki::basename($file);
 328                 my $f=$loc.$base;
 329                 $attachments{$f}={
 330                         $std->($f, (stat($file))[9], (stat(_))[7]),
 331                         link => "<span title=\"$heldmsg\">$base</span>",
 332                 }
 333         }
 334
 335         # Sort newer attachments to the top of the list, so a newly-added
 336         # attachment appears just before the form used to add it.
 337         return sort { $b->{mtime_raw} <=> $a->{mtime_raw} || $a->{link} cmp $b->{link} }
 338                 values %attachments;
 339 }
 340
 341 1