IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008-2009 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 3.00;
  12 use Encode;
  13 eval q{use Locale::Po4a::Common qw(nowrapi18n !/.*/)};
  14 if ($@) {
  15         print STDERR gettext("warning: Old po4a detected! Recommend upgrade to 0.35.")."\n";
  16         eval q{use Locale::Po4a::Common qw(!/.*/)};
  17         die $@ if $@;
  18 }
  19 use Locale::Po4a::Chooser;
  20 use Locale::Po4a::Po;
  21 use File::Basename;
  22 use File::Copy;
  23 use File::Spec;
  24 use File::Temp;
  25 use Memoize;
  26 use UNIVERSAL;
  27
  28 my %translations;
  29 my @origneedsbuild;
  30 my %origsubs;
  31
  32 memoize("istranslatable");
  33 memoize("_istranslation");
  34 memoize("percenttranslated");
  35
  36 sub import {
  37         hook(type => "getsetup", id => "po", call => \&getsetup);
  38         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  39         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  40         hook(type => "scan", id => "po", call => \&scan, last => 1);
  41         hook(type => "filter", id => "po", call => \&filter);
  42         hook(type => "htmlize", id => "po", call => \&htmlize);
  43         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  44         hook(type => "rename", id => "po", call => \&renamepages, first => 1);
  45         hook(type => "delete", id => "po", call => \&mydelete);
  46         hook(type => "change", id => "po", call => \&change);
  47         hook(type => "checkcontent", id => "po", call => \&checkcontent);
  48         hook(type => "canremove", id => "po", call => \&canremove);
  49         hook(type => "canrename", id => "po", call => \&canrename);
  50         hook(type => "editcontent", id => "po", call => \&editcontent);
  51         hook(type => "formbuilder_setup", id => "po", call => \&formbuilder_setup, last => 1);
  52         hook(type => "formbuilder", id => "po", call => \&formbuilder);
  53
  54         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  55         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  56         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  57         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  58         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  59         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  60         $origsubs{'urlto'}=\&IkiWiki::urlto;
  61         inject(name => "IkiWiki::urlto", call => \&myurlto);
  62         $origsubs{'cgiurl'}=\&IkiWiki::cgiurl;
  63         inject(name => "IkiWiki::cgiurl", call => \&mycgiurl);
  64 }
  65
  66
  67 # ,----
  68 # | Table of contents
  69 # `----
  70
  71 # 1. Hooks
  72 # 2. Injected functions
  73 # 3. Blackboxes for private data
  74 # 4. Helper functions
  75 # 5. PageSpecs
  76
  77
  78 # ,----
  79 # | Hooks
  80 # `----
  81
  82 sub getsetup () {
  83         return
  84                 plugin => {
  85                         safe => 0,
  86                         rebuild => 1,
  87                 },
  88                 po_master_language => {
  89                         type => "string",
  90                         example => {
  91                                 'code' => 'en',
  92                                 'name' => 'English'
  93                         },
  94                         description => "master language (non-PO files)",
  95                         safe => 1,
  96                         rebuild => 1,
  97                 },
  98                 po_slave_languages => {
  99                         type => "string",
 100                         example => {
 101                                 'fr' => 'Français',
 102                                 'es' => 'Español',
 103                                 'de' => 'Deutsch'
 104                         },
 105                         description => "slave languages (PO files)",
 106                         safe => 1,
 107                         rebuild => 1,
 108                 },
 109                 po_translatable_pages => {
 110                         type => "pagespec",
 111                         example => "* and !*/Discussion",
 112                         description => "PageSpec controlling which pages are translatable",
 113                         link => "ikiwiki/PageSpec",
 114                         safe => 1,
 115                         rebuild => 1,
 116                 },
 117                 po_link_to => {
 118                         type => "string",
 119                         example => "current",
 120                         description => "internal linking behavior (default/current/negotiated)",
 121                         safe => 1,
 122                         rebuild => 1,
 123                 },
 124 }
 125
 126 sub checkconfig () {
 127         foreach my $field (qw{po_master_language}) {
 128                 if (! exists $config{$field} || ! defined $config{$field}) {
 129                         error(sprintf(gettext("Must specify %s when using the %s plugin"),
 130                                       $field, 'po'));
 131                 }
 132         }
 133
 134         map {
 135                 islanguagecode($_)
 136                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 137         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 138
 139         if (! exists $config{po_translatable_pages} ||
 140             ! defined $config{po_translatable_pages}) {
 141                 $config{po_translatable_pages}="";
 142         }
 143         if (! exists $config{po_link_to} ||
 144             ! defined $config{po_link_to}) {
 145                 $config{po_link_to}='default';
 146         }
 147         elsif ($config{po_link_to} !~ /^(default|current|negotiated)$/) {
 148                 warn(sprintf(gettext('%s is not a valid value for po_link_to, falling back to po_link_to=default'),
 149                              $config{po_link_to}));
 150                 $config{po_link_to}='default';
 151         }
 152         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 153                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 154                 $config{po_link_to}='default';
 155         }
 156
 157         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 158
 159         # Translated versions of the underlays are added if available.
 160         foreach my $underlay ("basewiki",
 161                               map { m/^\Q$config{underlaydirbase}\E\/*(.*)/ }
 162                                   reverse @{$config{underlaydirs}}) {
 163                 next if $underlay=~/^locale\//;
 164
 165                 # Underlays containing the po files for slave languages.
 166                 foreach my $ll (keys %{$config{po_slave_languages}}) {
 167                         add_underlay("po/$ll/$underlay")
 168                                 if -d "$config{underlaydirbase}/po/$ll/$underlay";
 169                 }
 170
 171                 if ($config{po_master_language}{code} ne 'en') {
 172                         # Add underlay containing translated source files
 173                         # for the master language.
 174                         add_underlay("locale/$config{po_master_language}{code}/$underlay");
 175                 }
 176         }
 177 }
 178
 179 sub needsbuild () {
 180         my $needsbuild=shift;
 181
 182         # backup @needsbuild content so that change() can know whether
 183         # a given master page was rendered because its source file was changed
 184         @origneedsbuild=(@$needsbuild);
 185
 186         flushmemoizecache();
 187         buildtranslationscache();
 188
 189         # make existing translations depend on the corresponding master page
 190         foreach my $master (keys %translations) {
 191                 map add_depends($_, $master), values %{otherlanguages($master)};
 192         }
 193 }
 194
 195 # Massage the recorded state of internal links so that:
 196 # - it matches the actually generated links, rather than the links as written
 197 #   in the pages' source
 198 # - backlinks are consistent in all cases
 199 sub scan (@) {
 200         my %params=@_;
 201         my $page=$params{page};
 202         my $content=$params{content};
 203
 204         if (istranslation($page)) {
 205                 foreach my $destpage (@{$links{$page}}) {
 206                         if (istranslatable($destpage)) {
 207                                 # replace one occurence of $destpage in $links{$page}
 208                                 # (we only want to replace the one that was added by
 209                                 # IkiWiki::Plugin::link::scan, other occurences may be
 210                                 # there for other reasons)
 211                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 212                                         if (@{$links{$page}}[$i] eq $destpage) {
 213                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 214                                                 last;
 215                                         }
 216                                 }
 217                         }
 218                 }
 219         }
 220         elsif (! istranslatable($page) && ! istranslation($page)) {
 221                 foreach my $destpage (@{$links{$page}}) {
 222                         if (istranslatable($destpage)) {
 223                                 # make sure any destpage's translations has
 224                                 # $page in its backlinks
 225                                 push @{$links{$page}},
 226                                         values %{otherlanguages($destpage)};
 227                         }
 228                 }
 229         }
 230 }
 231
 232 # We use filter to convert PO to the master page's format,
 233 # since the rest of ikiwiki should not work on PO files.
 234 sub filter (@) {
 235         my %params = @_;
 236
 237         my $page = $params{page};
 238         my $destpage = $params{destpage};
 239         my $content = $params{content};
 240         if (istranslation($page) && ! alreadyfiltered($page, $destpage)) {
 241                 $content = po_to_markup($page, $content);
 242                 setalreadyfiltered($page, $destpage);
 243         }
 244         return $content;
 245 }
 246
 247 sub htmlize (@) {
 248         my %params=@_;
 249
 250         my $page = $params{page};
 251         my $content = $params{content};
 252
 253         # ignore PO files this plugin did not create
 254         return $content unless istranslation($page);
 255
 256         # force content to be htmlize'd as if it was the same type as the master page
 257         return IkiWiki::htmlize($page, $page,
 258                 pagetype(srcfile($pagesources{masterpage($page)})),
 259                 $content);
 260 }
 261
 262 sub pagetemplate (@) {
 263         my %params=@_;
 264         my $page=$params{page};
 265         my $destpage=$params{destpage};
 266         my $template=$params{template};
 267
 268         my ($masterpage, $lang) = istranslation($page);
 269
 270         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 271                 $template->param(percenttranslated => percenttranslated($page));
 272         }
 273         if ($template->query(name => "istranslation")) {
 274                 $template->param(istranslation => scalar istranslation($page));
 275         }
 276         if ($template->query(name => "istranslatable")) {
 277                 $template->param(istranslatable => istranslatable($page));
 278         }
 279         if ($template->query(name => "HOMEPAGEURL")) {
 280                 $template->param(homepageurl => homepageurl($page));
 281         }
 282         if ($template->query(name => "otherlanguages")) {
 283                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 284                 map add_depends($page, $_), (values %{otherlanguages($page)});
 285         }
 286         if ($config{discussion} && istranslation($page)) {
 287                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 288                    (length $config{cgiurl} ||
 289                     exists $links{$masterpage."/".lc($config{discussionpage})})) {
 290                         $template->param('discussionlink' => htmllink(
 291                                 $page,
 292                                 $destpage,
 293                                 $masterpage . '/' . $config{discussionpage},
 294                                 noimageinline => 1,
 295                                 forcesubpage => 0,
 296                                 linktext => $config{discussionpage},
 297                 ));
 298                 }
 299         }
 300         # Remove broken parentlink to ./index.html on home page's translations.
 301         # It works because this hook has the "last" parameter set, to ensure it
 302         # runs after parentlinks' own pagetemplate hook.
 303         if ($template->param('parentlinks')
 304             && istranslation($page)
 305             && $masterpage eq "index") {
 306                 $template->param('parentlinks' => []);
 307         }
 308 } # }}}
 309
 310 # Add the renamed page translations to the list of to-be-renamed pages.
 311 sub renamepages (@) {
 312         my %params = @_;
 313
 314         my %torename = %{$params{torename}};
 315         my $session = $params{session};
 316
 317         # Save the page(s) the user asked to rename, so that our
 318         # canrename hook can tell the difference between:
 319         #  - a translation being renamed as a consequence of its master page
 320         #    being renamed
 321         #  - a user trying to directly rename a translation
 322         # This is why this hook has to be run first, before the list of pages
 323         # to rename is modified by other plugins.
 324         my @orig_torename;
 325         @orig_torename=@{$session->param("po_orig_torename")}
 326                 if defined $session->param("po_orig_torename");
 327         push @orig_torename, $torename{src};
 328         $session->param(po_orig_torename => \@orig_torename);
 329         IkiWiki::cgi_savesession($session);
 330
 331         return () unless istranslatable($torename{src});
 332
 333         my @ret;
 334         my %otherpages=%{otherlanguages($torename{src})};
 335         while (my ($lang, $otherpage) = each %otherpages) {
 336                 push @ret, {
 337                         src => $otherpage,
 338                         srcfile => $pagesources{$otherpage},
 339                         dest => otherlanguage($torename{dest}, $lang),
 340                         destfile => $torename{dest}.".".$lang.".po",
 341                         required => 0,
 342                 };
 343         }
 344         return @ret;
 345 }
 346
 347 sub mydelete (@) {
 348         my @deleted=@_;
 349
 350         map { deletetranslations($_) } grep istranslatablefile($_), @deleted;
 351 }
 352
 353 sub change (@) {
 354         my @rendered=@_;
 355
 356         # All meta titles are first extracted at scan time, i.e. before we turn
 357         # PO files back into translated markdown; escaping of double-quotes in
 358         # PO files breaks the meta plugin's parsing enough to save ugly titles
 359         # to %pagestate at this time.
 360         #
 361         # Then, at render time, every page passes in turn through the Great
 362         # Rendering Chain (filter->preprocess->linkify->htmlize), and the meta
 363         # plugin's preprocess hook is this time in a position to correctly
 364         # extract the titles from slave pages.
 365         #
 366         # This is, unfortunately, too late: if the page A, linking to the page
 367         # B, is rendered before B, it will display the wrongly-extracted meta
 368         # title as the link text to B.
 369         #
 370         # On the one hand, such a corner case only happens on rebuild: on
 371         # refresh, every rendered page is fixed to contain correct meta titles.
 372         # On the other hand, it can take some time to get every page fixed.
 373         # We therefore re-render every rendered page after a rebuild to fix them
 374         # at once. As this more or less doubles the time needed to rebuild the
 375         # wiki, we do so only when really needed.
 376
 377         if (@rendered
 378             && exists $config{rebuild} && defined $config{rebuild} && $config{rebuild}
 379             && UNIVERSAL::can("IkiWiki::Plugin::meta", "getsetup")
 380             && exists $config{meta_overrides_page_title}
 381             && defined $config{meta_overrides_page_title}
 382             && $config{meta_overrides_page_title}) {
 383                 debug(sprintf(gettext("rebuilding all pages to fix meta titles")));
 384                 resetalreadyfiltered();
 385                 require IkiWiki::Render;
 386                 foreach my $file (@rendered) {
 387                         debug(sprintf(gettext("building %s"), $file));
 388                         IkiWiki::render($file);
 389                 }
 390         }
 391
 392         my $updated_po_files=0;
 393
 394         # Refresh/create POT and PO files as needed.
 395         # (But avoid doing so if they are in an underlay directory.)
 396         foreach my $file (grep {istranslatablefile($_)} @rendered) {
 397                 my $masterfile=srcfile($file);
 398                 my $page=pagename($file);
 399                 my $updated_pot_file=0;
 400                 # Only refresh POT file if it does not exist, or if
 401                 # $pagesources{$page} was changed: don't if only the HTML was
 402                 # refreshed, e.g. because of a dependency.
 403                 if ($masterfile eq "$config{srcdir}/$file" &&
 404                    ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 405                     || ! -e potfile($masterfile))) {
 406                         refreshpot($masterfile);
 407                         $updated_pot_file=1;
 408                 }
 409                 my @pofiles;
 410                 foreach my $po (pofiles($masterfile)) {
 411                         next if ! $updated_pot_file && ! -e $po;
 412                         next if grep { $po=~/\Q$_\E/ } @{$config{underlaydirs}};
 413                         push @pofiles, $po;
 414                 }
 415                 if (@pofiles) {
 416                         refreshpofiles($masterfile, @pofiles);
 417                         map { s/^\Q$config{srcdir}\E\/*//; IkiWiki::rcs_add($_) } @pofiles if $config{rcs};
 418                         $updated_po_files=1;
 419                 }
 420         }
 421
 422         if ($updated_po_files) {
 423                 commit_and_refresh(
 424                         gettext("updated PO files"),
 425                         "IkiWiki::Plugin::po::change");
 426         }
 427 }
 428
 429 sub checkcontent (@) {
 430         my %params=@_;
 431
 432         if (istranslation($params{page})) {
 433                 my $res = isvalidpo($params{content});
 434                 if ($res) {
 435                         return undef;
 436                 }
 437                 else {
 438                         return "$res";
 439                 }
 440         }
 441         return undef;
 442 }
 443
 444 sub canremove (@) {
 445         my %params = @_;
 446
 447         if (istranslation($params{page})) {
 448                 return gettext("Can not remove a translation. If the master page is removed, ".
 449                                "however, its translations will be removed as well.");
 450         }
 451         return undef;
 452 }
 453
 454 sub canrename (@) {
 455         my %params = @_;
 456         my $session = $params{session};
 457
 458         if (istranslation($params{src})) {
 459                 my $masterpage = masterpage($params{src});
 460                 # Tell the difference between:
 461                 #  - a translation being renamed as a consequence of its master page
 462                 #    being renamed, which is allowed
 463                 #  - a user trying to directly rename a translation, which is forbidden
 464                 # by looking for the master page in the list of to-be-renamed pages we
 465                 # saved early in the renaming process.
 466                 my $orig_torename = $session->param("po_orig_torename");
 467                 unless (grep { $_ eq $masterpage } @{$orig_torename}) {
 468                         return gettext("Can not rename a translation. If the master page is renamed, ".
 469                                        "however, its translations will be renamed as well.");
 470                 }
 471         }
 472         return undef;
 473 }
 474
 475 # As we're previewing or saving a page, the content may have
 476 # changed, so tell the next filter() invocation it must not be lazy.
 477 sub editcontent () {
 478         my %params=@_;
 479
 480         unsetalreadyfiltered($params{page}, $params{page});
 481         return $params{content};
 482 }
 483
 484 sub formbuilder_setup (@) {
 485         my %params=@_;
 486         my $form=$params{form};
 487         my $q=$params{cgi};
 488
 489         return unless defined $form->field("do");
 490
 491         if ($form->field("do") eq "create") {
 492                 # Warn the user: new pages must be written in master language.
 493                 my $template=template("pocreatepage.tmpl");
 494                 $template->param(LANG => $config{po_master_language}{name});
 495                 $form->tmpl_param(message => $template->output);
 496         }
 497         elsif ($form->field("do") eq "edit") {
 498                 # Remove the rename/remove buttons on slave pages.
 499                 # This has to be done after the rename/remove plugins have added
 500                 # their buttons, which is why this hook must be run last.
 501                 # The canrename/canremove hooks already ensure this is forbidden
 502                 # at the backend level, so this is only UI sugar.
 503                 if (istranslation($form->field("page"))) {
 504                         map {
 505                                 for (my $i = 0; $i < @{$params{buttons}}; $i++) {
 506                                         if (@{$params{buttons}}[$i] eq $_) {
 507                                                 delete  @{$params{buttons}}[$i];
 508                                                 last;
 509                                         }
 510                                 }
 511                         } qw(Rename Remove);
 512                 }
 513         }
 514 }
 515
 516 sub formbuilder (@) {
 517         my %params=@_;
 518         my $form=$params{form};
 519         my $q=$params{cgi};
 520
 521         return unless defined $form->field("do");
 522
 523         # Do not allow to create pages of type po: they are automatically created.
 524         # The main reason to do so is to bypass the "favor the type of linking page
 525         # on page creation" logic, which is unsuitable when a broken link is clicked
 526         # on a slave (PO) page.
 527         # This cannot be done in the formbuilder_setup hook as the list of types is
 528         # computed later.
 529         if ($form->field("do") eq "create") {
 530                 foreach my $field ($form->field) {
 531                         next unless "$field" eq "type";
 532                         if ($field->type eq 'select') {
 533                                 # remove po from the list of types
 534                                 my @types = grep { $_ ne 'po' } $field->options;
 535                                 $field->options(\@types) if @types;
 536                         }
 537                 }
 538         }
 539 }
 540
 541 # ,----
 542 # | Injected functions
 543 # `----
 544
 545 # Implement po_link_to 'current' and 'negotiated' settings.
 546 sub mybestlink ($$) {
 547         my $page=shift;
 548         my $link=shift;
 549
 550         return $origsubs{'bestlink'}->($page, $link)
 551                 if $config{po_link_to} eq "default";
 552
 553         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 554         if (length $res
 555             && ($config{po_link_to} eq "current" || $config{po_link_to} eq "negotiated")
 556             && istranslatable($res)
 557             && istranslation($page)) {
 558                 return $res . "." . lang($page);
 559         }
 560         return $res;
 561 }
 562
 563 sub mybeautify_urlpath ($) {
 564         my $url=shift;
 565
 566         my $res=$origsubs{'beautify_urlpath'}->($url);
 567         if ($config{po_link_to} eq "negotiated") {
 568                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 569                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 570                 map {
 571                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 572                 } (keys %{$config{po_slave_languages}});
 573         }
 574         return $res;
 575 }
 576
 577 sub mytargetpage ($$) {
 578         my $page=shift;
 579         my $ext=shift;
 580
 581         if (istranslation($page) || istranslatable($page)) {
 582                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 583                 if (! $config{usedirs} || $masterpage eq 'index') {
 584                         return $masterpage . "." . $lang . "." . $ext;
 585                 }
 586                 else {
 587                         return $masterpage . "/index." . $lang . "." . $ext;
 588                 }
 589         }
 590         return $origsubs{'targetpage'}->($page, $ext);
 591 }
 592
 593 sub myurlto ($$;$) {
 594         my $to=shift;
 595         my $from=shift;
 596         my $absolute=shift;
 597
 598         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 599         if (! length $to
 600             && $config{po_link_to} eq "current"
 601             && istranslatable('index')) {
 602                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 603         }
 604         # avoid using our injected beautify_urlpath if run by cgi_editpage,
 605         # so that one is redirected to the just-edited page rather than to the
 606         # negociated translation; to prevent unnecessary fiddling with caller/inject,
 607         # we only do so when our beautify_urlpath would actually do what we want to
 608         # avoid, i.e. when po_link_to = negotiated
 609         if ($config{po_link_to} eq "negotiated") {
 610                 my @caller = caller(1);
 611                 my $run_by_editpage = 0;
 612                 $run_by_editpage = 1 if (exists $caller[3] && defined $caller[3]
 613                                          && $caller[3] eq "IkiWiki::cgi_editpage");
 614                 inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'})
 615                         if $run_by_editpage;
 616                 my $res = $origsubs{'urlto'}->($to,$from,$absolute);
 617                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath)
 618                         if $run_by_editpage;
 619                 return $res;
 620         }
 621         else {
 622                 return $origsubs{'urlto'}->($to,$from,$absolute)
 623         }
 624 }
 625
 626 sub mycgiurl (@) {
 627         my %params=@_;
 628
 629         # slave pages have no subpages
 630         if (istranslation($params{'from'})) {
 631                 $params{'from'} = masterpage($params{'from'});
 632         }
 633         return $origsubs{'cgiurl'}->(%params);
 634 }
 635
 636 # ,----
 637 # | Blackboxes for private data
 638 # `----
 639
 640 {
 641         my %filtered;
 642
 643         sub alreadyfiltered($$) {
 644                 my $page=shift;
 645                 my $destpage=shift;
 646
 647                 return exists $filtered{$page}{$destpage}
 648                          && $filtered{$page}{$destpage} eq 1;
 649         }
 650
 651         sub setalreadyfiltered($$) {
 652                 my $page=shift;
 653                 my $destpage=shift;
 654
 655                 $filtered{$page}{$destpage}=1;
 656         }
 657
 658         sub unsetalreadyfiltered($$) {
 659                 my $page=shift;
 660                 my $destpage=shift;
 661
 662                 if (exists $filtered{$page}{$destpage}) {
 663                         delete $filtered{$page}{$destpage};
 664                 }
 665         }
 666
 667         sub resetalreadyfiltered() {
 668                 undef %filtered;
 669         }
 670 }
 671
 672 # ,----
 673 # | Helper functions
 674 # `----
 675
 676 sub maybe_add_leading_slash ($;$) {
 677         my $str=shift;
 678         my $add=shift;
 679         $add=1 unless defined $add;
 680         return '/' . $str if $add;
 681         return $str;
 682 }
 683
 684 sub istranslatablefile ($) {
 685         my $file=shift;
 686
 687         return 0 unless defined $file;
 688         my $type=pagetype($file);
 689         return 0 if ! defined $type || $type eq 'po';
 690         return 0 if $file =~ /\.pot$/;
 691         return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
 692         return;
 693 }
 694
 695 sub istranslatable ($) {
 696         my $page=shift;
 697
 698         $page=~s#^/##;
 699         return 1 if istranslatablefile($pagesources{$page});
 700         return;
 701 }
 702
 703 sub _istranslation ($) {
 704         my $page=shift;
 705
 706         $page='' unless defined $page && length $page;
 707         my $hasleadingslash = ($page=~s#^/##);
 708         my $file=$pagesources{$page};
 709         return 0 unless defined $file
 710                          && defined pagetype($file)
 711                          && pagetype($file) eq 'po';
 712         return 0 if $file =~ /\.pot$/;
 713
 714         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 715         return 0 unless defined $masterpage && defined $lang
 716                          && length $masterpage && length $lang
 717                          && defined $pagesources{$masterpage}
 718                          && defined $config{po_slave_languages}{$lang};
 719
 720         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 721                 if istranslatable($masterpage);
 722 }
 723
 724 sub istranslation ($) {
 725         my $page=shift;
 726
 727         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 728                 my $hasleadingslash = ($masterpage=~s#^/##);
 729                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 730                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 731         }
 732         return "";
 733 }
 734
 735 sub masterpage ($) {
 736         my $page=shift;
 737
 738         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 739                 return $masterpage;
 740         }
 741         return $page;
 742 }
 743
 744 sub lang ($) {
 745         my $page=shift;
 746
 747         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 748                 return $lang;
 749         }
 750         return $config{po_master_language}{code};
 751 }
 752
 753 sub islanguagecode ($) {
 754         my $code=shift;
 755
 756         return $code =~ /^[a-z]{2}$/;
 757 }
 758
 759 sub otherlanguage ($$) {
 760         my $page=shift;
 761         my $code=shift;
 762
 763         return masterpage($page) if $code eq $config{po_master_language}{code};
 764         return masterpage($page) . '.' . $code;
 765 }
 766
 767 sub otherlanguages ($) {
 768         my $page=shift;
 769
 770         my %ret;
 771         return \%ret unless istranslation($page) || istranslatable($page);
 772         my $curlang=lang($page);
 773         foreach my $lang
 774                 ($config{po_master_language}{code}, keys %{$config{po_slave_languages}}) {
 775                 next if $lang eq $curlang;
 776                 $ret{$lang}=otherlanguage($page, $lang);
 777         }
 778         return \%ret;
 779 }
 780
 781 sub potfile ($) {
 782         my $masterfile=shift;
 783
 784         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 785         $dir='' if $dir eq './';
 786         return File::Spec->catpath('', $dir, $name . ".pot");
 787 }
 788
 789 sub pofile ($$) {
 790         my $masterfile=shift;
 791         my $lang=shift;
 792
 793         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 794         $dir='' if $dir eq './';
 795         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 796 }
 797
 798 sub pofiles ($) {
 799         my $masterfile=shift;
 800
 801         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 802 }
 803
 804 sub refreshpot ($) {
 805         my $masterfile=shift;
 806
 807         my $potfile=potfile($masterfile);
 808         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 809         my $doc=Locale::Po4a::Chooser::new('text',%options);
 810         $doc->{TT}{utf_mode} = 1;
 811         $doc->{TT}{file_in_charset} = 'utf-8';
 812         $doc->{TT}{file_out_charset} = 'utf-8';
 813         $doc->read($masterfile);
 814         # let's cheat a bit to force porefs option to be passed to
 815         # Locale::Po4a::Po; this is undocument use of internal
 816         # Locale::Po4a::TransTractor's data, compulsory since this module
 817         # prevents us from using the porefs option.
 818         $doc->{TT}{po_out}=Locale::Po4a::Po->new({ 'porefs' => 'none' });
 819         $doc->{TT}{po_out}->set_charset('utf-8');
 820         # do the actual work
 821         $doc->parse;
 822         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 823         $doc->writepo($potfile);
 824 }
 825
 826 sub refreshpofiles ($@) {
 827         my $masterfile=shift;
 828         my @pofiles=@_;
 829
 830         my $potfile=potfile($masterfile);
 831         if (! -e $potfile) {
 832                 error("po(refreshpofiles) ".sprintf(gettext("POT file (%s) does not exist"), $potfile));
 833         }
 834
 835         foreach my $pofile (@pofiles) {
 836                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 837
 838                 if (! -e $pofile) {
 839                         # If the po file exists in an underlay, copy it
 840                         # from there.
 841                         my ($pobase)=$pofile=~/^\Q$config{srcdir}\E\/?(.*)$/;
 842                         foreach my $dir (@{$config{underlaydirs}}) {
 843                                 if (-e "$dir/$pobase") {
 844                                         File::Copy::syscopy("$dir/$pobase",$pofile)
 845                                                 or error("po(refreshpofiles) ".
 846                                                          sprintf(gettext("failed to copy underlay PO file to %s"),
 847                                                                  $pofile));
 848                                 }
 849                         }
 850                 }
 851
 852                 if (-e $pofile) {
 853                         system("msgmerge", "--previous", "-q", "-U", "--backup=none", $pofile, $potfile) == 0
 854                                 or error("po(refreshpofiles) ".
 855                                          sprintf(gettext("failed to update %s"),
 856                                                  $pofile));
 857                 }
 858                 else {
 859                         File::Copy::syscopy($potfile,$pofile)
 860                                 or error("po(refreshpofiles) ".
 861                                          sprintf(gettext("failed to copy the POT file to %s"),
 862                                                  $pofile));
 863                 }
 864         }
 865 }
 866
 867 sub buildtranslationscache() {
 868         # use istranslation's side-effect
 869         map istranslation($_), (keys %pagesources);
 870 }
 871
 872 sub resettranslationscache() {
 873         undef %translations;
 874 }
 875
 876 sub flushmemoizecache() {
 877         Memoize::flush_cache("istranslatable");
 878         Memoize::flush_cache("_istranslation");
 879         Memoize::flush_cache("percenttranslated");
 880 }
 881
 882 sub urlto_with_orig_beautiful_urlpath($$) {
 883         my $to=shift;
 884         my $from=shift;
 885
 886         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 887         my $res=urlto($to, $from);
 888         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 889
 890         return $res;
 891 }
 892
 893 sub percenttranslated ($) {
 894         my $page=shift;
 895
 896         $page=~s/^\///;
 897         return gettext("N/A") unless istranslation($page);
 898         my $file=srcfile($pagesources{$page});
 899         my $masterfile = srcfile($pagesources{masterpage($page)});
 900         my %options = (
 901                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 902         );
 903         my $doc=Locale::Po4a::Chooser::new('text',%options);
 904         $doc->process(
 905                 'po_in_name'    => [ $file ],
 906                 'file_in_name'  => [ $masterfile ],
 907                 'file_in_charset'  => 'utf-8',
 908                 'file_out_charset' => 'utf-8',
 909         ) or error("po(percenttranslated) ".
 910                    sprintf(gettext("failed to translate %s"), $page));
 911         my ($percent,$hit,$queries) = $doc->stats();
 912         $percent =~ s/\.[0-9]+$//;
 913         return $percent;
 914 }
 915
 916 sub languagename ($) {
 917         my $code=shift;
 918
 919         return $config{po_master_language}{name}
 920                 if $code eq $config{po_master_language}{code};
 921         return $config{po_slave_languages}{$code}
 922                 if defined $config{po_slave_languages}{$code};
 923         return;
 924 }
 925
 926 sub otherlanguagesloop ($) {
 927         my $page=shift;
 928
 929         my @ret;
 930         my %otherpages=%{otherlanguages($page)};
 931         while (my ($lang, $otherpage) = each %otherpages) {
 932                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 933                         push @ret, {
 934                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 935                                 code => $lang,
 936                                 language => languagename($lang),
 937                                 master => 1,
 938                         };
 939                 }
 940                 elsif (istranslation($otherpage)) {
 941                         push @ret, {
 942                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 943                                 code => $lang,
 944                                 language => languagename($lang),
 945                                 percent => percenttranslated($otherpage),
 946                         }
 947                 }
 948         }
 949         return sort {
 950                 return -1 if $a->{code} eq $config{po_master_language}{code};
 951                 return 1 if $b->{code} eq $config{po_master_language}{code};
 952                 return $a->{language} cmp $b->{language};
 953         } @ret;
 954 }
 955
 956 sub homepageurl (;$) {
 957         my $page=shift;
 958
 959         return urlto('', $page);
 960 }
 961
 962 sub deletetranslations ($) {
 963         my $deletedmasterfile=shift;
 964
 965         my $deletedmasterpage=pagename($deletedmasterfile);
 966         my @todelete;
 967         map {
 968                 my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
 969                 my $absfile = "$config{srcdir}/$file";
 970                 if (-e $absfile && ! -l $absfile && ! -d $absfile) {
 971                         push @todelete, $file;
 972                 }
 973         } keys %{$config{po_slave_languages}};
 974
 975         map {
 976                 if ($config{rcs}) {
 977                         IkiWiki::rcs_remove($_);
 978                 }
 979                 else {
 980                         IkiWiki::prune("$config{srcdir}/$_");
 981                 }
 982         } @todelete;
 983
 984         if (@todelete) {
 985                 commit_and_refresh(
 986                         gettext("removed obsolete PO files"),
 987                         "IkiWiki::Plugin::po::deletetranslations");
 988         }
 989 }
 990
 991 sub commit_and_refresh ($$) {
 992         my ($msg, $author) = (shift, shift);
 993
 994         if ($config{rcs}) {
 995                 IkiWiki::disable_commit_hook();
 996                 IkiWiki::rcs_commit_staged($msg, $author, "127.0.0.1");
 997                 IkiWiki::enable_commit_hook();
 998                 IkiWiki::rcs_update();
 999         }
1000         # Reinitialize module's private variables.
1001         resetalreadyfiltered();
1002         resettranslationscache();
1003         flushmemoizecache();
1004         # Trigger a wiki refresh.
1005         require IkiWiki::Render;
1006         # without preliminary saveindex/loadindex, refresh()
1007         # complains about a lot of uninitialized variables
1008         IkiWiki::saveindex();
1009         IkiWiki::loadindex();
1010         IkiWiki::refresh();
1011         IkiWiki::saveindex();
1012 }
1013
1014 # on success, returns the filtered content.
1015 # on error, if $nonfatal, warn and return undef; else, error out.
1016 sub po_to_markup ($$;$) {
1017         my ($page, $content) = (shift, shift);
1018         my $nonfatal = shift;
1019
1020         $content = '' unless defined $content;
1021         $content = decode_utf8(encode_utf8($content));
1022         # CRLF line terminators make poor Locale::Po4a feel bad
1023         $content=~s/\r\n/\n/g;
1024
1025         # There are incompatibilities between some File::Temp versions
1026         # (including 0.18, bundled with Lenny's perl-modules package)
1027         # and others (e.g. 0.20, previously present in the archive as
1028         # a standalone package): under certain circumstances, some
1029         # return a relative filename, whereas others return an absolute one;
1030         # we here use this module in a way that is at least compatible
1031         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1032         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
1033                                     DIR => File::Spec->tmpdir,
1034                                     UNLINK => 1)->filename;
1035         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
1036                                      DIR => File::Spec->tmpdir,
1037                                      UNLINK => 1)->filename;
1038
1039         my $fail = sub ($) {
1040                 my $msg = "po(po_to_markup) - $page : " . shift;
1041                 if ($nonfatal) {
1042                         warn $msg;
1043                         return undef;
1044                 }
1045                 error($msg, sub { unlink $infile, $outfile});
1046         };
1047
1048         writefile(basename($infile), File::Spec->tmpdir, $content)
1049                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1050
1051         my $masterfile = srcfile($pagesources{masterpage($page)});
1052         my %options = (
1053                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
1054         );
1055         my $doc=Locale::Po4a::Chooser::new('text',%options);
1056         $doc->process(
1057                 'po_in_name'    => [ $infile ],
1058                 'file_in_name'  => [ $masterfile ],
1059                 'file_in_charset'  => 'utf-8',
1060                 'file_out_charset' => 'utf-8',
1061         ) or return $fail->(gettext("failed to translate"));
1062         $doc->write($outfile)
1063                 or return $fail->(sprintf(gettext("failed to write %s"), $outfile));
1064
1065         $content = readfile($outfile)
1066                 or return $fail->(sprintf(gettext("failed to read %s"), $outfile));
1067
1068         # Unlinking should happen automatically, thanks to File::Temp,
1069         # but it does not work here, probably because of the way writefile()
1070         # and Locale::Po4a::write() work.
1071         unlink $infile, $outfile;
1072
1073         return $content;
1074 }
1075
1076 # returns a SuccessReason or FailReason object
1077 sub isvalidpo ($) {
1078         my $content = shift;
1079
1080         # NB: we don't use po_to_markup here, since Po4a parser does
1081         # not mind invalid PO content
1082         $content = '' unless defined $content;
1083         $content = decode_utf8(encode_utf8($content));
1084
1085         # There are incompatibilities between some File::Temp versions
1086         # (including 0.18, bundled with Lenny's perl-modules package)
1087         # and others (e.g. 0.20, previously present in the archive as
1088         # a standalone package): under certain circumstances, some
1089         # return a relative filename, whereas others return an absolute one;
1090         # we here use this module in a way that is at least compatible
1091         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1092         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-isvalidpo.XXXXXXXXXX",
1093                                     DIR => File::Spec->tmpdir,
1094                                     UNLINK => 1)->filename;
1095
1096         my $fail = sub ($) {
1097                 my $msg = '[po/isvalidpo] ' . shift;
1098                 unlink $infile;
1099                 return IkiWiki::FailReason->new("$msg");
1100         };
1101
1102         writefile(basename($infile), File::Spec->tmpdir, $content)
1103                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1104
1105         my $res = (system("msgfmt", "--check", $infile, "-o", "/dev/null") == 0);
1106
1107         # Unlinking should happen automatically, thanks to File::Temp,
1108         # but it does not work here, probably because of the way writefile()
1109         # and Locale::Po4a::write() work.
1110         unlink $infile;
1111
1112         if ($res) {
1113             return IkiWiki::SuccessReason->new("valid gettext data");
1114         }
1115         return IkiWiki::FailReason->new(gettext("invalid gettext data, go back ".
1116                                         "to previous page to continue edit"));
1117 }
1118
1119 # ,----
1120 # | PageSpecs
1121 # `----
1122
1123 package IkiWiki::PageSpec;
1124
1125 sub match_istranslation ($;@) {
1126         my $page=shift;
1127
1128         if (IkiWiki::Plugin::po::istranslation($page)) {
1129                 return IkiWiki::SuccessReason->new("is a translation page");
1130         }
1131         else {
1132                 return IkiWiki::FailReason->new("is not a translation page");
1133         }
1134 }
1135
1136 sub match_istranslatable ($;@) {
1137         my $page=shift;
1138
1139         if (IkiWiki::Plugin::po::istranslatable($page)) {
1140                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
1141         }
1142         else {
1143                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
1144         }
1145 }
1146
1147 sub match_lang ($$;@) {
1148         my $page=shift;
1149         my $wanted=shift;
1150
1151         my $regexp=IkiWiki::glob2re($wanted);
1152         my $lang=IkiWiki::Plugin::po::lang($page);
1153         if ($lang !~ /^$regexp$/i) {
1154                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
1155         }
1156         else {
1157                 return IkiWiki::SuccessReason->new("file language is $wanted");
1158         }
1159 }
1160
1161 sub match_currentlang ($$;@) {
1162         my $page=shift;
1163         shift;
1164         my %params=@_;
1165
1166         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
1167
1168         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
1169         my $lang=IkiWiki::Plugin::po::lang($page);
1170
1171         if ($lang eq $currentlang) {
1172                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
1173         }
1174         else {
1175                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
1176         }
1177 }
1178
1179 1