IkiWiki/Plugin/meta.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki metadata plugin.
   3 package IkiWiki::Plugin::meta;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8
   9 my %metaheaders;
  10
  11 sub import {
  12         hook(type => "getsetup", id => "meta", call => \&getsetup);
  13         hook(type => "needsbuild", id => "meta", call => \&needsbuild);
  14         hook(type => "preprocess", id => "meta", call => \&preprocess, scan => 1);
  15         hook(type => "pagetemplate", id => "meta", call => \&pagetemplate);
  16 }
  17
  18 sub getsetup () {
  19         return
  20                 plugin => {
  21                         safe => 1,
  22                         rebuild => undef,
  23                         section => "core",
  24                 },
  25 }
  26
  27 sub needsbuild (@) {
  28         my $needsbuild=shift;
  29         foreach my $page (keys %pagestate) {
  30                 if (exists $pagestate{$page}{meta}) {
  31                         if (exists $pagesources{$page} &&
  32                             grep { $_ eq $pagesources{$page} } @$needsbuild) {
  33                                 # remove state, it will be re-added
  34                                 # if the preprocessor directive is still
  35                                 # there during the rebuild
  36                                 delete $pagestate{$page}{meta};
  37                         }
  38                 }
  39         }
  40         return $needsbuild;
  41 }
  42
  43 sub scrub ($$$) {
  44         if (IkiWiki::Plugin::htmlscrubber->can("sanitize")) {
  45                 return IkiWiki::Plugin::htmlscrubber::sanitize(
  46                         content => shift, page => shift, destpage => shift);
  47         }
  48         else {
  49                 return shift;
  50         }
  51 }
  52
  53 sub safeurl ($) {
  54         my $url=shift;
  55         if (exists $IkiWiki::Plugin::htmlscrubber::{safe_url_regexp} &&
  56             defined $IkiWiki::Plugin::htmlscrubber::safe_url_regexp) {
  57                 return $url=~/$IkiWiki::Plugin::htmlscrubber::safe_url_regexp/;
  58         }
  59         else {
  60                 return 1;
  61         }
  62 }
  63
  64 sub htmlize ($$$) {
  65         my $page = shift;
  66         my $destpage = shift;
  67
  68         return IkiWiki::htmlize($page, $destpage, pagetype($pagesources{$page}),
  69                 IkiWiki::linkify($page, $destpage,
  70                 IkiWiki::preprocess($page, $destpage, shift)));
  71 }
  72
  73 sub preprocess (@) {
  74         return "" unless @_;
  75         my %params=@_;
  76         my $key=shift;
  77         my $value=$params{$key};
  78         delete $params{$key};
  79         my $page=$params{page};
  80         delete $params{page};
  81         my $destpage=$params{destpage};
  82         delete $params{destpage};
  83         delete $params{preview};
  84
  85         eval q{use HTML::Entities};
  86         # Always decode, even if encoding later, since it might not be
  87         # fully encoded.
  88         $value=decode_entities($value);
  89
  90         # Metadata collection that needs to happen during the scan pass.
  91         if ($key eq 'title') {
  92                 $pagestate{$page}{meta}{title}=$value;
  93                 if (exists $params{sortas}) {
  94                         $pagestate{$page}{meta}{titlesort}=$params{sortas};
  95                 }
  96                 else {
  97                         delete $pagestate{$page}{meta}{titlesort};
  98                 }
  99                 return "";
 100         }
 101         elsif ($key eq 'description') {
 102                 $pagestate{$page}{meta}{description}=$value;
 103                 # fallthrough
 104         }
 105         elsif ($key eq 'guid') {
 106                 $pagestate{$page}{meta}{guid}=$value;
 107                 # fallthrough
 108         }
 109         elsif ($key eq 'license') {
 110                 push @{$metaheaders{$page}}, '<link rel="license" href="#pagelicense" />';
 111                 $pagestate{$page}{meta}{license}=$value;
 112                 return "";
 113         }
 114         elsif ($key eq 'copyright') {
 115                 push @{$metaheaders{$page}}, '<link rel="copyright" href="#pagecopyright" />';
 116                 $pagestate{$page}{meta}{copyright}=$value;
 117                 return "";
 118         }
 119         elsif ($key eq 'link' && ! %params) {
 120                 # hidden WikiLink
 121                 add_link($page, $value);
 122                 return "";
 123         }
 124         elsif ($key eq 'enclosure') {
 125                 my $link=bestlink($page, $value);
 126                 if (! length $link) {
 127                         error gettext("enclosure not found")
 128                 }
 129                 add_depends($page, $link, deptype("presence"));
 130
 131                 $value=urlto($link, $page, 1);
 132                 $pagestate{$page}{meta}{enclosure}=$value;
 133                 $pagestate{$page}{meta}{enclosurefile}=$link;
 134                 # fallthrough
 135         }
 136         elsif ($key eq 'author') {
 137                 $pagestate{$page}{meta}{author}=$value;
 138                 if (exists $params{sortas}) {
 139                         $pagestate{$page}{meta}{authorsort}=$params{sortas};
 140                 }
 141                 else {
 142                         delete $pagestate{$page}{meta}{authorsort};
 143                 }
 144                 # fallthorough
 145         }
 146         elsif ($key eq 'authorurl') {
 147                 $pagestate{$page}{meta}{authorurl}=$value if safeurl($value);
 148                 # fallthrough
 149         }
 150         elsif ($key eq 'permalink') {
 151                 $pagestate{$page}{meta}{permalink}=$value if safeurl($value);
 152                 # fallthrough
 153         }
 154         elsif ($key eq 'date') {
 155                 eval q{use Date::Parse};
 156                 if (! $@) {
 157                         my $time = str2time($value);
 158                         $IkiWiki::pagectime{$page}=$time if defined $time;
 159                 }
 160         }
 161         elsif ($key eq 'updated') {
 162                 eval q{use Date::Parse};
 163                 if (! $@) {
 164                         my $time = str2time($value);
 165                         $pagestate{$page}{meta}{updated}=$time if defined $time;
 166                 }
 167         }
 168
 169         if (! defined wantarray) {
 170                 # avoid collecting duplicate data during scan pass
 171                 return;
 172         }
 173
 174         # Metadata handling that happens only during preprocessing pass.
 175         if ($key eq 'permalink') {
 176                 if (safeurl($value)) {
 177                         push @{$metaheaders{$page}}, scrub('<link rel="bookmark" href="'.encode_entities($value).'" />', $page, $destpage);
 178                 }
 179         }
 180         elsif ($key eq 'stylesheet') {
 181                 my $rel=exists $params{rel} ? $params{rel} : "alternate stylesheet";
 182                 my $title=exists $params{title} ? $params{title} : $value;
 183                 # adding .css to the value prevents using any old web
 184                 # editable page as a stylesheet
 185                 my $stylesheet=bestlink($page, $value.".css");
 186                 if (! length $stylesheet) {
 187                         error gettext("stylesheet not found")
 188                 }
 189                 push @{$metaheaders{$page}}, scrub('<link href="'.urlto($stylesheet, $page).
 190                         '" rel="'.encode_entities($rel).
 191                         '" title="'.encode_entities($title).
 192                         "\" type=\"text/css\" />", $page, $destpage);
 193         }
 194         elsif ($key eq 'script') {
 195                 my $defer=exists $params{defer} ? ' defer="defer"' : '';
 196                 my $async=exists $params{async} ? ' async="async"' : '';
 197                 my $js=bestlink($page, $value.".js");
 198                 if (! length $js) {
 199                         error gettext("script not found");
 200                 }
 201                 push @{$metaheaders{$page}}, scrub('<script src="'.urlto($js, $page).
 202                         '"' . $defer . $async . ' type="text/javascript"></script>',
 203                         $page, $destpage);
 204         }
 205         elsif ($key eq 'openid') {
 206                 my $delegate=0; # both by default
 207                 if (exists $params{delegate}) {
 208                         $delegate = 1 if lc $params{delegate} eq 'openid';
 209                         $delegate = 2 if lc $params{delegate} eq 'openid2';
 210                 }
 211                 if (exists $params{server} && safeurl($params{server})) {
 212                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($params{server}).
 213                                 '" rel="openid.server" />' if $delegate ne 2;
 214                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($params{server}).
 215                                 '" rel="openid2.provider" />' if $delegate ne 1;
 216                 }
 217                 if (safeurl($value)) {
 218                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($value).
 219                                 '" rel="openid.delegate" />' if $delegate ne 2;
 220                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($value).
 221                                 '" rel="openid2.local_id" />' if $delegate ne 1;
 222                 }
 223                 if (exists $params{"xrds-location"} && safeurl($params{"xrds-location"})) {
 224                         # force url absolute
 225                         eval q{use URI};
 226                         error($@) if $@;
 227                         my $url=URI->new_abs($params{"xrds-location"}, $config{url});
 228                         push @{$metaheaders{$page}}, '<meta http-equiv="X-XRDS-Location" '.
 229                                 'content="'.encode_entities($url).'" />';
 230                 }
 231         }
 232         elsif ($key eq 'foaf') {
 233                 if (safeurl($value)) {
 234                         push @{$metaheaders{$page}}, '<link rel="meta" '.
 235                                 'type="application/rdf+xml" title="FOAF" '.
 236                                 'href="'.encode_entities($value).'" />';
 237                 }
 238         }
 239         elsif ($key eq 'redir') {
 240                 return "" if $page ne $destpage;
 241                 my $safe=0;
 242                 if ($value !~ /^\w+:\/\//) {
 243                         my ($redir_page, $redir_anchor) = split /\#/, $value;
 244
 245                         my $link=bestlink($page, $redir_page);
 246                         if (! length $link) {
 247                                 error gettext("redir page not found")
 248                         }
 249                         add_depends($page, $link, deptype("presence"));
 250
 251                         $value=urlto($link, $page);
 252                         $value.='#'.$redir_anchor if defined $redir_anchor;
 253                         $safe=1;
 254
 255                         # redir cycle detection
 256                         $pagestate{$page}{meta}{redir}=$link;
 257                         my $at=$page;
 258                         my %seen;
 259                         while (exists $pagestate{$at}{meta}{redir}) {
 260                                 if ($seen{$at}) {
 261                                         error gettext("redir cycle is not allowed")
 262                                 }
 263                                 $seen{$at}=1;
 264                                 $at=$pagestate{$at}{meta}{redir};
 265                         }
 266                 }
 267                 else {
 268                         $value=encode_entities($value);
 269                 }
 270                 my $delay=int(exists $params{delay} ? $params{delay} : 0);
 271                 my $redir="<meta http-equiv=\"refresh\" content=\"$delay; URL=$value\" />";
 272                 if (! $safe) {
 273                         $redir=scrub($redir, $page, $destpage);
 274                 }
 275                 push @{$metaheaders{$page}}, $redir;
 276         }
 277         elsif ($key eq 'link') {
 278                 if (%params) {
 279                         push @{$metaheaders{$page}}, scrub("<link href=\"".encode_entities($value)."\" ".
 280                                 join(" ", map {
 281                                         encode_entities($_)."=\"".encode_entities(decode_entities($params{$_}))."\""
 282                                 } keys %params).
 283                                 " />\n", $page, $destpage);
 284                 }
 285         }
 286         elsif ($key eq 'robots') {
 287                 push @{$metaheaders{$page}}, '<meta name="robots"'.
 288                         ' content="'.encode_entities($value).'" />';
 289         }
 290         elsif ($key eq 'description' || $key eq 'author') {
 291                 push @{$metaheaders{$page}}, '<meta name="'.$key.
 292                         '" content="'.encode_entities($value).'" />';
 293         }
 294         elsif ($key eq 'name') {
 295                 push @{$metaheaders{$page}}, scrub('<meta name="'.
 296                         encode_entities($value).
 297                         '" '.
 298                         join(' ', map { "$_=\"$params{$_}\"" } keys %params).
 299                         ' />', $page, $destpage);
 300         }
 301         elsif ($key eq 'keywords') {
 302                 # Make sure the keyword string is safe: only allow alphanumeric
 303                 # characters, space and comma and strip the rest.
 304                 $value =~ s/[^[:alnum:], ]+//g;
 305                 push @{$metaheaders{$page}}, '<meta name="keywords"'.
 306                         ' content="'.encode_entities($value).'" />';
 307         }
 308         else {
 309                 push @{$metaheaders{$page}}, scrub('<meta name="'.
 310                         encode_entities($key).'" content="'.
 311                         encode_entities($value).'" />', $page, $destpage);
 312         }
 313
 314         return "";
 315 }
 316
 317 sub pagetemplate (@) {
 318         my %params=@_;
 319         my $page=$params{page};
 320         my $destpage=$params{destpage};
 321         my $template=$params{template};
 322
 323         if (exists $metaheaders{$page} && $template->query(name => "meta")) {
 324                 # avoid duplicate meta lines
 325                 my %seen;
 326                 $template->param(meta => join("\n", grep { (! $seen{$_}) && ($seen{$_}=1) } @{$metaheaders{$page}}));
 327         }
 328         if (exists $pagestate{$page}{meta}{title} && $template->query(name => "title")) {
 329                 eval q{use HTML::Entities};
 330                 $template->param(title => HTML::Entities::encode_numeric($pagestate{$page}{meta}{title}));
 331                 $template->param(title_overridden => 1);
 332         }
 333
 334         if (exists $pagestate{$page}{meta}{enclosure}) {
 335                 $template->param(enclosure => HTML::Entities::encode_entities(IkiWiki::urlabs($pagestate{$page}{meta}{enclosure}, $config{url})));
 336         }
 337
 338         foreach my $field (qw{authorurl}) {
 339                 eval q{use HTML::Entities};
 340                 $template->param($field => HTML::Entities::encode_entities($pagestate{$page}{meta}{$field}))
 341                         if exists $pagestate{$page}{meta}{$field} && $template->query(name => $field);
 342         }
 343
 344         foreach my $field (qw{permalink}) {
 345                 if (exists $pagestate{$page}{meta}{$field} && $template->query(name => $field)) {
 346                         eval q{use HTML::Entities};
 347                         $template->param($field => HTML::Entities::encode_entities(IkiWiki::urlabs($pagestate{$page}{meta}{$field}, $config{url})));
 348                 }
 349         }
 350
 351         foreach my $field (qw{description author}) {
 352                 eval q{use HTML::Entities};
 353                 $template->param($field => HTML::Entities::encode_numeric($pagestate{$page}{meta}{$field}))
 354                         if exists $pagestate{$page}{meta}{$field} && $template->query(name => $field);
 355         }
 356
 357         foreach my $field (qw{license copyright}) {
 358                 if (exists $pagestate{$page}{meta}{$field} && $template->query(name => $field) &&
 359                     ($page eq $destpage || ! exists $pagestate{$destpage}{meta}{$field} ||
 360                      $pagestate{$page}{meta}{$field} ne $pagestate{$destpage}{meta}{$field})) {
 361                         $template->param($field => htmlize($page, $destpage, $pagestate{$page}{meta}{$field}));
 362                 }
 363         }
 364 }
 365
 366 sub get_sort_key {
 367         my $page = shift;
 368         my $meta = shift;
 369
 370         # e.g. titlesort (also makes sense for author)
 371         my $key = $pagestate{$page}{meta}{$meta . "sort"};
 372         return $key if defined $key;
 373
 374         # e.g. title
 375         $key = $pagestate{$page}{meta}{$meta};
 376         return $key if defined $key;
 377
 378         # fall back to closer-to-core things
 379         if ($meta eq 'title') {
 380                 return pagetitle(IkiWiki::basename($page));
 381         }
 382         elsif ($meta eq 'date') {
 383                 return $IkiWiki::pagectime{$page};
 384         }
 385         elsif ($meta eq 'updated') {
 386                 return $IkiWiki::pagemtime{$page};
 387         }
 388         else {
 389                 return '';
 390         }
 391 }
 392
 393 sub match {
 394         my $field=shift;
 395         my $page=shift;
 396
 397         # turn glob into a safe regexp
 398         my $re=IkiWiki::glob2re(shift);
 399
 400         my $val;
 401         if (exists $pagestate{$page}{meta}{$field}) {
 402                 $val=$pagestate{$page}{meta}{$field};
 403         }
 404         elsif ($field eq 'title') {
 405                 $val = pagetitle($page);
 406         }
 407
 408         if (defined $val) {
 409                 if ($val=~$re) {
 410                         return IkiWiki::SuccessReason->new("$re matches $field of $page", $page => $IkiWiki::DEPEND_CONTENT, "" => 1);
 411                 }
 412                 else {
 413                         return IkiWiki::FailReason->new("$re does not match $field of $page", $page => $IkiWiki::DEPEND_CONTENT, "" => 1);
 414                 }
 415         }
 416         else {
 417                 return IkiWiki::FailReason->new("$page does not have a $field", $page => $IkiWiki::DEPEND_CONTENT);
 418         }
 419 }
 420
 421 package IkiWiki::PageSpec;
 422
 423 sub match_title ($$;@) {
 424         IkiWiki::Plugin::meta::match("title", @_);
 425 }
 426
 427 sub match_author ($$;@) {
 428         IkiWiki::Plugin::meta::match("author", @_);
 429 }
 430
 431 sub match_authorurl ($$;@) {
 432         IkiWiki::Plugin::meta::match("authorurl", @_);
 433 }
 434
 435 sub match_license ($$;@) {
 436         IkiWiki::Plugin::meta::match("license", @_);
 437 }
 438
 439 sub match_copyright ($$;@) {
 440         IkiWiki::Plugin::meta::match("copyright", @_);
 441 }
 442
 443 sub match_guid ($$;@) {
 444         IkiWiki::Plugin::meta::match("guid", @_);
 445 }
 446
 447 package IkiWiki::SortSpec;
 448
 449 sub cmp_meta {
 450         my $meta = shift;
 451         error(gettext("sort=meta requires a parameter")) unless defined $meta;
 452
 453         if ($meta eq 'updated' || $meta eq 'date') {
 454                 return IkiWiki::Plugin::meta::get_sort_key($a, $meta)
 455                         <=>
 456                         IkiWiki::Plugin::meta::get_sort_key($b, $meta);
 457         }
 458
 459         return IkiWiki::Plugin::meta::get_sort_key($a, $meta)
 460                 cmp
 461                 IkiWiki::Plugin::meta::get_sort_key($b, $meta);
 462 }
 463
 464 # A prototype of how sort=title could behave in 4.0 or something
 465 sub cmp_meta_title {
 466         $_[0] = 'title';
 467         return cmp_meta(@_);
 468 }
 469
 470 1