projects / git.ikiwiki.info.git / blob

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9
  10 sub linkify ($$$) { #{{{
  11         my $lpage=shift;
  12         my $page=shift;
  13         my $content=shift;
  14
  15         $content =~ s{(\\?)$config{wiki_link_regexp}}{
  16                 $2 ? ( $1 ? "[[$2|$3]]" : htmllink($lpage, $page, titlepage($3), 0, 0, pagetitle($2)))
  17                    : ( $1 ? "[[$3]]" :    htmllink($lpage, $page, titlepage($3)))
  18         }eg;
  19
  20         return $content;
  21 } #}}}
  22
  23 sub htmlize ($$) { #{{{
  24         my $type=shift;
  25         my $content=shift;
  26
  27         if (exists $hooks{htmlize}{$type}) {
  28                 $content=$hooks{htmlize}{$type}{call}->($content);
  29         }
  30         else {
  31                 error("htmlization of $type not supported");
  32         }
  33
  34         if (exists $hooks{sanitize}) {
  35                 foreach my $id (keys %{$hooks{sanitize}}) {
  36                         $content=$hooks{sanitize}{$id}{call}->($content);
  37                 }
  38         }
  39
  40         return $content;
  41 } #}}}
  42
  43 sub backlinks ($) { #{{{
  44         my $page=shift;
  45
  46         my @links;
  47         foreach my $p (keys %links) {
  48                 next if bestlink($page, $p) eq $page;
  49                 if (grep { length $_ && bestlink($p, $_) eq $page } @{$links{$p}}) {
  50                         my $href=abs2rel(htmlpage($p), dirname($page));
  51
  52                         # Trim common dir prefixes from both pages.
  53                         my $p_trimmed=$p;
  54                         my $page_trimmed=$page;
  55                         my $dir;
  56                         1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  57                                 defined $dir &&
  58                                 $p_trimmed=~s/^\Q$dir\E// &&
  59                                 $page_trimmed=~s/^\Q$dir\E//;
  60
  61                         push @links, { url => $href, page => $p_trimmed };
  62                 }
  63         }
  64
  65         return sort { $a->{page} cmp $b->{page} } @links;
  66 } #}}}
  67
  68 sub parentlinks ($) { #{{{
  69         my $page=shift;
  70
  71         my @ret;
  72         my $pagelink="";
  73         my $path="";
  74         my $skip=1;
  75         return if $page eq 'index'; # toplevel
  76         foreach my $dir (reverse split("/", $page)) {
  77                 if (! $skip) {
  78                         $path.="../";
  79                         unshift @ret, { url => "$path$dir.html", page => $dir };
  80                 }
  81                 else {
  82                         $skip=0;
  83                 }
  84         }
  85         unshift @ret, { url => length $path ? $path : ".", page => $config{wikiname} };
  86         return @ret;
  87 } #}}}
  88
  89 sub preprocess ($$;$) { #{{{
  90         my $page=shift;
  91         my $content=shift;
  92         my $onlystrip=shift || 0; # strip directives without processing
  93
  94         my $handle=sub {
  95                 my $escape=shift;
  96                 my $command=shift;
  97                 my $params=shift;
  98                 if (length $escape) {
  99                         return "[[$command $params]]";
 100                 }
 101                 elsif ($onlystrip) {
 102                         return "";
 103                 }
 104                 elsif (exists $hooks{preprocess}{$command}) {
 105                         # Note: preserve order of params, some plugins may
 106                         # consider it significant.
 107                         my @params;
 108                         while ($params =~ /(\w+)=\"?([^"]+)"?(\s+|$)/g) {
 109                                 push @params, $1, $2;
 110                         }
 111                         return $hooks{preprocess}{$command}{call}->(@params, page => $page);
 112                 }
 113                 else {
 114                         return "[[$command not processed]]";
 115                 }
 116         };
 117
 118         $content =~ s{(\\?)$config{wiki_processor_regexp}}{$handle->($1, $2, $3)}eg;
 119         return $content;
 120 } #}}}
 121
 122 sub add_depends ($$) { #{{{
 123         my $page=shift;
 124         my $globlist=shift;
 125
 126         if (! exists $depends{$page}) {
 127                 $depends{$page}=$globlist;
 128         }
 129         else {
 130                 $depends{$page}=globlist_merge($depends{$page}, $globlist);
 131         }
 132 } # }}}
 133
 134 sub globlist_merge ($$) { #{{{
 135         my $a=shift;
 136         my $b=shift;
 137
 138         my $ret="";
 139         # Only add negated globs if they are not matched by the other globlist.
 140         foreach my $i ((map { [ $a, $_ ] } split(" ", $b)),
 141                        (map { [ $b, $_ ] } split(" ", $a))) {
 142                 if ($i->[1]=~/^!(.*)/) {
 143                         if (! globlist_match($1, $i->[0])) {
 144                                 $ret.=" ".$i->[1];
 145                         }
 146                 }
 147                 else {
 148                         $ret.=" ".$i->[1];
 149                 }
 150         }
 151
 152         return $ret;
 153 } #}}}
 154
 155 sub genpage ($$$) { #{{{
 156         my $page=shift;
 157         my $content=shift;
 158         my $mtime=shift;
 159
 160         my $template=template("page.tmpl", blind_cache => 1);
 161         my $actions=0;
 162
 163         if (length $config{cgiurl}) {
 164                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 165                 $template->param(prefsurl => cgiurl(do => "prefs"));
 166                 if ($config{rcs}) {
 167                         $template->param(recentchangesurl => cgiurl(do => "recentchanges"));
 168                 }
 169                 $actions++;
 170         }
 171
 172         if (length $config{historyurl}) {
 173                 my $u=$config{historyurl};
 174                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
 175                 $template->param(historyurl => $u);
 176                 $actions++;
 177         }
 178         if ($config{discussion}) {
 179                 $template->param(discussionlink => htmllink($page, $page, "Discussion", 1, 1));
 180                 $actions++;
 181         }
 182
 183         if ($actions) {
 184                 $template->param(have_actions => 1);
 185         }
 186
 187         $template->param(
 188                 title => $page eq 'index'
 189                         ? $config{wikiname}
 190                         : pagetitle(basename($page)),
 191                 wikiname => $config{wikiname},
 192                 parentlinks => [parentlinks($page)],
 193                 content => $content,
 194                 backlinks => [backlinks($page)],
 195                 mtime => displaytime($mtime),
 196                 styleurl => styleurl($page),
 197         );
 198
 199         if (exists $hooks{pagetemplate}) {
 200                 foreach my $id (keys %{$hooks{pagetemplate}}) {
 201                         $hooks{pagetemplate}{$id}{call}->($page, $template);
 202                 }
 203         }
 204
 205         return $template->output;
 206 } #}}}
 207
 208 sub check_overwrite ($$) { #{{{
 209         # Important security check. Make sure to call this before saving
 210         # any files to the source directory.
 211         my $dest=shift;
 212         my $src=shift;
 213
 214         if (! exists $renderedfiles{$src} && -e $dest && ! $config{rebuild}) {
 215                 error("$dest already exists and was not rendered from $src before");
 216         }
 217 } #}}}
 218
 219 sub displaytime ($) { #{{{
 220         my $time=shift;
 221
 222         eval q{use POSIX};
 223         # strftime doesn't know about encodings, so make sure
 224         # its output is properly treated as utf8
 225         return decode_utf8(POSIX::strftime(
 226                         $config{timeformat}, localtime($time)));
 227 } #}}}
 228
 229 sub mtime ($) { #{{{
 230         my $file=shift;
 231
 232         return (stat($file))[9];
 233 } #}}}
 234
 235 sub findlinks ($$) { #{{{
 236         my $page=shift;
 237         my $content=shift;
 238
 239         my @links;
 240         while ($content =~ /(?<!\\)$config{wiki_link_regexp}/g) {
 241                 push @links, titlepage($2);
 242         }
 243         if ($config{discussion}) {
 244                 # Discussion links are a special case since they're not in the
 245                 # text of the page, but on its template.
 246                 return @links, "$page/discussion";
 247         }
 248         else {
 249                 return @links;
 250         }
 251 } #}}}
 252
 253 sub filter ($$) {
 254         my $page=shift;
 255         my $content=shift;
 256
 257         if (exists $hooks{filter}) {
 258                 foreach my $id (keys %{$hooks{filter}}) {
 259                         $content=$hooks{filter}{$id}{call}->(
 260                                 page => $page,
 261                                 content => $content
 262                         );
 263                 }
 264         }
 265
 266         return $content;
 267 }
 268
 269 sub render ($) { #{{{
 270         my $file=shift;
 271
 272         my $type=pagetype($file);
 273         my $srcfile=srcfile($file);
 274         if (defined $type) {
 275                 my $content=readfile($srcfile);
 276                 my $page=pagename($file);
 277                 delete $depends{$page};
 278
 279                 $content=filter($page, $content);
 280
 281                 $links{$page}=[findlinks($page, $content)];
 282
 283                 $content=linkify($page, $page, $content);
 284                 $content=preprocess($page, $content);
 285                 $content=htmlize($type, $content);
 286
 287                 check_overwrite("$config{destdir}/".htmlpage($page), $page);
 288                 writefile(htmlpage($page), $config{destdir},
 289                         genpage($page, $content, mtime($srcfile)));
 290                 $oldpagemtime{$page}=time;
 291                 $renderedfiles{$page}=htmlpage($page);
 292         }
 293         else {
 294                 my $content=readfile($srcfile, 1);
 295                 $links{$file}=[];
 296                 delete $depends{$file};
 297                 check_overwrite("$config{destdir}/$file", $file);
 298                 writefile($file, $config{destdir}, $content, 1);
 299                 $oldpagemtime{$file}=time;
 300                 $renderedfiles{$file}=$file;
 301         }
 302 } #}}}
 303
 304 sub prune ($) { #{{{
 305         my $file=shift;
 306
 307         unlink($file);
 308         my $dir=dirname($file);
 309         while (rmdir($dir)) {
 310                 $dir=dirname($dir);
 311         }
 312 } #}}}
 313
 314 sub refresh () { #{{{
 315         # find existing pages
 316         my %exists;
 317         my @files;
 318         eval q{use File::Find};
 319         find({
 320                 no_chdir => 1,
 321                 wanted => sub {
 322                         $_=decode_utf8($_);
 323                         if (/$config{wiki_file_prune_regexp}/) {
 324                                 $File::Find::prune=1;
 325                         }
 326                         elsif (! -d $_ && ! -l $_) {
 327                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 328                                 if (! defined $f) {
 329                                         warn("skipping bad filename $_\n");
 330                                 }
 331                                 else {
 332                                         $f=~s/^\Q$config{srcdir}\E\/?//;
 333                                         push @files, $f;
 334                                         $exists{pagename($f)}=1;
 335                                 }
 336                         }
 337                 },
 338         }, $config{srcdir});
 339         find({
 340                 no_chdir => 1,
 341                 wanted => sub {
 342                         $_=decode_utf8($_);
 343                         if (/$config{wiki_file_prune_regexp}/) {
 344                                 $File::Find::prune=1;
 345                         }
 346                         elsif (! -d $_ && ! -l $_) {
 347                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 348                                 if (! defined $f) {
 349                                         warn("skipping bad filename $_\n");
 350                                 }
 351                                 else {
 352                                         # Don't add files that are in the
 353                                         # srcdir.
 354                                         $f=~s/^\Q$config{underlaydir}\E\/?//;
 355                                         if (! -e "$config{srcdir}/$f" &&
 356                                             ! -l "$config{srcdir}/$f") {
 357                                                 push @files, $f;
 358                                                 $exists{pagename($f)}=1;
 359                                         }
 360                                 }
 361                         }
 362                 },
 363         }, $config{underlaydir});
 364
 365         my %rendered;
 366
 367         # check for added or removed pages
 368         my @add;
 369         foreach my $file (@files) {
 370                 my $page=pagename($file);
 371                 if (! $oldpagemtime{$page}) {
 372                         debug("new page $page") unless exists $pagectime{$page};
 373                         push @add, $file;
 374                         $links{$page}=[];
 375                         $pagesources{$page}=$file;
 376                         if ($config{getctime} && -e "$config{srcdir}/$file") {
 377                                 $pagectime{$page}=rcs_getctime("$config{srcdir}/$file");
 378                         }
 379                         elsif (! exists $pagectime{$page}) {
 380                                 $pagectime{$page}=mtime(srcfile($file));
 381                         }
 382                 }
 383         }
 384         my @del;
 385         foreach my $page (keys %oldpagemtime) {
 386                 if (! $exists{$page}) {
 387                         debug("removing old page $page");
 388                         push @del, $pagesources{$page};
 389                         prune($config{destdir}."/".$renderedfiles{$page});
 390                         delete $renderedfiles{$page};
 391                         $oldpagemtime{$page}=0;
 392                         delete $pagesources{$page};
 393                 }
 394         }
 395
 396         # render any updated files
 397         foreach my $file (@files) {
 398                 my $page=pagename($file);
 399
 400                 if (! exists $oldpagemtime{$page} ||
 401                     mtime(srcfile($file)) > $oldpagemtime{$page}) {
 402                         debug("rendering $file");
 403                         render($file);
 404                         $rendered{$file}=1;
 405                 }
 406         }
 407
 408         # if any files were added or removed, check to see if each page
 409         # needs an update due to linking to them or inlining them.
 410         # TODO: inefficient; pages may get rendered above and again here;
 411         # problem is the bestlink may have changed and we won't know until
 412         # now
 413         if (@add || @del) {
 414 FILE:           foreach my $file (@files) {
 415                         my $page=pagename($file);
 416                         foreach my $f (@add, @del) {
 417                                 my $p=pagename($f);
 418                                 foreach my $link (@{$links{$page}}) {
 419                                         if (bestlink($page, $link) eq $p) {
 420                                                 debug("rendering $file, which links to $p");
 421                                                 render($file);
 422                                                 $rendered{$file}=1;
 423                                                 next FILE;
 424                                         }
 425                                 }
 426                         }
 427                 }
 428         }
 429
 430         # Handle backlinks; if a page has added/removed links, update the
 431         # pages it links to. Also handles rebuilding dependant pages.
 432         # TODO: inefficient; pages may get rendered above and again here;
 433         # problem is the backlinks could be wrong in the first pass render
 434         # above
 435         if (%rendered || @del) {
 436                 foreach my $f (@files) {
 437                         my $p=pagename($f);
 438                         if (exists $depends{$p}) {
 439                                 foreach my $file (keys %rendered, @del) {
 440                                         next if $f eq $file;
 441                                         my $page=pagename($file);
 442                                         if (globlist_match($page, $depends{$p})) {
 443                                                 debug("rendering $f, which depends on $page");
 444                                                 render($f);
 445                                                 $rendered{$f}=1;
 446                                                 last;
 447                                         }
 448                                 }
 449                         }
 450                 }
 451
 452                 my %linkchanged;
 453                 foreach my $file (keys %rendered, @del) {
 454                         my $page=pagename($file);
 455
 456                         if (exists $links{$page}) {
 457                                 foreach my $link (map { bestlink($page, $_) } @{$links{$page}}) {
 458                                         if (length $link &&
 459                                             (! exists $oldlinks{$page} ||
 460                                              ! grep { bestlink($page, $_) eq $link } @{$oldlinks{$page}})) {
 461                                                 $linkchanged{$link}=1;
 462                                         }
 463                                 }
 464                         }
 465                         if (exists $oldlinks{$page}) {
 466                                 foreach my $link (map { bestlink($page, $_) } @{$oldlinks{$page}}) {
 467                                         if (length $link &&
 468                                             (! exists $links{$page} ||
 469                                              ! grep { bestlink($page, $_) eq $link } @{$links{$page}})) {
 470                                                 $linkchanged{$link}=1;
 471                                         }
 472                                 }
 473                         }
 474                 }
 475                 foreach my $link (keys %linkchanged) {
 476                         my $linkfile=$pagesources{$link};
 477                         if (defined $linkfile) {
 478                                 debug("rendering $linkfile, to update its backlinks");
 479                                 render($linkfile);
 480                                 $rendered{$linkfile}=1;
 481                         }
 482                 }
 483         }
 484
 485         if (@del && exists $hooks{delete}) {
 486                 foreach my $id (keys %{$hooks{delete}}) {
 487                         $hooks{delete}{$id}{call}->(@del);
 488                 }
 489         }
 490         if (%rendered && exists $hooks{change}) {
 491                 foreach my $id (keys %{$hooks{change}}) {
 492                         $hooks{change}{$id}{call}->(keys %rendered);
 493                 }
 494         }
 495 } #}}}
 496
 497 1