IkiWiki/Plugin/table.pm

   1 package IkiWiki::Plugin::table;
   2 # by Victor Moral <victor@taquiones.net>
   3
   4 use warnings;
   5 use strict;
   6
   7 use IkiWiki;
   8 use IkiWiki::Plugin::mdwn;
   9
  10 my %defaults = (
  11         data    => undef,
  12         file    => undef,
  13         format  => 'auto',
  14         sep_char        =>  {
  15                 'csv'   => ',',
  16                 'dsv'   => '\|',
  17         },
  18         class   =>  undef,
  19         header  =>  1,
  20 );
  21
  22 sub import { #{{{
  23         hook(type => "preprocess", id => "table", call => \&preprocess);
  24 } # }}}
  25
  26 sub preprocess (@) { #{{{
  27         my %params = (%defaults, @_);
  28
  29         if (defined $params{delimiter}) {
  30                 $params{sep_char}->{$params{format}} = $params{delimiter};
  31         }
  32         if (defined $params{file}) {
  33                 if (! $pagesources{$params{file}}) {
  34                         return "[[table cannot find file]]";
  35                 }
  36                 $params{data} = readfile(srcfile($params{file}));
  37         }
  38
  39         if (lc $params{format} eq 'auto') {
  40                 # first try the more simple format
  41                 if (is_dsv_data($params{data})) {
  42                         $params{format} = 'dsv';
  43                         $params{sep_char}->{dsv} = '\|';
  44                 }
  45                 else {
  46                         $params{format} = 'csv';
  47                         $params{sep_char}->{csv} = ',';
  48                 }
  49         }
  50
  51         my @data;
  52         if (lc $params{format} eq 'csv') {
  53                 @data=read_csv(\%params);
  54         }
  55         elsif (lc $params{format} eq 'dsv') {
  56                 @data=read_dsv(\%params);
  57         }
  58         else {
  59                 return "[[table unknown data format]]";
  60         }
  61
  62         my $header;
  63         if ($params{header} != 1) {
  64                 $header=shift @data;
  65         }
  66         if (! @data) {
  67                 return "[[table has empty data]]";
  68         }
  69
  70         my $html = tidy_up(open_table(\%params, $header),
  71                         build_rows(\%params, @data),
  72                         close_table(\%params, $header));
  73
  74         if (defined $params{file}) {
  75                 return $html."\n\n".
  76                         htmllink($params{page}, $params{destpage}, $params{file},
  77                                 linktext => gettext('Direct data download'));
  78         }
  79         else {
  80                 return $html;
  81         }
  82 } #}}}
  83
  84 sub tidy_up (@) { #{{{
  85         my $html="";
  86
  87         foreach my $text (@_) {
  88                 my $indentation = $text =~ m{thead>|tbody>}   ? 0 :
  89                                   $text =~ m{tr>}             ? 4 :
  90                                   $text =~ m{td>|th>}         ? 8 :
  91                                                                 0;
  92                 $html .= (' ' x $indentation)."$text\n";
  93         }
  94
  95         return $html;
  96 } #}}}
  97
  98 sub is_dsv_data ($) { #{{{
  99         my $text = shift;
 100
 101         my ($line) = split(/\n/, $text);
 102         return $line =~ m{.+\|};
 103 }
 104
 105 sub read_csv ($) { #{{{
 106         my $params=shift;
 107         my @text_lines = split(/\n/, $params->{data});
 108
 109         eval q{use Text::CSV};
 110         error($@) if $@;
 111         my $csv = Text::CSV->new({
 112                 sep_char        => $params->{sep_char}->{csv},
 113                 binary          => 1,
 114         }) || error("could not create a Text::CSV object");
 115
 116         my $l=0;
 117         my @data;
 118         foreach my $line (@text_lines) {
 119                 $l++;
 120                 if ($csv->parse($line)) {
 121                         push(@data, [ $csv->fields() ]);
 122                 }
 123                 else {
 124                         debug(sprintf(gettext('parse fail at line %d: %s'),
 125                                 $l, $csv->error_input()));
 126                 }
 127         }
 128
 129         return @data;
 130 } #}}}
 131
 132 sub read_dsv ($) { #{{{
 133         my $params = shift;
 134         my @text_lines = split(/\n/, $params->{data});
 135
 136         my @data;
 137         my $splitter = qr{$params->{sep_char}->{dsv}};
 138         foreach my $line (@text_lines) {
 139                 push @data, [ split($splitter, $line) ];
 140         }
 141
 142         return @data;
 143 } #}}}
 144
 145 sub open_table ($$) { #{{{
 146         my $params = shift;
 147         my $header = shift;
 148
 149         my @items;
 150         push @items, defined $params->{class}
 151                         ? "<table class=\"".$params->{class}.'">'
 152                         : '<table>';
 153         push @items, '<thead>','<tr>',
 154                      (map { "<th>".htmlize($params, $_)."</th>" } @$header),
 155                      '</tr>','</thead>' if defined $header;
 156         push @items, '<tbody>';
 157
 158         return @items;
 159 }
 160
 161 sub build_rows ($@) { #{{{
 162         my $params = shift;
 163
 164         my @items;
 165         foreach my $record (@_) {
 166                 push @items, '<tr>',
 167                              (map { "<td>".htmlize($params, $_)."</td>" } @$record),
 168                              '</tr>';
 169         }
 170         return @items;
 171 } #}}}
 172
 173 sub close_table ($$) { #{{{
 174         my $params = shift;
 175         my $header = shift;
 176
 177         my @items;
 178         push @items, '</tbody>' if defined $header;
 179         push @items, '</table>';
 180         return @items;
 181 } #}}}
 182
 183 sub htmlize { #{{{
 184         my $params = shift;
 185         my $text = shift;
 186
 187         $text=IkiWiki::preprocess($params->{page},
 188                 $params->{destpage}, $text);
 189         $text=IkiWiki::htmlize($params->{page},
 190                 pagetype($pagesources{$params->{page}}), $text);
 191
 192         # hack to get rid of enclosing junk added by markdown
 193         $text=~s!^<p>!!;
 194         $text=~s!</p>$!!;
 195         chomp $text;
 196
 197         return $text;
 198 }
 199
 200 1